git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for mmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7 dnl (I was able to configure with autoconf-2.59 --meillo 2012-03-22)
   8
   9 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
  10 AC_CONFIG_SRCDIR(h/nmh.h)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 AC_CANONICAL_TARGET
  14
  15 dnl ---------------------
  16 dnl define a macro or two
  17 dnl ---------------------
  18
  19 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  20 if test -n "$LIBTOOL" ; then
  21   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  22   if test x"$tmptest" != x  ; then
  23     GNU_LIBTOOL=1
  24     AC_SUBST(GNU_LIBTOOL)dnl
  25   fi
  26 fi
  27 ] )
  28
  29 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  30 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  31
  32 dnl What date of mmh are we building?
  33 DATE=`cat ${srcdir}/DATE`
  34 echo "configuring for mmh dated $DATE"
  35 AC_SUBST(DATE)dnl
  36
  37 dnl --------------------------
  38 dnl CHECK COMMAND LINE OPTIONS
  39 dnl --------------------------
  40
  41 dnl Do you want to debug mmh?
  42 AC_ARG_ENABLE(debug,
  43   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  44 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  45 if test x"$enable_nmh_debug" = x"yes"; then
  46   enable_debug=yes
  47 fi
  48
  49 dnl Do you want to disable use of locale functions
  50 AH_TEMPLATE([LOCALE],
  51 [Undefine if you don't want locale features.  By default this is defined.])
  52 AC_ARG_ENABLE([locale],
  53 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  54 [if test x$enableval = xyes; then
  55   AC_DEFINE(LOCALE)
  56 fi],
  57 AC_DEFINE(LOCALE)
  58 )
  59
  60 dnl What method of locking to use?
  61 AC_ARG_WITH(locking,
  62   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  63   [specify the file locking method]))
  64
  65 if test x"$with_locking" = x"dot"; then
  66   LOCKTYPE="dot"
  67   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  68 elif test x"$with_locking" = x"flock"; then
  69   LOCKTYPE="flock"
  70   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  71 elif test x"$with_locking" = x"lockf"; then
  72   LOCKTYPE="lockf"
  73   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  74 elif test x"$with_locking" = x"fcntl"; then
  75   LOCKTYPE="fcntl"
  76   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  77 else
  78   LOCKTYPE="dot"
  79   AC_DEFINE(DOT_LOCKING)dnl
  80 fi
  81
  82
  83 dnl ----------------------------------------------------
  84 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
  85 dnl ----------------------------------------------------
  86 AC_PREFIX_DEFAULT(/usr/local/mmh)
  87
  88
  89 dnl ------------------
  90 dnl CHECK THE COMPILER
  91 dnl ------------------
  92 dnl We want these before the checks,
  93 dnl so the checks can modify their values.
  94 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
  95 if test x"$enable_debug" = x"yes"; then
  96   test -z "$LDFLAGS" && LDFLAGS=-g
  97 fi
  98
  99 AC_PROG_CC
 100
 101 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 102 [nmh_saved_cflags="$CFLAGS"
 103  CFLAGS="$CFLAGS -Wno-pointer-sign"
 104  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 105  CFLAGS="$nmh_saved_cflags"])
 106
 107 dnl if the user hasn't specified CFLAGS, then
 108 dnl   if compiler is gcc, then
 109 dnl     use -O2 and some warning flags
 110 dnl   else use -O
 111 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 112 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 113 dnl spurious and which in any case we don't want to deal with now.
 114 if test "$nmh_cv_has_noptrsign" = "yes"; then
 115   nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 116 else
 117   nmh_gcc_warnflags="-Wall"
 118 fi
 119
 120 if test -n "$auto_cflags"; then
 121   if test x"$enable_debug" = x"yes"; then
 122     if test -n "$GCC"; then
 123       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 124     else
 125       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 126     fi
 127   else
 128     if test -z "$LDFLAGS"; then
 129       case "$build_os" in
 130         darwin*)
 131           LDFLAGS=
 132           ;;
 133         *)
 134           LDFLAGS=-s
 135           ;;
 136       esac
 137     fi
 138     if test -n "$GCC"; then
 139       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 140     else
 141       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 142     fi
 143   fi
 144 fi
 145
 146 AC_C_CONST          dnl Does compiler support `const'.
 147
 148 dnl ------------------
 149 dnl CHECK FOR PROGRAMS
 150 dnl ------------------
 151 AC_PROG_MAKE_SET    dnl Does make define $MAKE
 152 AC_PROG_INSTALL     dnl Check for BSD compatible `install'
 153 AC_PROG_RANLIB      dnl Check for `ranlib'
 154 AC_PROG_AWK         dnl Check for mawk,gawk,nawk, then awk
 155 AC_PROG_LEX         dnl Check for lex/flex
 156
 157 dnl Look for `cut'
 158 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 159 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 160
 161 dnl ----------------------------------------------
 162 dnl check for lclint, and lint if it doesn't exist
 163 dnl ----------------------------------------------
 164 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 165 if test x$ac_cv_prog_linttmp1 != xno ; then
 166   LINT=$ac_cv_prog_linttmp1
 167   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 168 else
 169   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 170   if test x$ac_cv_prog_linttmp2 != xno ; then
 171     LINT=$ac_cv_prog_linttmp2
 172     LINTFLAGS=""
 173   else
 174     LINT="echo 'No lint program found'"
 175     LINTFLAGS=""
 176   fi
 177 fi
 178 AC_SUBST(LINT)dnl
 179 AC_SUBST(LINTFLAGS)dnl
 180
 181 dnl try to figure out which one we've got
 182 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 183 NMH_PROG_GNU_LIBTOOL
 184
 185 dnl Check for lorder and tsort commands
 186 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 187 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 188
 189 dnl If either doesn't exist, replace them with echo and cat
 190 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 191   LORDER=echo
 192   TSORT=cat
 193   AC_SUBST(LORDER)dnl
 194   AC_SUBST(TSORT)dnl
 195 dnl Mac OS X has lorder, but sh is too broken for it to work
 196 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 197 dnl   LORDER=echo
 198 dnl   TSORT=cat
 199 dnl   AC_SUBST(LORDER)dnl
 200 dnl   AC_SUBST(TSORT)dnl
 201 fi
 202
 203 dnl Check whether tsort can deal with loops
 204 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 205   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 206     nmh_cv_tsort_loop=no
 207   else
 208     nmh_cv_tsort_loop=yes
 209   fi])
 210 if test x$nmh_cv_tsort_loop = xno ; then
 211   LORDER=echo
 212   TSORT=cat
 213   AC_SUBST(LORDER)dnl
 214   AC_SUBST(TSORT)dnl
 215 fi
 216
 217 dnl Look for `ls'
 218 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 219 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 220
 221 dnl See how we get ls to display the owner and the group
 222 if test "$lspath" != "no"; then
 223   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 224                  nmh_cv_ls_grpopt,
 225   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 226     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 227     dnl ls, it would seem -l gave us both the user and group.  On this type of
 228     dnl ls, -g makes _only_ the group be displayed (and not the user).
 229     nmh_cv_ls_grpopt="-l"
 230   else
 231     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 232     nmh_cv_ls_grpopt="-lg"
 233   fi])
 234 fi
 235
 236 dnl Look for `sendmail'
 237 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 238 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 239
 240 dnl Look for `vi'
 241 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 242 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 243
 244 dnl ----------------------------------------------------------
 245 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 246 dnl ----------------------------------------------------------
 247 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 248 [for mailspool in /var/mail        dnl
 249                   /var/spool/mail  dnl
 250                   /usr/spool/mail  dnl
 251                   /dev/null;       dnl Just in case we fall through
 252 do
 253   test -d $mailspool && break
 254 done
 255 nmh_cv_mailspool=$mailspool
 256 ])
 257 mailspool=$nmh_cv_mailspool
 258 AC_SUBST(mailspool)dnl
 259
 260 dnl See whether the mail spool directory is world-writable.
 261 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 262   AC_CACHE_CHECK(whether the mail spool is world-writable,
 263                  nmh_cv_mailspool_world_writable,
 264   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 265     nmh_cv_mailspool_world_writable=no
 266   else
 267     nmh_cv_mailspool_world_writable=yes
 268   fi])
 269 fi
 270
 271 dnl Also, check for liblockfile (as found on Debian systems)
 272 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 273
 274 dnl and whether its companion program dotlockfile is setgid
 275 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 276 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 277   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 278     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 279     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 280         nmh_cv_dotlockfile_setgid=yes
 281       else
 282         nmh_cv_dotlockfile_setgid=no
 283       fi])
 284   fi
 285 fi
 286
 287 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 288 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 289 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 290   dnl do we really need both of these?
 291   AC_DEFINE(MAILGROUP,1,
 292     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 293   SETGID_MAIL=1
 294 fi
 295 AC_SUBST(SETGID_MAIL)dnl
 296
 297 dnl Use ls to see which group owns the mail spool directory.
 298 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 299 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 300 ])
 301 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 302 AC_SUBST(MAIL_SPOOL_GRP)dnl
 303
 304 dnl ------------------
 305 dnl CHECK HEADER FILES
 306 dnl ------------------
 307
 308 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 309 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 310 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 311 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 312 dnl declared; if so they should have an entry added to this case statement.
 313 dnl NB that we must define this on the compiler command line, not in config.h,
 314 dnl because it must be set before any system header is included and there's no
 315 dnl portable way to make sure that files generated by lex include config.h
 316 dnl before system header files.
 317
 318 case "$target_os" in
 319   linux*)
 320     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 321     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 322     ;;
 323 esac
 324 AC_SUBST(OURDEFS)
 325
 326 AC_HEADER_STDC
 327 AC_HEADER_TIOCGWINSZ
 328 AC_CHECK_HEADERS(fcntl.h crypt.h termcap.h \
 329                  langinfo.h wchar.h wctype.h iconv.h \
 330                  sys/param.h sys/time.h sys/stream.h )
 331
 332 dnl
 333 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 334 dnl really use a whole set of them, but this check should be
 335 dnl sufficient.
 336 dnl
 337 AC_CHECK_HEADER(libio.h, [
 338   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 339     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 340
 341 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 342   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 343 [[#if HAVE_SYS_STREAM_H
 344 #  include <sys/stream.h>
 345 #endif
 346 ]])
 347
 348 dnl ---------------
 349 dnl CHECK FUNCTIONS
 350 dnl ---------------
 351 AC_CHECK_FUNCS(nl_langinfo mbtowc wcwidth)
 352
 353 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 354 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 355 dnl any system header.
 356 dnl
 357 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 358 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 359 dnl need to check?
 360 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 361 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 362                 AC_EGREP_HEADER(initgroups, unistd.h,
 363                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 364
 365 dnl Check for multibyte character set support
 366 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 367     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 368   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 369     [Define to enable support for multibyte character sets.])
 370 fi
 371
 372 dnl -------------------
 373 dnl CHECK FOR LIBRARIES
 374 dnl -------------------
 375 dnl Check location of modf
 376 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 377
 378 dnl Checks for network libraries (nsl, socket)
 379 NMH_CHECK_NETLIBS
 380
 381 termcap_curses_order="termcap curses ncurses"
 382 for lib in $termcap_curses_order; do
 383   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 384 done
 385 AC_SUBST(TERMLIB)dnl
 386 if test "x$TERMLIB" = "x"; then
 387         echo 'Could not find tgetent() in any library.'
 388         echo 'Is there a ncurses-devel package that you can install?'
 389         exit 1
 390 fi
 391
 392
 393 dnl ---------------
 394 dnl CHECK FOR ICONV
 395 dnl ---------------
 396
 397 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 398 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 399   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 400   if test "x$ac_found_iconv" = "xno"; then
 401     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 402     if test "x$ac_found_iconv" = "xno"; then
 403       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 404     fi
 405     if test "x$ac_found_iconv" != "xno"; then
 406       LIBS="-liconv $LIBS"
 407     fi
 408   else
 409     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 410     AC_CHECK_DECL(_libiconv_version,
 411       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 412       [ #include <iconv.h> ])
 413   fi
 414 fi
 415 if test "x$ac_found_iconv" = xyes; then
 416   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 417 fi
 418
 419 dnl Check if iconv uses const in prototype declaration
 420 if test "x$ac_found_iconv" = "xyes"; then
 421   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 422     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 423         #include <iconv.h>]],
 424         [[#ifdef __cplusplus
 425           "C"
 426           #endif
 427           #if defined(__STDC__) || defined(__cplusplus)
 428           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 429           #else
 430           size_t iconv();
 431           #endif]])],
 432       [ac_cv_iconv_const=],
 433       [ac_cv_iconv_const=const])])
 434   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 435     [Define as const if the declaration of iconv() needs const.])
 436 fi
 437
 438
 439 dnl ---------------------
 440 dnl CHECK TERMCAP LIBRARY
 441 dnl ---------------------
 442
 443 dnl Add the termcap library, so that the following configure
 444 dnl tests will find it when it tries to link test programs.
 445 nmh_save_LIBS="$LIBS"
 446 LIBS="$TERMLIB $LIBS"
 447
 448 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 449 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 450 dnl in tgetstr().
 451 dnl Under Cygwin test program crashes but exit code is still 0. So,
 452 dnl we test for a file that porgram should create
 453 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 454 [Define to 1 if tgetent() accepts NULL as a buffer.])
 455 AC_CACHE_CHECK(if tgetent accepts NULL,
 456 nmh_cv_func_tgetent_accepts_null,
 457 [AC_TRY_RUN([
 458 main()
 459 {
 460         char buf[4096];
 461         int r1 = tgetent(buf, "vt100");
 462         int r2 = tgetent(NULL,"vt100");
 463         if (r1 >= 0 && r1 == r2) {
 464                 char tbuf[1024], *u;
 465                 u = tbuf;
 466                         tgetstr("cl", &u);
 467                 creat("conftest.tgetent", 0640);
 468         }
 469         exit((r1 != r2) || r2 == -1);
 470 }
 471 ],
 472   if test -f conftest.tgetent; then
 473     nmh_cv_func_tgetent_accepts_null=yes
 474   else
 475     nmh_cv_func_tgetent_accepts_null=no
 476   fi,
 477   nmh_cv_func_tgetent_accepts_null=no,
 478   nmh_cv_func_tgetent_accepts_null=no)])
 479 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 480   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 481 fi
 482 AC_CACHE_CHECK(if tgetent returns 0 on success,
 483 nmh_cv_func_tgetent_zero_success,
 484 [AC_TRY_RUN([
 485 main()
 486 {
 487         char buf[4096];
 488         int r1 = tgetent(buf, "!@#$%^&*");
 489         int r2 = tgetent(buf, "vt100");
 490         if (r1 < 0 && r2 == 0) {
 491                 char tbuf[1024], *u;
 492                 u = tbuf;
 493                         tgetstr("cl", &u);
 494                 creat("conftest.tgetent0", 0640);
 495         }
 496         exit(r1 == r2);
 497 }
 498 ],
 499   if test -f conftest.tgetent0; then
 500     nmh_cv_func_tgetent_zero_success=yes
 501   else
 502     nmh_cv_func_tgetent_zero_success=no
 503   fi,
 504   nmh_cv_func_tgetent_zero_success=no,
 505   nmh_cv_func_tgetent_zero_success=no)])
 506 AH_TEMPLATE([TGETENT_SUCCESS],
 507 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 508 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 509   AC_DEFINE(TGETENT_SUCCESS, 0)
 510 else
 511   AC_DEFINE(TGETENT_SUCCESS, 1)
 512 fi
 513
 514 dnl Now put the libraries back to what it was before we
 515 dnl starting checking the termcap library.
 516 LIBS="$nmh_save_LIBS"
 517
 518 dnl --------------
 519 dnl CHECK TYPEDEFS
 520 dnl --------------
 521 AC_TYPE_PID_T
 522 AC_TYPE_OFF_T
 523 AC_TYPE_UID_T
 524 AC_TYPE_MODE_T
 525 AC_TYPE_SIZE_T
 526
 527 dnl ----------------
 528 dnl CHECK STRUCTURES
 529 dnl ----------------
 530
 531 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 532 dnl (FreeBSD has a timezone() function but not a timezone global
 533 dnl variable that is visible).
 534 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 535
 536 AC_STRUCT_DIRENT_D_TYPE
 537
 538 dnl Where is <signal.h> located?  Needed as input for signames.awk
 539 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 540 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 541                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 542                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 543                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 544                  /usr/include/sys/signal.h      dnl Almost everybody else
 545                  /dev/null;                     dnl Just in case we fall through
 546 do
 547   test -f $SIGNAL_H && \
 548   grep '#[         ]*define[         ][         ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 549   break
 550 done
 551 nmh_cv_path_signal_h=$SIGNAL_H
 552 ])
 553 SIGNAL_H=$nmh_cv_path_signal_h
 554 AC_SUBST(SIGNAL_H)dnl
 555
 556
 557 dnl ----------------
 558 dnl OUTPUT MAKEFILES
 559 dnl ----------------
 560 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 561                 etc/Makefile docs/Makefile man/Makefile)
 562 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 563 AC_OUTPUT
 564
 565 dnl These odd looking assignments are done to expand out unexpanded
 566 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 567 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 568 dnl again to get the final answer.
 569 dnl We only use the expanded versions to print the install paths in
 570 dnl the final summary and should use them nowhere else (see the autoconf
 571 dnl docs for the rationale for bindir etc being unexpanded).
 572 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 573 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 574 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 575 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 576
 577 echo "
 578 mmh configuration
 579 -----------------
 580 mmh version            : AC_PACKAGE_VERSION
 581 target os              : ${target}
 582 compiler               : ${CC}
 583 compiler flags         : ${CFLAGS}
 584 linker flags           : ${LDFLAGS}
 585 definitions            : ${OURDEFS}
 586 source code location   : ${srcdir}
 587
 588 binary install path    : ${nmhbin}
 589 library install path   : ${nmhlib}
 590 config install path    : ${nmhsysconf}
 591 man page install path  : ${nmhman}
 592
 593 sendmail path          : ${sendmailpath}
 594 mail spool             : ${mailspool}
 595
 596 file locking type      : ${LOCKTYPE}
 597 "