git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4 dnl $Id$
   5 dnl
   6
   7 dnl 2.13 definitely chokes; 2.53 is the earliest version I've tested.
   8 dnl 2.58 needed for help string macro but that only affects help output
   9 dnl 2.50 is the major breakpoint between the old autoconf and the new,
  10 dnl so require that. If there are bug reports about 2.50-2.52 not working
  11 dnl we can always move this up a little.
  12 AC_PREREQ(2.50)
  13
  14 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
  15 AC_CONFIG_SRCDIR(h/nmh.h)
  16 AC_CONFIG_HEADER(config.h)
  17
  18 AC_CANONICAL_TARGET
  19
  20 dnl ---------------------
  21 dnl define a macro or two
  22 dnl ---------------------
  23
  24 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  25 if test -n "$LIBTOOL" ; then
  26   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  27   if test x"$tmptest" != x  ; then
  28     GNU_LIBTOOL=1
  29     AC_SUBST(GNU_LIBTOOL)dnl
  30   fi
  31 fi
  32 ] )
  33
  34 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  35 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  36
  37 dnl What date of nmh are we building?
  38 DATE=`cat ${srcdir}/DATE`
  39 echo "configuring for nmh dated $DATE"
  40 AC_SUBST(DATE)dnl
  41
  42 dnl --------------------------
  43 dnl CHECK COMMAND LINE OPTIONS
  44 dnl --------------------------
  45
  46 dnl Do you want client-side support for apop?
  47 AC_ARG_ENABLE(apop, AS_HELP_STRING([--enable-apop],
  48   [enable client-side support for POP3 and APOP]))
  49 if test x"$enable_apop" = x"yes"; then
  50   AC_DEFINE(APOP)dnl
  51   APOPLIB=md5.o
  52   enable_pop=yes
  53 fi
  54 AC_SUBST(APOPLIB)dnl
  55
  56 dnl Do you want to debug nmh?
  57 AC_ARG_ENABLE(debug,
  58   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  59 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  60 if test x"$enable_nmh_debug" = x"yes"; then
  61   enable_debug=yes
  62 fi
  63
  64 dnl Allow users to send email from addresses other than their default?
  65 AC_ARG_ENABLE(masquerade,
  66   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  67     [enable up to 3 types of address masquerading]),
  68   [if test x"$enable_masquerade" = x"yes"; then
  69     masquerade="draft_from mmailid username_extension"
  70   else
  71     masquerade="$enable_masquerade"
  72   fi])
  73 AC_SUBST(masquerade)dnl
  74
  75 dnl Do you want mhe support?
  76 AC_ARG_ENABLE(mhe,
  77   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  78
  79 dnl mhe support is on by default, so define it unless --disable-mhe or the
  80 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  81 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  82   AC_DEFINE(MHE)dnl
  83 fi
  84
  85 dnl Do you want client-side support for pop?
  86 AC_ARG_ENABLE(pop,
  87   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  88 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  89 if test x"$enable_nmh_pop" = x"yes"; then
  90   enable_pop=yes
  91 fi
  92
  93 dnl Do you want client-side support for using SASL for authentication?
  94 dnl Note that this code will be enabled for both POP and SMTP
  95 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl=DIR],
  96   [specify location of Cyrus SASL library]))
  97 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  98   AC_DEFINE(CYRUS_SASL)dnl
  99   sasl_support=yes
 100 else
 101   sasl_support=no
 102 fi
 103
 104 dnl What should be the default editor?
 105 AC_ARG_WITH(editor,
 106   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 107
 108 if test -n "$with_editor"; then
 109   editorpath="$with_editor"
 110 fi
 111
 112 dnl Set the backup prefix
 113 AC_ARG_WITH([hash-backup],
 114   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 115 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 116   backup_prefix="#"
 117 else
 118   backup_prefix=","
 119 fi
 120 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix")dnl
 121
 122 dnl Do you want support for hesiod
 123 AC_ARG_WITH(hesiod,
 124   AS_HELP_STRING([--with-hesiod=DIR],[specify location of Hesiod]))
 125 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 126   AC_DEFINE(HESIOD)dnl
 127 fi
 128
 129 dnl Do you want client-side support for kpop
 130 AC_ARG_WITH(krb4, AS_HELP_STRING([--with-krb4=DIR],
 131   [specify location of Kerberos V4 for KPOP support]))
 132 if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 133   enable_pop=yes
 134   AC_DEFINE(KPOP)dnl
 135   AC_DEFINE(KPOP_PRINCIPAL, "pop")dnl
 136 fi
 137
 138 dnl After we know if we're including apop and kpop support, do pop stuff
 139 if test x"$enable_pop" = x"yes"; then
 140   AC_DEFINE(POP)dnl
 141   POPLIB=popsbr.o
 142   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 143 else
 144   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 145 fi
 146 AC_SUBST(POPLIB)dnl
 147 AC_SUBST(POPSED)dnl
 148
 149 dnl What method of locking to use?
 150 AC_ARG_WITH(locking,
 151   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 152   [specify the file locking method]))
 153
 154 if test x"$with_locking" = x"dot"; then
 155   LOCKTYPE="dot"
 156   AC_DEFINE(DOT_LOCKING)dnl
 157 elif test x"$with_locking" = x"flock"; then
 158   LOCKTYPE="flock"
 159   AC_DEFINE(FLOCK_LOCKING)dnl
 160 elif test x"$with_locking" = x"lockf"; then
 161   LOCKTYPE="lockf"
 162   AC_DEFINE(LOCKF_LOCKING)dnl
 163 elif test x"$with_locking" = x"fcntl"; then
 164   LOCKTYPE="fcntl"
 165   AC_DEFINE(FCNTL_LOCKING)dnl
 166 else
 167   LOCKTYPE="dot"
 168   AC_DEFINE(DOT_LOCKING)dnl
 169 fi
 170
 171 dnl What method of posting should post use?
 172 AC_ARG_WITH(mts,
 173   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 174   [specify the default mail transport agent/service]))
 175
 176 if test x"$with_mts" = x"smtp"; then
 177   MTS="smtp"
 178 elif test x"$with_mts" = x"sendmail"; then
 179   MTS="sendmail"
 180 else
 181   MTS="smtp"
 182 fi
 183 AC_SUBST(MTS)dnl
 184
 185 dnl Both the smtp and sendmail mail transport services use the smtp code
 186 AC_DEFINE(SMTPMTS)dnl
 187
 188 dnl What should be the default pager?
 189 AC_ARG_WITH(pager,
 190   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 191
 192 if test -n "$with_pager"; then
 193   pagerpath="$with_pager"
 194 fi
 195
 196 dnl What should be the default mail server(s)?
 197 AC_ARG_WITH(smtpservers,
 198   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 199   [specify the default SMTP server(s) @<:@localhost@:>@]))
 200 if test -n "$with_smtpservers"; then
 201   smtpservers="$with_smtpservers"
 202 else
 203   smtpservers="localhost"
 204 fi
 205 AC_SUBST(smtpservers)dnl
 206
 207 dnl ----------------------------------------------------
 208 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 209 dnl ----------------------------------------------------
 210 AC_PREFIX_DEFAULT(/usr/local/nmh)
 211
 212 dnl ------------------
 213 dnl CHECK THE COMPILER
 214 dnl ------------------
 215 dnl We want these before the checks,
 216 dnl so the checks can modify their values.
 217 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 218 if test x"$enable_debug" = x"yes"; then
 219   test -z "$LDFLAGS" && LDFLAGS=-g
 220 fi
 221
 222 AC_PROG_CC
 223
 224 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 225 [nmh_saved_cflags="$CFLAGS"
 226  CFLAGS="$CFLAGS -Wno-pointer-sign"
 227  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 228  CFLAGS="$nmh_saved_cflags"])
 229
 230 dnl if the user hasn't specified CFLAGS, then
 231 dnl   if compiler is gcc, then
 232 dnl     use -O2 and some warning flags
 233 dnl   else use -O
 234 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 235 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 236 dnl spurious and which in any case we don't want to deal with now.
 237 if test "$nmh_cv_has_noptrsign" = "yes"; then
 238         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 239 else
 240         nmh_gcc_warnflags="-Wall"
 241 fi
 242
 243 if test -n "$auto_cflags"; then
 244   if test x"$enable_debug" = x"yes"; then
 245     if test -n "$GCC"; then
 246       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 247     else
 248       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 249     fi
 250   else
 251     if test -z "$LDFLAGS"; then
 252       case "$build_os" in
 253         darwin*)
 254           LDFLAGS=
 255           ;;
 256         *)
 257           LDFLAGS=-s
 258           ;;
 259       esac
 260     fi
 261     if test -n "$GCC"; then
 262       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 263     else
 264       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 265     fi
 266   fi
 267 fi
 268
 269 AC_C_CONST              dnl Does compiler support `const'.
 270
 271 dnl ------------------
 272 dnl CHECK FOR PROGRAMS
 273 dnl ------------------
 274 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 275 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 276 AC_PROG_RANLIB          dnl Check for `ranlib'
 277 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 278 AC_PROG_LEX             dnl Check for lex/flex
 279
 280 dnl Look for `cut'
 281 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 282 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 283
 284 dnl ----------------------------------------------
 285 dnl check for lclint, and lint if it doesn't exist
 286 dnl ----------------------------------------------
 287 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 288 if test x$ac_cv_prog_linttmp1 != xno ; then
 289   LINT=$ac_cv_prog_linttmp1
 290   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 291 else
 292   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 293   if test x$ac_cv_prog_linttmp2 != xno ; then
 294     LINT=$ac_cv_prog_linttmp2
 295     LINTFLAGS=""
 296   else
 297     LINT="echo 'No lint program found'"
 298     LINTFLAGS=""
 299   fi
 300 fi
 301 AC_SUBST(LINT)dnl
 302 AC_SUBST(LINTFLAGS)dnl
 303
 304 dnl try to figure out which one we've got
 305 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 306 NMH_PROG_GNU_LIBTOOL
 307
 308 dnl Check for lorder and tsort commands
 309 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 310 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 311
 312 dnl If either doesn't exist, replace them with echo and cat
 313 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 314   LORDER=echo
 315   TSORT=cat
 316   AC_SUBST(LORDER)dnl
 317   AC_SUBST(TSORT)dnl
 318 dnl Mac OS X has lorder, but sh is too broken for it to work
 319 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 320 dnl   LORDER=echo
 321 dnl   TSORT=cat
 322 dnl   AC_SUBST(LORDER)dnl
 323 dnl   AC_SUBST(TSORT)dnl
 324 fi
 325
 326 dnl Check whether tsort can deal with loops
 327 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 328   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 329     nmh_cv_tsort_loop=no
 330   else
 331     nmh_cv_tsort_loop=yes
 332   fi])
 333 if test x$nmh_cv_tsort_loop = xno ; then
 334   LORDER=echo
 335   TSORT=cat
 336   AC_SUBST(LORDER)dnl
 337   AC_SUBST(TSORT)dnl
 338 fi
 339
 340 dnl Look for `ls'
 341 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 342 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 343
 344 dnl See how we get ls to display the owner and the group
 345 if test "$lspath" != "no"; then
 346   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 347                  nmh_cv_ls_grpopt,
 348   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 349     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 350     dnl ls, it would seem -l gave us both the user and group.  On this type of
 351     dnl ls, -g makes _only_ the group be displayed (and not the user).
 352     nmh_cv_ls_grpopt="-l"
 353   else
 354     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 355     nmh_cv_ls_grpopt="-lg"
 356   fi])
 357 fi
 358
 359 dnl Look for `more'
 360 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 361 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 362
 363 dnl If pager is not specified yet,
 364 dnl then use `more' as the default.
 365 if test -z "$pagerpath"; then
 366   pagerpath="$morepath"
 367 fi
 368 AC_SUBST(pagerpath)dnl
 369
 370 dnl Look for `sendmail'
 371 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 372 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 373
 374 dnl Look for `vi'
 375 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 376 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 377
 378 dnl If editor is not specified yet,
 379 dnl then use `vi' as the default.
 380 if test -z "$editorpath"; then
 381   editorpath="$vipath"
 382 fi
 383 AC_SUBST(editorpath)dnl
 384
 385 dnl ----------------------------------------------------------
 386 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 387 dnl ----------------------------------------------------------
 388 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 389 [for mailspool in /var/mail        dnl
 390                   /var/spool/mail  dnl
 391                   /usr/spool/mail  dnl
 392                   /dev/null;       dnl Just in case we fall through
 393 do
 394   test -d $mailspool && break
 395 done
 396 nmh_cv_mailspool=$mailspool
 397 ])
 398 mailspool=$nmh_cv_mailspool
 399 AC_SUBST(mailspool)dnl
 400
 401 dnl See whether the mail spool directory is world-writable.
 402 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 403   AC_CACHE_CHECK(whether the mail spool is world-writable,
 404                  nmh_cv_mailspool_world_writable,
 405   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 406     nmh_cv_mailspool_world_writable=no
 407   else
 408     nmh_cv_mailspool_world_writable=yes
 409   fi])
 410 fi
 411
 412 dnl Also, check for liblockfile (as found on Debian systems)
 413 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 414
 415 dnl and whether its companion program dotlockfile is setgid
 416 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 417 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 418   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 419     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 420     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 421         nmh_cv_dotlockfile_setgid=yes
 422       else
 423         nmh_cv_dotlockfile_setgid=no
 424       fi])
 425   fi
 426 fi
 427
 428 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 429 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 430 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 431   dnl do we really need both of these?
 432   AC_DEFINE(MAILGROUP)dnl
 433   SETGID_MAIL=1
 434 fi
 435 AC_SUBST(SETGID_MAIL)dnl
 436
 437 dnl Use ls to see which group owns the mail spool directory.
 438 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 439 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 440 ])
 441 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 442 AC_SUBST(MAIL_SPOOL_GRP)dnl
 443
 444 dnl ------------------
 445 dnl CHECK HEADER FILES
 446 dnl ------------------
 447
 448 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 449 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 450 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 451 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 452 dnl declared; if so they should have an entry added to this case statement.
 453 dnl NB that we must define this on the compiler command line, not in config.h,
 454 dnl because it must be set before any system header is included and there's no
 455 dnl portable way to make sure that files generated by lex include config.h
 456 dnl before system header files.
 457
 458 case "$target_os" in
 459   linux*)
 460     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 461     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 462     ;;
 463 esac
 464 AC_SUBST(OURDEFS)
 465
 466 AC_HEADER_DIRENT
 467 AC_HEADER_STDC
 468 AC_HEADER_TIME
 469 AC_HEADER_SYS_WAIT
 470 AC_HEADER_STAT
 471 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 472                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 473                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 474                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 475                  arpa/inet.h arpa/ftp.h)
 476
 477 AC_CACHE_CHECK(POSIX termios, nmh_cv_sys_posix_termios,
 478 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 479 #include <unistd.h>
 480 #include <termios.h>]],
 481 [[/* SunOS 4.0.3 has termios.h but not the library calls.  */
 482 tcgetattr(0, 0);]])],
 483 nmh_cv_sys_posix_termios=yes, nmh_cv_sys_posix_termios=no)])
 484
 485 if test $nmh_cv_sys_posix_termios = yes; then
 486   AC_CACHE_CHECK(TIOCGWINSZ in termios.h,
 487   nmh_cv_header_termios_h_tiocgwinsz,
 488   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 489 #include <termios.h>]],
 490   [[int x = TIOCGWINSZ;]])],
 491   nmh_cv_header_termios_h_tiocgwinsz=yes,nmh_cv_header_termios_h_tiocgwinsz=no)])
 492 else
 493   nmh_cv_header_termios_h_tiocgwinsz=no
 494 fi
 495
 496 if test $nmh_cv_header_termios_h_tiocgwinsz = no; then
 497   AC_CACHE_CHECK(TIOCGWINSZ in sys/ioctl.h,
 498   nmh_cv_header_sys_ioctl_h_tiocgwinsz,
 499   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 500 #include <sys/ioctl.h>]],
 501   [[int x = TIOCGWINSZ;]])],
 502   nmh_cv_header_sys_ioctl_h_tiocgwinsz=yes,nmh_cv_header_sys_ioctl_h_tiocgwinsz=no)])
 503   if test $nmh_cv_header_sys_ioctl_h_tiocgwinsz = yes; then
 504     AC_DEFINE(GWINSZ_IN_SYS_IOCTL)dnl
 505   fi
 506 fi
 507
 508 dnl
 509 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 510 dnl really use a whole set of them, but this check should be
 511 dnl sufficient.
 512 dnl
 513 AC_CHECK_HEADER(libio.h, [
 514   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 515     AC_DEFINE(LINUX_STDIO) ]) ])
 516
 517 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM),,
 518 [[#if HAVE_SYS_STREAM_H
 519 #  include <sys/stream.h>
 520 #endif
 521 ]])
 522
 523 dnl ---------------
 524 dnl CHECK FUNCTIONS
 525 dnl ---------------
 526 AC_FUNC_VFORK
 527 AC_CHECK_LIB(mkstemp,mkstemp)
 528 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 529                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 530                sethostent getutent nl_langinfo mbtowc wcwidth)
 531
 532 dnl solaris screws this up
 533 AC_CHECK_FUNC(gethostbyname, [AC_DEFINE(HAVE_GETHOSTBYNAME)],
 534   AC_CHECK_LIB(nsl, gethostbyname, [AC_DEFINE(HAVE_GETHOSTBYNAME)] ) )
 535
 536 dnl sigsetjmp may be a macro
 537 AC_MSG_CHECKING(for sigsetjmp)
 538 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 539   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP) AC_MSG_RESULT(yes)],
 540   [AC_MSG_RESULT(no)])
 541
 542 AC_REPLACE_FUNCS(snprintf strdup)
 543
 544 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 545 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 546 dnl any system header.
 547 dnl
 548 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 549 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 550 dnl need to check?
 551 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 552                 AC_EGREP_HEADER(initgroups, unistd.h,
 553                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 554
 555 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 556 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 557 dnl seems to work perfectly and IBM apparently uses it in internal code).
 558 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 559 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 560 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 561 dnl prototype.
 562 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE))
 563
 564 dnl Check for multibyte character set support
 565 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 566     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 567   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 568     [Define to enable support for multibyte character sets])
 569 fi
 570
 571 dnl -------------------
 572 dnl CHECK FOR LIBRARIES
 573 dnl -------------------
 574 dnl Check location of modf
 575 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 576
 577 dnl Checks for network libraries (nsl, socket)
 578 AC_CHECK_NETLIBS
 579
 580 termcap_curses_order="termcap curses ncurses"
 581 for lib in $termcap_curses_order; do
 582   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 583 done
 584 AC_SUBST(TERMLIB)dnl
 585
 586 dnl ---------------
 587 dnl CHECK FOR ICONV
 588 dnl ---------------
 589
 590 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 591 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 592   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 593   if test "x$ac_found_iconv" = "xno"; then
 594     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 595     if test "x$ac_found_iconv" = "xno"; then
 596       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 597     fi
 598     if test "x$ac_found_iconv" != "xno"; then
 599       LIBS="-liconv $LIBS"
 600     fi
 601   else
 602     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 603     AC_CHECK_DECL(_libiconv_version,
 604       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 605       [ #include <iconv.h> ])
 606   fi
 607 fi
 608 if test "x$ac_found_iconv" = xyes; then
 609   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 610 fi
 611
 612 dnl Check if iconv uses const in prototype declaration
 613 if test "x$ac_found_iconv" = "xyes"; then
 614   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 615     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 616         #include <iconv.h>]],
 617         [[#ifdef __cplusplus
 618           "C"
 619           #endif
 620           #if defined(__STDC__) || defined(__cplusplus)
 621           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 622           #else
 623           size_t iconv();
 624           #endif]])],
 625       [ac_cv_iconv_const=],
 626       [ac_cv_iconv_const=const])])
 627   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 628     [Define as const if the declaration of iconv() needs const.])
 629 fi
 630
 631 dnl --------------
 632 dnl CHECK FOR NDBM
 633 dnl --------------
 634
 635 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 636             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 637 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 638             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 639
 640 if test "$nmh_ndbm" = "autodetect"; then
 641   if test "$nmh_ndbmheader" != "autodetect"; then
 642     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 643   else
 644
 645     dnl There are at least four implementations of ndbm, and
 646     dnl several of those can be in different places at the whim
 647     dnl of the system integrator. A good summary of this mess
 648     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 649
 650     dnl Classic ndbm with no library required (eg NetBSD): try this
 651     dnl first so we don't accidentally link in a pointless but harmless
 652     dnl library in one of the later ndbm.h+libfoo tests:
 653     NMH_CHECK_NDBM(ndbm.h,,,
 654     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 655       NMH_CHECK_NDBM(db.h,db,,
 656     dnl Berkeley DBv1 emulating ndbm:
 657         NMH_CHECK_NDBM(ndbm.h,db,,
 658           NMH_CHECK_NDBM(ndbm.h,db1,,
 659     dnl Classic ndbm:
 660             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 661     dnl glibc2.1 systems put db1 in a subdir:
 662               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 663     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 664     dnl and possibly needing gbdm_compat library:
 665                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 666                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 667                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 668                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 669
 670   fi
 671 else
 672   dnl We don't really need to check that the user-specified values work,
 673   dnl but it is a convenience to the user to bomb out early rather than
 674   dnl after configure and half the compile process.
 675   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 676 fi
 677
 678 if test "$nmh_ndbm_found" = "no"; then
 679   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 680 else
 681   dnl Now export the lib/header to our makefile/config.h:
 682   if test x"$nmh_ndbmheader" != x; then
 683     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>)
 684   fi
 685   if test x"$nmh_ndbm" != x; then
 686     NDBM_LIBS="-l$nmh_ndbm"
 687   else
 688     NDBM_LIBS=
 689   fi
 690   AC_SUBST(NDBM_LIBS)
 691 fi
 692
 693
 694 dnl ----------------
 695 dnl CHECK FOR HESIOD
 696 dnl ----------------
 697 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 698   if test x"$with_hesiod" != x"yes"; then
 699     HESIOD_INCLUDES="-I$with_hesiod/include"
 700     HESIOD_LIBS="-L$with_hesiod/lib"
 701   fi
 702   AC_CHECK_FUNC(res_send,
 703         [AC_CHECK_LIB(hesiod, hes_resolve,
 704                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod"],
 705                 [AC_MSG_ERROR(Hesiod library not found)],
 706                 $HESIOD_LIBS)],
 707         [AC_CHECK_LIB(hesiod, hes_resolve,
 708                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod -lresolv"],
 709                 [AC_MSG_ERROR(Hesiod library not found)],
 710                 $HESIOD_LIBS -lresolv)])
 711
 712 fi
 713 AC_SUBST(HESIOD_INCLUDES)dnl
 714 AC_SUBST(HESIOD_LIBS)dnl
 715
 716 dnl ----------------------------------
 717 dnl CHECK FOR KRB4 (Kerberos4 support)
 718 dnl ----------------------------------
 719 if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 720   if test x"$with_krb4" != x"yes"; then
 721     KRB4_INCLUDES="-I$with_krb4/include"
 722     if test -d "$with_krb4/include/kerberosIV"; then
 723       KRB4_INCLUDES="$KRB4_INCLUDES -I$with_krb4/include/kerberosIV"
 724     fi
 725     KRB4_LIBS="-L$with_krb4/lib"
 726   elif test -d /usr/include/kerberosIV; then
 727     KRB4_INCLUDES="-I/usr/include/kerberosIV"
 728   fi
 729 dnl First, check if we have -lk5crypto, since that means we have a recent krb5
 730
 731   AC_CHECK_LIB(k5crypto, krb5_encrypt,
 732         [AC_CHECK_LIB(krb4, krb_rd_req,
 733                 [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lk5crypto -lcom_err"],
 734                 [AC_MSG_ERROR(Kerberos 4 compatibility libraries not found)],
 735                 $KRB4_LIBS -ldes425 -lkrb5 -lk5crypto -lcom_err)],
 736
 737         [AC_CHECK_LIB(krb4, krb_rd_req,
 738             [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lcrypto -lcom_err"],
 739             [AC_CHECK_LIB(krb, krb_rd_req,
 740               [KRB4_LIBS="$KRB4_LIBS -lkrb -ldes"],
 741               [AC_MSG_ERROR(Kerberos 4 libraries not found)],
 742               $KRB4_LIBS -ldes)],
 743             $KRB4_LIBS -ldes425 -lkrb5 -lcrypto -lcom_err)],
 744         $KRB4_LIBS)
 745
 746 fi
 747 AC_SUBST(KRB4_INCLUDES)dnl
 748 AC_SUBST(KRB4_LIBS)dnl
 749
 750 dnl --------------------
 751 dnl CHECK FOR CYRUS SASL
 752 dnl --------------------
 753 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
 754   if test x"$with_cyrus_sasl" != x"yes"; then
 755     SASL_INCLUDES="-I$with_cyrus_sasl/include"
 756     SASL_LIBS="-L$with_cyrus_sasl/lib"
 757
 758     dnl Do OS-specific hardcoding of SASL shared library path into executables,
 759     dnl so user isn't forced to set environment variables like Solaris'
 760     dnl LD_LIBRARY_PATH.
 761     case "$target_os" in
 762       solaris*)
 763         SASL_LIBS="$SASL_LIBS -R$with_cyrus_sasl/lib"
 764         ;;
 765     esac
 766   fi
 767   save_LDFLAGS="$LDFLAGS"
 768   LDFLAGS="$LDFLAGS $SASL_LIBS"
 769   AC_CHECK_LIB(sasl2, sasl_client_new,
 770     [SASL_LIBS="$SASL_LIBS -lsasl2"],
 771     [AC_MSG_ERROR(Cyrus SASL library not found)])
 772   LDFLAGS="$save_LDFLAGS"
 773 fi
 774 AC_SUBST(SASL_INCLUDES)dnl
 775 AC_SUBST(SASL_LIBS)dnl
 776
 777 dnl ---------------------
 778 dnl CHECK TERMCAP LIBRARY
 779 dnl ---------------------
 780
 781 dnl Add the termcap library, so that the following configure
 782 dnl tests will find it when it tries to link test programs.
 783 nmh_save_LIBS="$LIBS"
 784 LIBS="$TERMLIB $LIBS"
 785
 786 dnl Checks for external variable ospeed in the termcap library.
 787 AC_CACHE_CHECK(if an include file defines ospeed,
 788 nmh_cv_decl_ospeed_include_defines,
 789 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 790 #if HAVE_TERMIOS_H
 791 #include <termios.h>
 792 #endif
 793 #if HAVE_TERMCAP_H
 794 #include <termcap.h>
 795 #endif]], [[ospeed = 0;]])],
 796 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 797
 798 if test $nmh_cv_decl_ospeed_include_defines = no; then
 799   AC_CACHE_CHECK(if you must define ospeed,
 800   nmh_cv_decl_ospeed_must_define,
 801   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 802   [[extern short ospeed; ospeed = 0;]])],
 803   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 804 fi
 805
 806 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 807   AC_DEFINE(HAVE_OSPEED)dnl
 808 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 809   AC_DEFINE(HAVE_OSPEED)
 810   AC_DEFINE(MUST_DEFINE_OSPEED)
 811 fi
 812
 813 dnl dnl Checks if tgetent accepts NULL and will
 814 dnl dnl allocate its own termcap buffer.
 815 dnl AC_CACHE_CHECK(if tgetent accepts NULL,
 816 dnl nmh_cv_func_tgetent_accepts_null,
 817 dnl [AC_TRY_RUN([main(){int i = tgetent((char*)0,"vt100");exit(!i || i == -1);}],
 818 dnl   nmh_cv_func_tgetent_accepts_null=yes,
 819 dnl   nmh_cv_func_tgetent_accepts_null=no,
 820 dnl   nmh_cv_func_tgetent_accepts_null=no)])
 821 dnl if test $nmh_cv_func_tgetent_accepts_null = yes; then
 822 dnl   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 823 dnl fi
 824
 825 dnl Now put the libraries back to what it was before we
 826 dnl starting checking the termcap library.
 827 LIBS="$nmh_save_LIBS"
 828
 829 dnl --------------
 830 dnl CHECK TYPEDEFS
 831 dnl --------------
 832 AC_TYPE_SIGNAL
 833 AC_TYPE_PID_T
 834 AC_TYPE_OFF_T
 835 AC_TYPE_UID_T
 836 AC_TYPE_MODE_T
 837 AC_TYPE_SIZE_T
 838
 839 dnl Check for sigset_t.  Currently I'm looking in
 840 dnl <sys/types.h> and <signal.h>.  Others might need
 841 dnl to be added.
 842 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 843 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 844 #include <signal.h>]], [[sigset_t tempsigset;]])],
 845 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 846 if test $nmh_cv_type_sigset_t = no; then
 847   AC_DEFINE(sigset_t, unsigned int)
 848 fi
 849
 850 dnl ----------------
 851 dnl CHECK STRUCTURES
 852 dnl ----------------
 853 AC_CHECK_MEMBERS(struct stat.st_blksize)
 854
 855 AC_CACHE_CHECK(for tm_gmtoff in struct tm, nmh_cv_struct_tm_gmtoff,
 856 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
 857 # include <sys/time.h>
 858 # include <time.h>
 859 #else
 860 # ifdef TM_IN_SYS_TIME
 861 #  include <sys/time.h>
 862 # else
 863 #  include <time.h>
 864 # endif
 865 #endif]], [[struct tm temptm; temptm.tm_gmtoff = 0;]])],
 866 nmh_cv_struct_tm_gmtoff=yes,nmh_cv_struct_tm_gmtoff=no)])
 867 if test $nmh_cv_struct_tm_gmtoff = yes; then
 868   AC_DEFINE(HAVE_TM_GMTOFF)
 869 fi
 870
 871 AC_CACHE_CHECK(for ut_type in struct utmp, nmh_cv_struct_utmp_ut_type,
 872 [AC_TRY_COMPILE(
 873 [#include <utmp.h>],
 874 [struct utmp temputmp; temputmp.ut_type = 0;],
 875   nmh_cv_struct_utmp_ut_type=yes, nmh_cv_struct_utmp_ut_type=no)])
 876 if test $nmh_cv_struct_utmp_ut_type = yes; then
 877   AC_DEFINE(HAVE_UTMP_UT_TYPE)
 878 fi
 879
 880 dnl -------------
 881 dnl CHECK SIGNALS
 882 dnl -------------
 883 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 884 AC_MSG_CHECKING(what style of signals to use)
 885 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 886   signals_style=POSIX_SIGNALS
 887   AC_DEFINE(POSIX_SIGNALS)
 888   AC_DEFINE(RELIABLE_SIGNALS)
 889 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 890   signals_style=BSD_SIGNALS
 891   AC_DEFINE(BSD_SIGNALS)
 892   AC_DEFINE(RELIABLE_SIGNALS)
 893 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 894   signals_style=SYSV_SIGNALS
 895   AC_DEFINE(SYSV_SIGNALS)
 896 else
 897   signals_style=NO_SIGNAL_BLOCKING
 898   AC_DEFINE(NO_SIGNAL_BLOCKING)
 899 fi
 900
 901 AC_MSG_RESULT($signals_style)
 902
 903 dnl Where is <signal.h> located?  Needed as input for signames.awk
 904 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 905 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 906                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 907                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 908                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 909                  /usr/include/sys/signal.h      dnl Almost everybody else
 910                  /dev/null;                     dnl Just in case we fall through
 911 do
 912   test -f $SIGNAL_H && \
 913   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 914   break
 915 done
 916 nmh_cv_path_signal_h=$SIGNAL_H
 917 ])
 918 SIGNAL_H=$nmh_cv_path_signal_h
 919 AC_SUBST(SIGNAL_H)dnl
 920
 921 dnl ----------------
 922 dnl OS SPECIFIC DEFINES
 923 dnl ----------------
 924 case "$target_os" in
 925
 926   solaris2*)
 927     AC_DEFINE(SYS5)
 928     AC_DEFINE(SVR4)
 929     ;;
 930   irix*)
 931     AC_DEFINE(SYS5)
 932     AC_DEFINE(SVR4)
 933     ;;
 934   osf*)
 935     AC_DEFINE(SYS5)
 936     AC_DEFINE(SVR4)
 937     ;;
 938   aix*)
 939     AC_DEFINE(SYS5)
 940     AC_DEFINE(SVR4)
 941     ;;
 942   sunos4*)
 943     AC_DEFINE(BSD42)
 944     ;;
 945   freebsd*)
 946     AC_DEFINE(BSD42)
 947     AC_DEFINE(BSD44)
 948     ;;
 949   netbsd*)
 950     AC_DEFINE(BSD42)
 951     AC_DEFINE(BSD44)
 952     ;;
 953   openbsd*)
 954     AC_DEFINE(BSD42)
 955     AC_DEFINE(BSD44)
 956     ;;
 957   bsd/os*)
 958     AC_DEFINE(BSD42)
 959     AC_DEFINE(BSD44)
 960     ;;
 961   sco5*)
 962     AC_DEFINE(SYS5)
 963     AC_DEFINE(SCO_5_STDIO)
 964     ;;
 965 esac
 966
 967
 968 dnl ----------------
 969 dnl OUTPUT MAKEFILES
 970 dnl ----------------
 971 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 972                 mts/Makefile mts/smtp/Makefile \
 973                 etc/Makefile docs/Makefile man/Makefile)
 974 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 975 AC_OUTPUT
 976
 977 dnl Umm, what's the point of these assignments??  -- <dan-nmh@dilvish.speed.net>
 978 eval "nmhbin=${bindir}";         eval "nmhbin2=${nmhbin}"
 979 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf2=${nmhsysconf}"
 980 eval "nmhlib=${libdir}";         eval "nmhlib2=${nmhlib}"
 981 eval "nmhman=${mandir}"
 982
 983 pop_kinds=no
 984 if test x"$enable_pop" = x"yes"; then
 985   pop_kinds="yes ("
 986
 987   if test x"$enable_apop" = x"yes"; then
 988     pop_kinds="${pop_kinds}APOP "
 989   fi
 990
 991   if test x"$with_krb4" != x -a x"$with_krb4" != x"no"; then
 992     pop_kinds="${pop_kinds}KPOP "
 993   fi
 994
 995   pop_kinds="${pop_kinds}POP3)"
 996 fi
 997
 998 echo "
 999 nmh configuration
1000 -----------------
1001 nmh version                : AC_PACKAGE_VERSION
1002 target os                  : ${target}
1003 compiler                   : ${CC}
1004 compiler flags             : ${CFLAGS}
1005 linker flags               : ${LDFLAGS}
1006 definitions                : ${OURDEFS}
1007 source code location       : ${srcdir}
1008 binary install path        : ${nmhbin2}
1009 libary install path        : ${nmhlib2}
1010 config files install path  : ${nmhsysconf2}
1011 man page install path      : ${nmhman}
1012 backup prefix              : ${backup_prefix}
1013 transport system           : ${MTS}
1014 file locking type          : ${LOCKTYPE}
1015 default smtp servers       : ${smtpservers}
1016 default editor             : ${editorpath}
1017 default pager              : ${pagerpath}
1018 email address masquerading : ${masquerade}
1019 pop is enabled             : ${pop_kinds}
1020 SASL support               : ${sasl_support}"
1021 echo ""