git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4 dnl $Id$
   5 dnl
   6
   7 AC_INIT(h/nmh.h)
   8 AC_CONFIG_HEADER(config.h)
   9
  10 AC_CANONICAL_SYSTEM
  11
  12 dnl What version of nmh are we building?
  13 VERSION=`sed -e 's/nmh-//' ${srcdir}/VERSION`
  14 echo "configuring for nmh-$VERSION"
  15 AC_SUBST(VERSION)dnl
  16
  17 dnl -------------------------
  18 dnl CHECK COMMAND LINE OPTION
  19 dnl -------------------------
  20 dnl What method of posting should post use?
  21 undefine([mts])dnl
  22 AC_ARG_WITH(mts,
  23 [  --with-mts=MTS          specify the mail transport agent])
  24
  25 if test x$with_mts = xsmtp; then
  26   MTS="smtp"
  27   MTSLIB="mts/smtp/libsmtp.a"
  28   AC_DEFINE(SMTPMTS)dnl
  29 elif test x$with_mts = xsendmail; then
  30   MTS="sendmail"
  31   MTSLIB="mts/sendmail/libsend.a"
  32   AC_DEFINE(SENDMTS)dnl
  33 else
  34   MTS="smtp"
  35   MTSLIB="mts/smtp/libsmtp.a"
  36   AC_DEFINE(SMTPMTS)dnl
  37 fi
  38
  39 AC_SUBST(MTS)
  40 AC_SUBST(MTSLIB)
  41
  42 dnl What should be the default editor?
  43 undefine([editor])dnl
  44 AC_ARG_WITH(editor,
  45 [  --with-editor=EDITOR    specify the default editor])
  46
  47 if test -n "$with_editor"; then
  48   editorpath="$with_editor"
  49 fi
  50
  51 dnl What should be the default pager?
  52 undefine([pager])dnl
  53 AC_ARG_WITH(pager,
  54 [  --with-pager=PAGER      specify the default pager])
  55
  56 if test -n "$with_pager"; then
  57   pagerpath="$with_pager"
  58 fi
  59
  60 dnl Do you want mhe support?
  61 undefine([nmh-mhe])dnl
  62 AC_ARG_ENABLE(nmh-mhe,
  63 [  --enable-nmh-mhe        enable mhe support (DEFAULT)])
  64
  65 dnl mhe support is on by default, so define it unless
  66 dnl explicitly disabled.
  67 if test x$enable_nmh_mhe != xno; then
  68   AC_DEFINE(MHE)dnl
  69 fi
  70
  71 dnl Do you want client-side support for pop
  72 undefine([nmh-pop])dnl
  73 AC_ARG_ENABLE(nmh-pop,
  74 [  --enable-nmh-pop        enable client-side support for pop])
  75 if test x$enable_nmh_pop = xyes; then
  76   AC_DEFINE(POP)dnl
  77   POPLIB=popsbr.o
  78   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
  79 else
  80   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
  81 fi
  82 AC_SUBST(POPLIB)dnl
  83 AC_SUBST(POPSED)dnl
  84
  85 dnl Do you want client-side support for kpop
  86 AC_ARG_WITH(krb4,
  87 [  --with-krb4=PREFIX      specify location of Kerberos V4 for kpop support])
  88 if test x$with_krb4 != x -a x$with_krb4 != xno; then
  89   AC_DEFINE(KPOP)dnl
  90   AC_DEFINE(KPOP_PRINCIPAL, "pop")dnl
  91 fi
  92
  93 dnl Do you want support for hesiod
  94 AC_ARG_WITH(hesiod,
  95 [  --with-hesiod=PREFIX    specify location of Hesiod])
  96 if test x$with_hesiod != x -a x$with_hesiod != xno; then
  97   AC_DEFINE(HESIOD)dnl
  98 fi
  99
 100 dnl Do you want to debug nmh?
 101 undefine([nmh-debug])dnl
 102 AC_ARG_ENABLE(nmh-debug,
 103 [  --enable-nmh-debug      enable nmh code debugging])
 104
 105 dnl ----------------------------------------------------
 106 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 107 dnl ----------------------------------------------------
 108 AC_PREFIX_DEFAULT(/usr/local/nmh)
 109
 110 dnl ------------------
 111 dnl CHECK THE COMPILER
 112 dnl ------------------
 113 dnl We want these before the checks,
 114 dnl so the checks can modify their values.
 115 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 116 if test x$enable_nmh_debug = xyes; then
 117   test -z "$LDFLAGS" && LDFLAGS=-g
 118 fi
 119
 120 AC_PROG_CC
 121
 122 dnl if the user hasn't specified CFLAGS, then
 123 dnl   if compiler is gcc, then
 124 dnl     use -O2 and some warning flags
 125 dnl   else use -O
 126 if test -n "$auto_cflags"; then
 127   if test x$enable_nmh_debug = xyes; then
 128     if test -n "$GCC"; then
 129       test -z "$CFLAGS" && CFLAGS="-Wall -g" || CFLAGS="$CFLAGS -Wall -g"
 130     else
 131       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 132     fi
 133   else
 134     test -z "$LDFLAGS" && LDFLAGS=-s
 135     if test -n "$GCC"; then
 136       test -z "$CFLAGS" && CFLAGS=-O2 || CFLAGS="$CFLAGS -O2"
 137     else
 138       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 139     fi
 140   fi
 141 fi
 142
 143 AC_C_CONST              dnl Does compiler support `const'.
 144
 145 dnl ------------------
 146 dnl CHECK FOR PROGRAMS
 147 dnl ------------------
 148 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 149 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 150 AC_PROG_RANLIB          dnl Check for `ranlib'
 151 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 152 AC_PROG_LEX             dnl Check for lex/flex
 153
 154 dnl Look for `cut'
 155 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 156 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 157
 158 dnl Check for lorder and tsort commands
 159 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 160 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 161
 162 dnl If either doesn't exist, replace them with echo and cat
 163 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 164   LORDER=echo
 165   TSORT=cat
 166   AC_SUBST(LORDER)dnl
 167   AC_SUBST(TSORT)dnl
 168 fi
 169
 170 dnl Look for `ls'
 171 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 172 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 173
 174 dnl See how we get ls to display the owner and the group
 175 if test "$lspath" != "no"; then
 176   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 177                  nmh_cv_ls_grpopt,
 178   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 179     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 180     dnl ls, it would seem -l gave us both the user and group.  On this type of
 181     dnl ls, -g makes _only_ the group be displayed (and not the user).
 182     nmh_cv_ls_grpopt="-l"
 183   else
 184     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 185     nmh_cv_ls_grpopt="-lg"
 186   fi])
 187 fi
 188
 189 dnl Look for `more'
 190 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 191 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 192
 193 dnl If pager is not specified yet,
 194 dnl then use `more' as the default.
 195 if test -z "$pagerpath"; then
 196   pagerpath="$morepath"
 197 fi
 198 AC_SUBST(pagerpath)dnl
 199
 200 dnl Look for `sendmail'
 201 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 202 AC_PATH_PROG(sendmailpath, sendmail, no, [$pathtmp])
 203
 204 dnl Look for `vi'
 205 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 206 AC_PATH_PROG(vipath, vi, no, [$pathtmp])
 207
 208 dnl If editor is not specified yet,
 209 dnl then use `vi' as the default.
 210 if test -z "$editorpath"; then
 211   editorpath="$vipath"
 212 fi
 213 AC_SUBST(editorpath)dnl
 214
 215 dnl Check for broken vi
 216 AC_CACHE_CHECK(for broken vi, nmh_cv_attvibug,
 217 [if echo 'r /nonexist-file
 218 q' | ex > /dev/null 2>&1
 219 then
 220         nmh_cv_attvibug=no
 221 else
 222         nmh_cv_attvibug=yes
 223 fi])
 224
 225 if test "$nmh_cv_attvibug" = yes; then
 226   AC_DEFINE(ATTVIBUG)
 227 fi
 228
 229 dnl ----------------------------------------------------------
 230 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 231 dnl ----------------------------------------------------------
 232 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 233 [for mailspool in /var/mail        dnl
 234                   /var/spool/mail  dnl
 235                   /usr/spool/mail  dnl
 236                   /dev/null;       dnl Just in case we fall through
 237 do
 238   test -d $mailspool && break
 239 done
 240 nmh_cv_mailspool=$mailspool
 241 ])
 242 mailspool=$nmh_cv_mailspool
 243 AC_SUBST(mailspool)dnl
 244
 245 dnl See whether the mail spool directory is world-writable.
 246 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 247   AC_CACHE_CHECK(whether the mail spool is world-writable,
 248                  nmh_cv_mailspool_world_writable,
 249   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 250     nmh_cv_mailspool_world_writable=no
 251   else
 252     nmh_cv_mailspool_world_writable=yes
 253   fi])
 254 fi
 255
 256 dnl ...If it's not, we need to #define MAILGROUP to 1 and make inc setgid.
 257 if test x"$nmh_cv_mailspool_world_writable" = x"no"; then
 258   dnl do we really need both of these?
 259   AC_DEFINE(MAILGROUP)
 260   SETGID_MAIL=1
 261 fi
 262 AC_SUBST(SETGID_MAIL)dnl
 263
 264 dnl see if we can determine which group owns the mail spool dir
 265 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 266 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 267  dnl Should we just set it to whatever ls reports, rather than only allowing
 268  dnl certain values...?
 269  if test x$nmh_cv_ls_mail_grp = xmail; then
 270    MAIL_SPOOL_GRP="mail"
 271  elif test x$nmh_cv_ls_mail_grp = xwheel; then
 272    MAIL_SPOOL_GRP="wheel"
 273  else
 274    MAIL_SPOOL_GRP="'0'"
 275  fi])
 276 AC_SUBST(MAIL_SPOOL_GRP)dnl
 277
 278 dnl ------------------
 279 dnl CHECK HEADER FILES
 280 dnl ------------------
 281 AC_HEADER_DIRENT
 282 AC_HEADER_STDC
 283 AC_HEADER_TIME
 284 AC_HEADER_SYS_WAIT
 285 AC_HEADER_STAT
 286 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 287                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 288                  sys/param.h sys/time.h sys/utsname.h arpa/inet.h \
 289                  arpa/ftp.h)
 290
 291
 292 AC_CACHE_CHECK(POSIX termios, nmh_cv_sys_posix_termios,
 293 [AC_TRY_LINK([#include <sys/types.h>
 294 #include <unistd.h>
 295 #include <termios.h>],
 296 [/* SunOS 4.0.3 has termios.h but not the library calls.  */
 297 tcgetattr(0, 0);],
 298   nmh_cv_sys_posix_termios=yes, nmh_cv_sys_posix_termios=no)])
 299
 300 if test $nmh_cv_sys_posix_termios = yes; then
 301   AC_CACHE_CHECK(TIOCGWINSZ in termios.h,
 302   nmh_cv_header_termios_h_tiocgwinsz,
 303   [AC_TRY_LINK([#include <sys/types.h>
 304 #include <termios.h>],
 305   [int x = TIOCGWINSZ;],
 306   nmh_cv_header_termios_h_tiocgwinsz=yes,
 307   nmh_cv_header_termios_h_tiocgwinsz=no)])
 308 else
 309   nmh_cv_header_termios_h_tiocgwinsz=no
 310 fi
 311
 312 if test $nmh_cv_header_termios_h_tiocgwinsz = no; then
 313   AC_CACHE_CHECK(TIOCGWINSZ in sys/ioctl.h,
 314   nmh_cv_header_sys_ioctl_h_tiocgwinsz,
 315   [AC_TRY_LINK([#include <sys/types.h>
 316 #include <sys/ioctl.h>],
 317   [int x = TIOCGWINSZ;],
 318   nmh_cv_header_sys_ioctl_h_tiocgwinsz=yes,
 319   nmh_cv_header_sys_ioctl_h_tiocgwinsz=no)])
 320   if test $nmh_cv_header_sys_ioctl_h_tiocgwinsz = yes; then
 321     AC_DEFINE(GWINSZ_IN_SYS_IOCTL)
 322   fi
 323 fi
 324
 325 dnl
 326 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 327 dnl really use a whole set of them, but this check should be
 328 dnl sufficient.
 329 dnl
 330 AC_CHECK_HEADER(libio.h, [
 331   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 332     AC_DEFINE(LINUX_STDIO) ]) ])
 333
 334 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM))
 335
 336 dnl ---------------
 337 dnl CHECK FUNCTIONS
 338 dnl ---------------
 339 AC_FUNC_VFORK
 340 AC_CHECK_LIB(mkstemp,mkstemp)
 341 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 342                sighold sigrelse writev lstat uname tzset killpg mkstemp)
 343
 344 dnl sigsetjmp may be a macro
 345 AC_MSG_CHECKING(for sigsetjmp)
 346 AC_TRY_LINK([#include <setjmp.h>], [sigsetjmp((void *)0, 0);],
 347         [AC_DEFINE(HAVE_SIGSETJMP) AC_MSG_RESULT(yes)], AC_MSG_RESULT(no))
 348
 349 AC_REPLACE_FUNCS(snprintf strerror strdup)
 350
 351 dnl -------------------
 352 dnl CHECK FOR LIBRARIES
 353 dnl -------------------
 354 dnl Check location of modf
 355 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 356
 357 dnl Checks for network libraries (nsl, socket)
 358 AC_CHECK_NETLIBS
 359
 360 dnl Check for bug in libraries such that ruserpass
 361 dnl needs to be linked as _ruserpass.
 362 AC_CHECK_RUSERPASS
 363
 364 termcap_curses_order="termcap curses ncurses"
 365 for lib in $termcap_curses_order; do
 366   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 367 done
 368 AC_SUBST(TERMLIB)dnl
 369
 370
 371 dnl --------------
 372 dnl CHECK FOR NDBM
 373 dnl --------------
 374 dnl Checks for ndbm
 375 AC_CHECK_FUNC(dbm_open, ,
 376   AC_CHECK_LIB(ndbm, dbm_open, ,
 377     AC_CHECK_LIB(dbm, dbm_open)))
 378
 379 dnl ----------------
 380 dnl CHECK FOR NDBM.H
 381 dnl ----------------
 382 AC_CHECK_HEADERS(db1/ndbm.h)
 383
 384 dnl ----------------
 385 dnl CHECK FOR HESIOD
 386 dnl ----------------
 387 if test x$with_hesiod != x -a x$with_hesiod != xno; then
 388   if test x$with_hesiod != xyes; then
 389     HESIOD_INCLUDES="-I$with_hesiod/include"
 390     HESIOD_LIBS="-L$with_hesiod/lib"
 391   fi
 392   AC_CHECK_FUNC(res_send, ,
 393     AC_CHECK_LIB(resolv, res_send))
 394   AC_CHECK_LIB(hesiod, hes_resolve, [HESIOD_LIBS="$HESIOD_LIBS -lhesiod"],
 395     [AC_MSG_ERROR(Hesiod library not found)], $HESIOD_LIBS)
 396 fi
 397 AC_SUBST(HESIOD_INCLUDES)dnl
 398 AC_SUBST(HESIOD_LIBS)dnl
 399
 400 dnl ----------------------------------
 401 dnl CHECK FOR KRB4 (Kerberos4 support)
 402 dnl ----------------------------------
 403 if test x$with_krb4 != x -a x$with_krb4 != xno; then
 404   if test x$with_krb4 != xyes; then
 405     KRB4_INCLUDES="-I$with_krb4/include"
 406     if test -d "$with_krb4/include/kerberosIV"; then
 407       KRB4_INCLUDES="$KRB4_INCLUDES -I$with_krb4/include/kerberosIV"
 408     fi
 409     KRB4_LIBS="-L$with_krb4/lib"
 410   elif test -d /usr/include/kerberosIV; then
 411     KRB4_INCLUDES="-I/usr/include/kerberosIV"
 412   fi
 413   AC_CHECK_LIB(krb4, krb_rd_req,
 414     [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lcrypto -lcom_err"],
 415     [AC_CHECK_LIB(krb, krb_rd_req,
 416       [KRB4_LIBS="$KRB4_LIBS -lkrb -ldes"],
 417       [AC_MSG_ERROR(Kerberos 4 libraries not found)],
 418       $KRB4_LIBS -ldes)],
 419     $KRB4_LIBS -ldes425 -lkrb5 -lcrypto -lcom_err)
 420 fi
 421 AC_SUBST(KRB4_INCLUDES)dnl
 422 AC_SUBST(KRB4_LIBS)dnl
 423
 424 dnl ---------------------
 425 dnl CHECK TERMCAP LIBRARY
 426 dnl ---------------------
 427
 428 dnl Add the termcap library, so that the following configure
 429 dnl tests will find it when it tries to link test programs.
 430 nmh_save_LIBS="$LIBS"
 431 LIBS="$TERMLIB $LIBS"
 432
 433 dnl Checks for external variable ospeed in the termcap library.
 434 AC_CACHE_CHECK(if an include file defines ospeed,
 435 nmh_cv_decl_ospeed_include_defines,
 436 [AC_TRY_LINK(
 437 [#include <sys/types.h>
 438 #if HAVE_TERMIOS_H
 439 #include <termios.h>
 440 #endif
 441 #if HAVE_TERMCAP_H
 442 #include <termcap.h>
 443 #endif], [ospeed = 0;],
 444 nmh_cv_decl_ospeed_include_defines=yes,
 445 nmh_cv_decl_ospeed_include_defines=no)])
 446
 447 if test $nmh_cv_decl_ospeed_include_defines = no; then
 448   AC_CACHE_CHECK(if you must define ospeed,
 449   nmh_cv_decl_ospeed_must_define,
 450   [AC_TRY_LINK( ,[extern short ospeed; ospeed = 0;],
 451   nmh_cv_decl_ospeed_must_define=yes,
 452   nmh_cv_decl_ospeed_must_define=no)])
 453 fi
 454
 455 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 456   AC_DEFINE(HAVE_OSPEED)
 457 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 458   AC_DEFINE(HAVE_OSPEED)
 459   AC_DEFINE(MUST_DEFINE_OSPEED)
 460 fi
 461
 462 dnl dnl Checks if tgetent accepts NULL and will
 463 dnl dnl allocate its own termcap buffer.
 464 dnl AC_CACHE_CHECK(if tgetent accepts NULL,
 465 dnl nmh_cv_func_tgetent_accepts_null,
 466 dnl [AC_TRY_RUN([main(){int i = tgetent((char*)0,"vt100");exit(!i || i == -1);}],
 467 dnl   nmh_cv_func_tgetent_accepts_null=yes,
 468 dnl   nmh_cv_func_tgetent_accepts_null=no,
 469 dnl   nmh_cv_func_tgetent_accepts_null=no)])
 470 dnl if test $nmh_cv_func_tgetent_accepts_null = yes; then
 471 dnl   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 472 dnl fi
 473
 474 dnl Now put the libraries back to what it was before we
 475 dnl starting checking the termcap library.
 476 LIBS="$nmh_save_LIBS"
 477
 478 dnl --------------
 479 dnl CHECK TYPEDEFS
 480 dnl --------------
 481 AC_TYPE_SIGNAL
 482 AC_TYPE_PID_T
 483 AC_TYPE_OFF_T
 484 AC_TYPE_UID_T
 485 AC_TYPE_MODE_T
 486 AC_TYPE_SIZE_T
 487
 488 dnl Check for sigset_t.  Currently I'm looking in
 489 dnl <sys/types.h> and <signal.h>.  Others might need
 490 dnl to be added.
 491 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 492 [AC_TRY_COMPILE(
 493 [#include <sys/types.h>
 494 #include <signal.h>], [sigset_t tempsigset;],
 495   nmh_cv_type_sigset_t=yes, nmh_cv_type_sigset_t=no)])
 496 if test $nmh_cv_type_sigset_t = no; then
 497   AC_DEFINE(sigset_t, unsigned int)
 498 fi
 499
 500 dnl ----------------
 501 dnl CHECK STRUCTURES
 502 dnl ----------------
 503 AC_STRUCT_ST_BLKSIZE
 504
 505 AC_CACHE_CHECK(for tm_gmtoff in struct tm, nmh_cv_struct_tm_gmtoff,
 506 [AC_TRY_COMPILE(
 507 [#ifdef TIME_WITH_SYS_TIME
 508 # include <sys/time.h>
 509 # include <time.h>
 510 #else
 511 # ifdef TM_IN_SYS_TIME
 512 #  include <sys/time.h>
 513 # else
 514 #  include <time.h>
 515 # endif
 516 #endif],
 517 [struct tm temptm; temptm.tm_gmtoff = 0;],
 518   nmh_cv_struct_tm_gmtoff=yes, nmh_cv_struct_tm_gmtoff=no)])
 519 if test $nmh_cv_struct_tm_gmtoff = yes; then
 520   AC_DEFINE(HAVE_TM_GMTOFF)
 521 fi
 522
 523 dnl -------------
 524 dnl CHECK SIGNALS
 525 dnl -------------
 526 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 527 AC_MSG_CHECKING(what style of signals to use)
 528 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 529   signals_style=POSIX_SIGNALS
 530   AC_DEFINE(POSIX_SIGNALS)
 531   AC_DEFINE(RELIABLE_SIGNALS)
 532 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 533   signals_style=BSD_SIGNALS
 534   AC_DEFINE(BSD_SIGNALS)
 535   AC_DEFINE(RELIABLE_SIGNALS)
 536 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 537   signals_style=SYSV_SIGNALS
 538   AC_DEFINE(SYSV_SIGNALS)
 539 else
 540   signals_style=NO_SIGNAL_BLOCKING
 541   AC_DEFINE(NO_SIGNAL_BLOCKING)
 542 fi
 543
 544 AC_MSG_RESULT($signals_style)
 545
 546 dnl Where is <signal.h> located?  Needed as input for signames.awk
 547 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 548 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 549                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 550                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 551                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 552                  /usr/include/sys/signal.h      dnl Almost everybody else
 553                  /dev/null;                     dnl Just in case we fall through
 554 do
 555   test -f $SIGNAL_H && \
 556   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 557   break
 558 done
 559 nmh_cv_path_signal_h=$SIGNAL_H
 560 ])
 561 SIGNAL_H=$nmh_cv_path_signal_h
 562 AC_SUBST(SIGNAL_H)dnl
 563
 564 dnl ----------------
 565 dnl OS SPECIFIC DEFINES
 566 dnl ----------------
 567 case "$target_os" in
 568
 569   solaris2*)
 570     AC_DEFINE(SYS5)
 571     AC_DEFINE(SVR4)
 572     ;;
 573   irix*)
 574     AC_DEFINE(SYS5)
 575     AC_DEFINE(SVR4)
 576     ;;
 577   osf*)
 578     AC_DEFINE(SYS5)
 579     AC_DEFINE(SVR4)
 580     ;;
 581   aix*)
 582     AC_DEFINE(SYS5)
 583     AC_DEFINE(SVR4)
 584     ;;
 585   sunos4*)
 586     AC_DEFINE(BIND)
 587     AC_DEFINE(BSD42)
 588     ;;
 589   freebsd*)
 590     AC_DEFINE(BIND)
 591     AC_DEFINE(BSD42)
 592     AC_DEFINE(BSD44)
 593     ;;
 594   netbsd*)
 595     AC_DEFINE(BIND)
 596     AC_DEFINE(BSD42)
 597     AC_DEFINE(BSD44)
 598     ;;
 599   openbsd*)
 600     AC_DEFINE(BIND)
 601     AC_DEFINE(BSD42)
 602     AC_DEFINE(BSD44)
 603     ;;
 604   bsd/os*)
 605     AC_DEFINE(BIND)
 606     AC_DEFINE(BSD42)
 607     AC_DEFINE(BSD44)
 608     ;;
 609   sco5*)
 610     AC_DEFINE(SYS5)
 611     AC_DEFINE(SCO_5_STDIO)
 612     ;;
 613 esac
 614
 615
 616 dnl ----------------
 617 dnl OUTPUT MAKEFILES
 618 dnl ----------------
 619 AC_OUTPUT(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 620           zotnet/Makefile zotnet/mts/Makefile zotnet/tws/Makefile \
 621           zotnet/mf/Makefile zotnet/bboards/Makefile mts/Makefile \
 622           mts/smtp/Makefile mts/sendmail/Makefile mts/mmdf/Makefile \
 623           etc/Makefile man/Makefile, \
 624           [test -z "$CONFIG_HEADERS" || echo > stamp-h])
 625
 626 eval "nmhbin=${bindir}";         eval "nmhbin2=${nmhbin}"
 627 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf2=${nmhsysconf}"
 628 eval "nmhlib=${libdir}";         eval "nmhlib2=${nmhlib}"
 629 eval "nmhman=${mandir}"
 630
 631 echo "
 632 nmh configuration
 633 -----------------
 634 nmh version               : ${VERSION}
 635 target os                 : ${target}
 636 compiler                  : ${CC}
 637 compiler flags            : ${CFLAGS}
 638 linker flags              : ${LDFLAGS}
 639 source code location      : ${srcdir}
 640 binary install path       : ${nmhbin2}
 641 libary install path       : ${nmhlib2}
 642 config files install path : ${nmhsysconf2}
 643 man page install path     : ${nmhman}
 644 transport system          : ${MTS}
 645 default editor            : ${editorpath}
 646 default pager             : ${pagerpath}"
 647 echo ""