git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for mmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of mmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for mmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug mmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want mhe support?
  60 AC_ARG_ENABLE(mhe,
  61   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  62
  63 dnl mhe support is on by default, so define it unless --disable-mhe or the
  64 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  65 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  66   AC_DEFINE(MHE, 1,
  67     [Define to compile in support for the Emacs front-end mh-e.])dnl
  68 fi
  69
  70 dnl Do you want to disable use of locale functions
  71 AH_TEMPLATE([LOCALE],
  72 [Undefine if you don't want locale features.  By default this is defined.])
  73 AC_ARG_ENABLE([locale],
  74 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  75 [if test x$enableval = xyes; then
  76   AC_DEFINE(LOCALE)
  77 fi],
  78 AC_DEFINE(LOCALE)
  79 )
  80
  81 dnl What method of locking to use?
  82 AC_ARG_WITH(locking,
  83   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  84   [specify the file locking method]))
  85
  86 if test x"$with_locking" = x"dot"; then
  87   LOCKTYPE="dot"
  88   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  89 elif test x"$with_locking" = x"flock"; then
  90   LOCKTYPE="flock"
  91   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  92 elif test x"$with_locking" = x"lockf"; then
  93   LOCKTYPE="lockf"
  94   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  95 elif test x"$with_locking" = x"fcntl"; then
  96   LOCKTYPE="fcntl"
  97   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  98 else
  99   LOCKTYPE="dot"
 100   AC_DEFINE(DOT_LOCKING)dnl
 101 fi
 102
 103 dnl What should be the default pager?
 104 AC_ARG_WITH(pager,
 105   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 106
 107 if test -n "$with_pager"; then
 108   pagerpath="$with_pager"
 109 fi
 110
 111 dnl ----------------------------------------------------
 112 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
 113 dnl ----------------------------------------------------
 114 AC_PREFIX_DEFAULT(/usr/local/mmh)
 115
 116
 117 dnl ------------------
 118 dnl CHECK THE COMPILER
 119 dnl ------------------
 120 dnl We want these before the checks,
 121 dnl so the checks can modify their values.
 122 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 123 if test x"$enable_debug" = x"yes"; then
 124   test -z "$LDFLAGS" && LDFLAGS=-g
 125 fi
 126
 127 AC_PROG_CC
 128
 129 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 130 [nmh_saved_cflags="$CFLAGS"
 131  CFLAGS="$CFLAGS -Wno-pointer-sign"
 132  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 133  CFLAGS="$nmh_saved_cflags"])
 134
 135 dnl if the user hasn't specified CFLAGS, then
 136 dnl   if compiler is gcc, then
 137 dnl     use -O2 and some warning flags
 138 dnl   else use -O
 139 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 140 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 141 dnl spurious and which in any case we don't want to deal with now.
 142 if test "$nmh_cv_has_noptrsign" = "yes"; then
 143   nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 144 else
 145   nmh_gcc_warnflags="-Wall"
 146 fi
 147
 148 if test -n "$auto_cflags"; then
 149   if test x"$enable_debug" = x"yes"; then
 150     if test -n "$GCC"; then
 151       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 152     else
 153       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 154     fi
 155   else
 156     if test -z "$LDFLAGS"; then
 157       case "$build_os" in
 158         darwin*)
 159           LDFLAGS=
 160           ;;
 161         *)
 162           LDFLAGS=-s
 163           ;;
 164       esac
 165     fi
 166     if test -n "$GCC"; then
 167       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 168     else
 169       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 170     fi
 171   fi
 172 fi
 173
 174 AC_C_CONST          dnl Does compiler support `const'.
 175
 176 dnl ------------------
 177 dnl CHECK FOR PROGRAMS
 178 dnl ------------------
 179 AC_PROG_MAKE_SET    dnl Does make define $MAKE
 180 AC_PROG_INSTALL     dnl Check for BSD compatible `install'
 181 AC_PROG_RANLIB      dnl Check for `ranlib'
 182 AC_PROG_AWK         dnl Check for mawk,gawk,nawk, then awk
 183 AC_PROG_LEX         dnl Check for lex/flex
 184
 185 dnl Look for `cut'
 186 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 187 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 188
 189 dnl ----------------------------------------------
 190 dnl check for lclint, and lint if it doesn't exist
 191 dnl ----------------------------------------------
 192 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 193 if test x$ac_cv_prog_linttmp1 != xno ; then
 194   LINT=$ac_cv_prog_linttmp1
 195   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 196 else
 197   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 198   if test x$ac_cv_prog_linttmp2 != xno ; then
 199     LINT=$ac_cv_prog_linttmp2
 200     LINTFLAGS=""
 201   else
 202     LINT="echo 'No lint program found'"
 203     LINTFLAGS=""
 204   fi
 205 fi
 206 AC_SUBST(LINT)dnl
 207 AC_SUBST(LINTFLAGS)dnl
 208
 209 dnl try to figure out which one we've got
 210 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 211 NMH_PROG_GNU_LIBTOOL
 212
 213 dnl Check for lorder and tsort commands
 214 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 215 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 216
 217 dnl If either doesn't exist, replace them with echo and cat
 218 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 219   LORDER=echo
 220   TSORT=cat
 221   AC_SUBST(LORDER)dnl
 222   AC_SUBST(TSORT)dnl
 223 dnl Mac OS X has lorder, but sh is too broken for it to work
 224 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 225 dnl   LORDER=echo
 226 dnl   TSORT=cat
 227 dnl   AC_SUBST(LORDER)dnl
 228 dnl   AC_SUBST(TSORT)dnl
 229 fi
 230
 231 dnl Check whether tsort can deal with loops
 232 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 233   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 234     nmh_cv_tsort_loop=no
 235   else
 236     nmh_cv_tsort_loop=yes
 237   fi])
 238 if test x$nmh_cv_tsort_loop = xno ; then
 239   LORDER=echo
 240   TSORT=cat
 241   AC_SUBST(LORDER)dnl
 242   AC_SUBST(TSORT)dnl
 243 fi
 244
 245 dnl Look for `ls'
 246 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 247 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 248
 249 dnl See how we get ls to display the owner and the group
 250 if test "$lspath" != "no"; then
 251   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 252                  nmh_cv_ls_grpopt,
 253   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 254     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 255     dnl ls, it would seem -l gave us both the user and group.  On this type of
 256     dnl ls, -g makes _only_ the group be displayed (and not the user).
 257     nmh_cv_ls_grpopt="-l"
 258   else
 259     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 260     nmh_cv_ls_grpopt="-lg"
 261   fi])
 262 fi
 263
 264 dnl Look for `sendmail'
 265 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 266 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 267
 268 dnl Look for `vi'
 269 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 270 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 271
 272 dnl ----------------------------------------------------------
 273 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 274 dnl ----------------------------------------------------------
 275 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 276 [for mailspool in /var/mail        dnl
 277                   /var/spool/mail  dnl
 278                   /usr/spool/mail  dnl
 279                   /dev/null;       dnl Just in case we fall through
 280 do
 281   test -d $mailspool && break
 282 done
 283 nmh_cv_mailspool=$mailspool
 284 ])
 285 mailspool=$nmh_cv_mailspool
 286 AC_SUBST(mailspool)dnl
 287
 288 dnl See whether the mail spool directory is world-writable.
 289 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 290   AC_CACHE_CHECK(whether the mail spool is world-writable,
 291                  nmh_cv_mailspool_world_writable,
 292   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 293     nmh_cv_mailspool_world_writable=no
 294   else
 295     nmh_cv_mailspool_world_writable=yes
 296   fi])
 297 fi
 298
 299 dnl Also, check for liblockfile (as found on Debian systems)
 300 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 301
 302 dnl and whether its companion program dotlockfile is setgid
 303 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 304 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 305   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 306     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 307     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 308         nmh_cv_dotlockfile_setgid=yes
 309       else
 310         nmh_cv_dotlockfile_setgid=no
 311       fi])
 312   fi
 313 fi
 314
 315 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 316 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 317 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 318   dnl do we really need both of these?
 319   AC_DEFINE(MAILGROUP,1,
 320     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 321   SETGID_MAIL=1
 322 fi
 323 AC_SUBST(SETGID_MAIL)dnl
 324
 325 dnl Use ls to see which group owns the mail spool directory.
 326 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 327 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 328 ])
 329 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 330 AC_SUBST(MAIL_SPOOL_GRP)dnl
 331
 332 dnl ------------------
 333 dnl CHECK HEADER FILES
 334 dnl ------------------
 335
 336 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 337 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 338 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 339 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 340 dnl declared; if so they should have an entry added to this case statement.
 341 dnl NB that we must define this on the compiler command line, not in config.h,
 342 dnl because it must be set before any system header is included and there's no
 343 dnl portable way to make sure that files generated by lex include config.h
 344 dnl before system header files.
 345
 346 case "$target_os" in
 347   linux*)
 348     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 349     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 350     ;;
 351 esac
 352 AC_SUBST(OURDEFS)
 353
 354 AC_HEADER_DIRENT
 355 AC_HEADER_STDC
 356 AC_HEADER_TIME
 357 AC_HEADER_SYS_WAIT
 358 AC_HEADER_STAT
 359 AC_HEADER_TIOCGWINSZ
 360 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 361                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 362                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 363                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 364                  arpa/inet.h arpa/ftp.h)
 365
 366 dnl
 367 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 368 dnl really use a whole set of them, but this check should be
 369 dnl sufficient.
 370 dnl
 371 AC_CHECK_HEADER(libio.h, [
 372   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 373     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 374
 375 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 376   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 377 [[#if HAVE_SYS_STREAM_H
 378 #  include <sys/stream.h>
 379 #endif
 380 ]])
 381
 382 dnl ---------------
 383 dnl CHECK FUNCTIONS
 384 dnl ---------------
 385 AC_FUNC_VFORK
 386 AC_CHECK_LIB(mkstemp,mkstemp)
 387 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 388                sighold sigrelse lstat uname tzset killpg mkstemp \
 389                getutent nl_langinfo mbtowc wcwidth)
 390
 391 dnl sigsetjmp may be a macro
 392 AC_MSG_CHECKING(for sigsetjmp)
 393 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 394   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 395     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 396   [AC_MSG_RESULT(no)])
 397
 398 AC_REPLACE_FUNCS(snprintf strdup)
 399
 400 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 401 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 402 dnl any system header.
 403 dnl
 404 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 405 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 406 dnl need to check?
 407 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 408 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 409                 AC_EGREP_HEADER(initgroups, unistd.h,
 410                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 411
 412 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 413 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 414 dnl seems to work perfectly and IBM apparently uses it in internal code).
 415 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 416 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 417 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 418 dnl prototype.
 419 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 420   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 421
 422 dnl Check for multibyte character set support
 423 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 424     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 425   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 426     [Define to enable support for multibyte character sets.])
 427 fi
 428
 429 dnl -------------------
 430 dnl CHECK FOR LIBRARIES
 431 dnl -------------------
 432 dnl Check location of modf
 433 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 434
 435 dnl Checks for network libraries (nsl, socket)
 436 AC_CHECK_NETLIBS
 437
 438 termcap_curses_order="termcap curses ncurses"
 439 for lib in $termcap_curses_order; do
 440   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 441 done
 442 AC_SUBST(TERMLIB)dnl
 443
 444 dnl ---------------
 445 dnl CHECK FOR ICONV
 446 dnl ---------------
 447
 448 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 449 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 450   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 451   if test "x$ac_found_iconv" = "xno"; then
 452     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 453     if test "x$ac_found_iconv" = "xno"; then
 454       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 455     fi
 456     if test "x$ac_found_iconv" != "xno"; then
 457       LIBS="-liconv $LIBS"
 458     fi
 459   else
 460     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 461     AC_CHECK_DECL(_libiconv_version,
 462       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 463       [ #include <iconv.h> ])
 464   fi
 465 fi
 466 if test "x$ac_found_iconv" = xyes; then
 467   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 468 fi
 469
 470 dnl Check if iconv uses const in prototype declaration
 471 if test "x$ac_found_iconv" = "xyes"; then
 472   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 473     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 474         #include <iconv.h>]],
 475         [[#ifdef __cplusplus
 476           "C"
 477           #endif
 478           #if defined(__STDC__) || defined(__cplusplus)
 479           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 480           #else
 481           size_t iconv();
 482           #endif]])],
 483       [ac_cv_iconv_const=],
 484       [ac_cv_iconv_const=const])])
 485   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 486     [Define as const if the declaration of iconv() needs const.])
 487 fi
 488
 489 dnl --------------
 490 dnl CHECK FOR NDBM
 491 dnl --------------
 492
 493 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 494             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 495 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 496             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 497
 498 if test "$nmh_ndbm" = "autodetect"; then
 499   if test "$nmh_ndbmheader" != "autodetect"; then
 500     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 501   else
 502
 503     dnl There are at least four implementations of ndbm, and
 504     dnl several of those can be in different places at the whim
 505     dnl of the system integrator. A good summary of this mess
 506     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 507
 508     dnl Classic ndbm with no library required (eg NetBSD): try this
 509     dnl first so we don't accidentally link in a pointless but harmless
 510     dnl library in one of the later ndbm.h+libfoo tests:
 511     NMH_CHECK_NDBM(ndbm.h,,,
 512     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 513       NMH_CHECK_NDBM(db.h,db,,
 514     dnl Berkeley DBv1 emulating ndbm:
 515         NMH_CHECK_NDBM(ndbm.h,db,,
 516           NMH_CHECK_NDBM(ndbm.h,db1,,
 517     dnl Classic ndbm:
 518             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 519     dnl glibc2.1 systems put db1 in a subdir:
 520               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 521     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 522     dnl and possibly needing gbdm_compat library:
 523                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 524                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 525                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 526                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 527
 528   fi
 529 else
 530   dnl We don't really need to check that the user-specified values work,
 531   dnl but it is a convenience to the user to bomb out early rather than
 532   dnl after configure and half the compile process.
 533   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 534 fi
 535
 536 if test "$nmh_ndbm_found" = "no"; then
 537   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 538 else
 539   dnl Now export the lib/header to our makefile/config.h:
 540   if test x"$nmh_ndbmheader" != x; then
 541     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 542       [Define to the header containing the ndbm API prototypes.])
 543   fi
 544   if test x"$nmh_ndbm" != x; then
 545     NDBM_LIBS="-l$nmh_ndbm"
 546   else
 547     NDBM_LIBS=
 548   fi
 549   AC_SUBST(NDBM_LIBS)
 550 fi
 551
 552
 553 dnl ---------------------
 554 dnl CHECK TERMCAP LIBRARY
 555 dnl ---------------------
 556
 557 dnl Add the termcap library, so that the following configure
 558 dnl tests will find it when it tries to link test programs.
 559 nmh_save_LIBS="$LIBS"
 560 LIBS="$TERMLIB $LIBS"
 561
 562 dnl Checks for external variable ospeed in the termcap library.
 563 AC_CACHE_CHECK(if an include file defines ospeed,
 564 nmh_cv_decl_ospeed_include_defines,
 565 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 566 #if HAVE_TERMIOS_H
 567 # include <termios.h>
 568 #endif
 569 #if HAVE_TERMCAP_H
 570 # include <termcap.h>
 571 #endif]], [[ospeed = 0;]])],
 572 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 573
 574 if test $nmh_cv_decl_ospeed_include_defines = no; then
 575   AC_CACHE_CHECK(if you must define ospeed,
 576   nmh_cv_decl_ospeed_must_define,
 577   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 578   [[extern short ospeed; ospeed = 0;]])],
 579   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 580 fi
 581
 582 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 583 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 584   AC_DEFINE(HAVE_OSPEED)dnl
 585 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 586   AC_DEFINE(HAVE_OSPEED)
 587   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 588     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 589 fi
 590
 591 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 592 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 593 dnl in tgetstr().
 594 dnl Under Cygwin test program crashes but exit code is still 0. So,
 595 dnl we test for a file that porgram should create
 596 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 597 [Define to 1 if tgetent() accepts NULL as a buffer.])
 598 AC_CACHE_CHECK(if tgetent accepts NULL,
 599 nmh_cv_func_tgetent_accepts_null,
 600 [AC_TRY_RUN([
 601 main()
 602 {
 603         char buf[4096];
 604         int r1 = tgetent(buf, "vt100");
 605         int r2 = tgetent(NULL,"vt100");
 606         if (r1 >= 0 && r1 == r2) {
 607                 char tbuf[1024], *u;
 608                 u = tbuf;
 609                         tgetstr("cl", &u);
 610                 creat("conftest.tgetent", 0640);
 611         }
 612         exit((r1 != r2) || r2 == -1);
 613 }
 614 ],
 615   if test -f conftest.tgetent; then
 616     nmh_cv_func_tgetent_accepts_null=yes
 617   else
 618     nmh_cv_func_tgetent_accepts_null=no
 619   fi,
 620   nmh_cv_func_tgetent_accepts_null=no,
 621   nmh_cv_func_tgetent_accepts_null=no)])
 622 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 623   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 624 fi
 625 AC_CACHE_CHECK(if tgetent returns 0 on success,
 626 nmh_cv_func_tgetent_zero_success,
 627 [AC_TRY_RUN([
 628 main()
 629 {
 630         char buf[4096];
 631         int r1 = tgetent(buf, "!@#$%^&*");
 632         int r2 = tgetent(buf, "vt100");
 633         if (r1 < 0 && r2 == 0) {
 634                 char tbuf[1024], *u;
 635                 u = tbuf;
 636                         tgetstr("cl", &u);
 637                 creat("conftest.tgetent0", 0640);
 638         }
 639         exit(r1 == r2);
 640 }
 641 ],
 642   if test -f conftest.tgetent0; then
 643     nmh_cv_func_tgetent_zero_success=yes
 644   else
 645     nmh_cv_func_tgetent_zero_success=no
 646   fi,
 647   nmh_cv_func_tgetent_zero_success=no,
 648   nmh_cv_func_tgetent_zero_success=no)])
 649 AH_TEMPLATE([TGETENT_SUCCESS],
 650 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 651 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 652   AC_DEFINE(TGETENT_SUCCESS, 0)
 653 else
 654   AC_DEFINE(TGETENT_SUCCESS, 1)
 655 fi
 656
 657 dnl Now put the libraries back to what it was before we
 658 dnl starting checking the termcap library.
 659 LIBS="$nmh_save_LIBS"
 660
 661 dnl --------------
 662 dnl CHECK TYPEDEFS
 663 dnl --------------
 664 AC_TYPE_SIGNAL
 665 AC_TYPE_PID_T
 666 AC_TYPE_OFF_T
 667 AC_TYPE_UID_T
 668 AC_TYPE_MODE_T
 669 AC_TYPE_SIZE_T
 670
 671 dnl Check for sigset_t.  Currently I'm looking in
 672 dnl <sys/types.h> and <signal.h>.  Others might need
 673 dnl to be added.
 674 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 675 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 676 #include <signal.h>]], [[sigset_t tempsigset;]])],
 677 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 678 if test $nmh_cv_type_sigset_t = no; then
 679   AC_DEFINE(sigset_t, unsigned int,
 680     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 681 fi
 682
 683 dnl ----------------
 684 dnl CHECK STRUCTURES
 685 dnl ----------------
 686 AC_CHECK_MEMBERS(struct stat.st_blksize)
 687
 688 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 689   [#ifdef TIME_WITH_SYS_TIME
 690 # include <sys/time.h>
 691 # include <time.h>
 692 #else
 693 # ifdef TM_IN_SYS_TIME
 694 #  include <sys/time.h>
 695 # else
 696 #  include <time.h>
 697 # endif
 698 #endif])
 699
 700 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 701
 702 AC_MSG_CHECKING(for union wait)
 703 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 704   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 705 #include <sys/wait.h>]],
 706     [[union wait status; int pid; pid = wait (&status);
 707 #ifdef WEXITSTATUS
 708 /* Some POSIXoid systems have both the new-style macros and the old
 709    union wait type, and they do not work together.  If union wait
 710    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 711         if (WEXITSTATUS (status) != 0) pid = -1;
 712 #ifdef WTERMSIG
 713         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 714         -- blow chunks here --
 715 #endif
 716 #endif
 717 #ifdef HAVE_WAITPID
 718         /* Make sure union wait works with waitpid.  */
 719         pid = waitpid (-1, &status, 0);
 720 #endif
 721       ]])],
 722     [nmh_cv_union_wait=yes],
 723     [nmh_cv_union_wait=no])])
 724 if test "$nmh_cv_union_wait" = yes; then
 725   AC_DEFINE(HAVE_UNION_WAIT, 1,
 726     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 727 fi
 728 AC_MSG_RESULT($nmh_cv_union_wait)
 729
 730 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 731
 732 dnl -------------
 733 dnl CHECK SIGNALS
 734 dnl -------------
 735 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 736 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 737 AC_MSG_CHECKING(what style of signals to use)
 738 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 739   signals_style=POSIX_SIGNALS
 740   AC_DEFINE(POSIX_SIGNALS, 1,
 741     [Define to 1 if you use POSIX style signal handling.])
 742   AC_DEFINE(RELIABLE_SIGNALS)
 743 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 744   signals_style=BSD_SIGNALS
 745   AC_DEFINE(BSD_SIGNALS,1,
 746     [Define to 1 if you use BSD style signal handling (and can block signals).])
 747   AC_DEFINE(RELIABLE_SIGNALS)
 748 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 749   signals_style=SYSV_SIGNALS
 750   AC_DEFINE(SYSV_SIGNALS,1,
 751     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 752 else
 753   signals_style=NO_SIGNAL_BLOCKING
 754   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 755     [Define to 1 if you have no signal blocking at all (bummer).])
 756 fi
 757
 758 AC_MSG_RESULT($signals_style)
 759
 760 dnl Where is <signal.h> located?  Needed as input for signames.awk
 761 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 762 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 763                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 764                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 765                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 766                  /usr/include/sys/signal.h      dnl Almost everybody else
 767                  /dev/null;                     dnl Just in case we fall through
 768 do
 769   test -f $SIGNAL_H && \
 770   grep '#[         ]*define[         ][         ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 771   break
 772 done
 773 nmh_cv_path_signal_h=$SIGNAL_H
 774 ])
 775 SIGNAL_H=$nmh_cv_path_signal_h
 776 AC_SUBST(SIGNAL_H)dnl
 777
 778 dnl ----------------
 779 dnl OS SPECIFIC DEFINES
 780 dnl ----------------
 781 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 782 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 783
 784 case "$target_os" in
 785
 786   sunos4*)
 787     AC_DEFINE(BSD42)
 788     ;;
 789   freebsd*)
 790     AC_DEFINE(BSD42)
 791     ;;
 792   netbsd*)
 793     AC_DEFINE(BSD42)
 794     ;;
 795   openbsd*)
 796     AC_DEFINE(BSD42)
 797     ;;
 798   bsd/os*)
 799     AC_DEFINE(BSD42)
 800     ;;
 801   sco5*)
 802     AC_DEFINE(SCO_5_STDIO)
 803     ;;
 804 esac
 805
 806
 807 dnl ----------------
 808 dnl OUTPUT MAKEFILES
 809 dnl ----------------
 810 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 811                 etc/Makefile docs/Makefile man/Makefile)
 812 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 813 AC_OUTPUT
 814
 815 dnl These odd looking assignments are done to expand out unexpanded
 816 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 817 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 818 dnl again to get the final answer.
 819 dnl We only use the expanded versions to print the install paths in
 820 dnl the final summary and should use them nowhere else (see the autoconf
 821 dnl docs for the rationale for bindir etc being unexpanded).
 822 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 823 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 824 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 825 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 826
 827 echo "
 828 mmh configuration
 829 -----------------
 830 mmh version            : AC_PACKAGE_VERSION
 831 target os              : ${target}
 832 compiler               : ${CC}
 833 compiler flags         : ${CFLAGS}
 834 linker flags           : ${LDFLAGS}
 835 definitions            : ${OURDEFS}
 836 source code location   : ${srcdir}
 837
 838 binary install path    : ${nmhbin}
 839 library install path   : ${nmhlib}
 840 config install path    : ${nmhsysconf}
 841 man page install path  : ${nmhman}
 842
 843 sendmail path          : ${sendmailpath}
 844
 845 file locking type      : ${LOCKTYPE}
 846 address masquerading   : ${masquerade}
 847 "