git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Do you want to disable use of locale functions
  34 AH_TEMPLATE([LOCALE],
  35 [Undefine if you don't want locale features.  By default this is defined.])
  36 AC_ARG_ENABLE([locale],
  37   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  38   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  39   [AC_DEFINE(LOCALE)])
  40
  41 dnl Do you want client-side support for using SASL for authentication?
  42 dnl Note that this code will be enabled for both POP and SMTP
  43 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  44   [Enable SASL support via the Cyrus SASL library]))
  45 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  46       AC_DEFINE([CYRUS_SASL], [1],
  47                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  48       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  49             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  50             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  51       sasl_support=yes], [sasl_support=no])
  52
  53 dnl Do you want client-side support for encryption with TLS?
  54 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  55 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  56       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  57       tls_support=yes],[tls_support=no])
  58
  59 dnl What should be the default editor?
  60 AC_ARG_WITH([editor],
  61   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  62
  63 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  64
  65 dnl Set the backup prefix
  66 AC_ARG_WITH([hash-backup],
  67   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  68 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  69       [backup_prefix="#"], [backup_prefix=","])
  70 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  71     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  72
  73 dnl What method of locking to use?
  74 AS_CASE(["$host_os"],
  75   [aix*|cygwin*|linux*],
  76     [default_locktype="fcntl"; default_locking=FCNTL_LOCKING],
  77   [freebsd*], [default_locktype="flock"; default_locking=FLOCK_LOCKING],
  78   [default_locktype="dot"; default_locking=DOT_LOCKING])
  79
  80 AC_ARG_WITH(locking,
  81   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  82   [specify the file locking method]))
  83
  84 if test x"$with_locking" = x"dot"; then
  85   LOCKTYPE="dot"
  86   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  87 elif test x"$with_locking" = x"flock"; then
  88   LOCKTYPE="flock"
  89   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  90 elif test x"$with_locking" = x"lockf"; then
  91   LOCKTYPE="lockf"
  92   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  93 elif test x"$with_locking" = x"fcntl"; then
  94   LOCKTYPE="fcntl"
  95   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  96 else
  97   LOCKTYPE="$default_locktype"
  98   AC_DEFINE_UNQUOTED($default_locking, 1)dnl
  99 fi
 100
 101 dnl Should we use a locking directory?
 102 AC_ARG_ENABLE([lockdir],
 103   [AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 104   AS_IF([test "x$enableval" = xyes],[
 105     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 106   AS_IF([test "x$LOCKTYPE" != xdot],[
 107     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 108   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 109                      [Directory to store dot-locking lock files])
 110 ])
 111
 112 dnl What method of posting should post use?
 113 AC_ARG_WITH([mts],
 114   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 115   [specify the default mail transport agent/service]))
 116
 117 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 118       [test x"$with_mts" = x"sendmail"], [MTS="sendmail"],
 119       [MTS="smtp"])
 120 AC_SUBST([MTS])dnl
 121
 122 dnl What should be the default pager?
 123 AC_ARG_WITH([pager],
 124   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 125
 126 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 127
 128 dnl If a pager is not explicitly specified, then look for one.
 129 dnl Fall back to `cat', to avoid catastrophic failure of
 130 dnl `mhshow', et al., if pagerpath is set to `no'.
 131 if test -z "$pagerpath"; then
 132   pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 133   AC_PATH_PROGS([pagerpath], [more less most cat], [no], [$pathtmp])
 134 fi
 135 AC_SUBST(pagerpath)dnl
 136
 137 dnl What should be the default mail server(s)?
 138 AC_ARG_WITH(smtpservers,
 139   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 140   [specify the default SMTP server(s) @<:@localhost@:>@]))
 141 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 142       [smtpservers="localhost"])
 143 AC_SUBST([smtpservers])dnl
 144
 145 dnl ----------------------------------------------------
 146 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 147 dnl ----------------------------------------------------
 148 AC_PREFIX_DEFAULT([/usr/local/nmh])
 149
 150 dnl ------------------
 151 dnl CHECK THE COMPILER
 152 dnl ------------------
 153 dnl We want these before the checks,
 154 dnl so the checks can modify their values.
 155 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 156 if test x"$enable_debug" = x"yes"; then
 157   test -z "$LDFLAGS" && LDFLAGS=-g
 158 fi
 159
 160 AC_PROG_CC
 161 AM_PROG_CC_C_O
 162
 163 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 164   [nmh_cv_has_unusedmacros],
 165   [nmh_saved_cppflags="$CPPFLAGS"
 166    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 167    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 168    CPPFLAGS="$nmh_saved_cppflags"])
 169
 170 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 171   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 172                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 173   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 174 fi
 175 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 176
 177 AC_CACHE_CHECK([whether compiler supports -Wno-sign-compare],
 178   [nmh_cv_has_nosigncompare],
 179   [nmh_saved_cppflags="$CPPFLAGS"
 180    CPPFLAGS="$CPPFLAGS -Wno-sign-compare"
 181    AC_TRY_COMPILE([],[],nmh_cv_has_nosigncompare=yes,
 182                   nmh_cv_has_nosigncompare=no)
 183    CPPFLAGS="$nmh_saved_cppflags"])
 184
 185 if test "$nmh_cv_has_nosigncompare" = 'yes'; then
 186   DISABLE_SIGN_COMPARE_WARNING=-Wno-sign-compare
 187 fi
 188 AC_SUBST(DISABLE_SIGN_COMPARE_WARNING)dnl
 189
 190 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 191 [nmh_saved_cflags="$CFLAGS"
 192  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 193  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 194  CFLAGS="$nmh_saved_cflags"])
 195
 196 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 197 [nmh_saved_cflags="$CFLAGS"
 198  CFLAGS="$CFLAGS -Wno-pointer-sign"
 199  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 200  CFLAGS="$nmh_saved_cflags"])
 201
 202 dnl Can't use -ansi with gcc 4.5.3 on Cygwin, at least through setup
 203 dnl setup version 2.763, because it disables some features in the
 204 dnl system system header files and warns about them with -Wall.  Try
 205 dnl to test for that generally, though still with gcc.
 206 if test "$GCC" = yes; then
 207   AC_CACHE_CHECK([whether we can use -ansi with gcc], [nmh_cv_has_dash_ansi],
 208     [nmh_saved_cppflags="$CPPFLAGS"
 209      nmh_saved_cflags="$CFLAGS"
 210      CPPFLAGS="-D_GNU_SOURCE"
 211      CFLAGS="-ansi -Wall -Werror"
 212      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>],[tzset();])],
 213        [nmh_cv_has_dash_ansi=yes],
 214        [nmh_cv_has_dash_ansi=no])
 215      CPPFLAGS="$nmh_saved_cppflags"
 216      CFLAGS="$nmh_saved_cflags"])
 217 else
 218   nmh_cv_has_dash_ansi=no
 219 fi
 220
 221 dnl if the user hasn't specified CFLAGS, then
 222 dnl   if compiler is gcc, then
 223 dnl    use -O2 and some warning flags
 224 dnl   else use -O
 225 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 226 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 227 dnl warnings which are probably mostly spurious and which in any case we
 228 dnl don't want to deal with now.
 229 if test "$nmh_cv_has_noptrsign" = "yes"; then
 230     if test "$nmh_cv_has_dash_ansi" = "yes"; then
 231         nmh_gcc_common_flags="-ansi -pedantic -Wall"
 232     else
 233         nmh_gcc_common_flags="-Wall"
 234     fi
 235     if test "$nmh_cv_has_wextra" = "yes"; then
 236         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered "\
 237 "-Wno-pointer-sign"
 238     else
 239         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wno-pointer-sign"
 240     fi
 241 else
 242     if test "$nmh_cv_has_wextra" = "yes"; then
 243         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered"
 244     else
 245         nmh_gcc_warnflags="${nmh_gcc_common_flags}"
 246     fi
 247 fi
 248
 249 if test -n "$auto_cflags"; then
 250   if test x"$enable_debug" = x"yes"; then
 251     if test -n "$GCC"; then
 252       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 253     else
 254       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 255     fi
 256   else
 257     if test -z "$LDFLAGS"; then
 258       case "$build_os" in
 259         darwin*)
 260           LDFLAGS=
 261           ;;
 262         *)
 263           LDFLAGS=-s
 264           ;;
 265       esac
 266     fi
 267     if test -n "$GCC"; then
 268       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 269     else
 270       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 271     fi
 272   fi
 273 fi
 274
 275 AC_C_CONST              dnl Does compiler support `const'.
 276
 277 dnl ------------------
 278 dnl CHECK FOR PROGRAMS
 279 dnl ------------------
 280 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 281 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 282 AC_PROG_RANLIB          dnl Check for `ranlib'
 283 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 284 AC_PROG_SED             dnl Check for Posix-compliant sed
 285 AC_PROG_LEX             dnl Check for lex/flex
 286
 287 dnl Look for `cut'
 288 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 289 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 290
 291 dnl
 292 dnl Check for MD5 program and formatting command
 293 dnl
 294 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 295 AS_CASE(["${MD5SUM}"],
 296         [md5sum], [MD5FMT="cat"],
 297         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 298         [MD5FMT="missing"])
 299 AC_SUBST([MD5FMT])
 300
 301 dnl ----------------------------------------------
 302 dnl check for lclint, and lint if it doesn't exist
 303 dnl ----------------------------------------------
 304 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 305 if test x$ac_cv_prog_linttmp1 != xno ; then
 306   LINT=$ac_cv_prog_linttmp1
 307   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 308 else
 309   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 310   if test x$ac_cv_prog_linttmp2 != xno ; then
 311     LINT=$ac_cv_prog_linttmp2
 312     LINTFLAGS=""
 313   else
 314     LINT="echo 'No lint program found'"
 315     LINTFLAGS=""
 316   fi
 317 fi
 318 AC_SUBST([LINT])dnl
 319 AC_SUBST([LINTFLAGS])dnl
 320
 321 dnl Look for `ls'
 322 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 323 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 324
 325 dnl See how we get ls to display the owner and the group
 326 if test "$lspath" != "no"; then
 327   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 328                  [nmh_cv_ls_grpopt],
 329   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 330     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 331     dnl ls, it would seem -l gave us both the user and group.  On this type of
 332     dnl ls, -g makes _only_ the group be displayed (and not the user).
 333     nmh_cv_ls_grpopt="-l"
 334   else
 335     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 336     nmh_cv_ls_grpopt="-lg"
 337   fi])
 338 fi
 339
 340 dnl Look for `sendmail'
 341 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 342 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 343
 344 dnl Look for `vi'
 345 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 346 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 347
 348 dnl If editor is not specified yet,
 349 dnl then use `vi' as the default.
 350 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 351 AC_SUBST([editorpath])dnl
 352
 353 dnl Cygwin FAT filesystems do not support hard links.  So use cp instead,
 354 dnl even if running on an NTFS or other filesystem.
 355 AS_CASE(["$host_os"],
 356   [cygwin*],[LINK_FILE=cp],
 357   [LINK_FILE=ln])
 358 AC_SUBST([LINK_FILE])
 359
 360 dnl ----------------------------------------------------------
 361 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 362 dnl ----------------------------------------------------------
 363 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 364 [for mailspool in /var/mail        dnl
 365                   /var/spool/mail  dnl
 366                   /usr/spool/mail  dnl
 367                   /dev/null;       dnl Just in case we fall through
 368 do
 369   test -d $mailspool && break
 370 done
 371 nmh_cv_mailspool=$mailspool
 372 ])
 373 mailspool=$nmh_cv_mailspool
 374 AC_SUBST([mailspool])dnl
 375
 376 dnl See whether the mail spool directory is world-writable.
 377 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 378   AC_CACHE_CHECK(whether the mail spool is world-writable,
 379                  nmh_cv_mailspool_world_writable,
 380   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 381     nmh_cv_mailspool_world_writable=no
 382   else
 383     nmh_cv_mailspool_world_writable=yes
 384   fi])
 385 fi
 386
 387 dnl Also, check for liblockfile (as found on Debian systems)
 388 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 389
 390 dnl and whether its companion program dotlockfile is setgid
 391 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 392 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 393   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 394     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 395     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 396         nmh_cv_dotlockfile_setgid=yes
 397       else
 398         nmh_cv_dotlockfile_setgid=no
 399       fi])
 400   fi
 401 fi
 402
 403 dnl Provide a way for distcheck to disable setgid_mail via
 404 dnl DISTCHECK_CONFIGURE_FLAGS.
 405 if test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0; then
 406   nmh_cv_dotlockfile_setgid=yes
 407 fi
 408
 409 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 410 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 411 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 412   dnl do we really need both of these?
 413   AC_DEFINE(MAILGROUP,1,
 414     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 415   SETGID_MAIL=1
 416 fi
 417 AC_SUBST(SETGID_MAIL)dnl
 418
 419 dnl Use ls to see which group owns the mail spool directory.
 420 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 421 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 422 ])
 423 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 424 AC_SUBST(MAIL_SPOOL_GRP)dnl
 425
 426 dnl ------------------
 427 dnl CHECK HEADER FILES
 428 dnl ------------------
 429
 430 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 431 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 432 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 433 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 434 dnl declared; if so they should have an entry added to this case statement.
 435 dnl NB that we must define this on the compiler command line, not in config.h,
 436 dnl because it must be set before any system header is included and there's no
 437 dnl portable way to make sure that files generated by lex include config.h
 438 dnl before system header files.
 439
 440 AS_CASE(["$host_os"],
 441         [linux*],
 442         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 443           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 444                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 445
 446 AC_HEADER_STDC
 447 AC_HEADER_TIOCGWINSZ
 448 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 449                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 450                   sys/param.h sys/time.h sys/stream.h])
 451
 452 dnl
 453 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 454 dnl really use a whole set of them, but this check should be
 455 dnl sufficient.
 456 dnl
 457 AC_CHECK_HEADER(libio.h, [
 458   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 459     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 460
 461 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 462   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 463 [[#if HAVE_SYS_STREAM_H
 464 #  include <sys/stream.h>
 465 #endif
 466 ]])
 467
 468 dnl ---------------
 469 dnl CHECK FUNCTIONS
 470 dnl ---------------
 471 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 472
 473 dnl Check for multibyte character set support
 474 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 475             "x$ac_cv_header_wctype_h" = "xyes" -a \
 476             "x$ac_cv_func_wcwidth" = "xyes" -a \
 477             "x$ac_cv_func_mbtowc" = "xyes"],
 478       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 479                  [Define to enable support for multibyte character sets.])
 480        MULTIBYTE_ENABLED=1],
 481       [MULTIBYTE_ENABLED=0])
 482 AC_SUBST([MULTIBYTE_ENABLED])
 483
 484 dnl -------------------
 485 dnl CHECK FOR LIBRARIES
 486 dnl -------------------
 487 dnl Check location of modf
 488 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 489
 490 dnl Checks for network libraries (nsl, socket)
 491 NMH_CHECK_NETLIBS
 492
 493 NMH_READLINE
 494
 495 termcap_curses_order="termcap curses ncurses"
 496 for lib in $termcap_curses_order; do
 497   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 498 done
 499 AC_SUBST([TERMLIB])dnl
 500 AS_IF([test "x$TERMLIB" = "x"],
 501       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 502 or ncurses library or package that you can install?])])
 503
 504
 505 dnl ---------------
 506 dnl CHECK FOR ICONV
 507 dnl ---------------
 508
 509 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 510 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 511   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 512   if test "x$ac_found_iconv" = "xno"; then
 513     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 514     if test "x$ac_found_iconv" = "xno"; then
 515       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 516     fi
 517     if test "x$ac_found_iconv" != "xno"; then
 518       ICONVLIB="-liconv"
 519     fi
 520   else
 521     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 522     AC_CHECK_DECL(_libiconv_version,
 523       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 524       [ #include <iconv.h> ])
 525   fi
 526 fi
 527 if test "x$ac_found_iconv" = xyes; then
 528   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 529 fi
 530 AC_SUBST([ICONVLIB])
 531
 532 dnl Check if iconv uses const in prototype declaration
 533 if test "x$ac_found_iconv" = "xyes"; then
 534   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 535     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 536         #include <iconv.h>]],
 537         [[#ifdef __cplusplus
 538           "C"
 539           #endif
 540           #if defined(__STDC__) || defined(__cplusplus)
 541           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 542           #else
 543           size_t iconv();
 544           #endif]])],
 545       [ac_cv_iconv_const=],
 546       [ac_cv_iconv_const=const])])
 547   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 548     [Define as const if the declaration of iconv() needs const.])
 549 fi
 550
 551 dnl --------------
 552 dnl CHECK FOR NDBM
 553 dnl --------------
 554
 555 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 556             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 557 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 558             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 559
 560 if test "$nmh_ndbm" = "autodetect"; then
 561   if test "$nmh_ndbmheader" != "autodetect"; then
 562     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 563   else
 564
 565     dnl There are at least four implementations of ndbm, and
 566     dnl several of those can be in different places at the whim
 567     dnl of the system integrator. A good summary of this mess
 568     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 569
 570     dnl Classic ndbm with no library required (eg NetBSD): try this
 571     dnl first so we don't accidentally link in a pointless but harmless
 572     dnl library in one of the later ndbm.h+libfoo tests:
 573     NMH_CHECK_NDBM(ndbm.h,,,
 574     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 575       NMH_CHECK_NDBM(db.h,db,,
 576     dnl Berkeley DBv1 emulating ndbm:
 577         NMH_CHECK_NDBM(ndbm.h,db,,
 578           NMH_CHECK_NDBM(ndbm.h,db1,,
 579     dnl Classic ndbm:
 580             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 581     dnl glibc2.1 systems put db1 in a subdir:
 582               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 583     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 584     dnl and possibly needing gbdm_compat library:
 585                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 586                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 587                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 588                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 589
 590   fi
 591 else
 592   dnl We don't really need to check that the user-specified values work,
 593   dnl but it is a convenience to the user to bomb out early rather than
 594   dnl after configure and half the compile process.
 595   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 596 fi
 597
 598 if test "$nmh_ndbm_found" = "no"; then
 599   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 600 else
 601   dnl Now export the lib/header to our makefile/config.h:
 602   if test x"$nmh_ndbmheader" != x; then
 603     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 604       [Define to the header containing the ndbm API prototypes.])
 605   fi
 606   if test x"$nmh_ndbm" != x; then
 607     NDBM_LIBS="-l$nmh_ndbm"
 608   else
 609     NDBM_LIBS=
 610   fi
 611   AC_SUBST([NDBM_LIBS])
 612 fi
 613
 614 dnl ------------------
 615 dnl Set RPM build root
 616 dnl ------------------
 617 dnl nmhrpm is used in the final summary, see below.  The default value is
 618 dnl reported there as ./RPM, consistent with the reporting of the default
 619 dnl source code location as ., but its absolute path is used in the Makefile.
 620 AC_ARG_WITH(rpmdir,
 621   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 622   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 623           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 624 AC_SUBST([rpmdir])
 625
 626
 627 dnl --------------------
 628 dnl CHECK FOR CYRUS-SASL
 629 dnl --------------------
 630
 631 AS_IF([test x"$sasl_support" = x"yes"],[
 632   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 633   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 634     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 635 AC_SUBST([SASLLIB])
 636
 637 dnl -----------------
 638 dnl CHECK FOR OPENSSL
 639 dnl -----------------
 640
 641 AS_IF([test x"$tls_support" = x"yes"],[
 642   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 643   AC_CHECK_LIB([crypto], [BIO_write], ,
 644     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 645   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 646     [AC_MSG_ERROR([OpenSSL library not found])])])
 647
 648 dnl ---------------------
 649 dnl CHECK TERMCAP LIBRARY
 650 dnl ---------------------
 651
 652 dnl Add the termcap library, so that the following configure
 653 dnl tests will find it when it tries to link test programs.
 654 nmh_save_LIBS="$LIBS"
 655 LIBS="$TERMLIB $LIBS"
 656
 657 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 658 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 659 dnl in tgetstr().
 660 dnl Under Cygwin test program crashes but exit code is still 0. So,
 661 dnl we test for a file that porgram should create
 662 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 663 [Define to 1 if tgetent() accepts NULL as a buffer.])
 664 AC_CACHE_CHECK(if tgetent accepts NULL,
 665 nmh_cv_func_tgetent_accepts_null,
 666 [AC_TRY_RUN([
 667 main()
 668 {
 669     char buf[4096];
 670     int r1 = tgetent(buf, "vt100");
 671     int r2 = tgetent((char*)0,"vt100");
 672     if (r1 >= 0 && r1 == r2) {
 673         char tbuf[1024], *u;
 674         u = tbuf;
 675         tgetstr("cl", &u);
 676         creat("conftest.tgetent", 0640);
 677     }
 678     exit((r1 != r2) || r2 == -1);
 679 }
 680 ],
 681   if test -f conftest.tgetent; then
 682     nmh_cv_func_tgetent_accepts_null=yes
 683   else
 684     nmh_cv_func_tgetent_accepts_null=no
 685   fi,
 686   nmh_cv_func_tgetent_accepts_null=no,
 687   nmh_cv_func_tgetent_accepts_null=no)])
 688 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 689   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 690 fi
 691 AC_CACHE_CHECK(if tgetent returns 0 on success,
 692 nmh_cv_func_tgetent_zero_success,
 693 [AC_TRY_RUN([
 694 main()
 695 {
 696     char buf[4096];
 697     int r1 = tgetent(buf, "!@#$%^&*");
 698     int r2 = tgetent(buf, "vt100");
 699     if (r1 < 0 && r2 == 0) {
 700         char tbuf[1024], *u;
 701         u = tbuf;
 702         tgetstr("cl", &u);
 703         creat("conftest.tgetent0", 0640);
 704     }
 705     exit(r1 == r2);
 706 }
 707 ],
 708   if test -f conftest.tgetent0; then
 709     nmh_cv_func_tgetent_zero_success=yes
 710   else
 711     nmh_cv_func_tgetent_zero_success=no
 712   fi,
 713   nmh_cv_func_tgetent_zero_success=no,
 714   nmh_cv_func_tgetent_zero_success=no)])
 715 AH_TEMPLATE([TGETENT_SUCCESS],
 716 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 717 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 718   AC_DEFINE(TGETENT_SUCCESS, 0)
 719 else
 720   AC_DEFINE(TGETENT_SUCCESS, 1)
 721 fi
 722
 723 dnl Now put the libraries back to what it was before we
 724 dnl starting checking the termcap library.
 725 LIBS="$nmh_save_LIBS"
 726
 727 dnl --------------
 728 dnl CHECK TYPEDEFS
 729 dnl --------------
 730 AC_TYPE_PID_T
 731 AC_TYPE_OFF_T
 732 AC_TYPE_UID_T
 733 AC_TYPE_MODE_T
 734 AC_TYPE_SIZE_T
 735
 736 dnl ----------------
 737 dnl CHECK STRUCTURES
 738 dnl ----------------
 739
 740 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 741 dnl (FreeBSD has a timezone() function but not a timezone global
 742 dnl variable that is visible).
 743 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 744
 745 AC_STRUCT_DIRENT_D_TYPE
 746
 747 dnl Where is <signal.h> located?  Needed as input for signames.awk
 748 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 749 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 750                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 751                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 752                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 753                  /usr/include/sys/signal.h      dnl Almost everybody else
 754                  /dev/null;                     dnl Just in case we fall through
 755 do
 756   test -f $SIGNAL_H && \
 757   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 758   break
 759 done
 760 nmh_cv_path_signal_h=$SIGNAL_H
 761 ])
 762 SIGNAL_H=$nmh_cv_path_signal_h
 763 AC_SUBST(SIGNAL_H)dnl
 764
 765 dnl
 766 dnl Sigh, this is required because under the new world order autoconf has
 767 dnl nothing to create in a few of the build directories when doing an object
 768 dnl tree build.  So make sure we created certain directories if they don't
 769 dnl exist.
 770 dnl
 771
 772 AC_CONFIG_COMMANDS([build-directories],
 773 [test -d etc || ${MKDIR_P} etc
 774 test -d man || ${MKDIR_P} man])
 775
 776 AC_CONFIG_COMMANDS_POST([
 777
 778 dnl These odd looking assignments are done to expand out unexpanded
 779 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 780 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 781 dnl again to get the final answer.
 782 dnl We only use the expanded versions to print the install paths in
 783 dnl the final summary and should use them nowhere else (see the autoconf
 784 dnl docs for the rationale for bindir etc being unexpanded).
 785 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 786 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 787 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 788 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 789 eval "nmhrpm=${nmhrpm}";
 790
 791 AC_MSG_NOTICE([
 792 nmh configuration
 793 -----------------
 794 nmh version                : AC_PACKAGE_VERSION
 795 host os                    : ${host}
 796 compiler                   : ${CC}
 797 compiler flags             : ${CFLAGS}
 798 linker flags               : ${LDFLAGS}
 799 preprocessor flags         : ${CPPFLAGS}
 800 source code location       : ${srcdir}
 801 binary install path        : ${nmhbin}
 802 library install path       : ${nmhlib}
 803 config files install path  : ${nmhsysconf}
 804 man page install path      : ${nmhman}
 805 RPM build root             : ${nmhrpm}
 806 backup prefix              : ${backup_prefix}
 807 transport system           : ${MTS}
 808 file locking type          : ${LOCKTYPE}
 809 default smtp servers       : ${smtpservers}
 810 default editor             : ${editorpath}
 811 default pager              : ${pagerpath}
 812 SASL support               : ${sasl_support}
 813 TLS support                : ${tls_support}
 814 ])])dnl
 815
 816 dnl ---------------
 817 dnl OUTPUT MAKEFILE
 818 dnl ---------------
 819 AC_CONFIG_FILES([Makefile test/common.sh])
 820 AC_OUTPUT