git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4 dnl $Id$
   5 dnl
   6
   7 dnl 2.13 definitely chokes; 2.53 is the earliest version I've tested.
   8 dnl 2.50 is the major breakpoint between the old autoconf and the new,
   9 dnl so require that. If there are bug reports about 2.50-2.52 not working
  10 dnl we can always move this up a little.
  11 AC_PREREQ(2.50)
  12
  13 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
  14 AC_CONFIG_SRCDIR(h/nmh.h)
  15 AC_CONFIG_HEADER(config.h)
  16
  17 AC_CANONICAL_TARGET
  18
  19 dnl ---------------------
  20 dnl define a macro or two
  21 dnl ---------------------
  22
  23 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  24 if test -n "$LIBTOOL" ; then
  25   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  26   if test x"$tmptest" != x  ; then
  27     GNU_LIBTOOL=1
  28     AC_SUBST(GNU_LIBTOOL)dnl
  29   fi
  30 fi
  31 ] )
  32
  33 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  34 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  35
  36 dnl What date of nmh are we building?
  37 DATE=`cat ${srcdir}/DATE`
  38 echo "configuring for nmh dated $DATE"
  39 AC_SUBST(DATE)dnl
  40
  41 dnl --------------------------
  42 dnl CHECK COMMAND LINE OPTIONS
  43 dnl --------------------------
  44
  45 dnl Do you want client-side support for apop?
  46 AC_ARG_ENABLE(apop,
  47 [  --enable-apop           enable client-side support for POP3 and APOP])
  48 if test x"$enable_apop" = x"yes"; then
  49   AC_DEFINE(APOP)dnl
  50   APOPLIB=md5.o
  51   enable_pop=yes
  52 fi
  53 AC_SUBST(APOPLIB)dnl
  54
  55 dnl Do you want to debug nmh?
  56 AC_ARG_ENABLE(debug,
  57 [  --enable-debug          enable nmh code debugging])
  58 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  59 if test x"$enable_nmh_debug" = x"yes"; then
  60   enable_debug=yes
  61 fi
  62
  63 dnl Allow users to send email from addresses other than their default?
  64 AC_ARG_ENABLE(masquerade,
  65   [  --enable-masquerade[='draft_from mmailid username_extension']
  66                           enable up to 3 types of address masquerading [none]],
  67   [if test x"$enable_masquerade" = x"yes"; then
  68     masquerade="draft_from mmailid username_extension"
  69   else
  70     masquerade="$enable_masquerade"
  71   fi])
  72 AC_SUBST(masquerade)dnl
  73
  74 dnl Do you want mhe support?
  75 AC_ARG_ENABLE(mhe,
  76 [  --enable-mhe            enable mhe support (DEFAULT)])
  77
  78 dnl mhe support is on by default, so define it unless --disable-mhe or the
  79 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  80 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  81   AC_DEFINE(MHE)dnl
  82 fi
  83
  84 dnl Do you want client-side support for pop?
  85 AC_ARG_ENABLE(pop,
  86 [  --enable-pop            enable client-side support for plain POP3])
  87 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  88 if test x"$enable_nmh_pop" = x"yes"; then
  89   enable_pop=yes
  90 fi
  91
  92 dnl Do you want client-side support for using SASL for authentication?
  93 dnl Note that this code will be enabled for both POP and SMTP
  94 AC_ARG_WITH(cyrus-sasl,
  95 [  --with-cyrus-sasl=<dir> Specify location of Cyrus SASL library for auth])
  96 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  97   AC_DEFINE(CYRUS_SASL)dnl
  98   sasl_support=yes
  99 else
 100   sasl_support=no
 101 fi
 102
 103 dnl What should be the default editor?
 104 AC_ARG_WITH(editor,
 105 [  --with-editor=EDITOR    specify the default editor])
 106
 107 if test -n "$with_editor"; then
 108   editorpath="$with_editor"
 109 fi
 110
 111 dnl Set the backup prefix
 112 AC_ARG_WITH([hash-backup],
 113   [  --with-hash-backup      use # as the backup prefix (default: ,)])
 114 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 115   backup_prefix="#"
 116 else
 117   backup_prefix=","
 118 fi
 119 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix")dnl
 120
 121 dnl Do you want support for hesiod
 122 AC_ARG_WITH(hesiod,
 123 [  --with-hesiod=PREFIX    specify location of Hesiod])
 124 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 125   AC_DEFINE(HESIOD)dnl
 126 fi
 127
 128 dnl Do you want client-side support for kpop
 129 AC_ARG_WITH(krb4,
 130 [  --with-krb4=PREFIX      specify location of Kerberos V4 for KPOP support])
 131 if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 132   enable_pop=yes
 133   AC_DEFINE(KPOP)dnl
 134   AC_DEFINE(KPOP_PRINCIPAL, "pop")dnl
 135 fi
 136
 137 dnl After we know if we're including apop and kpop support, do pop stuff
 138 if test x"$enable_pop" = x"yes"; then
 139   AC_DEFINE(POP)dnl
 140   POPLIB=popsbr.o
 141   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 142 else
 143   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 144 fi
 145 AC_SUBST(POPLIB)dnl
 146 AC_SUBST(POPSED)dnl
 147
 148 dnl What method of locking to use?
 149 AC_ARG_WITH(locking,
 150 [  --with-locking=LOCKTYPE specify the file locking method
 151                           (one of dot, fcntl, flock, lockf)])
 152
 153 if test x"$with_locking" = x"dot"; then
 154   LOCKTYPE="dot"
 155   AC_DEFINE(DOT_LOCKING)dnl
 156 elif test x"$with_locking" = x"flock"; then
 157   LOCKTYPE="flock"
 158   AC_DEFINE(FLOCK_LOCKING)dnl
 159 elif test x"$with_locking" = x"lockf"; then
 160   LOCKTYPE="lockf"
 161   AC_DEFINE(LOCKF_LOCKING)dnl
 162 elif test x"$with_locking" = x"fcntl"; then
 163   LOCKTYPE="fcntl"
 164   AC_DEFINE(FCNTL_LOCKING)dnl
 165 else
 166   LOCKTYPE="dot"
 167   AC_DEFINE(DOT_LOCKING)dnl
 168 fi
 169
 170 dnl What method of posting should post use?
 171 AC_ARG_WITH(mts,
 172 [  --with-mts=MTS          specify the default mail transport agent/service])
 173
 174 if test x"$with_mts" = x"smtp"; then
 175   MTS="smtp"
 176 elif test x"$with_mts" = x"sendmail"; then
 177   MTS="sendmail"
 178 else
 179   MTS="smtp"
 180 fi
 181 AC_SUBST(MTS)dnl
 182
 183 dnl Both the smtp and sendmail mail transport services use the smtp code
 184 AC_DEFINE(SMTPMTS)dnl
 185
 186 dnl What should be the default pager?
 187 AC_ARG_WITH(pager,
 188 [  --with-pager=PAGER      specify the default pager])
 189
 190 if test -n "$with_pager"; then
 191   pagerpath="$with_pager"
 192 fi
 193
 194 dnl What should be the default mail server(s)?
 195 AC_ARG_WITH(smtpservers,
 196 [  --with-smtpservers='SMTPSERVER1[ SMTPSERVER2...]'
 197                           specify the default SMTP server(s) [localhost]])
 198 if test -n "$with_smtpservers"; then
 199   smtpservers="$with_smtpservers"
 200 else
 201   smtpservers="localhost"
 202 fi
 203 AC_SUBST(smtpservers)dnl
 204
 205 dnl ----------------------------------------------------
 206 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 207 dnl ----------------------------------------------------
 208 AC_PREFIX_DEFAULT(/usr/local/nmh)
 209
 210 dnl ------------------
 211 dnl CHECK THE COMPILER
 212 dnl ------------------
 213 dnl We want these before the checks,
 214 dnl so the checks can modify their values.
 215 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 216 if test x"$enable_debug" = x"yes"; then
 217   test -z "$LDFLAGS" && LDFLAGS=-g
 218 fi
 219
 220 AC_PROG_CC
 221
 222 dnl if the user hasn't specified CFLAGS, then
 223 dnl   if compiler is gcc, then
 224 dnl     use -O2 and some warning flags
 225 dnl   else use -O
 226 if test -n "$auto_cflags"; then
 227   if test x"$enable_debug" = x"yes"; then
 228     if test -n "$GCC"; then
 229       test -z "$CFLAGS" && CFLAGS="-Wall -g" || CFLAGS="$CFLAGS -Wall -g"
 230     else
 231       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 232     fi
 233   else
 234     if test -z "$LDFLAGS"; then
 235       case "$build_os" in
 236         darwin*)
 237           LDFLAGS=
 238           ;;
 239         *)
 240           LDFLAGS=-s
 241           ;;
 242       esac
 243     fi
 244     if test -n "$GCC"; then
 245       test -z "$CFLAGS" && CFLAGS="-Wall -O2" || CFLAGS="$CFLAGS -Wall -O2"
 246     else
 247       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 248     fi
 249   fi
 250 fi
 251
 252 AC_C_CONST              dnl Does compiler support `const'.
 253
 254 dnl ------------------
 255 dnl CHECK FOR PROGRAMS
 256 dnl ------------------
 257 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 258 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 259 AC_PROG_RANLIB          dnl Check for `ranlib'
 260 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 261 AC_PROG_LEX             dnl Check for lex/flex
 262
 263 dnl Look for `cut'
 264 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 265 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 266
 267 dnl ----------------------------------------------
 268 dnl check for lclint, and lint if it doesn't exist
 269 dnl ----------------------------------------------
 270 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 271 if test x$ac_cv_prog_linttmp1 != xno ; then
 272   LINT=$ac_cv_prog_linttmp1
 273   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 274 else
 275   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 276   if test x$ac_cv_prog_linttmp2 != xno ; then
 277     LINT=$ac_cv_prog_linttmp2
 278     LINTFLAGS=""
 279   else
 280     LINT="echo 'No lint program found'"
 281     LINTFLAGS=""
 282   fi
 283 fi
 284 AC_SUBST(LINT)dnl
 285 AC_SUBST(LINTFLAGS)dnl
 286
 287 dnl try to figure out which one we've got
 288 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 289 NMH_PROG_GNU_LIBTOOL
 290
 291 dnl Check for lorder and tsort commands
 292 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 293 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 294
 295 dnl If either doesn't exist, replace them with echo and cat
 296 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 297   LORDER=echo
 298   TSORT=cat
 299   AC_SUBST(LORDER)dnl
 300   AC_SUBST(TSORT)dnl
 301 dnl Mac OS X has lorder, but sh is too broken for it to work
 302 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 303 dnl   LORDER=echo
 304 dnl   TSORT=cat
 305 dnl   AC_SUBST(LORDER)dnl
 306 dnl   AC_SUBST(TSORT)dnl
 307 fi
 308
 309 dnl Check whether tsort can deal with loops
 310 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 311   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 312     nmh_cv_tsort_loop=no
 313   else
 314     nmh_cv_tsort_loop=yes
 315   fi])
 316 if test x$nmh_cv_tsort_loop = xno ; then
 317   LORDER=echo
 318   TSORT=cat
 319   AC_SUBST(LORDER)dnl
 320   AC_SUBST(TSORT)dnl
 321 fi
 322
 323 dnl Look for `ls'
 324 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 325 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 326
 327 dnl See how we get ls to display the owner and the group
 328 if test "$lspath" != "no"; then
 329   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 330                  nmh_cv_ls_grpopt,
 331   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 332     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 333     dnl ls, it would seem -l gave us both the user and group.  On this type of
 334     dnl ls, -g makes _only_ the group be displayed (and not the user).
 335     nmh_cv_ls_grpopt="-l"
 336   else
 337     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 338     nmh_cv_ls_grpopt="-lg"
 339   fi])
 340 fi
 341
 342 dnl Look for `more'
 343 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 344 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 345
 346 dnl If pager is not specified yet,
 347 dnl then use `more' as the default.
 348 if test -z "$pagerpath"; then
 349   pagerpath="$morepath"
 350 fi
 351 AC_SUBST(pagerpath)dnl
 352
 353 dnl Look for `sendmail'
 354 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 355 AC_PATH_PROG(sendmailpath, sendmail, no, [$pathtmp])
 356
 357 dnl Look for `vi'
 358 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 359 AC_PATH_PROG(vipath, vi, no, [$pathtmp])
 360
 361 dnl If editor is not specified yet,
 362 dnl then use `vi' as the default.
 363 if test -z "$editorpath"; then
 364   editorpath="$vipath"
 365 fi
 366 AC_SUBST(editorpath)dnl
 367
 368 dnl Check for broken vi
 369 AC_CACHE_CHECK(for broken vi, nmh_cv_attvibug,
 370 [if echo 'r /nonexist-file
 371 q' | ex > /dev/null
 372 then
 373         nmh_cv_attvibug=no
 374 else
 375         nmh_cv_attvibug=yes
 376 fi])
 377
 378 if test "$nmh_cv_attvibug" = yes; then
 379   AC_DEFINE(ATTVIBUG)dnl
 380 fi
 381
 382 dnl ----------------------------------------------------------
 383 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 384 dnl ----------------------------------------------------------
 385 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 386 [for mailspool in /var/mail        dnl
 387                   /var/spool/mail  dnl
 388                   /usr/spool/mail  dnl
 389                   /dev/null;       dnl Just in case we fall through
 390 do
 391   test -d $mailspool && break
 392 done
 393 nmh_cv_mailspool=$mailspool
 394 ])
 395 mailspool=$nmh_cv_mailspool
 396 AC_SUBST(mailspool)dnl
 397
 398 dnl See whether the mail spool directory is world-writable.
 399 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 400   AC_CACHE_CHECK(whether the mail spool is world-writable,
 401                  nmh_cv_mailspool_world_writable,
 402   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 403     nmh_cv_mailspool_world_writable=no
 404   else
 405     nmh_cv_mailspool_world_writable=yes
 406   fi])
 407 fi
 408
 409 dnl Also, check for liblockfile (as found on Debian systems)
 410 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 411
 412 dnl and whether its companion program dotlockfile is setgid
 413 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 414 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 415   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 416     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 417     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 418         nmh_cv_dotlockfile_setgid=yes
 419       else
 420         nmh_cv_dotlockfile_setgid=no
 421       fi])
 422   fi
 423 fi
 424
 425 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 426 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 427 if test x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 428   dnl do we really need both of these?
 429   AC_DEFINE(MAILGROUP)dnl
 430   SETGID_MAIL=1
 431 fi
 432 AC_SUBST(SETGID_MAIL)dnl
 433
 434 dnl Use ls to see which group owns the mail spool directory.
 435 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 436 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 437 ])
 438 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 439 AC_SUBST(MAIL_SPOOL_GRP)dnl
 440
 441 dnl ------------------
 442 dnl CHECK HEADER FILES
 443 dnl ------------------
 444 AC_HEADER_DIRENT
 445 AC_HEADER_STDC
 446 AC_HEADER_TIME
 447 AC_HEADER_SYS_WAIT
 448 AC_HEADER_STAT
 449 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 450                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 451                  langinfo.h netdb.h sys/param.h sys/time.h sys/utsname.h \
 452                  iconv.h sys/stream.h arpa/inet.h arpa/ftp.h)
 453
 454
 455 AC_CACHE_CHECK(POSIX termios, nmh_cv_sys_posix_termios,
 456 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 457 #include <unistd.h>
 458 #include <termios.h>]],
 459 [[/* SunOS 4.0.3 has termios.h but not the library calls.  */
 460 tcgetattr(0, 0);]])],
 461 nmh_cv_sys_posix_termios=yes, nmh_cv_sys_posix_termios=no)])
 462
 463 if test $nmh_cv_sys_posix_termios = yes; then
 464   AC_CACHE_CHECK(TIOCGWINSZ in termios.h,
 465   nmh_cv_header_termios_h_tiocgwinsz,
 466   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 467 #include <termios.h>]],
 468   [[int x = TIOCGWINSZ;]])],
 469   nmh_cv_header_termios_h_tiocgwinsz=yes,nmh_cv_header_termios_h_tiocgwinsz=no)])
 470 else
 471   nmh_cv_header_termios_h_tiocgwinsz=no
 472 fi
 473
 474 if test $nmh_cv_header_termios_h_tiocgwinsz = no; then
 475   AC_CACHE_CHECK(TIOCGWINSZ in sys/ioctl.h,
 476   nmh_cv_header_sys_ioctl_h_tiocgwinsz,
 477   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 478 #include <sys/ioctl.h>]],
 479   [[int x = TIOCGWINSZ;]])],
 480   nmh_cv_header_sys_ioctl_h_tiocgwinsz=yes,nmh_cv_header_sys_ioctl_h_tiocgwinsz=no)])
 481   if test $nmh_cv_header_sys_ioctl_h_tiocgwinsz = yes; then
 482     AC_DEFINE(GWINSZ_IN_SYS_IOCTL)dnl
 483   fi
 484 fi
 485
 486 dnl
 487 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 488 dnl really use a whole set of them, but this check should be
 489 dnl sufficient.
 490 dnl
 491 AC_CHECK_HEADER(libio.h, [
 492   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 493     AC_DEFINE(LINUX_STDIO) ]) ])
 494
 495 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM),,
 496 [[#if HAVE_SYS_STREAM_H
 497 #  include <sys/stream.h>
 498 #endif
 499 ]])
 500
 501 dnl ---------------
 502 dnl CHECK FUNCTIONS
 503 dnl ---------------
 504 AC_FUNC_VFORK
 505 AC_CHECK_LIB(mkstemp,mkstemp)
 506 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 507                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 508                sethostent getutent nl_langinfo)
 509
 510 dnl solaris screws this up
 511 AC_CHECK_FUNC(gethostbyname, [AC_DEFINE(HAVE_GETHOSTBYNAME)],
 512   AC_CHECK_LIB(nsl, gethostbyname, [AC_DEFINE(HAVE_GETHOSTBYNAME)] ) )
 513
 514 dnl sigsetjmp may be a macro
 515 AC_MSG_CHECKING(for sigsetjmp)
 516 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 517   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP) AC_MSG_RESULT(yes)],
 518   [AC_MSG_RESULT(no)])
 519
 520 AC_REPLACE_FUNCS(snprintf strerror strdup)
 521
 522 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 523 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 524 dnl any system header.
 525 dnl
 526 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 527 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 528 dnl need to check?
 529 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 530                 AC_EGREP_HEADER(initgroups, unistd.h,
 531                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 532
 533 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 534 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 535 dnl seems to work perfectly and IBM apparently uses it in internal code).
 536 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 537 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 538 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 539 dnl prototype.
 540 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE))
 541
 542 dnl -------------------
 543 dnl CHECK FOR LIBRARIES
 544 dnl -------------------
 545 dnl Check location of modf
 546 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 547
 548 dnl Checks for network libraries (nsl, socket)
 549 AC_CHECK_NETLIBS
 550
 551 termcap_curses_order="termcap curses ncurses"
 552 for lib in $termcap_curses_order; do
 553   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 554 done
 555 AC_SUBST(TERMLIB)dnl
 556
 557 dnl ---------------
 558 dnl CHECK FOR ICONV
 559 dnl ---------------
 560
 561 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 562 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 563   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 564   if test "x$ac_found_iconv" = "xno"; then
 565     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 566     if test "x$ac_found_iconv" = "xno"; then
 567       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 568     fi
 569     if test "x$ac_found_iconv" != "xno"; then
 570       LIBS="-liconv $LIBS"
 571     fi
 572   else
 573     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 574     AC_CHECK_DECL(_libiconv_version,
 575       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 576       [ #include <iconv.h> ])
 577   fi
 578 fi
 579 if test "x$ac_found_iconv" = xyes; then
 580   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 581 fi
 582
 583 dnl Check if iconv uses const in prototype declaration
 584 if test "x$ac_found_iconv" = "xyes"; then
 585   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 586     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 587         #include <iconv.h>]],
 588         [[#ifdef __cplusplus
 589           "C"
 590           #endif
 591           #if defined(__STDC__) || defined(__cplusplus)
 592           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 593           #else
 594           size_t iconv();
 595           #endif]])],
 596       [ac_cv_iconv_const=],
 597       [ac_cv_iconv_const=const])])
 598   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 599     [Define as const if the declaration of iconv() needs const.])
 600 fi
 601
 602 dnl --------------
 603 dnl CHECK FOR NDBM
 604 dnl --------------
 605 dnl Checks for ndbm
 606 AC_CHECK_FUNC(dbm_open, ,
 607   AC_CHECK_LIB(ndbm, dbm_open, ,
 608     AC_CHECK_LIB(dbm, dbm_open, ,
 609       AC_CHECK_LIB(db1, dbm_open, ,
 610         AC_CHECK_LIB(gdbm, dbm_open, ,
 611           AC_CHECK_LIB(db, __db_ndbm_open))))))
 612
 613 dnl ----------------
 614 dnl CHECK FOR NDBM.H
 615 dnl ----------------
 616
 617 AC_CHECK_HEADERS(db1/ndbm.h gdbm/ndbm.h db.h, break, )
 618
 619 dnl ----------------
 620 dnl CHECK FOR HESIOD
 621 dnl ----------------
 622 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 623   if test x"$with_hesiod" != x"yes"; then
 624     HESIOD_INCLUDES="-I$with_hesiod/include"
 625     HESIOD_LIBS="-L$with_hesiod/lib"
 626   fi
 627   AC_CHECK_FUNC(res_send,
 628         [AC_CHECK_LIB(hesiod, hes_resolve,
 629                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod"],
 630                 [AC_MSG_ERROR(Hesiod library not found)],
 631                 $HESIOD_LIBS)],
 632         [AC_CHECK_LIB(hesiod, hes_resolve,
 633                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod -lresolv"],
 634                 [AC_MSG_ERROR(Hesiod library not found)],
 635                 $HESIOD_LIBS -lresolv)])
 636
 637 fi
 638 AC_SUBST(HESIOD_INCLUDES)dnl
 639 AC_SUBST(HESIOD_LIBS)dnl
 640
 641 dnl ----------------------------------
 642 dnl CHECK FOR KRB4 (Kerberos4 support)
 643 dnl ----------------------------------
 644 if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 645   if test x"$with_krb4" != x"yes"; then
 646     KRB4_INCLUDES="-I$with_krb4/include"
 647     if test -d "$with_krb4/include/kerberosIV"; then
 648       KRB4_INCLUDES="$KRB4_INCLUDES -I$with_krb4/include/kerberosIV"
 649     fi
 650     KRB4_LIBS="-L$with_krb4/lib"
 651   elif test -d /usr/include/kerberosIV; then
 652     KRB4_INCLUDES="-I/usr/include/kerberosIV"
 653   fi
 654 dnl First, check if we have -lk5crypto, since that means we have a recent krb5
 655
 656   AC_CHECK_LIB(k5crypto, krb5_encrypt,
 657         [AC_CHECK_LIB(krb4, krb_rd_req,
 658                 [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lk5crypto -lcom_err"],
 659                 [AC_MSG_ERROR(Kerberos 4 compatibility libraries not found)],
 660                 $KRB4_LIBS -ldes425 -lkrb5 -lk5crypto -lcom_err)],
 661
 662         [AC_CHECK_LIB(krb4, krb_rd_req,
 663             [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lcrypto -lcom_err"],
 664             [AC_CHECK_LIB(krb, krb_rd_req,
 665               [KRB4_LIBS="$KRB4_LIBS -lkrb -ldes"],
 666               [AC_MSG_ERROR(Kerberos 4 libraries not found)],
 667               $KRB4_LIBS -ldes)],
 668             $KRB4_LIBS -ldes425 -lkrb5 -lcrypto -lcom_err)],
 669         $KRB4_LIBS)
 670
 671 fi
 672 AC_SUBST(KRB4_INCLUDES)dnl
 673 AC_SUBST(KRB4_LIBS)dnl
 674
 675 dnl --------------------
 676 dnl CHECK FOR CYRUS SASL
 677 dnl --------------------
 678 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
 679   if test x"$with_cyrus_sasl" != x"yes"; then
 680     SASL_INCLUDES="-I$with_cyrus_sasl/include"
 681     SASL_LIBS="-L$with_cyrus_sasl/lib"
 682
 683     dnl Do OS-specific hardcoding of SASL shared library path into executables,
 684     dnl so user isn't forced to set environment variables like Solaris'
 685     dnl LD_LIBRARY_PATH.
 686     case "$target_os" in
 687       solaris*)
 688         SASL_LIBS="$SASL_LIBS -R$with_cyrus_sasl/lib"
 689         ;;
 690     esac
 691   fi
 692   save_LDFLAGS="$LDFLAGS"
 693   LDFLAGS="$LDFLAGS $SASL_LIBS"
 694   AC_CHECK_LIB(sasl2, sasl_client_new,
 695     [SASL_LIBS="$SASL_LIBS -lsasl2"],
 696     [AC_MSG_ERROR(Cyrus SASL library not found)])
 697   LDFLAGS="$save_LDFLAGS"
 698 fi
 699 AC_SUBST(SASL_INCLUDES)dnl
 700 AC_SUBST(SASL_LIBS)dnl
 701
 702 dnl ---------------------
 703 dnl CHECK TERMCAP LIBRARY
 704 dnl ---------------------
 705
 706 dnl Add the termcap library, so that the following configure
 707 dnl tests will find it when it tries to link test programs.
 708 nmh_save_LIBS="$LIBS"
 709 LIBS="$TERMLIB $LIBS"
 710
 711 dnl Checks for external variable ospeed in the termcap library.
 712 AC_CACHE_CHECK(if an include file defines ospeed,
 713 nmh_cv_decl_ospeed_include_defines,
 714 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 715 #if HAVE_TERMIOS_H
 716 #include <termios.h>
 717 #endif
 718 #if HAVE_TERMCAP_H
 719 #include <termcap.h>
 720 #endif]], [[ospeed = 0;]])],
 721 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 722
 723 if test $nmh_cv_decl_ospeed_include_defines = no; then
 724   AC_CACHE_CHECK(if you must define ospeed,
 725   nmh_cv_decl_ospeed_must_define,
 726   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 727   [[extern short ospeed; ospeed = 0;]])],
 728   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 729 fi
 730
 731 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 732   AC_DEFINE(HAVE_OSPEED)dnl
 733 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 734   AC_DEFINE(HAVE_OSPEED)
 735   AC_DEFINE(MUST_DEFINE_OSPEED)
 736 fi
 737
 738 dnl dnl Checks if tgetent accepts NULL and will
 739 dnl dnl allocate its own termcap buffer.
 740 dnl AC_CACHE_CHECK(if tgetent accepts NULL,
 741 dnl nmh_cv_func_tgetent_accepts_null,
 742 dnl [AC_TRY_RUN([main(){int i = tgetent((char*)0,"vt100");exit(!i || i == -1);}],
 743 dnl   nmh_cv_func_tgetent_accepts_null=yes,
 744 dnl   nmh_cv_func_tgetent_accepts_null=no,
 745 dnl   nmh_cv_func_tgetent_accepts_null=no)])
 746 dnl if test $nmh_cv_func_tgetent_accepts_null = yes; then
 747 dnl   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 748 dnl fi
 749
 750 dnl Now put the libraries back to what it was before we
 751 dnl starting checking the termcap library.
 752 LIBS="$nmh_save_LIBS"
 753
 754 dnl --------------
 755 dnl CHECK TYPEDEFS
 756 dnl --------------
 757 AC_TYPE_SIGNAL
 758 AC_TYPE_PID_T
 759 AC_TYPE_OFF_T
 760 AC_TYPE_UID_T
 761 AC_TYPE_MODE_T
 762 AC_TYPE_SIZE_T
 763
 764 dnl Check for sigset_t.  Currently I'm looking in
 765 dnl <sys/types.h> and <signal.h>.  Others might need
 766 dnl to be added.
 767 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 768 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 769 #include <signal.h>]], [[sigset_t tempsigset;]])],
 770 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 771 if test $nmh_cv_type_sigset_t = no; then
 772   AC_DEFINE(sigset_t, unsigned int)
 773 fi
 774
 775 dnl ----------------
 776 dnl CHECK STRUCTURES
 777 dnl ----------------
 778 AC_CHECK_MEMBERS(struct stat.st_blksize)
 779
 780 AC_CACHE_CHECK(for tm_gmtoff in struct tm, nmh_cv_struct_tm_gmtoff,
 781 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
 782 # include <sys/time.h>
 783 # include <time.h>
 784 #else
 785 # ifdef TM_IN_SYS_TIME
 786 #  include <sys/time.h>
 787 # else
 788 #  include <time.h>
 789 # endif
 790 #endif]], [[struct tm temptm; temptm.tm_gmtoff = 0;]])],
 791 nmh_cv_struct_tm_gmtoff=yes,nmh_cv_struct_tm_gmtoff=no)])
 792 if test $nmh_cv_struct_tm_gmtoff = yes; then
 793   AC_DEFINE(HAVE_TM_GMTOFF)
 794 fi
 795
 796 AC_CACHE_CHECK(for ut_type in struct utmp, nmh_cv_struct_utmp_ut_type,
 797 [AC_TRY_COMPILE(
 798 [#include <utmp.h>],
 799 [struct utmp temputmp; temputmp.ut_type = 0;],
 800   nmh_cv_struct_utmp_ut_type=yes, nmh_cv_struct_utmp_ut_type=no)])
 801 if test $nmh_cv_struct_utmp_ut_type = yes; then
 802   AC_DEFINE(HAVE_UTMP_UT_TYPE)
 803 fi
 804
 805 dnl -------------
 806 dnl CHECK SIGNALS
 807 dnl -------------
 808 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 809 AC_MSG_CHECKING(what style of signals to use)
 810 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 811   signals_style=POSIX_SIGNALS
 812   AC_DEFINE(POSIX_SIGNALS)
 813   AC_DEFINE(RELIABLE_SIGNALS)
 814 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 815   signals_style=BSD_SIGNALS
 816   AC_DEFINE(BSD_SIGNALS)
 817   AC_DEFINE(RELIABLE_SIGNALS)
 818 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 819   signals_style=SYSV_SIGNALS
 820   AC_DEFINE(SYSV_SIGNALS)
 821 else
 822   signals_style=NO_SIGNAL_BLOCKING
 823   AC_DEFINE(NO_SIGNAL_BLOCKING)
 824 fi
 825
 826 AC_MSG_RESULT($signals_style)
 827
 828 dnl Where is <signal.h> located?  Needed as input for signames.awk
 829 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 830 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 831                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 832                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 833                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 834                  /usr/include/sys/signal.h      dnl Almost everybody else
 835                  /dev/null;                     dnl Just in case we fall through
 836 do
 837   test -f $SIGNAL_H && \
 838   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 839   break
 840 done
 841 nmh_cv_path_signal_h=$SIGNAL_H
 842 ])
 843 SIGNAL_H=$nmh_cv_path_signal_h
 844 AC_SUBST(SIGNAL_H)dnl
 845
 846 dnl ----------------
 847 dnl OS SPECIFIC DEFINES
 848 dnl ----------------
 849 case "$target_os" in
 850
 851   solaris2*)
 852     AC_DEFINE(SYS5)
 853     AC_DEFINE(SVR4)
 854     ;;
 855   irix*)
 856     AC_DEFINE(SYS5)
 857     AC_DEFINE(SVR4)
 858     ;;
 859   osf*)
 860     AC_DEFINE(SYS5)
 861     AC_DEFINE(SVR4)
 862     ;;
 863   aix*)
 864     AC_DEFINE(SYS5)
 865     AC_DEFINE(SVR4)
 866     ;;
 867   sunos4*)
 868     AC_DEFINE(BSD42)
 869     ;;
 870   freebsd*)
 871     AC_DEFINE(BSD42)
 872     AC_DEFINE(BSD44)
 873     ;;
 874   netbsd*)
 875     AC_DEFINE(BSD42)
 876     AC_DEFINE(BSD44)
 877     ;;
 878   openbsd*)
 879     AC_DEFINE(BSD42)
 880     AC_DEFINE(BSD44)
 881     ;;
 882   bsd/os*)
 883     AC_DEFINE(BSD42)
 884     AC_DEFINE(BSD44)
 885     ;;
 886   sco5*)
 887     AC_DEFINE(SYS5)
 888     AC_DEFINE(SCO_5_STDIO)
 889     ;;
 890 esac
 891
 892
 893 dnl ----------------
 894 dnl OUTPUT MAKEFILES
 895 dnl ----------------
 896 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 897                 mts/Makefile mts/smtp/Makefile \
 898                 etc/Makefile docs/Makefile man/Makefile)
 899 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 900 AC_OUTPUT
 901
 902 dnl Umm, what's the point of these assignments??  -- <dan-nmh@dilvish.speed.net>
 903 eval "nmhbin=${bindir}";         eval "nmhbin2=${nmhbin}"
 904 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf2=${nmhsysconf}"
 905 eval "nmhlib=${libdir}";         eval "nmhlib2=${nmhlib}"
 906 eval "nmhman=${mandir}"
 907
 908 pop_kinds=no
 909 if test x"$enable_pop" = x"yes"; then
 910   pop_kinds="yes ("
 911
 912   if test x"$enable_apop" = x"yes"; then
 913     pop_kinds="${pop_kinds}APOP "
 914   fi
 915
 916   if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 917     pop_kinds="${pop_kinds}KPOP "
 918   fi
 919
 920   pop_kinds="${pop_kinds}POP3)"
 921 fi
 922
 923 echo "
 924 nmh configuration
 925 -----------------
 926 nmh version                : AC_PACKAGE_VERSION
 927 target os                  : ${target}
 928 compiler                   : ${CC}
 929 compiler flags             : ${CFLAGS}
 930 linker flags               : ${LDFLAGS}
 931 source code location       : ${srcdir}
 932 binary install path        : ${nmhbin2}
 933 libary install path        : ${nmhlib2}
 934 config files install path  : ${nmhsysconf2}
 935 man page install path      : ${nmhman}
 936 backup prefix              : ${backup_prefix}
 937 transport system           : ${MTS}
 938 file locking type          : ${LOCKTYPE}
 939 default smtp servers       : ${smtpservers}
 940 default editor             : ${editorpath}
 941 default pager              : ${pagerpath}
 942 email address masquerading : ${masquerade}
 943 pop is enabled             : ${pop_kinds}
 944 SASL support               : ${sasl_support}"
 945 echo ""