git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4 dnl $Id$
   5 dnl
   6
   7 AC_INIT(h/nmh.h)
   8 AC_CONFIG_HEADER(config.h)
   9
  10 AC_CANONICAL_SYSTEM
  11
  12 dnl What version of nmh are we building?
  13 VERSION=`sed -e 's/nmh-//' ${srcdir}/VERSION`
  14 echo "configuring for nmh-$VERSION"
  15 AC_SUBST(VERSION)dnl
  16
  17 dnl -------------------------
  18 dnl CHECK COMMAND LINE OPTION
  19 dnl -------------------------
  20 dnl What method of posting should post use?
  21 undefine([mts])dnl
  22 AC_ARG_WITH(mts,
  23 [  --with-mts=MTS          specify the mail transport agent])
  24
  25 if test x$with_mts = xsmtp; then
  26   MTS="smtp"
  27   MTSLIB="mts/smtp/libsmtp.a"
  28   AC_DEFINE(SMTPMTS)dnl
  29 elif test x$with_mts = xsendmail; then
  30   MTS="sendmail"
  31   MTSLIB="mts/sendmail/libsend.a"
  32   AC_DEFINE(SENDMTS)dnl
  33 else
  34   MTS="smtp"
  35   MTSLIB="mts/smtp/libsmtp.a"
  36   AC_DEFINE(SMTPMTS)dnl
  37 fi
  38
  39 AC_SUBST(MTS)
  40 AC_SUBST(MTSLIB)
  41
  42 dnl What should be the default editor?
  43 undefine([editor])dnl
  44 AC_ARG_WITH(editor,
  45 [  --with-editor=EDITOR    specify the default editor])
  46
  47 if test -n "$with_editor"; then
  48   editorpath="$with_editor"
  49 fi
  50
  51 dnl What should be the default pager?
  52 undefine([pager])dnl
  53 AC_ARG_WITH(pager,
  54 [  --with-pager=PAGER      specify the default pager])
  55
  56 if test -n "$with_pager"; then
  57   pagerpath="$with_pager"
  58 fi
  59
  60 dnl Do you want mhe support?
  61 undefine([nmh-mhe])dnl
  62 AC_ARG_ENABLE(nmh-mhe,
  63 [  --enable-nmh-mhe        enable mhe support (DEFAULT)])
  64
  65 dnl mhe support is on by default, so define it unless
  66 dnl explicitly disabled.
  67 if test x$enable_nmh_mhe != xno; then
  68   AC_DEFINE(MHE)dnl
  69 fi
  70
  71 dnl Do you want client-side support for pop
  72 undefine([nmh-pop])dnl
  73 AC_ARG_ENABLE(nmh-pop,
  74 [  --enable-nmh-pop        enable client-side support for pop])
  75 if test x$enable_nmh_pop = xyes; then
  76   AC_DEFINE(POP)dnl
  77   POPLIB=popsbr.o
  78   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
  79 else
  80   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
  81 fi
  82 AC_SUBST(POPLIB)dnl
  83 AC_SUBST(POPSED)dnl
  84
  85 dnl Do you want client-side support for kpop
  86 AC_ARG_WITH(krb4,
  87 [  --with-krb4=PREFIX      specify location of Kerberos V4 for kpop support])
  88 if test x$with_krb4 != x -a x$with_krb4 != xno; then
  89   AC_DEFINE(KPOP)dnl
  90   AC_DEFINE(KPOP_PRINCIPAL, "pop")dnl
  91 fi
  92
  93 dnl Do you want support for hesiod
  94 AC_ARG_WITH(hesiod,
  95 [  --with-hesiod=PREFIX    specify location of Hesiod])
  96 if test x$with_hesiod != x -a x$with_hesiod != xno; then
  97   AC_DEFINE(HESIOD)dnl
  98 fi
  99
 100 dnl Do you want to debug nmh?
 101 undefine([nmh-debug])dnl
 102 AC_ARG_ENABLE(nmh-debug,
 103 [  --enable-nmh-debug      enable nmh code debugging])
 104
 105 dnl ----------------------------------------------------
 106 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 107 dnl ----------------------------------------------------
 108 AC_PREFIX_DEFAULT(/usr/local/nmh)
 109
 110 dnl ------------------
 111 dnl CHECK THE COMPILER
 112 dnl ------------------
 113 dnl We want these before the checks,
 114 dnl so the checks can modify their values.
 115 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 116 if test x$enable_nmh_debug = xyes; then
 117   test -z "$LDFLAGS" && LDFLAGS=-g
 118 fi
 119
 120 AC_PROG_CC
 121
 122 dnl if the user hasn't specified CFLAGS, then
 123 dnl   if compiler is gcc, then
 124 dnl     use -O2 and some warning flags
 125 dnl   else use -O
 126 if test -n "$auto_cflags"; then
 127   if test x$enable_nmh_debug = xyes; then
 128     if test -n "$GCC"; then
 129       test -z "$CFLAGS" && CFLAGS="-Wall -g" || CFLAGS="$CFLAGS -Wall -g"
 130     else
 131       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 132     fi
 133   else
 134     test -z "$LDFLAGS" && LDFLAGS=-s
 135     if test -n "$GCC"; then
 136       test -z "$CFLAGS" && CFLAGS=-O2 || CFLAGS="$CFLAGS -O2"
 137     else
 138       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 139     fi
 140   fi
 141 fi
 142
 143 AC_C_CONST              dnl Does compiler support `const'.
 144
 145 dnl ------------------
 146 dnl CHECK FOR PROGRAMS
 147 dnl ------------------
 148 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 149 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 150 AC_PROG_RANLIB          dnl Check for `ranlib'
 151 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 152 AC_PROG_LEX             dnl Check for lex/flex
 153
 154 dnl Check for lorder and tsort commands
 155 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 156 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 157
 158 dnl If either doesn't exist, replace them with echo and cat
 159 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 160   LORDER=echo
 161   TSORT=cat
 162   AC_SUBST(LORDER)dnl
 163   AC_SUBST(TSORT)dnl
 164 fi
 165
 166 dnl Look for `sendmail'
 167 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 168 AC_PATH_PROG(sendmailpath, sendmail, no, [$pathtmp])
 169
 170 dnl Look for `more'
 171 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 172 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 173
 174 dnl If pager is not specified yet,
 175 dnl then use `more' as the default.
 176 if test -z "$pagerpath"; then
 177   pagerpath="$morepath"
 178 fi
 179 AC_SUBST(pagerpath)dnl
 180
 181 dnl Look for `vi'
 182 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 183 AC_PATH_PROG(vipath, vi, no, [$pathtmp])
 184
 185 dnl If editor is not specified yet,
 186 dnl then use `vi' as the default.
 187 if test -z "$editorpath"; then
 188   editorpath="$vipath"
 189 fi
 190 AC_SUBST(editorpath)dnl
 191
 192 dnl Check for broken vi
 193 AC_CACHE_CHECK(for broken vi, nmh_cv_attvibug,
 194 [if echo 'r /nonexist-file
 195 q' | ex > /dev/null 2>&1
 196 then
 197         nmh_cv_attvibug=no
 198 else
 199         nmh_cv_attvibug=yes
 200 fi])
 201
 202 if test "$nmh_cv_attvibug" = yes; then
 203   AC_DEFINE(ATTVIBUG)
 204 fi
 205
 206 dnl ---------------
 207 dnl FIND MAIL SPOOL
 208 dnl ---------------
 209 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 210 [for mailspool in /var/mail        dnl
 211                   /var/spool/mail  dnl
 212                   /usr/spool/mail  dnl
 213                   /dev/null;       dnl Just in case we fall through
 214 do
 215   test -d $mailspool && break
 216 done
 217 nmh_cv_mailspool=$mailspool
 218 ])
 219 mailspool=$nmh_cv_mailspool
 220 AC_SUBST(mailspool)dnl
 221
 222 dnl ------------------
 223 dnl CHECK HEADER FILES
 224 dnl ------------------
 225 AC_HEADER_DIRENT
 226 AC_HEADER_STDC
 227 AC_HEADER_TIME
 228 AC_HEADER_SYS_WAIT
 229 AC_HEADER_STAT
 230 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 231                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 232                  sys/param.h sys/time.h sys/utsname.h arpa/inet.h \
 233                  arpa/ftp.h)
 234
 235 AC_CACHE_CHECK(POSIX termios, nmh_cv_sys_posix_termios,
 236 [AC_TRY_LINK([#include <sys/types.h>
 237 #include <unistd.h>
 238 #include <termios.h>],
 239 [/* SunOS 4.0.3 has termios.h but not the library calls.  */
 240 tcgetattr(0, 0);],
 241   nmh_cv_sys_posix_termios=yes, nmh_cv_sys_posix_termios=no)])
 242
 243 if test $nmh_cv_sys_posix_termios = yes; then
 244   AC_CACHE_CHECK(TIOCGWINSZ in termios.h,
 245   nmh_cv_header_termios_h_tiocgwinsz,
 246   [AC_TRY_LINK([#include <sys/types.h>
 247 #include <termios.h>],
 248   [int x = TIOCGWINSZ;],
 249   nmh_cv_header_termios_h_tiocgwinsz=yes,
 250   nmh_cv_header_termios_h_tiocgwinsz=no)])
 251 else
 252   nmh_cv_header_termios_h_tiocgwinsz=no
 253 fi
 254
 255 if test $nmh_cv_header_termios_h_tiocgwinsz = no; then
 256   AC_CACHE_CHECK(TIOCGWINSZ in sys/ioctl.h,
 257   nmh_cv_header_sys_ioctl_h_tiocgwinsz,
 258   [AC_TRY_LINK([#include <sys/types.h>
 259 #include <sys/ioctl.h>],
 260   [int x = TIOCGWINSZ;],
 261   nmh_cv_header_sys_ioctl_h_tiocgwinsz=yes,
 262   nmh_cv_header_sys_ioctl_h_tiocgwinsz=no)])
 263   if test $nmh_cv_header_sys_ioctl_h_tiocgwinsz = yes; then
 264     AC_DEFINE(GWINSZ_IN_SYS_IOCTL)
 265   fi
 266 fi
 267
 268 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM))
 269
 270 dnl ---------------
 271 dnl CHECK FUNCTIONS
 272 dnl ---------------
 273 AC_FUNC_VFORK
 274 AC_CHECK_LIB(mkstemp,mkstemp)
 275 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 276                sighold sigrelse writev lstat uname tzset killpg mkstemp)
 277
 278 dnl sigsetjmp may be a macro
 279 AC_MSG_CHECKING(for sigsetjmp)
 280 AC_TRY_LINK([#include <setjmp.h>], [sigsetjmp((void *)0, 0);],
 281         [AC_DEFINE(HAVE_SIGSETJMP) AC_MSG_RESULT(yes)], AC_MSG_RESULT(no))
 282
 283 AC_REPLACE_FUNCS(snprintf strerror strdup)
 284
 285 dnl -------------------
 286 dnl CHECK FOR LIBRARIES
 287 dnl -------------------
 288 dnl Check location of modf
 289 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 290
 291 dnl Checks for network libraries (nsl, socket)
 292 AC_CHECK_NETLIBS
 293
 294 dnl Check for bug in libraries such that ruserpass
 295 dnl needs to be linked as _ruserpass.
 296 AC_CHECK_RUSERPASS
 297
 298 termcap_curses_order="termcap curses ncurses"
 299 for lib in $termcap_curses_order; do
 300   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 301 done
 302 AC_SUBST(TERMLIB)dnl
 303
 304
 305 dnl --------------
 306 dnl CHECK FOR NDBM
 307 dnl --------------
 308 dnl Checks for ndbm
 309 AC_CHECK_FUNC(dbm_open, ,
 310   AC_CHECK_LIB(ndbm, dbm_open, ,
 311     AC_CHECK_LIB(dbm, dbm_open)))
 312
 313 dnl ----------------
 314 dnl CHECK FOR HESIOD
 315 dnl ----------------
 316 if test x$with_hesiod != x -a x$with_hesiod != xno; then
 317   if test x$with_hesiod != xyes; then
 318     HESIOD_INCLUDES="-I$with_hesiod/include"
 319     HESIOD_LIBS="-L$with_hesiod/lib"
 320   fi
 321   AC_CHECK_FUNC(res_send, ,
 322     AC_CHECK_LIB(resolv, res_send))
 323   AC_CHECK_LIB(hesiod, hes_resolve, [HESIOD_LIBS="$HESIOD_LIBS -lhesiod"],
 324     [AC_MSG_ERROR(Hesiod library not found)], $HESIOD_LIBS)
 325 fi
 326 AC_SUBST(HESIOD_INCLUDES)dnl
 327 AC_SUBST(HESIOD_LIBS)dnl
 328
 329 dnl ----------------------------------
 330 dnl CHECK FOR KRB4 (Kerberos4 support)
 331 dnl ----------------------------------
 332 if test x$with_krb4 != x -a x$with_krb4 != xno; then
 333   if test x$with_krb4 != xyes; then
 334     KRB4_INCLUDES="-I$with_krb4/include"
 335     if test -d "$with_krb4/include/kerberosIV"; then
 336       KRB4_INCLUDES="$KRB4_INCLUDES -I$with_krb4/include/kerberosIV"
 337     fi
 338     KRB4_LIBS="-L$with_krb4/lib"
 339   elif test -d /usr/include/kerberosIV; then
 340     KRB4_INCLUDES="-I/usr/include/kerberosIV"
 341   fi
 342   AC_CHECK_LIB(krb4, krb_rd_req,
 343     [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lcrypto -lcom_err"],
 344     [AC_CHECK_LIB(krb, krb_rd_req,
 345       [KRB4_LIBS="$KRB4_LIBS -lkrb -ldes"],
 346       [AC_MSG_ERROR(Kerberos 4 libraries not found)],
 347       $KRB4_LIBS -ldes)],
 348     $KRB4_LIBS -ldes425 -lkrb5 -lcrypto -lcom_err)
 349 fi
 350 AC_SUBST(KRB4_INCLUDES)dnl
 351 AC_SUBST(KRB4_LIBS)dnl
 352
 353 dnl ---------------------
 354 dnl CHECK TERMCAP LIBRARY
 355 dnl ---------------------
 356
 357 dnl Add the termcap library, so that the following configure
 358 dnl tests will find it when it tries to link test programs.
 359 nmh_save_LIBS="$LIBS"
 360 LIBS="$TERMLIB $LIBS"
 361
 362 dnl Checks for external variable ospeed in the termcap library.
 363 AC_CACHE_CHECK(if an include file defines ospeed,
 364 nmh_cv_decl_ospeed_include_defines,
 365 [AC_TRY_LINK(
 366 [#include <sys/types.h>
 367 #if HAVE_TERMIOS_H
 368 #include <termios.h>
 369 #endif
 370 #if HAVE_TERMCAP_H
 371 #include <termcap.h>
 372 #endif], [ospeed = 0;],
 373 nmh_cv_decl_ospeed_include_defines=yes,
 374 nmh_cv_decl_ospeed_include_defines=no)])
 375
 376 if test $nmh_cv_decl_ospeed_include_defines = no; then
 377   AC_CACHE_CHECK(if you must define ospeed,
 378   nmh_cv_decl_ospeed_must_define,
 379   [AC_TRY_LINK( ,[extern short ospeed; ospeed = 0;],
 380   nmh_cv_decl_ospeed_must_define=yes,
 381   nmh_cv_decl_ospeed_must_define=no)])
 382 fi
 383
 384 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 385   AC_DEFINE(HAVE_OSPEED)
 386 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 387   AC_DEFINE(HAVE_OSPEED)
 388   AC_DEFINE(MUST_DEFINE_OSPEED)
 389 fi
 390
 391 dnl dnl Checks if tgetent accepts NULL and will
 392 dnl dnl allocate its own termcap buffer.
 393 dnl AC_CACHE_CHECK(if tgetent accepts NULL,
 394 dnl nmh_cv_func_tgetent_accepts_null,
 395 dnl [AC_TRY_RUN([main(){int i = tgetent((char*)0,"vt100");exit(!i || i == -1);}],
 396 dnl   nmh_cv_func_tgetent_accepts_null=yes,
 397 dnl   nmh_cv_func_tgetent_accepts_null=no,
 398 dnl   nmh_cv_func_tgetent_accepts_null=no)])
 399 dnl if test $nmh_cv_func_tgetent_accepts_null = yes; then
 400 dnl   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 401 dnl fi
 402
 403 dnl Now put the libraries back to what it was before we
 404 dnl starting checking the termcap library.
 405 LIBS="$nmh_save_LIBS"
 406
 407 dnl --------------
 408 dnl CHECK TYPEDEFS
 409 dnl --------------
 410 AC_TYPE_SIGNAL
 411 AC_TYPE_PID_T
 412 AC_TYPE_OFF_T
 413 AC_TYPE_UID_T
 414 AC_TYPE_MODE_T
 415 AC_TYPE_SIZE_T
 416
 417 dnl Check for sigset_t.  Currently I'm looking in
 418 dnl <sys/types.h> and <signal.h>.  Others might need
 419 dnl to be added.
 420 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 421 [AC_TRY_COMPILE(
 422 [#include <sys/types.h>
 423 #include <signal.h>], [sigset_t tempsigset;],
 424   nmh_cv_type_sigset_t=yes, nmh_cv_type_sigset_t=no)])
 425 if test $nmh_cv_type_sigset_t = no; then
 426   AC_DEFINE(sigset_t, unsigned int)
 427 fi
 428
 429 dnl ----------------
 430 dnl CHECK STRUCTURES
 431 dnl ----------------
 432 AC_STRUCT_ST_BLKSIZE
 433
 434 AC_CACHE_CHECK(for tm_gmtoff in struct tm, nmh_cv_struct_tm_gmtoff,
 435 [AC_TRY_COMPILE(
 436 [#ifdef TIME_WITH_SYS_TIME
 437 # include <sys/time.h>
 438 # include <time.h>
 439 #else
 440 # ifdef TM_IN_SYS_TIME
 441 #  include <sys/time.h>
 442 # else
 443 #  include <time.h>
 444 # endif
 445 #endif],
 446 [struct tm temptm; temptm.tm_gmtoff = 0;],
 447   nmh_cv_struct_tm_gmtoff=yes, nmh_cv_struct_tm_gmtoff=no)])
 448 if test $nmh_cv_struct_tm_gmtoff = yes; then
 449   AC_DEFINE(HAVE_TM_GMTOFF)
 450 fi
 451
 452 dnl -------------
 453 dnl CHECK SIGNALS
 454 dnl -------------
 455 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 456 AC_MSG_CHECKING(what style of signals to use)
 457 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 458   signals_style=POSIX_SIGNALS
 459   AC_DEFINE(POSIX_SIGNALS)
 460   AC_DEFINE(RELIABLE_SIGNALS)
 461 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 462   signals_style=BSD_SIGNALS
 463   AC_DEFINE(BSD_SIGNALS)
 464   AC_DEFINE(RELIABLE_SIGNALS)
 465 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 466   signals_style=SYSV_SIGNALS
 467   AC_DEFINE(SYSV_SIGNALS)
 468 else
 469   signals_style=NO_SIGNAL_BLOCKING
 470   AC_DEFINE(NO_SIGNAL_BLOCKING)
 471 fi
 472
 473 AC_MSG_RESULT($signals_style)
 474
 475 dnl Where is <signal.h> located?  Needed as input for signames.awk
 476 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 477 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 478                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 479                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 480                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 481                  /usr/include/sys/signal.h      dnl Almost everybody else
 482                  /dev/null;                     dnl Just in case we fall through
 483 do
 484   test -f $SIGNAL_H && \
 485   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 486   break
 487 done
 488 nmh_cv_path_signal_h=$SIGNAL_H
 489 ])
 490 SIGNAL_H=$nmh_cv_path_signal_h
 491 AC_SUBST(SIGNAL_H)dnl
 492
 493 dnl ----------------
 494 dnl OS SPECIFIC DEFINES
 495 dnl ----------------
 496 case "$target_os" in
 497
 498   solaris2*)
 499     AC_DEFINE(SYS5)
 500     AC_DEFINE(SVR4)
 501     ;;
 502   irix*)
 503     AC_DEFINE(SYS5)
 504     AC_DEFINE(SVR4)
 505     ;;
 506   osf*)
 507     AC_DEFINE(SYS5)
 508     AC_DEFINE(SVR4)
 509     ;;
 510   aix*)
 511     AC_DEFINE(SYS5)
 512     AC_DEFINE(SVR4)
 513     ;;
 514   sunos4*)
 515     AC_DEFINE(BIND)
 516     AC_DEFINE(BSD42)
 517     ;;
 518   linux*)
 519     AC_DEFINE(LINUX_STDIO)
 520     ;;
 521   freebsd*)
 522     AC_DEFINE(BIND)
 523     AC_DEFINE(BSD42)
 524     AC_DEFINE(BSD44)
 525     ;;
 526   netbsd*)
 527     AC_DEFINE(BIND)
 528     AC_DEFINE(BSD42)
 529     AC_DEFINE(BSD44)
 530     ;;
 531   openbsd*)
 532     AC_DEFINE(BIND)
 533     AC_DEFINE(BSD42)
 534     AC_DEFINE(BSD44)
 535     ;;
 536   bsd/os*)
 537     AC_DEFINE(BIND)
 538     AC_DEFINE(BSD42)
 539     AC_DEFINE(BSD44)
 540     ;;
 541   sco5*)
 542     AC_DEFINE(SYS5)
 543     AC_DEFINE(SCO_5_STDIO)
 544     ;;
 545 esac
 546
 547
 548 dnl ----------------
 549 dnl OUTPUT MAKEFILES
 550 dnl ----------------
 551 AC_OUTPUT(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 552           zotnet/Makefile zotnet/mts/Makefile zotnet/tws/Makefile \
 553           zotnet/mf/Makefile zotnet/bboards/Makefile mts/Makefile \
 554           mts/smtp/Makefile mts/sendmail/Makefile mts/mmdf/Makefile \
 555           etc/Makefile man/Makefile, \
 556           [test -z "$CONFIG_HEADERS" || echo > stamp-h])
 557
 558 eval "nmhbin=${bindir}";         eval "nmhbin2=${nmhbin}"
 559 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf2=${nmhsysconf}"
 560 eval "nmhlib=${libdir}";         eval "nmhlib2=${nmhlib}"
 561 eval "nmhman=${mandir}"
 562
 563 echo "
 564 nmh configuration
 565 -----------------
 566 nmh version               : ${VERSION}
 567 target os                 : ${target}
 568 compiler                  : ${CC}
 569 compiler flags            : ${CFLAGS}
 570 linker flags              : ${LDFLAGS}
 571 source code location      : ${srcdir}
 572 binary install path       : ${nmhbin2}
 573 libary install path       : ${nmhlib2}
 574 config files install path : ${nmhsysconf2}
 575 man page install path     : ${nmhman}
 576 transport system          : ${MTS}
 577 default editor            : ${editorpath}
 578 default pager             : ${pagerpath}"
 579 echo ""