git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for mmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7 dnl (I was able to configure with autoconf-2.59 --meillo 2012-03-22)
   8
   9 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
  10 AC_CONFIG_SRCDIR(h/nmh.h)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 AC_CANONICAL_TARGET
  14
  15 dnl ---------------------
  16 dnl define a macro or two
  17 dnl ---------------------
  18
  19 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  20 if test -n "$LIBTOOL" ; then
  21   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  22   if test x"$tmptest" != x  ; then
  23     GNU_LIBTOOL=1
  24     AC_SUBST(GNU_LIBTOOL)dnl
  25   fi
  26 fi
  27 ] )
  28
  29 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  30 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  31
  32 dnl What date of mmh are we building?
  33 DATE=`cat ${srcdir}/DATE`
  34 echo "configuring for mmh dated $DATE"
  35 AC_SUBST(DATE)dnl
  36
  37 dnl --------------------------
  38 dnl CHECK COMMAND LINE OPTIONS
  39 dnl --------------------------
  40
  41 dnl Do you want to debug mmh?
  42 AC_ARG_ENABLE(debug,
  43   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  44 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  45 if test x"$enable_nmh_debug" = x"yes"; then
  46   enable_debug=yes
  47 fi
  48
  49 dnl Do you want mhe support?
  50 AC_ARG_ENABLE(mhe,
  51   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  52
  53 dnl mhe support is on by default, so define it unless --disable-mhe or the
  54 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  55 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  56   AC_DEFINE(MHE, 1,
  57     [Define to compile in support for the Emacs front-end mh-e.])dnl
  58 fi
  59
  60 dnl Do you want to disable use of locale functions
  61 AH_TEMPLATE([LOCALE],
  62 [Undefine if you don't want locale features.  By default this is defined.])
  63 AC_ARG_ENABLE([locale],
  64 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  65 [if test x$enableval = xyes; then
  66   AC_DEFINE(LOCALE)
  67 fi],
  68 AC_DEFINE(LOCALE)
  69 )
  70
  71 dnl What method of locking to use?
  72 AC_ARG_WITH(locking,
  73   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  74   [specify the file locking method]))
  75
  76 if test x"$with_locking" = x"dot"; then
  77   LOCKTYPE="dot"
  78   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  79 elif test x"$with_locking" = x"flock"; then
  80   LOCKTYPE="flock"
  81   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  82 elif test x"$with_locking" = x"lockf"; then
  83   LOCKTYPE="lockf"
  84   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  85 elif test x"$with_locking" = x"fcntl"; then
  86   LOCKTYPE="fcntl"
  87   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  88 else
  89   LOCKTYPE="dot"
  90   AC_DEFINE(DOT_LOCKING)dnl
  91 fi
  92
  93
  94 dnl ----------------------------------------------------
  95 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
  96 dnl ----------------------------------------------------
  97 AC_PREFIX_DEFAULT(/usr/local/mmh)
  98
  99
 100 dnl ------------------
 101 dnl CHECK THE COMPILER
 102 dnl ------------------
 103 dnl We want these before the checks,
 104 dnl so the checks can modify their values.
 105 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 106 if test x"$enable_debug" = x"yes"; then
 107   test -z "$LDFLAGS" && LDFLAGS=-g
 108 fi
 109
 110 AC_PROG_CC
 111
 112 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 113 [nmh_saved_cflags="$CFLAGS"
 114  CFLAGS="$CFLAGS -Wno-pointer-sign"
 115  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 116  CFLAGS="$nmh_saved_cflags"])
 117
 118 dnl if the user hasn't specified CFLAGS, then
 119 dnl   if compiler is gcc, then
 120 dnl     use -O2 and some warning flags
 121 dnl   else use -O
 122 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 123 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 124 dnl spurious and which in any case we don't want to deal with now.
 125 if test "$nmh_cv_has_noptrsign" = "yes"; then
 126   nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 127 else
 128   nmh_gcc_warnflags="-Wall"
 129 fi
 130
 131 if test -n "$auto_cflags"; then
 132   if test x"$enable_debug" = x"yes"; then
 133     if test -n "$GCC"; then
 134       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 135     else
 136       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 137     fi
 138   else
 139     if test -z "$LDFLAGS"; then
 140       case "$build_os" in
 141         darwin*)
 142           LDFLAGS=
 143           ;;
 144         *)
 145           LDFLAGS=-s
 146           ;;
 147       esac
 148     fi
 149     if test -n "$GCC"; then
 150       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 151     else
 152       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 153     fi
 154   fi
 155 fi
 156
 157 AC_C_CONST          dnl Does compiler support `const'.
 158
 159 dnl ------------------
 160 dnl CHECK FOR PROGRAMS
 161 dnl ------------------
 162 AC_PROG_MAKE_SET    dnl Does make define $MAKE
 163 AC_PROG_INSTALL     dnl Check for BSD compatible `install'
 164 AC_PROG_RANLIB      dnl Check for `ranlib'
 165 AC_PROG_AWK         dnl Check for mawk,gawk,nawk, then awk
 166 AC_PROG_LEX         dnl Check for lex/flex
 167
 168 dnl Look for `cut'
 169 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 170 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 171
 172 dnl ----------------------------------------------
 173 dnl check for lclint, and lint if it doesn't exist
 174 dnl ----------------------------------------------
 175 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 176 if test x$ac_cv_prog_linttmp1 != xno ; then
 177   LINT=$ac_cv_prog_linttmp1
 178   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 179 else
 180   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 181   if test x$ac_cv_prog_linttmp2 != xno ; then
 182     LINT=$ac_cv_prog_linttmp2
 183     LINTFLAGS=""
 184   else
 185     LINT="echo 'No lint program found'"
 186     LINTFLAGS=""
 187   fi
 188 fi
 189 AC_SUBST(LINT)dnl
 190 AC_SUBST(LINTFLAGS)dnl
 191
 192 dnl try to figure out which one we've got
 193 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 194 NMH_PROG_GNU_LIBTOOL
 195
 196 dnl Check for lorder and tsort commands
 197 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 198 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 199
 200 dnl If either doesn't exist, replace them with echo and cat
 201 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 202   LORDER=echo
 203   TSORT=cat
 204   AC_SUBST(LORDER)dnl
 205   AC_SUBST(TSORT)dnl
 206 dnl Mac OS X has lorder, but sh is too broken for it to work
 207 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 208 dnl   LORDER=echo
 209 dnl   TSORT=cat
 210 dnl   AC_SUBST(LORDER)dnl
 211 dnl   AC_SUBST(TSORT)dnl
 212 fi
 213
 214 dnl Check whether tsort can deal with loops
 215 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 216   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 217     nmh_cv_tsort_loop=no
 218   else
 219     nmh_cv_tsort_loop=yes
 220   fi])
 221 if test x$nmh_cv_tsort_loop = xno ; then
 222   LORDER=echo
 223   TSORT=cat
 224   AC_SUBST(LORDER)dnl
 225   AC_SUBST(TSORT)dnl
 226 fi
 227
 228 dnl Look for `ls'
 229 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 230 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 231
 232 dnl See how we get ls to display the owner and the group
 233 if test "$lspath" != "no"; then
 234   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 235                  nmh_cv_ls_grpopt,
 236   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 237     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 238     dnl ls, it would seem -l gave us both the user and group.  On this type of
 239     dnl ls, -g makes _only_ the group be displayed (and not the user).
 240     nmh_cv_ls_grpopt="-l"
 241   else
 242     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 243     nmh_cv_ls_grpopt="-lg"
 244   fi])
 245 fi
 246
 247 dnl Look for `sendmail'
 248 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 249 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 250
 251 dnl Look for `vi'
 252 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 253 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 254
 255 dnl ----------------------------------------------------------
 256 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 257 dnl ----------------------------------------------------------
 258 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 259 [for mailspool in /var/mail        dnl
 260                   /var/spool/mail  dnl
 261                   /usr/spool/mail  dnl
 262                   /dev/null;       dnl Just in case we fall through
 263 do
 264   test -d $mailspool && break
 265 done
 266 nmh_cv_mailspool=$mailspool
 267 ])
 268 mailspool=$nmh_cv_mailspool
 269 AC_SUBST(mailspool)dnl
 270
 271 dnl See whether the mail spool directory is world-writable.
 272 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 273   AC_CACHE_CHECK(whether the mail spool is world-writable,
 274                  nmh_cv_mailspool_world_writable,
 275   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 276     nmh_cv_mailspool_world_writable=no
 277   else
 278     nmh_cv_mailspool_world_writable=yes
 279   fi])
 280 fi
 281
 282 dnl Also, check for liblockfile (as found on Debian systems)
 283 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 284
 285 dnl and whether its companion program dotlockfile is setgid
 286 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 287 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 288   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 289     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 290     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 291         nmh_cv_dotlockfile_setgid=yes
 292       else
 293         nmh_cv_dotlockfile_setgid=no
 294       fi])
 295   fi
 296 fi
 297
 298 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 299 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 300 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 301   dnl do we really need both of these?
 302   AC_DEFINE(MAILGROUP,1,
 303     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 304   SETGID_MAIL=1
 305 fi
 306 AC_SUBST(SETGID_MAIL)dnl
 307
 308 dnl Use ls to see which group owns the mail spool directory.
 309 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 310 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 311 ])
 312 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 313 AC_SUBST(MAIL_SPOOL_GRP)dnl
 314
 315 dnl ------------------
 316 dnl CHECK HEADER FILES
 317 dnl ------------------
 318
 319 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 320 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 321 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 322 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 323 dnl declared; if so they should have an entry added to this case statement.
 324 dnl NB that we must define this on the compiler command line, not in config.h,
 325 dnl because it must be set before any system header is included and there's no
 326 dnl portable way to make sure that files generated by lex include config.h
 327 dnl before system header files.
 328
 329 case "$target_os" in
 330   linux*)
 331     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 332     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 333     ;;
 334 esac
 335 AC_SUBST(OURDEFS)
 336
 337 AC_HEADER_STDC
 338 AC_HEADER_TIME
 339 AC_HEADER_STAT
 340 AC_HEADER_TIOCGWINSZ
 341 AC_CHECK_HEADERS(fcntl.h crypt.h termcap.h \
 342                  langinfo.h wchar.h wctype.h iconv.h \
 343                  sys/param.h sys/time.h sys/stream.h )
 344
 345 dnl
 346 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 347 dnl really use a whole set of them, but this check should be
 348 dnl sufficient.
 349 dnl
 350 AC_CHECK_HEADER(libio.h, [
 351   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 352     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 353
 354 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 355   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 356 [[#if HAVE_SYS_STREAM_H
 357 #  include <sys/stream.h>
 358 #endif
 359 ]])
 360
 361 dnl ---------------
 362 dnl CHECK FUNCTIONS
 363 dnl ---------------
 364 AC_CHECK_FUNCS(sigaction sigprocmask sigblock sigsetmask \
 365                sighold sigrelse lstat tzset \
 366                getutent nl_langinfo mbtowc wcwidth)
 367
 368 dnl sigsetjmp may be a macro
 369 AC_MSG_CHECKING(for sigsetjmp)
 370 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 371   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 372     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 373   [AC_MSG_RESULT(no)])
 374
 375 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 376 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 377 dnl any system header.
 378 dnl
 379 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 380 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 381 dnl need to check?
 382 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 383 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 384                 AC_EGREP_HEADER(initgroups, unistd.h,
 385                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 386
 387 dnl Check for multibyte character set support
 388 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 389     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 390   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 391     [Define to enable support for multibyte character sets.])
 392 fi
 393
 394 dnl -------------------
 395 dnl CHECK FOR LIBRARIES
 396 dnl -------------------
 397 dnl Check location of modf
 398 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 399
 400 dnl Checks for network libraries (nsl, socket)
 401 AC_CHECK_NETLIBS
 402
 403 termcap_curses_order="termcap curses ncurses"
 404 for lib in $termcap_curses_order; do
 405   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 406 done
 407 AC_SUBST(TERMLIB)dnl
 408
 409 dnl ---------------
 410 dnl CHECK FOR ICONV
 411 dnl ---------------
 412
 413 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 414 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 415   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 416   if test "x$ac_found_iconv" = "xno"; then
 417     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 418     if test "x$ac_found_iconv" = "xno"; then
 419       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 420     fi
 421     if test "x$ac_found_iconv" != "xno"; then
 422       LIBS="-liconv $LIBS"
 423     fi
 424   else
 425     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 426     AC_CHECK_DECL(_libiconv_version,
 427       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 428       [ #include <iconv.h> ])
 429   fi
 430 fi
 431 if test "x$ac_found_iconv" = xyes; then
 432   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 433 fi
 434
 435 dnl Check if iconv uses const in prototype declaration
 436 if test "x$ac_found_iconv" = "xyes"; then
 437   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 438     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 439         #include <iconv.h>]],
 440         [[#ifdef __cplusplus
 441           "C"
 442           #endif
 443           #if defined(__STDC__) || defined(__cplusplus)
 444           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 445           #else
 446           size_t iconv();
 447           #endif]])],
 448       [ac_cv_iconv_const=],
 449       [ac_cv_iconv_const=const])])
 450   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 451     [Define as const if the declaration of iconv() needs const.])
 452 fi
 453
 454
 455 dnl ---------------------
 456 dnl CHECK TERMCAP LIBRARY
 457 dnl ---------------------
 458
 459 dnl Add the termcap library, so that the following configure
 460 dnl tests will find it when it tries to link test programs.
 461 nmh_save_LIBS="$LIBS"
 462 LIBS="$TERMLIB $LIBS"
 463
 464 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 465 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 466 dnl in tgetstr().
 467 dnl Under Cygwin test program crashes but exit code is still 0. So,
 468 dnl we test for a file that porgram should create
 469 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 470 [Define to 1 if tgetent() accepts NULL as a buffer.])
 471 AC_CACHE_CHECK(if tgetent accepts NULL,
 472 nmh_cv_func_tgetent_accepts_null,
 473 [AC_TRY_RUN([
 474 main()
 475 {
 476         char buf[4096];
 477         int r1 = tgetent(buf, "vt100");
 478         int r2 = tgetent(NULL,"vt100");
 479         if (r1 >= 0 && r1 == r2) {
 480                 char tbuf[1024], *u;
 481                 u = tbuf;
 482                         tgetstr("cl", &u);
 483                 creat("conftest.tgetent", 0640);
 484         }
 485         exit((r1 != r2) || r2 == -1);
 486 }
 487 ],
 488   if test -f conftest.tgetent; then
 489     nmh_cv_func_tgetent_accepts_null=yes
 490   else
 491     nmh_cv_func_tgetent_accepts_null=no
 492   fi,
 493   nmh_cv_func_tgetent_accepts_null=no,
 494   nmh_cv_func_tgetent_accepts_null=no)])
 495 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 496   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 497 fi
 498 AC_CACHE_CHECK(if tgetent returns 0 on success,
 499 nmh_cv_func_tgetent_zero_success,
 500 [AC_TRY_RUN([
 501 main()
 502 {
 503         char buf[4096];
 504         int r1 = tgetent(buf, "!@#$%^&*");
 505         int r2 = tgetent(buf, "vt100");
 506         if (r1 < 0 && r2 == 0) {
 507                 char tbuf[1024], *u;
 508                 u = tbuf;
 509                         tgetstr("cl", &u);
 510                 creat("conftest.tgetent0", 0640);
 511         }
 512         exit(r1 == r2);
 513 }
 514 ],
 515   if test -f conftest.tgetent0; then
 516     nmh_cv_func_tgetent_zero_success=yes
 517   else
 518     nmh_cv_func_tgetent_zero_success=no
 519   fi,
 520   nmh_cv_func_tgetent_zero_success=no,
 521   nmh_cv_func_tgetent_zero_success=no)])
 522 AH_TEMPLATE([TGETENT_SUCCESS],
 523 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 524 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 525   AC_DEFINE(TGETENT_SUCCESS, 0)
 526 else
 527   AC_DEFINE(TGETENT_SUCCESS, 1)
 528 fi
 529
 530 dnl Now put the libraries back to what it was before we
 531 dnl starting checking the termcap library.
 532 LIBS="$nmh_save_LIBS"
 533
 534 dnl --------------
 535 dnl CHECK TYPEDEFS
 536 dnl --------------
 537 AC_TYPE_SIGNAL
 538 AC_TYPE_PID_T
 539 AC_TYPE_OFF_T
 540 AC_TYPE_UID_T
 541 AC_TYPE_MODE_T
 542 AC_TYPE_SIZE_T
 543
 544 dnl Check for sigset_t.  Currently I'm looking in
 545 dnl <sys/types.h> and <signal.h>.  Others might need
 546 dnl to be added.
 547 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 548 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 549 #include <signal.h>]], [[sigset_t tempsigset;]])],
 550 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 551 if test $nmh_cv_type_sigset_t = no; then
 552   AC_DEFINE(sigset_t, unsigned int,
 553     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 554 fi
 555
 556 dnl ----------------
 557 dnl CHECK STRUCTURES
 558 dnl ----------------
 559 AC_CHECK_MEMBERS(struct stat.st_blksize)
 560
 561 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 562   [#ifdef TIME_WITH_SYS_TIME
 563 # include <sys/time.h>
 564 # include <time.h>
 565 #else
 566 # ifdef TM_IN_SYS_TIME
 567 #  include <sys/time.h>
 568 # else
 569 #  include <time.h>
 570 # endif
 571 #endif])
 572
 573 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 574
 575 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 576
 577 dnl -------------
 578 dnl CHECK SIGNALS
 579 dnl -------------
 580 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 581 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 582 AC_MSG_CHECKING(what style of signals to use)
 583 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 584   signals_style=POSIX_SIGNALS
 585   AC_DEFINE(POSIX_SIGNALS, 1,
 586     [Define to 1 if you use POSIX style signal handling.])
 587   AC_DEFINE(RELIABLE_SIGNALS)
 588 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 589   signals_style=BSD_SIGNALS
 590   AC_DEFINE(BSD_SIGNALS,1,
 591     [Define to 1 if you use BSD style signal handling (and can block signals).])
 592   AC_DEFINE(RELIABLE_SIGNALS)
 593 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 594   signals_style=SYSV_SIGNALS
 595   AC_DEFINE(SYSV_SIGNALS,1,
 596     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 597 else
 598   signals_style=NO_SIGNAL_BLOCKING
 599   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 600     [Define to 1 if you have no signal blocking at all (bummer).])
 601 fi
 602
 603 AC_MSG_RESULT($signals_style)
 604
 605 dnl Where is <signal.h> located?  Needed as input for signames.awk
 606 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 607 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 608                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 609                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 610                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 611                  /usr/include/sys/signal.h      dnl Almost everybody else
 612                  /dev/null;                     dnl Just in case we fall through
 613 do
 614   test -f $SIGNAL_H && \
 615   grep '#[         ]*define[         ][         ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 616   break
 617 done
 618 nmh_cv_path_signal_h=$SIGNAL_H
 619 ])
 620 SIGNAL_H=$nmh_cv_path_signal_h
 621 AC_SUBST(SIGNAL_H)dnl
 622
 623 dnl ----------------
 624 dnl OS SPECIFIC DEFINES
 625 dnl ----------------
 626 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 627 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 628
 629 case "$target_os" in
 630
 631   sunos4*)
 632     AC_DEFINE(BSD42)
 633     ;;
 634   freebsd*)
 635     AC_DEFINE(BSD42)
 636     ;;
 637   netbsd*)
 638     AC_DEFINE(BSD42)
 639     ;;
 640   openbsd*)
 641     AC_DEFINE(BSD42)
 642     ;;
 643   bsd/os*)
 644     AC_DEFINE(BSD42)
 645     ;;
 646   sco5*)
 647     AC_DEFINE(SCO_5_STDIO)
 648     ;;
 649 esac
 650
 651
 652 dnl ----------------
 653 dnl OUTPUT MAKEFILES
 654 dnl ----------------
 655 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 656                 etc/Makefile docs/Makefile man/Makefile)
 657 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 658 AC_OUTPUT
 659
 660 dnl These odd looking assignments are done to expand out unexpanded
 661 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 662 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 663 dnl again to get the final answer.
 664 dnl We only use the expanded versions to print the install paths in
 665 dnl the final summary and should use them nowhere else (see the autoconf
 666 dnl docs for the rationale for bindir etc being unexpanded).
 667 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 668 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 669 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 670 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 671
 672 echo "
 673 mmh configuration
 674 -----------------
 675 mmh version            : AC_PACKAGE_VERSION
 676 target os              : ${target}
 677 compiler               : ${CC}
 678 compiler flags         : ${CFLAGS}
 679 linker flags           : ${LDFLAGS}
 680 definitions            : ${OURDEFS}
 681 source code location   : ${srcdir}
 682
 683 binary install path    : ${nmhbin}
 684 library install path   : ${nmhlib}
 685 config install path    : ${nmhsysconf}
 686 man page install path  : ${nmhman}
 687
 688 sendmail path          : ${sendmailpath}
 689 mail spool             : ${mailspool}
 690
 691 file locking type      : ${LOCKTYPE}
 692 "