git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4 dnl $Id$
   5 dnl
   6
   7 dnl Move this up a bit
   8 AC_PREREQ(2.61)
   9
  10 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
  11 AC_CONFIG_SRCDIR(h/nmh.h)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 AC_CANONICAL_TARGET
  15
  16 dnl ---------------------
  17 dnl define a macro or two
  18 dnl ---------------------
  19
  20 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  21 if test -n "$LIBTOOL" ; then
  22   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  23   if test x"$tmptest" != x  ; then
  24     GNU_LIBTOOL=1
  25     AC_SUBST(GNU_LIBTOOL)dnl
  26   fi
  27 fi
  28 ] )
  29
  30 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  31 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  32
  33 dnl What date of nmh are we building?
  34 DATE=`cat ${srcdir}/DATE`
  35 echo "configuring for nmh dated $DATE"
  36 AC_SUBST(DATE)dnl
  37
  38 dnl --------------------------
  39 dnl CHECK COMMAND LINE OPTIONS
  40 dnl --------------------------
  41
  42 dnl Do you want client-side support for apop?
  43 AC_ARG_ENABLE(apop, AS_HELP_STRING([--enable-apop],
  44   [enable client-side support for POP3 and APOP]))
  45 if test x"$enable_apop" = x"yes"; then
  46   AC_DEFINE(APOP, 1,
  47     [Define to compile client-side support for apop into inc and msgchk.])dnl
  48   APOPLIB=md5.o
  49   enable_pop=yes
  50 fi
  51 AC_SUBST(APOPLIB)dnl
  52
  53 dnl Do you want to debug nmh?
  54 AC_ARG_ENABLE(debug,
  55   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  56 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  57 if test x"$enable_nmh_debug" = x"yes"; then
  58   enable_debug=yes
  59 fi
  60
  61 dnl Allow users to send email from addresses other than their default?
  62 AC_ARG_ENABLE(masquerade,
  63   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  64     [enable up to 3 types of address masquerading]),
  65   [if test x"$enable_masquerade" = x"yes"; then
  66     masquerade="draft_from mmailid username_extension"
  67   else
  68     masquerade="$enable_masquerade"
  69   fi],
  70   masquerade="draft_from mmailid username_extension")
  71 AC_SUBST(masquerade)dnl
  72
  73 dnl Do you want mhe support?
  74 AC_ARG_ENABLE(mhe,
  75   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  76
  77 dnl mhe support is on by default, so define it unless --disable-mhe or the
  78 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  79 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  80   AC_DEFINE(MHE, 1,
  81     [Define to compile in support for the Emacs front-end mh-e.])dnl
  82 fi
  83
  84 dnl Do you want client-side support for pop?
  85 AC_ARG_ENABLE(pop,
  86   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  87 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  88 if test x"$enable_nmh_pop" = x"yes"; then
  89   enable_pop=yes
  90 fi
  91
  92 dnl Do you want to disable use of locale functions
  93 AH_TEMPLATE([LOCALE],
  94 [Undefine if you don't want locale features.  By default this is defined.])
  95 AC_ARG_ENABLE([locale],
  96 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  97 [if test x$enableval = xyes; then
  98   AC_DEFINE(LOCALE)
  99 fi],
 100 AC_DEFINE(LOCALE)
 101 )
 102
 103 dnl Do you want client-side support for using SASL for authentication?
 104 dnl Note that this code will be enabled for both POP and SMTP
 105 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
 106   [Enable SASL support via the Cyrus SASL library]))
 107 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
 108   AC_DEFINE(CYRUS_SASL, 1,
 109     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
 110   sasl_support=yes
 111 else
 112   sasl_support=no
 113 fi
 114
 115 dnl Do you want client-side support for encryption with TLS?
 116 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
 117 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
 118   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
 119   tls_support=yes
 120 else
 121   tls_support=no
 122 fi
 123
 124 dnl What should be the default editor?
 125 AC_ARG_WITH(editor,
 126   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 127
 128 if test -n "$with_editor"; then
 129   editorpath="$with_editor"
 130 fi
 131
 132 dnl Set the backup prefix
 133 AC_ARG_WITH([hash-backup],
 134   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 135 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 136   backup_prefix="#"
 137 else
 138   backup_prefix=","
 139 fi
 140 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 141     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 142
 143 dnl Do you want support for hesiod
 144 AC_ARG_WITH(hesiod,
 145   AS_HELP_STRING([--with-hesiod=DIR],[specify location of Hesiod]))
 146 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 147   AC_DEFINE(HESIOD,1,[Define this to compile support for using Hesiod.])dnl
 148 fi
 149
 150 dnl After we know if we're including apop and kpop support, do pop stuff
 151 if test x"$enable_pop" = x"yes"; then
 152   AC_DEFINE(POP, 1,
 153     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 154   POPLIB=popsbr.o
 155   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 156 else
 157   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 158 fi
 159 AC_SUBST(POPLIB)dnl
 160 AC_SUBST(POPSED)dnl
 161
 162 dnl What method of locking to use?
 163 AC_ARG_WITH(locking,
 164   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 165   [specify the file locking method]))
 166
 167 if test x"$with_locking" = x"dot"; then
 168   LOCKTYPE="dot"
 169   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 170 elif test x"$with_locking" = x"flock"; then
 171   LOCKTYPE="flock"
 172   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 173 elif test x"$with_locking" = x"lockf"; then
 174   LOCKTYPE="lockf"
 175   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 176 elif test x"$with_locking" = x"fcntl"; then
 177   LOCKTYPE="fcntl"
 178   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 179 else
 180   LOCKTYPE="dot"
 181   AC_DEFINE(DOT_LOCKING)dnl
 182 fi
 183
 184 dnl What method of posting should post use?
 185 AC_ARG_WITH(mts,
 186   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 187   [specify the default mail transport agent/service]))
 188
 189 if test x"$with_mts" = x"smtp"; then
 190   MTS="smtp"
 191 elif test x"$with_mts" = x"sendmail"; then
 192   MTS="sendmail"
 193 else
 194   MTS="smtp"
 195 fi
 196 AC_SUBST(MTS)dnl
 197
 198 dnl Both the smtp and sendmail mail transport services use the smtp code
 199 AC_DEFINE(SMTPMTS, 1,
 200   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 201
 202 dnl What should be the default pager?
 203 AC_ARG_WITH(pager,
 204   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 205
 206 if test -n "$with_pager"; then
 207   pagerpath="$with_pager"
 208 fi
 209
 210 dnl What should be the default mail server(s)?
 211 AC_ARG_WITH(smtpservers,
 212   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 213   [specify the default SMTP server(s) @<:@localhost@:>@]))
 214 if test -n "$with_smtpservers"; then
 215   smtpservers="$with_smtpservers"
 216 else
 217   smtpservers="localhost"
 218 fi
 219 AC_SUBST(smtpservers)dnl
 220
 221 dnl ----------------------------------------------------
 222 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 223 dnl ----------------------------------------------------
 224 AC_PREFIX_DEFAULT(/usr/local/nmh)
 225
 226 dnl ------------------
 227 dnl CHECK THE COMPILER
 228 dnl ------------------
 229 dnl We want these before the checks,
 230 dnl so the checks can modify their values.
 231 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 232 if test x"$enable_debug" = x"yes"; then
 233   test -z "$LDFLAGS" && LDFLAGS=-g
 234 fi
 235
 236 AC_PROG_CC
 237
 238 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 239 [nmh_saved_cflags="$CFLAGS"
 240  CFLAGS="$CFLAGS -Wno-pointer-sign"
 241  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 242  CFLAGS="$nmh_saved_cflags"])
 243
 244 dnl if the user hasn't specified CFLAGS, then
 245 dnl   if compiler is gcc, then
 246 dnl     use -O2 and some warning flags
 247 dnl   else use -O
 248 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 249 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 250 dnl spurious and which in any case we don't want to deal with now.
 251 if test "$nmh_cv_has_noptrsign" = "yes"; then
 252         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 253 else
 254         nmh_gcc_warnflags="-Wall"
 255 fi
 256
 257 if test -n "$auto_cflags"; then
 258   if test x"$enable_debug" = x"yes"; then
 259     if test -n "$GCC"; then
 260       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 261     else
 262       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 263     fi
 264   else
 265     if test -z "$LDFLAGS"; then
 266       case "$build_os" in
 267         darwin*)
 268           LDFLAGS=
 269           ;;
 270         *)
 271           LDFLAGS=-s
 272           ;;
 273       esac
 274     fi
 275     if test -n "$GCC"; then
 276       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 277     else
 278       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 279     fi
 280   fi
 281 fi
 282
 283 AC_C_CONST              dnl Does compiler support `const'.
 284
 285 dnl ------------------
 286 dnl CHECK FOR PROGRAMS
 287 dnl ------------------
 288 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 289 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 290 AC_PROG_RANLIB          dnl Check for `ranlib'
 291 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 292 AC_PROG_LEX             dnl Check for lex/flex
 293
 294 dnl Look for `cut'
 295 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 296 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 297
 298 dnl ----------------------------------------------
 299 dnl check for lclint, and lint if it doesn't exist
 300 dnl ----------------------------------------------
 301 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 302 if test x$ac_cv_prog_linttmp1 != xno ; then
 303   LINT=$ac_cv_prog_linttmp1
 304   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 305 else
 306   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 307   if test x$ac_cv_prog_linttmp2 != xno ; then
 308     LINT=$ac_cv_prog_linttmp2
 309     LINTFLAGS=""
 310   else
 311     LINT="echo 'No lint program found'"
 312     LINTFLAGS=""
 313   fi
 314 fi
 315 AC_SUBST(LINT)dnl
 316 AC_SUBST(LINTFLAGS)dnl
 317
 318 dnl try to figure out which one we've got
 319 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 320 NMH_PROG_GNU_LIBTOOL
 321
 322 dnl Check for lorder and tsort commands
 323 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 324 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 325
 326 dnl If either doesn't exist, replace them with echo and cat
 327 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 328   LORDER=echo
 329   TSORT=cat
 330   AC_SUBST(LORDER)dnl
 331   AC_SUBST(TSORT)dnl
 332 dnl Mac OS X has lorder, but sh is too broken for it to work
 333 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 334 dnl   LORDER=echo
 335 dnl   TSORT=cat
 336 dnl   AC_SUBST(LORDER)dnl
 337 dnl   AC_SUBST(TSORT)dnl
 338 fi
 339
 340 dnl Check whether tsort can deal with loops
 341 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 342   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 343     nmh_cv_tsort_loop=no
 344   else
 345     nmh_cv_tsort_loop=yes
 346   fi])
 347 if test x$nmh_cv_tsort_loop = xno ; then
 348   LORDER=echo
 349   TSORT=cat
 350   AC_SUBST(LORDER)dnl
 351   AC_SUBST(TSORT)dnl
 352 fi
 353
 354 dnl Look for `ls'
 355 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 356 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 357
 358 dnl See how we get ls to display the owner and the group
 359 if test "$lspath" != "no"; then
 360   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 361                  nmh_cv_ls_grpopt,
 362   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 363     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 364     dnl ls, it would seem -l gave us both the user and group.  On this type of
 365     dnl ls, -g makes _only_ the group be displayed (and not the user).
 366     nmh_cv_ls_grpopt="-l"
 367   else
 368     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 369     nmh_cv_ls_grpopt="-lg"
 370   fi])
 371 fi
 372
 373 dnl Look for `more'
 374 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 375 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 376
 377 dnl If pager is not specified yet,
 378 dnl then use `more' as the default.
 379 if test -z "$pagerpath"; then
 380   pagerpath="$morepath"
 381 fi
 382 AC_SUBST(pagerpath)dnl
 383
 384 dnl Look for `sendmail'
 385 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 386 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 387
 388 dnl Look for `vi'
 389 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 390 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 391
 392 dnl If editor is not specified yet,
 393 dnl then use `vi' as the default.
 394 if test -z "$editorpath"; then
 395   editorpath="$vipath"
 396 fi
 397 AC_SUBST(editorpath)dnl
 398
 399 dnl ----------------------------------------------------------
 400 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 401 dnl ----------------------------------------------------------
 402 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 403 [for mailspool in /var/mail        dnl
 404                   /var/spool/mail  dnl
 405                   /usr/spool/mail  dnl
 406                   /dev/null;       dnl Just in case we fall through
 407 do
 408   test -d $mailspool && break
 409 done
 410 nmh_cv_mailspool=$mailspool
 411 ])
 412 mailspool=$nmh_cv_mailspool
 413 AC_SUBST(mailspool)dnl
 414
 415 dnl See whether the mail spool directory is world-writable.
 416 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 417   AC_CACHE_CHECK(whether the mail spool is world-writable,
 418                  nmh_cv_mailspool_world_writable,
 419   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 420     nmh_cv_mailspool_world_writable=no
 421   else
 422     nmh_cv_mailspool_world_writable=yes
 423   fi])
 424 fi
 425
 426 dnl Also, check for liblockfile (as found on Debian systems)
 427 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 428
 429 dnl and whether its companion program dotlockfile is setgid
 430 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 431 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 432   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 433     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 434     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 435         nmh_cv_dotlockfile_setgid=yes
 436       else
 437         nmh_cv_dotlockfile_setgid=no
 438       fi])
 439   fi
 440 fi
 441
 442 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 443 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 444 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 445   dnl do we really need both of these?
 446   AC_DEFINE(MAILGROUP,1,
 447     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 448   SETGID_MAIL=1
 449 fi
 450 AC_SUBST(SETGID_MAIL)dnl
 451
 452 dnl Use ls to see which group owns the mail spool directory.
 453 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 454 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 455 ])
 456 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 457 AC_SUBST(MAIL_SPOOL_GRP)dnl
 458
 459 dnl ------------------
 460 dnl CHECK HEADER FILES
 461 dnl ------------------
 462
 463 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 464 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 465 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 466 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 467 dnl declared; if so they should have an entry added to this case statement.
 468 dnl NB that we must define this on the compiler command line, not in config.h,
 469 dnl because it must be set before any system header is included and there's no
 470 dnl portable way to make sure that files generated by lex include config.h
 471 dnl before system header files.
 472
 473 case "$target_os" in
 474   linux*)
 475     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 476     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 477     ;;
 478 esac
 479 AC_SUBST(OURDEFS)
 480
 481 AC_HEADER_DIRENT
 482 AC_HEADER_STDC
 483 AC_HEADER_TIME
 484 AC_HEADER_SYS_WAIT
 485 AC_HEADER_STAT
 486 AC_HEADER_TIOCGWINSZ
 487 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 488                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 489                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 490                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 491                  arpa/inet.h arpa/ftp.h)
 492
 493 dnl
 494 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 495 dnl really use a whole set of them, but this check should be
 496 dnl sufficient.
 497 dnl
 498 AC_CHECK_HEADER(libio.h, [
 499   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 500     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 501
 502 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 503   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 504 [[#if HAVE_SYS_STREAM_H
 505 #  include <sys/stream.h>
 506 #endif
 507 ]])
 508
 509 dnl ---------------
 510 dnl CHECK FUNCTIONS
 511 dnl ---------------
 512 AC_FUNC_VFORK
 513 AC_CHECK_LIB(mkstemp,mkstemp)
 514 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 515                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 516                getutent nl_langinfo mbtowc wcwidth)
 517
 518 dnl sigsetjmp may be a macro
 519 AC_MSG_CHECKING(for sigsetjmp)
 520 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 521   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 522     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 523   [AC_MSG_RESULT(no)])
 524
 525 AC_REPLACE_FUNCS(memmove snprintf strerror strdup)
 526
 527 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 528 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 529 dnl any system header.
 530 dnl
 531 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 532 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 533 dnl need to check?
 534 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 535 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 536                 AC_EGREP_HEADER(initgroups, unistd.h,
 537                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 538
 539 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 540 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 541 dnl seems to work perfectly and IBM apparently uses it in internal code).
 542 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 543 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 544 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 545 dnl prototype.
 546 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 547   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 548
 549 dnl Check for multibyte character set support
 550 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 551     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 552   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 553     [Define to enable support for multibyte character sets.])
 554 fi
 555
 556 dnl -------------------
 557 dnl CHECK FOR LIBRARIES
 558 dnl -------------------
 559 dnl Check location of modf
 560 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 561
 562 dnl Checks for network libraries (nsl, socket)
 563 AC_CHECK_NETLIBS
 564
 565 termcap_curses_order="termcap curses ncurses"
 566 for lib in $termcap_curses_order; do
 567   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 568 done
 569 AC_SUBST(TERMLIB)dnl
 570
 571 dnl ---------------
 572 dnl CHECK FOR ICONV
 573 dnl ---------------
 574
 575 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 576 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 577   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 578   if test "x$ac_found_iconv" = "xno"; then
 579     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 580     if test "x$ac_found_iconv" = "xno"; then
 581       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 582     fi
 583     if test "x$ac_found_iconv" != "xno"; then
 584       LIBS="-liconv $LIBS"
 585     fi
 586   else
 587     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 588     AC_CHECK_DECL(_libiconv_version,
 589       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 590       [ #include <iconv.h> ])
 591   fi
 592 fi
 593 if test "x$ac_found_iconv" = xyes; then
 594   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 595 fi
 596
 597 dnl Check if iconv uses const in prototype declaration
 598 if test "x$ac_found_iconv" = "xyes"; then
 599   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 600     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 601         #include <iconv.h>]],
 602         [[#ifdef __cplusplus
 603           "C"
 604           #endif
 605           #if defined(__STDC__) || defined(__cplusplus)
 606           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 607           #else
 608           size_t iconv();
 609           #endif]])],
 610       [ac_cv_iconv_const=],
 611       [ac_cv_iconv_const=const])])
 612   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 613     [Define as const if the declaration of iconv() needs const.])
 614 fi
 615
 616 dnl --------------
 617 dnl CHECK FOR NDBM
 618 dnl --------------
 619
 620 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 621             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 622 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 623             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 624
 625 if test "$nmh_ndbm" = "autodetect"; then
 626   if test "$nmh_ndbmheader" != "autodetect"; then
 627     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 628   else
 629
 630     dnl There are at least four implementations of ndbm, and
 631     dnl several of those can be in different places at the whim
 632     dnl of the system integrator. A good summary of this mess
 633     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 634
 635     dnl Classic ndbm with no library required (eg NetBSD): try this
 636     dnl first so we don't accidentally link in a pointless but harmless
 637     dnl library in one of the later ndbm.h+libfoo tests:
 638     NMH_CHECK_NDBM(ndbm.h,,,
 639     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 640       NMH_CHECK_NDBM(db.h,db,,
 641     dnl Berkeley DBv1 emulating ndbm:
 642         NMH_CHECK_NDBM(ndbm.h,db,,
 643           NMH_CHECK_NDBM(ndbm.h,db1,,
 644     dnl Classic ndbm:
 645             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 646     dnl glibc2.1 systems put db1 in a subdir:
 647               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 648     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 649     dnl and possibly needing gbdm_compat library:
 650                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 651                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 652                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 653                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 654
 655   fi
 656 else
 657   dnl We don't really need to check that the user-specified values work,
 658   dnl but it is a convenience to the user to bomb out early rather than
 659   dnl after configure and half the compile process.
 660   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 661 fi
 662
 663 if test "$nmh_ndbm_found" = "no"; then
 664   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 665 else
 666   dnl Now export the lib/header to our makefile/config.h:
 667   if test x"$nmh_ndbmheader" != x; then
 668     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 669       [Define to the header containing the ndbm API prototypes.])
 670   fi
 671   if test x"$nmh_ndbm" != x; then
 672     NDBM_LIBS="-l$nmh_ndbm"
 673   else
 674     NDBM_LIBS=
 675   fi
 676   AC_SUBST(NDBM_LIBS)
 677 fi
 678
 679
 680 dnl ----------------
 681 dnl CHECK FOR HESIOD
 682 dnl ----------------
 683 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 684   if test x"$with_hesiod" != x"yes"; then
 685     HESIOD_INCLUDES="-I$with_hesiod/include"
 686     HESIOD_LIBS="-L$with_hesiod/lib"
 687   fi
 688   AC_CHECK_FUNC(res_send,
 689         [AC_CHECK_LIB(hesiod, hes_resolve,
 690                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod"],
 691                 [AC_MSG_ERROR(Hesiod library not found)],
 692                 $HESIOD_LIBS)],
 693         [AC_CHECK_LIB(hesiod, hes_resolve,
 694                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod -lresolv"],
 695                 [AC_MSG_ERROR(Hesiod library not found)],
 696                 $HESIOD_LIBS -lresolv)])
 697
 698 fi
 699 AC_SUBST(HESIOD_INCLUDES)dnl
 700 AC_SUBST(HESIOD_LIBS)dnl
 701
 702 dnl --------------------
 703 dnl CHECK FOR CYRUS-SASL
 704 dnl --------------------
 705
 706 AS_IF([test x"$sasl_support" = x"yes"],[
 707   AC_CHECK_HEADER([sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 708   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 709     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 710
 711 dnl -----------------
 712 dnl CHECK FOR OPENSSL
 713 dnl -----------------
 714
 715 AS_IF([test x"$tls_support" = x"yes"],[
 716   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 717   AC_CHECK_LIB([crypto], [BIO_write], ,
 718     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 719   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 720     [AC_MSG_ERROR([OpenSSL library not found])])])
 721
 722 dnl ---------------------
 723 dnl CHECK TERMCAP LIBRARY
 724 dnl ---------------------
 725
 726 dnl Add the termcap library, so that the following configure
 727 dnl tests will find it when it tries to link test programs.
 728 nmh_save_LIBS="$LIBS"
 729 LIBS="$TERMLIB $LIBS"
 730
 731 dnl Checks for external variable ospeed in the termcap library.
 732 AC_CACHE_CHECK(if an include file defines ospeed,
 733 nmh_cv_decl_ospeed_include_defines,
 734 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 735 #if HAVE_TERMIOS_H
 736 #include <termios.h>
 737 #endif
 738 #if HAVE_TERMCAP_H
 739 #include <termcap.h>
 740 #endif]], [[ospeed = 0;]])],
 741 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 742
 743 if test $nmh_cv_decl_ospeed_include_defines = no; then
 744   AC_CACHE_CHECK(if you must define ospeed,
 745   nmh_cv_decl_ospeed_must_define,
 746   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 747   [[extern short ospeed; ospeed = 0;]])],
 748   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 749 fi
 750
 751 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 752 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 753   AC_DEFINE(HAVE_OSPEED)dnl
 754 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 755   AC_DEFINE(HAVE_OSPEED)
 756   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 757     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 758 fi
 759
 760 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 761 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 762 dnl in tgetstr().
 763 dnl Under Cygwin test program crashes but exit code is still 0. So,
 764 dnl we test for a file that porgram should create
 765 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 766 [Define to 1 if tgetent() accepts NULL as a buffer.])
 767 AC_CACHE_CHECK(if tgetent accepts NULL,
 768 nmh_cv_func_tgetent_accepts_null,
 769 [AC_TRY_RUN([
 770 main()
 771 {
 772     char buf[4096];
 773     int r1 = tgetent(buf, "vt100");
 774     int r2 = tgetent((char*)0,"vt100");
 775     if (r1 >= 0 && r1 == r2) {
 776         char tbuf[1024], *u;
 777         u = tbuf;
 778         tgetstr("cl", &u);
 779         creat("conftest.tgetent", 0640);
 780     }
 781     exit((r1 != r2) || r2 == -1);
 782 }
 783 ],
 784   if test -f conftest.tgetent; then
 785     nmh_cv_func_tgetent_accepts_null=yes
 786   else
 787     nmh_cv_func_tgetent_accepts_null=no
 788   fi,
 789   nmh_cv_func_tgetent_accepts_null=no,
 790   nmh_cv_func_tgetent_accepts_null=no)])
 791 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 792   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 793 fi
 794 AC_CACHE_CHECK(if tgetent returns 0 on success,
 795 nmh_cv_func_tgetent_zero_success,
 796 [AC_TRY_RUN([
 797 main()
 798 {
 799     char buf[4096];
 800     int r1 = tgetent(buf, "!@#$%^&*");
 801     int r2 = tgetent(buf, "vt100");
 802     if (r1 < 0 && r2 == 0) {
 803         char tbuf[1024], *u;
 804         u = tbuf;
 805         tgetstr("cl", &u);
 806         creat("conftest.tgetent0", 0640);
 807     }
 808     exit(r1 == r2);
 809 }
 810 ],
 811   if test -f conftest.tgetent0; then
 812     nmh_cv_func_tgetent_zero_success=yes
 813   else
 814     nmh_cv_func_tgetent_zero_success=no
 815   fi,
 816   nmh_cv_func_tgetent_zero_success=no,
 817   nmh_cv_func_tgetent_zero_success=no)])
 818 AH_TEMPLATE([TGETENT_SUCCESS],
 819 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 820 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 821   AC_DEFINE(TGETENT_SUCCESS, 0)
 822 else
 823   AC_DEFINE(TGETENT_SUCCESS, 1)
 824 fi
 825
 826 dnl Now put the libraries back to what it was before we
 827 dnl starting checking the termcap library.
 828 LIBS="$nmh_save_LIBS"
 829
 830 dnl --------------
 831 dnl CHECK TYPEDEFS
 832 dnl --------------
 833 AC_TYPE_SIGNAL
 834 AC_TYPE_PID_T
 835 AC_TYPE_OFF_T
 836 AC_TYPE_UID_T
 837 AC_TYPE_MODE_T
 838 AC_TYPE_SIZE_T
 839
 840 dnl Check for sigset_t.  Currently I'm looking in
 841 dnl <sys/types.h> and <signal.h>.  Others might need
 842 dnl to be added.
 843 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 844 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 845 #include <signal.h>]], [[sigset_t tempsigset;]])],
 846 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 847 if test $nmh_cv_type_sigset_t = no; then
 848   AC_DEFINE(sigset_t, unsigned int,
 849     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 850 fi
 851
 852 dnl ----------------
 853 dnl CHECK STRUCTURES
 854 dnl ----------------
 855 AC_CHECK_MEMBERS(struct stat.st_blksize)
 856
 857 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 858   [#ifdef TIME_WITH_SYS_TIME
 859 # include <sys/time.h>
 860 # include <time.h>
 861 #else
 862 # ifdef TM_IN_SYS_TIME
 863 #  include <sys/time.h>
 864 # else
 865 #  include <time.h>
 866 # endif
 867 #endif])
 868
 869 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 870
 871 AC_MSG_CHECKING(for union wait)
 872 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 873   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 874 #include <sys/wait.h>]],
 875     [[union wait status; int pid; pid = wait (&status);
 876 #ifdef WEXITSTATUS
 877 /* Some POSIXoid systems have both the new-style macros and the old
 878    union wait type, and they do not work together.  If union wait
 879    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 880         if (WEXITSTATUS (status) != 0) pid = -1;
 881 #ifdef WTERMSIG
 882         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 883         -- blow chunks here --
 884 #endif
 885 #endif
 886 #ifdef HAVE_WAITPID
 887         /* Make sure union wait works with waitpid.  */
 888         pid = waitpid (-1, &status, 0);
 889 #endif
 890       ]])],
 891     [nmh_cv_union_wait=yes],
 892     [nmh_cv_union_wait=no])])
 893 if test "$nmh_cv_union_wait" = yes; then
 894   AC_DEFINE(HAVE_UNION_WAIT, 1,
 895     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 896 fi
 897 AC_MSG_RESULT($nmh_cv_union_wait)
 898
 899 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 900
 901 dnl -------------
 902 dnl CHECK SIGNALS
 903 dnl -------------
 904 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 905 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 906 AC_MSG_CHECKING(what style of signals to use)
 907 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 908   signals_style=POSIX_SIGNALS
 909   AC_DEFINE(POSIX_SIGNALS, 1,
 910     [Define to 1 if you use POSIX style signal handling.])
 911   AC_DEFINE(RELIABLE_SIGNALS)
 912 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 913   signals_style=BSD_SIGNALS
 914   AC_DEFINE(BSD_SIGNALS,1,
 915     [Define to 1 if you use BSD style signal handling (and can block signals).])
 916   AC_DEFINE(RELIABLE_SIGNALS)
 917 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 918   signals_style=SYSV_SIGNALS
 919   AC_DEFINE(SYSV_SIGNALS,1,
 920     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 921 else
 922   signals_style=NO_SIGNAL_BLOCKING
 923   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 924     [Define to 1 if you have no signal blocking at all (bummer).])
 925 fi
 926
 927 AC_MSG_RESULT($signals_style)
 928
 929 dnl Where is <signal.h> located?  Needed as input for signames.awk
 930 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 931 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 932                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 933                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 934                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 935                  /usr/include/sys/signal.h      dnl Almost everybody else
 936                  /dev/null;                     dnl Just in case we fall through
 937 do
 938   test -f $SIGNAL_H && \
 939   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 940   break
 941 done
 942 nmh_cv_path_signal_h=$SIGNAL_H
 943 ])
 944 SIGNAL_H=$nmh_cv_path_signal_h
 945 AC_SUBST(SIGNAL_H)dnl
 946
 947 dnl ----------------
 948 dnl OS SPECIFIC DEFINES
 949 dnl ----------------
 950 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 951 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 952 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 953 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 954 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 955
 956 case "$target_os" in
 957
 958   solaris2*)
 959     AC_DEFINE(SYS5)
 960     AC_DEFINE(SVR4)
 961     ;;
 962   irix*)
 963     AC_DEFINE(SYS5)
 964     AC_DEFINE(SVR4)
 965     ;;
 966   osf*)
 967     AC_DEFINE(SYS5)
 968     AC_DEFINE(SVR4)
 969     ;;
 970   aix*)
 971     AC_DEFINE(SYS5)
 972     AC_DEFINE(SVR4)
 973     ;;
 974   sunos4*)
 975     AC_DEFINE(BSD42)
 976     ;;
 977   freebsd*)
 978     AC_DEFINE(BSD42)
 979     AC_DEFINE(BSD44)
 980     ;;
 981   netbsd*)
 982     AC_DEFINE(BSD42)
 983     AC_DEFINE(BSD44)
 984     ;;
 985   openbsd*)
 986     AC_DEFINE(BSD42)
 987     AC_DEFINE(BSD44)
 988     ;;
 989   bsd/os*)
 990     AC_DEFINE(BSD42)
 991     AC_DEFINE(BSD44)
 992     ;;
 993   sco5*)
 994     AC_DEFINE(SYS5)
 995     AC_DEFINE(SCO_5_STDIO)
 996     ;;
 997 esac
 998
 999
1000 dnl ----------------
1001 dnl OUTPUT MAKEFILES
1002 dnl ----------------
1003 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
1004                 mts/Makefile mts/smtp/Makefile \
1005                 etc/Makefile docs/Makefile man/Makefile)
1006 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
1007 AC_OUTPUT
1008
1009 dnl These odd looking assignments are done to expand out unexpanded
1010 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
1011 dnl but expanding that gives '${prefix}/share/man', so we need to expand
1012 dnl again to get the final answer.
1013 dnl We only use the expanded versions to print the install paths in
1014 dnl the final summary and should use them nowhere else (see the autoconf
1015 dnl docs for the rationale for bindir etc being unexpanded).
1016 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
1017 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
1018 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
1019 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
1020
1021 pop_kinds=no
1022 if test x"$enable_pop" = x"yes"; then
1023   pop_kinds="yes ("
1024
1025   if test x"$enable_apop" = x"yes"; then
1026     pop_kinds="${pop_kinds}APOP "
1027   fi
1028
1029   pop_kinds="${pop_kinds}POP3)"
1030 fi
1031
1032 echo "
1033 nmh configuration
1034 -----------------
1035 nmh version                : AC_PACKAGE_VERSION
1036 target os                  : ${target}
1037 compiler                   : ${CC}
1038 compiler flags             : ${CFLAGS}
1039 linker flags               : ${LDFLAGS}
1040 definitions                : ${OURDEFS}
1041 source code location       : ${srcdir}
1042 binary install path        : ${nmhbin}
1043 library install path       : ${nmhlib}
1044 config files install path  : ${nmhsysconf}
1045 man page install path      : ${nmhman}
1046 backup prefix              : ${backup_prefix}
1047 transport system           : ${MTS}
1048 file locking type          : ${LOCKTYPE}
1049 default smtp servers       : ${smtpservers}
1050 default editor             : ${editorpath}
1051 default pager              : ${pagerpath}
1052 email address masquerading : ${masquerade}
1053 pop is enabled             : ${pop_kinds}
1054 SASL support               : ${sasl_support}
1055 TLS support                : ${tls_support}"
1056 echo ""