git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want mhe support?
  60 AC_ARG_ENABLE(mhe,
  61   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  62
  63 dnl mhe support is on by default, so define it unless --disable-mhe or the
  64 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  65 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  66   AC_DEFINE(MHE, 1,
  67     [Define to compile in support for the Emacs front-end mh-e.])dnl
  68 fi
  69
  70 dnl Do you want to disable use of locale functions
  71 AH_TEMPLATE([LOCALE],
  72 [Undefine if you don't want locale features.  By default this is defined.])
  73 AC_ARG_ENABLE([locale],
  74 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  75 [if test x$enableval = xyes; then
  76   AC_DEFINE(LOCALE)
  77 fi],
  78 AC_DEFINE(LOCALE)
  79 )
  80
  81 dnl What should be the default editor?
  82 AC_ARG_WITH(editor,
  83   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  84
  85 if test -n "$with_editor"; then
  86   editorpath="$with_editor"
  87 fi
  88
  89 dnl What method of locking to use?
  90 AC_ARG_WITH(locking,
  91   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  92   [specify the file locking method]))
  93
  94 if test x"$with_locking" = x"dot"; then
  95   LOCKTYPE="dot"
  96   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  97 elif test x"$with_locking" = x"flock"; then
  98   LOCKTYPE="flock"
  99   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 100 elif test x"$with_locking" = x"lockf"; then
 101   LOCKTYPE="lockf"
 102   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 103 elif test x"$with_locking" = x"fcntl"; then
 104   LOCKTYPE="fcntl"
 105   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 106 else
 107   LOCKTYPE="dot"
 108   AC_DEFINE(DOT_LOCKING)dnl
 109 fi
 110
 111 dnl What should be the default pager?
 112 AC_ARG_WITH(pager,
 113   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 114
 115 if test -n "$with_pager"; then
 116   pagerpath="$with_pager"
 117 fi
 118
 119 dnl ----------------------------------------------------
 120 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
 121 dnl ----------------------------------------------------
 122 AC_PREFIX_DEFAULT(/usr/local/mmh)
 123
 124
 125 dnl ------------------
 126 dnl CHECK THE COMPILER
 127 dnl ------------------
 128 dnl We want these before the checks,
 129 dnl so the checks can modify their values.
 130 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 131 if test x"$enable_debug" = x"yes"; then
 132   test -z "$LDFLAGS" && LDFLAGS=-g
 133 fi
 134
 135 AC_PROG_CC
 136
 137 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 138 [nmh_saved_cflags="$CFLAGS"
 139  CFLAGS="$CFLAGS -Wno-pointer-sign"
 140  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 141  CFLAGS="$nmh_saved_cflags"])
 142
 143 dnl if the user hasn't specified CFLAGS, then
 144 dnl   if compiler is gcc, then
 145 dnl     use -O2 and some warning flags
 146 dnl   else use -O
 147 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 148 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 149 dnl spurious and which in any case we don't want to deal with now.
 150 if test "$nmh_cv_has_noptrsign" = "yes"; then
 151         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 152 else
 153         nmh_gcc_warnflags="-Wall"
 154 fi
 155
 156 if test -n "$auto_cflags"; then
 157   if test x"$enable_debug" = x"yes"; then
 158     if test -n "$GCC"; then
 159       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 160     else
 161       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 162     fi
 163   else
 164     if test -z "$LDFLAGS"; then
 165       case "$build_os" in
 166         darwin*)
 167           LDFLAGS=
 168           ;;
 169         *)
 170           LDFLAGS=-s
 171           ;;
 172       esac
 173     fi
 174     if test -n "$GCC"; then
 175       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 176     else
 177       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 178     fi
 179   fi
 180 fi
 181
 182 AC_C_CONST              dnl Does compiler support `const'.
 183
 184 dnl ------------------
 185 dnl CHECK FOR PROGRAMS
 186 dnl ------------------
 187 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 188 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 189 AC_PROG_RANLIB          dnl Check for `ranlib'
 190 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 191 AC_PROG_LEX             dnl Check for lex/flex
 192
 193 dnl Look for `cut'
 194 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 195 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 196
 197 dnl ----------------------------------------------
 198 dnl check for lclint, and lint if it doesn't exist
 199 dnl ----------------------------------------------
 200 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 201 if test x$ac_cv_prog_linttmp1 != xno ; then
 202   LINT=$ac_cv_prog_linttmp1
 203   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 204 else
 205   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 206   if test x$ac_cv_prog_linttmp2 != xno ; then
 207     LINT=$ac_cv_prog_linttmp2
 208     LINTFLAGS=""
 209   else
 210     LINT="echo 'No lint program found'"
 211     LINTFLAGS=""
 212   fi
 213 fi
 214 AC_SUBST(LINT)dnl
 215 AC_SUBST(LINTFLAGS)dnl
 216
 217 dnl try to figure out which one we've got
 218 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 219 NMH_PROG_GNU_LIBTOOL
 220
 221 dnl Check for lorder and tsort commands
 222 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 223 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 224
 225 dnl If either doesn't exist, replace them with echo and cat
 226 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 227   LORDER=echo
 228   TSORT=cat
 229   AC_SUBST(LORDER)dnl
 230   AC_SUBST(TSORT)dnl
 231 dnl Mac OS X has lorder, but sh is too broken for it to work
 232 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 233 dnl   LORDER=echo
 234 dnl   TSORT=cat
 235 dnl   AC_SUBST(LORDER)dnl
 236 dnl   AC_SUBST(TSORT)dnl
 237 fi
 238
 239 dnl Check whether tsort can deal with loops
 240 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 241   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 242     nmh_cv_tsort_loop=no
 243   else
 244     nmh_cv_tsort_loop=yes
 245   fi])
 246 if test x$nmh_cv_tsort_loop = xno ; then
 247   LORDER=echo
 248   TSORT=cat
 249   AC_SUBST(LORDER)dnl
 250   AC_SUBST(TSORT)dnl
 251 fi
 252
 253 dnl Look for `ls'
 254 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 255 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 256
 257 dnl See how we get ls to display the owner and the group
 258 if test "$lspath" != "no"; then
 259   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 260                  nmh_cv_ls_grpopt,
 261   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 262     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 263     dnl ls, it would seem -l gave us both the user and group.  On this type of
 264     dnl ls, -g makes _only_ the group be displayed (and not the user).
 265     nmh_cv_ls_grpopt="-l"
 266   else
 267     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 268     nmh_cv_ls_grpopt="-lg"
 269   fi])
 270 fi
 271
 272 dnl Look for `more'
 273 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 274 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 275
 276 dnl If pager is not specified yet,
 277 dnl then use `more' as the default.
 278 if test -z "$pagerpath"; then
 279   pagerpath="$morepath"
 280 fi
 281 AC_SUBST(pagerpath)dnl
 282
 283 dnl Look for `sendmail'
 284 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 285 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 286
 287 dnl Look for `vi'
 288 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 289 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 290
 291 dnl If editor is not specified yet,
 292 dnl then use `vi' as the default.
 293 if test -z "$editorpath"; then
 294   editorpath="$vipath"
 295 fi
 296 AC_SUBST(editorpath)dnl
 297
 298 dnl ----------------------------------------------------------
 299 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 300 dnl ----------------------------------------------------------
 301 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 302 [for mailspool in /var/mail        dnl
 303                   /var/spool/mail  dnl
 304                   /usr/spool/mail  dnl
 305                   /dev/null;       dnl Just in case we fall through
 306 do
 307   test -d $mailspool && break
 308 done
 309 nmh_cv_mailspool=$mailspool
 310 ])
 311 mailspool=$nmh_cv_mailspool
 312 AC_SUBST(mailspool)dnl
 313
 314 dnl See whether the mail spool directory is world-writable.
 315 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 316   AC_CACHE_CHECK(whether the mail spool is world-writable,
 317                  nmh_cv_mailspool_world_writable,
 318   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 319     nmh_cv_mailspool_world_writable=no
 320   else
 321     nmh_cv_mailspool_world_writable=yes
 322   fi])
 323 fi
 324
 325 dnl Also, check for liblockfile (as found on Debian systems)
 326 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 327
 328 dnl and whether its companion program dotlockfile is setgid
 329 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 330 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 331   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 332     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 333     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 334         nmh_cv_dotlockfile_setgid=yes
 335       else
 336         nmh_cv_dotlockfile_setgid=no
 337       fi])
 338   fi
 339 fi
 340
 341 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 342 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 343 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 344   dnl do we really need both of these?
 345   AC_DEFINE(MAILGROUP,1,
 346     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 347   SETGID_MAIL=1
 348 fi
 349 AC_SUBST(SETGID_MAIL)dnl
 350
 351 dnl Use ls to see which group owns the mail spool directory.
 352 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 353 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 354 ])
 355 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 356 AC_SUBST(MAIL_SPOOL_GRP)dnl
 357
 358 dnl ------------------
 359 dnl CHECK HEADER FILES
 360 dnl ------------------
 361
 362 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 363 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 364 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 365 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 366 dnl declared; if so they should have an entry added to this case statement.
 367 dnl NB that we must define this on the compiler command line, not in config.h,
 368 dnl because it must be set before any system header is included and there's no
 369 dnl portable way to make sure that files generated by lex include config.h
 370 dnl before system header files.
 371
 372 case "$target_os" in
 373   linux*)
 374     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 375     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 376     ;;
 377 esac
 378 AC_SUBST(OURDEFS)
 379
 380 AC_HEADER_DIRENT
 381 AC_HEADER_STDC
 382 AC_HEADER_TIME
 383 AC_HEADER_SYS_WAIT
 384 AC_HEADER_STAT
 385 AC_HEADER_TIOCGWINSZ
 386 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 387                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 388                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 389                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 390                  arpa/inet.h arpa/ftp.h)
 391
 392 dnl
 393 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 394 dnl really use a whole set of them, but this check should be
 395 dnl sufficient.
 396 dnl
 397 AC_CHECK_HEADER(libio.h, [
 398   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 399     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 400
 401 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 402   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 403 [[#if HAVE_SYS_STREAM_H
 404 #  include <sys/stream.h>
 405 #endif
 406 ]])
 407
 408 dnl ---------------
 409 dnl CHECK FUNCTIONS
 410 dnl ---------------
 411 AC_FUNC_VFORK
 412 AC_CHECK_LIB(mkstemp,mkstemp)
 413 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 414                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 415                getutent nl_langinfo mbtowc wcwidth)
 416
 417 dnl sigsetjmp may be a macro
 418 AC_MSG_CHECKING(for sigsetjmp)
 419 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 420   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 421     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 422   [AC_MSG_RESULT(no)])
 423
 424 AC_REPLACE_FUNCS(memmove snprintf strerror strdup)
 425
 426 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 427 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 428 dnl any system header.
 429 dnl
 430 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 431 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 432 dnl need to check?
 433 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 434 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 435                 AC_EGREP_HEADER(initgroups, unistd.h,
 436                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 437
 438 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 439 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 440 dnl seems to work perfectly and IBM apparently uses it in internal code).
 441 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 442 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 443 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 444 dnl prototype.
 445 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 446   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 447
 448 dnl Check for multibyte character set support
 449 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 450     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 451   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 452     [Define to enable support for multibyte character sets.])
 453 fi
 454
 455 dnl -------------------
 456 dnl CHECK FOR LIBRARIES
 457 dnl -------------------
 458 dnl Check location of modf
 459 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 460
 461 dnl Checks for network libraries (nsl, socket)
 462 AC_CHECK_NETLIBS
 463
 464 termcap_curses_order="termcap curses ncurses"
 465 for lib in $termcap_curses_order; do
 466   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 467 done
 468 AC_SUBST(TERMLIB)dnl
 469
 470 dnl ---------------
 471 dnl CHECK FOR ICONV
 472 dnl ---------------
 473
 474 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 475 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 476   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 477   if test "x$ac_found_iconv" = "xno"; then
 478     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 479     if test "x$ac_found_iconv" = "xno"; then
 480       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 481     fi
 482     if test "x$ac_found_iconv" != "xno"; then
 483       LIBS="-liconv $LIBS"
 484     fi
 485   else
 486     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 487     AC_CHECK_DECL(_libiconv_version,
 488       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 489       [ #include <iconv.h> ])
 490   fi
 491 fi
 492 if test "x$ac_found_iconv" = xyes; then
 493   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 494 fi
 495
 496 dnl Check if iconv uses const in prototype declaration
 497 if test "x$ac_found_iconv" = "xyes"; then
 498   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 499     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 500         #include <iconv.h>]],
 501         [[#ifdef __cplusplus
 502           "C"
 503           #endif
 504           #if defined(__STDC__) || defined(__cplusplus)
 505           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 506           #else
 507           size_t iconv();
 508           #endif]])],
 509       [ac_cv_iconv_const=],
 510       [ac_cv_iconv_const=const])])
 511   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 512     [Define as const if the declaration of iconv() needs const.])
 513 fi
 514
 515 dnl --------------
 516 dnl CHECK FOR NDBM
 517 dnl --------------
 518
 519 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 520             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 521 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 522             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 523
 524 if test "$nmh_ndbm" = "autodetect"; then
 525   if test "$nmh_ndbmheader" != "autodetect"; then
 526     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 527   else
 528
 529     dnl There are at least four implementations of ndbm, and
 530     dnl several of those can be in different places at the whim
 531     dnl of the system integrator. A good summary of this mess
 532     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 533
 534     dnl Classic ndbm with no library required (eg NetBSD): try this
 535     dnl first so we don't accidentally link in a pointless but harmless
 536     dnl library in one of the later ndbm.h+libfoo tests:
 537     NMH_CHECK_NDBM(ndbm.h,,,
 538     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 539       NMH_CHECK_NDBM(db.h,db,,
 540     dnl Berkeley DBv1 emulating ndbm:
 541         NMH_CHECK_NDBM(ndbm.h,db,,
 542           NMH_CHECK_NDBM(ndbm.h,db1,,
 543     dnl Classic ndbm:
 544             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 545     dnl glibc2.1 systems put db1 in a subdir:
 546               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 547     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 548     dnl and possibly needing gbdm_compat library:
 549                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 550                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 551                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 552                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 553
 554   fi
 555 else
 556   dnl We don't really need to check that the user-specified values work,
 557   dnl but it is a convenience to the user to bomb out early rather than
 558   dnl after configure and half the compile process.
 559   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 560 fi
 561
 562 if test "$nmh_ndbm_found" = "no"; then
 563   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 564 else
 565   dnl Now export the lib/header to our makefile/config.h:
 566   if test x"$nmh_ndbmheader" != x; then
 567     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 568       [Define to the header containing the ndbm API prototypes.])
 569   fi
 570   if test x"$nmh_ndbm" != x; then
 571     NDBM_LIBS="-l$nmh_ndbm"
 572   else
 573     NDBM_LIBS=
 574   fi
 575   AC_SUBST(NDBM_LIBS)
 576 fi
 577
 578
 579 dnl ---------------------
 580 dnl CHECK TERMCAP LIBRARY
 581 dnl ---------------------
 582
 583 dnl Add the termcap library, so that the following configure
 584 dnl tests will find it when it tries to link test programs.
 585 nmh_save_LIBS="$LIBS"
 586 LIBS="$TERMLIB $LIBS"
 587
 588 dnl Checks for external variable ospeed in the termcap library.
 589 AC_CACHE_CHECK(if an include file defines ospeed,
 590 nmh_cv_decl_ospeed_include_defines,
 591 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 592 #if HAVE_TERMIOS_H
 593 #include <termios.h>
 594 #endif
 595 #if HAVE_TERMCAP_H
 596 #include <termcap.h>
 597 #endif]], [[ospeed = 0;]])],
 598 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 599
 600 if test $nmh_cv_decl_ospeed_include_defines = no; then
 601   AC_CACHE_CHECK(if you must define ospeed,
 602   nmh_cv_decl_ospeed_must_define,
 603   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 604   [[extern short ospeed; ospeed = 0;]])],
 605   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 606 fi
 607
 608 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 609 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 610   AC_DEFINE(HAVE_OSPEED)dnl
 611 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 612   AC_DEFINE(HAVE_OSPEED)
 613   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 614     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 615 fi
 616
 617 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 618 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 619 dnl in tgetstr().
 620 dnl Under Cygwin test program crashes but exit code is still 0. So,
 621 dnl we test for a file that porgram should create
 622 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 623 [Define to 1 if tgetent() accepts NULL as a buffer.])
 624 AC_CACHE_CHECK(if tgetent accepts NULL,
 625 nmh_cv_func_tgetent_accepts_null,
 626 [AC_TRY_RUN([
 627 main()
 628 {
 629     char buf[4096];
 630     int r1 = tgetent(buf, "vt100");
 631     int r2 = tgetent((char*)0,"vt100");
 632     if (r1 >= 0 && r1 == r2) {
 633         char tbuf[1024], *u;
 634         u = tbuf;
 635         tgetstr("cl", &u);
 636         creat("conftest.tgetent", 0640);
 637     }
 638     exit((r1 != r2) || r2 == -1);
 639 }
 640 ],
 641   if test -f conftest.tgetent; then
 642     nmh_cv_func_tgetent_accepts_null=yes
 643   else
 644     nmh_cv_func_tgetent_accepts_null=no
 645   fi,
 646   nmh_cv_func_tgetent_accepts_null=no,
 647   nmh_cv_func_tgetent_accepts_null=no)])
 648 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 649   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 650 fi
 651 AC_CACHE_CHECK(if tgetent returns 0 on success,
 652 nmh_cv_func_tgetent_zero_success,
 653 [AC_TRY_RUN([
 654 main()
 655 {
 656     char buf[4096];
 657     int r1 = tgetent(buf, "!@#$%^&*");
 658     int r2 = tgetent(buf, "vt100");
 659     if (r1 < 0 && r2 == 0) {
 660         char tbuf[1024], *u;
 661         u = tbuf;
 662         tgetstr("cl", &u);
 663         creat("conftest.tgetent0", 0640);
 664     }
 665     exit(r1 == r2);
 666 }
 667 ],
 668   if test -f conftest.tgetent0; then
 669     nmh_cv_func_tgetent_zero_success=yes
 670   else
 671     nmh_cv_func_tgetent_zero_success=no
 672   fi,
 673   nmh_cv_func_tgetent_zero_success=no,
 674   nmh_cv_func_tgetent_zero_success=no)])
 675 AH_TEMPLATE([TGETENT_SUCCESS],
 676 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 677 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 678   AC_DEFINE(TGETENT_SUCCESS, 0)
 679 else
 680   AC_DEFINE(TGETENT_SUCCESS, 1)
 681 fi
 682
 683 dnl Now put the libraries back to what it was before we
 684 dnl starting checking the termcap library.
 685 LIBS="$nmh_save_LIBS"
 686
 687 dnl --------------
 688 dnl CHECK TYPEDEFS
 689 dnl --------------
 690 AC_TYPE_SIGNAL
 691 AC_TYPE_PID_T
 692 AC_TYPE_OFF_T
 693 AC_TYPE_UID_T
 694 AC_TYPE_MODE_T
 695 AC_TYPE_SIZE_T
 696
 697 dnl Check for sigset_t.  Currently I'm looking in
 698 dnl <sys/types.h> and <signal.h>.  Others might need
 699 dnl to be added.
 700 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 701 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 702 #include <signal.h>]], [[sigset_t tempsigset;]])],
 703 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 704 if test $nmh_cv_type_sigset_t = no; then
 705   AC_DEFINE(sigset_t, unsigned int,
 706     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 707 fi
 708
 709 dnl ----------------
 710 dnl CHECK STRUCTURES
 711 dnl ----------------
 712 AC_CHECK_MEMBERS(struct stat.st_blksize)
 713
 714 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 715   [#ifdef TIME_WITH_SYS_TIME
 716 # include <sys/time.h>
 717 # include <time.h>
 718 #else
 719 # ifdef TM_IN_SYS_TIME
 720 #  include <sys/time.h>
 721 # else
 722 #  include <time.h>
 723 # endif
 724 #endif])
 725
 726 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 727
 728 AC_MSG_CHECKING(for union wait)
 729 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 730   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 731 #include <sys/wait.h>]],
 732     [[union wait status; int pid; pid = wait (&status);
 733 #ifdef WEXITSTATUS
 734 /* Some POSIXoid systems have both the new-style macros and the old
 735    union wait type, and they do not work together.  If union wait
 736    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 737         if (WEXITSTATUS (status) != 0) pid = -1;
 738 #ifdef WTERMSIG
 739         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 740         -- blow chunks here --
 741 #endif
 742 #endif
 743 #ifdef HAVE_WAITPID
 744         /* Make sure union wait works with waitpid.  */
 745         pid = waitpid (-1, &status, 0);
 746 #endif
 747       ]])],
 748     [nmh_cv_union_wait=yes],
 749     [nmh_cv_union_wait=no])])
 750 if test "$nmh_cv_union_wait" = yes; then
 751   AC_DEFINE(HAVE_UNION_WAIT, 1,
 752     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 753 fi
 754 AC_MSG_RESULT($nmh_cv_union_wait)
 755
 756 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 757
 758 dnl -------------
 759 dnl CHECK SIGNALS
 760 dnl -------------
 761 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 762 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 763 AC_MSG_CHECKING(what style of signals to use)
 764 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 765   signals_style=POSIX_SIGNALS
 766   AC_DEFINE(POSIX_SIGNALS, 1,
 767     [Define to 1 if you use POSIX style signal handling.])
 768   AC_DEFINE(RELIABLE_SIGNALS)
 769 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 770   signals_style=BSD_SIGNALS
 771   AC_DEFINE(BSD_SIGNALS,1,
 772     [Define to 1 if you use BSD style signal handling (and can block signals).])
 773   AC_DEFINE(RELIABLE_SIGNALS)
 774 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 775   signals_style=SYSV_SIGNALS
 776   AC_DEFINE(SYSV_SIGNALS,1,
 777     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 778 else
 779   signals_style=NO_SIGNAL_BLOCKING
 780   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 781     [Define to 1 if you have no signal blocking at all (bummer).])
 782 fi
 783
 784 AC_MSG_RESULT($signals_style)
 785
 786 dnl Where is <signal.h> located?  Needed as input for signames.awk
 787 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 788 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 789                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 790                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 791                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 792                  /usr/include/sys/signal.h      dnl Almost everybody else
 793                  /dev/null;                     dnl Just in case we fall through
 794 do
 795   test -f $SIGNAL_H && \
 796   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 797   break
 798 done
 799 nmh_cv_path_signal_h=$SIGNAL_H
 800 ])
 801 SIGNAL_H=$nmh_cv_path_signal_h
 802 AC_SUBST(SIGNAL_H)dnl
 803
 804 dnl ----------------
 805 dnl OS SPECIFIC DEFINES
 806 dnl ----------------
 807 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 808 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 809 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 810 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 811 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 812
 813 case "$target_os" in
 814
 815   solaris2*)
 816     AC_DEFINE(SYS5)
 817     AC_DEFINE(SVR4)
 818     ;;
 819   irix*)
 820     AC_DEFINE(SYS5)
 821     AC_DEFINE(SVR4)
 822     ;;
 823   osf*)
 824     AC_DEFINE(SYS5)
 825     AC_DEFINE(SVR4)
 826     ;;
 827   aix*)
 828     AC_DEFINE(SYS5)
 829     AC_DEFINE(SVR4)
 830     ;;
 831   sunos4*)
 832     AC_DEFINE(BSD42)
 833     ;;
 834   freebsd*)
 835     AC_DEFINE(BSD42)
 836     AC_DEFINE(BSD44)
 837     ;;
 838   netbsd*)
 839     AC_DEFINE(BSD42)
 840     AC_DEFINE(BSD44)
 841     ;;
 842   openbsd*)
 843     AC_DEFINE(BSD42)
 844     AC_DEFINE(BSD44)
 845     ;;
 846   bsd/os*)
 847     AC_DEFINE(BSD42)
 848     AC_DEFINE(BSD44)
 849     ;;
 850   sco5*)
 851     AC_DEFINE(SYS5)
 852     AC_DEFINE(SCO_5_STDIO)
 853     ;;
 854 esac
 855
 856
 857 dnl ----------------
 858 dnl OUTPUT MAKEFILES
 859 dnl ----------------
 860 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 861                 etc/Makefile docs/Makefile man/Makefile)
 862 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 863 AC_OUTPUT
 864
 865 dnl These odd looking assignments are done to expand out unexpanded
 866 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 867 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 868 dnl again to get the final answer.
 869 dnl We only use the expanded versions to print the install paths in
 870 dnl the final summary and should use them nowhere else (see the autoconf
 871 dnl docs for the rationale for bindir etc being unexpanded).
 872 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 873 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 874 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 875 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 876
 877 echo "
 878 nmh configuration
 879 -----------------
 880 nmh version            : AC_PACKAGE_VERSION
 881 target os              : ${target}
 882 compiler               : ${CC}
 883 compiler flags         : ${CFLAGS}
 884 linker flags           : ${LDFLAGS}
 885 definitions            : ${OURDEFS}
 886 source code location   : ${srcdir}
 887
 888 binary install path    : ${nmhbin}
 889 library install path   : ${nmhlib}
 890 config install path    : ${nmhsysconf}
 891 man page install path  : ${nmhman}
 892
 893 default editor         : ${editorpath}
 894 default pager          : ${pagerpath}
 895 sendmail               : ${sendmailpath}
 896
 897 file locking type      : ${LOCKTYPE}
 898 email address masq.    : ${masquerade}
 899 "