git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want mhe support?
  60 AC_ARG_ENABLE(mhe,
  61   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  62
  63 dnl mhe support is on by default, so define it unless --disable-mhe or the
  64 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  65 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  66   AC_DEFINE(MHE, 1,
  67     [Define to compile in support for the Emacs front-end mh-e.])dnl
  68 fi
  69
  70 dnl Do you want client-side support for pop?
  71 AC_ARG_ENABLE(pop,
  72   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  73 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  74 if test x"$enable_nmh_pop" = x"yes"; then
  75   enable_pop=yes
  76 fi
  77
  78 dnl Do you want to disable use of locale functions
  79 AH_TEMPLATE([LOCALE],
  80 [Undefine if you don't want locale features.  By default this is defined.])
  81 AC_ARG_ENABLE([locale],
  82 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  83 [if test x$enableval = xyes; then
  84   AC_DEFINE(LOCALE)
  85 fi],
  86 AC_DEFINE(LOCALE)
  87 )
  88
  89 dnl Do you want client-side support for using SASL for authentication?
  90 dnl Note that this code will be enabled for both POP and SMTP
  91 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
  92   [Enable SASL support via the Cyrus SASL library]))
  93 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  94   AC_DEFINE(CYRUS_SASL, 1,
  95     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  96   if test x"$with_cyrus_sasl" != xyes; then
  97     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  98     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  99   fi
 100   sasl_support=yes
 101 else
 102   sasl_support=no
 103 fi
 104
 105 dnl Do you want client-side support for encryption with TLS?
 106 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
 107 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
 108   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
 109   tls_support=yes
 110 else
 111   tls_support=no
 112 fi
 113
 114 dnl What should be the default editor?
 115 AC_ARG_WITH(editor,
 116   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 117
 118 if test -n "$with_editor"; then
 119   editorpath="$with_editor"
 120 fi
 121
 122 dnl Set the backup prefix
 123 AC_ARG_WITH([hash-backup],
 124   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 125 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 126   backup_prefix="#"
 127 else
 128   backup_prefix=","
 129 fi
 130 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 131     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 132
 133 dnl After we know if we're including apop and kpop support, do pop stuff
 134 if test x"$enable_pop" = x"yes"; then
 135   AC_DEFINE(POP, 1,
 136     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 137   POPLIB=popsbr.o
 138   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 139 else
 140   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 141 fi
 142 AC_SUBST(POPLIB)dnl
 143 AC_SUBST(POPSED)dnl
 144
 145 dnl What method of locking to use?
 146 AC_ARG_WITH(locking,
 147   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 148   [specify the file locking method]))
 149
 150 if test x"$with_locking" = x"dot"; then
 151   LOCKTYPE="dot"
 152   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 153 elif test x"$with_locking" = x"flock"; then
 154   LOCKTYPE="flock"
 155   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 156 elif test x"$with_locking" = x"lockf"; then
 157   LOCKTYPE="lockf"
 158   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 159 elif test x"$with_locking" = x"fcntl"; then
 160   LOCKTYPE="fcntl"
 161   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 162 else
 163   LOCKTYPE="dot"
 164   AC_DEFINE(DOT_LOCKING)dnl
 165 fi
 166
 167 dnl What method of posting should post use?
 168 AC_ARG_WITH(mts,
 169   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 170   [specify the default mail transport agent/service]))
 171
 172 if test x"$with_mts" = x"smtp"; then
 173   MTS="smtp"
 174 elif test x"$with_mts" = x"sendmail"; then
 175   MTS="sendmail"
 176 else
 177   MTS="smtp"
 178 fi
 179 AC_SUBST(MTS)dnl
 180
 181 dnl Both the smtp and sendmail mail transport services use the smtp code
 182 AC_DEFINE(SMTPMTS, 1,
 183   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 184
 185 dnl What should be the default pager?
 186 AC_ARG_WITH(pager,
 187   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 188
 189 if test -n "$with_pager"; then
 190   pagerpath="$with_pager"
 191 fi
 192
 193 dnl What should be the default mail server(s)?
 194 AC_ARG_WITH(smtpservers,
 195   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 196   [specify the default SMTP server(s) @<:@localhost@:>@]))
 197 if test -n "$with_smtpservers"; then
 198   smtpservers="$with_smtpservers"
 199 else
 200   smtpservers="localhost"
 201 fi
 202 AC_SUBST(smtpservers)dnl
 203
 204 dnl ----------------------------------------------------
 205 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 206 dnl ----------------------------------------------------
 207 AC_PREFIX_DEFAULT(/usr/local/nmh)
 208
 209 dnl ------------------
 210 dnl CHECK THE COMPILER
 211 dnl ------------------
 212 dnl We want these before the checks,
 213 dnl so the checks can modify their values.
 214 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 215 if test x"$enable_debug" = x"yes"; then
 216   test -z "$LDFLAGS" && LDFLAGS=-g
 217 fi
 218
 219 AC_PROG_CC
 220
 221 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 222 [nmh_saved_cflags="$CFLAGS"
 223  CFLAGS="$CFLAGS -Wno-pointer-sign"
 224  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 225  CFLAGS="$nmh_saved_cflags"])
 226
 227 dnl if the user hasn't specified CFLAGS, then
 228 dnl   if compiler is gcc, then
 229 dnl     use -O2 and some warning flags
 230 dnl   else use -O
 231 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 232 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 233 dnl spurious and which in any case we don't want to deal with now.
 234 if test "$nmh_cv_has_noptrsign" = "yes"; then
 235         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 236 else
 237         nmh_gcc_warnflags="-Wall"
 238 fi
 239
 240 if test -n "$auto_cflags"; then
 241   if test x"$enable_debug" = x"yes"; then
 242     if test -n "$GCC"; then
 243       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 244     else
 245       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 246     fi
 247   else
 248     if test -z "$LDFLAGS"; then
 249       case "$build_os" in
 250         darwin*)
 251           LDFLAGS=
 252           ;;
 253         *)
 254           LDFLAGS=-s
 255           ;;
 256       esac
 257     fi
 258     if test -n "$GCC"; then
 259       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 260     else
 261       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 262     fi
 263   fi
 264 fi
 265
 266 AC_C_CONST              dnl Does compiler support `const'.
 267
 268 dnl ------------------
 269 dnl CHECK FOR PROGRAMS
 270 dnl ------------------
 271 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 272 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 273 AC_PROG_RANLIB          dnl Check for `ranlib'
 274 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 275 AC_PROG_LEX             dnl Check for lex/flex
 276
 277 dnl Look for `cut'
 278 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 279 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 280
 281 dnl ----------------------------------------------
 282 dnl check for lclint, and lint if it doesn't exist
 283 dnl ----------------------------------------------
 284 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 285 if test x$ac_cv_prog_linttmp1 != xno ; then
 286   LINT=$ac_cv_prog_linttmp1
 287   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 288 else
 289   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 290   if test x$ac_cv_prog_linttmp2 != xno ; then
 291     LINT=$ac_cv_prog_linttmp2
 292     LINTFLAGS=""
 293   else
 294     LINT="echo 'No lint program found'"
 295     LINTFLAGS=""
 296   fi
 297 fi
 298 AC_SUBST(LINT)dnl
 299 AC_SUBST(LINTFLAGS)dnl
 300
 301 dnl try to figure out which one we've got
 302 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 303 NMH_PROG_GNU_LIBTOOL
 304
 305 dnl Check for lorder and tsort commands
 306 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 307 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 308
 309 dnl If either doesn't exist, replace them with echo and cat
 310 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 311   LORDER=echo
 312   TSORT=cat
 313   AC_SUBST(LORDER)dnl
 314   AC_SUBST(TSORT)dnl
 315 dnl Mac OS X has lorder, but sh is too broken for it to work
 316 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 317 dnl   LORDER=echo
 318 dnl   TSORT=cat
 319 dnl   AC_SUBST(LORDER)dnl
 320 dnl   AC_SUBST(TSORT)dnl
 321 fi
 322
 323 dnl Check whether tsort can deal with loops
 324 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 325   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 326     nmh_cv_tsort_loop=no
 327   else
 328     nmh_cv_tsort_loop=yes
 329   fi])
 330 if test x$nmh_cv_tsort_loop = xno ; then
 331   LORDER=echo
 332   TSORT=cat
 333   AC_SUBST(LORDER)dnl
 334   AC_SUBST(TSORT)dnl
 335 fi
 336
 337 dnl Look for `ls'
 338 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 339 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 340
 341 dnl See how we get ls to display the owner and the group
 342 if test "$lspath" != "no"; then
 343   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 344                  nmh_cv_ls_grpopt,
 345   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 346     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 347     dnl ls, it would seem -l gave us both the user and group.  On this type of
 348     dnl ls, -g makes _only_ the group be displayed (and not the user).
 349     nmh_cv_ls_grpopt="-l"
 350   else
 351     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 352     nmh_cv_ls_grpopt="-lg"
 353   fi])
 354 fi
 355
 356 dnl Look for `more'
 357 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 358 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 359
 360 dnl If pager is not specified yet,
 361 dnl then use `more' as the default.
 362 if test -z "$pagerpath"; then
 363   pagerpath="$morepath"
 364 fi
 365 AC_SUBST(pagerpath)dnl
 366
 367 dnl Look for `sendmail'
 368 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 369 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 370
 371 dnl Look for `vi'
 372 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 373 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 374
 375 dnl If editor is not specified yet,
 376 dnl then use `vi' as the default.
 377 if test -z "$editorpath"; then
 378   editorpath="$vipath"
 379 fi
 380 AC_SUBST(editorpath)dnl
 381
 382 dnl ----------------------------------------------------------
 383 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 384 dnl ----------------------------------------------------------
 385 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 386 [for mailspool in /var/mail        dnl
 387                   /var/spool/mail  dnl
 388                   /usr/spool/mail  dnl
 389                   /dev/null;       dnl Just in case we fall through
 390 do
 391   test -d $mailspool && break
 392 done
 393 nmh_cv_mailspool=$mailspool
 394 ])
 395 mailspool=$nmh_cv_mailspool
 396 AC_SUBST(mailspool)dnl
 397
 398 dnl See whether the mail spool directory is world-writable.
 399 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 400   AC_CACHE_CHECK(whether the mail spool is world-writable,
 401                  nmh_cv_mailspool_world_writable,
 402   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 403     nmh_cv_mailspool_world_writable=no
 404   else
 405     nmh_cv_mailspool_world_writable=yes
 406   fi])
 407 fi
 408
 409 dnl Also, check for liblockfile (as found on Debian systems)
 410 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 411
 412 dnl and whether its companion program dotlockfile is setgid
 413 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 414 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 415   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 416     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 417     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 418         nmh_cv_dotlockfile_setgid=yes
 419       else
 420         nmh_cv_dotlockfile_setgid=no
 421       fi])
 422   fi
 423 fi
 424
 425 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 426 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 427 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 428   dnl do we really need both of these?
 429   AC_DEFINE(MAILGROUP,1,
 430     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 431   SETGID_MAIL=1
 432 fi
 433 AC_SUBST(SETGID_MAIL)dnl
 434
 435 dnl Use ls to see which group owns the mail spool directory.
 436 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 437 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 438 ])
 439 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 440 AC_SUBST(MAIL_SPOOL_GRP)dnl
 441
 442 dnl ------------------
 443 dnl CHECK HEADER FILES
 444 dnl ------------------
 445
 446 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 447 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 448 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 449 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 450 dnl declared; if so they should have an entry added to this case statement.
 451 dnl NB that we must define this on the compiler command line, not in config.h,
 452 dnl because it must be set before any system header is included and there's no
 453 dnl portable way to make sure that files generated by lex include config.h
 454 dnl before system header files.
 455
 456 case "$target_os" in
 457   linux*)
 458     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 459     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 460     ;;
 461 esac
 462 AC_SUBST(OURDEFS)
 463
 464 AC_HEADER_STDC
 465 AC_HEADER_TIME
 466 AC_HEADER_STAT
 467 AC_HEADER_TIOCGWINSZ
 468 AC_CHECK_HEADERS(errno.h fcntl.h crypt.h termcap.h \
 469                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 470                  sys/param.h sys/time.h sys/stream.h)
 471
 472 dnl
 473 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 474 dnl really use a whole set of them, but this check should be
 475 dnl sufficient.
 476 dnl
 477 AC_CHECK_HEADER(libio.h, [
 478   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 479     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 480
 481 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 482   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 483 [[#if HAVE_SYS_STREAM_H
 484 #  include <sys/stream.h>
 485 #endif
 486 ]])
 487
 488 dnl ---------------
 489 dnl CHECK FUNCTIONS
 490 dnl ---------------
 491 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 492                sighold sigrelse writev lstat uname tzset mkstemp \
 493                getutent nl_langinfo mbtowc wcwidth)
 494
 495 dnl sigsetjmp may be a macro
 496 AC_MSG_CHECKING(for sigsetjmp)
 497 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 498   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 499     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 500   [AC_MSG_RESULT(no)])
 501
 502 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 503 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 504 dnl any system header.
 505 dnl
 506 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 507 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 508 dnl need to check?
 509 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 510 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 511                 AC_EGREP_HEADER(initgroups, unistd.h,
 512                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 513
 514 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 515 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 516 dnl seems to work perfectly and IBM apparently uses it in internal code).
 517 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 518 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 519 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 520 dnl prototype.
 521 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 522   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 523
 524 dnl Check for multibyte character set support
 525 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 526     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 527   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 528     [Define to enable support for multibyte character sets.])
 529 fi
 530
 531 dnl -------------------
 532 dnl CHECK FOR LIBRARIES
 533 dnl -------------------
 534 dnl Check location of modf
 535 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 536
 537 dnl Checks for network libraries (nsl, socket)
 538 AC_CHECK_NETLIBS
 539
 540 termcap_curses_order="termcap curses ncurses"
 541 for lib in $termcap_curses_order; do
 542   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 543 done
 544 AC_SUBST(TERMLIB)dnl
 545
 546 dnl ---------------
 547 dnl CHECK FOR ICONV
 548 dnl ---------------
 549
 550 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 551 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 552   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 553   if test "x$ac_found_iconv" = "xno"; then
 554     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 555     if test "x$ac_found_iconv" = "xno"; then
 556       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 557     fi
 558     if test "x$ac_found_iconv" != "xno"; then
 559       LIBS="-liconv $LIBS"
 560     fi
 561   else
 562     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 563     AC_CHECK_DECL(_libiconv_version,
 564       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 565       [ #include <iconv.h> ])
 566   fi
 567 fi
 568 if test "x$ac_found_iconv" = xyes; then
 569   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 570 fi
 571
 572 dnl Check if iconv uses const in prototype declaration
 573 if test "x$ac_found_iconv" = "xyes"; then
 574   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 575     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 576         #include <iconv.h>]],
 577         [[#ifdef __cplusplus
 578           "C"
 579           #endif
 580           #if defined(__STDC__) || defined(__cplusplus)
 581           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 582           #else
 583           size_t iconv();
 584           #endif]])],
 585       [ac_cv_iconv_const=],
 586       [ac_cv_iconv_const=const])])
 587   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 588     [Define as const if the declaration of iconv() needs const.])
 589 fi
 590
 591 dnl --------------
 592 dnl CHECK FOR NDBM
 593 dnl --------------
 594
 595 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 596             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 597 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 598             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 599
 600 if test "$nmh_ndbm" = "autodetect"; then
 601   if test "$nmh_ndbmheader" != "autodetect"; then
 602     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 603   else
 604
 605     dnl There are at least four implementations of ndbm, and
 606     dnl several of those can be in different places at the whim
 607     dnl of the system integrator. A good summary of this mess
 608     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 609
 610     dnl Classic ndbm with no library required (eg NetBSD): try this
 611     dnl first so we don't accidentally link in a pointless but harmless
 612     dnl library in one of the later ndbm.h+libfoo tests:
 613     NMH_CHECK_NDBM(ndbm.h,,,
 614     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 615       NMH_CHECK_NDBM(db.h,db,,
 616     dnl Berkeley DBv1 emulating ndbm:
 617         NMH_CHECK_NDBM(ndbm.h,db,,
 618           NMH_CHECK_NDBM(ndbm.h,db1,,
 619     dnl Classic ndbm:
 620             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 621     dnl glibc2.1 systems put db1 in a subdir:
 622               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 623     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 624     dnl and possibly needing gbdm_compat library:
 625                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 626                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 627                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 628                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 629
 630   fi
 631 else
 632   dnl We don't really need to check that the user-specified values work,
 633   dnl but it is a convenience to the user to bomb out early rather than
 634   dnl after configure and half the compile process.
 635   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 636 fi
 637
 638 if test "$nmh_ndbm_found" = "no"; then
 639   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 640 else
 641   dnl Now export the lib/header to our makefile/config.h:
 642   if test x"$nmh_ndbmheader" != x; then
 643     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 644       [Define to the header containing the ndbm API prototypes.])
 645   fi
 646   if test x"$nmh_ndbm" != x; then
 647     NDBM_LIBS="-l$nmh_ndbm"
 648   else
 649     NDBM_LIBS=
 650   fi
 651   AC_SUBST(NDBM_LIBS)
 652 fi
 653
 654 dnl ------------------
 655 dnl Set RPM build root
 656 dnl ------------------
 657 dnl nmhrpm is used in the final summary, see below.  The default value is
 658 dnl reported there as ./RPM, consistent with the reporting of the default
 659 dnl source code location as ., but its absolute path is used in the Makefile.
 660 AC_ARG_WITH(rpmdir,
 661   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 662   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 663           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 664 AC_SUBST(rpmdir)
 665
 666
 667 dnl --------------------
 668 dnl CHECK FOR CYRUS-SASL
 669 dnl --------------------
 670
 671 AS_IF([test x"$sasl_support" = x"yes"],[
 672   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 673   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 674     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 675
 676 dnl -----------------
 677 dnl CHECK FOR OPENSSL
 678 dnl -----------------
 679
 680 AS_IF([test x"$tls_support" = x"yes"],[
 681   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 682   AC_CHECK_LIB([crypto], [BIO_write], ,
 683     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 684   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 685     [AC_MSG_ERROR([OpenSSL library not found])])])
 686
 687 dnl ---------------------
 688 dnl CHECK TERMCAP LIBRARY
 689 dnl ---------------------
 690
 691 dnl Add the termcap library, so that the following configure
 692 dnl tests will find it when it tries to link test programs.
 693 nmh_save_LIBS="$LIBS"
 694 LIBS="$TERMLIB $LIBS"
 695
 696 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 697 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 698 dnl in tgetstr().
 699 dnl Under Cygwin test program crashes but exit code is still 0. So,
 700 dnl we test for a file that porgram should create
 701 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 702 [Define to 1 if tgetent() accepts NULL as a buffer.])
 703 AC_CACHE_CHECK(if tgetent accepts NULL,
 704 nmh_cv_func_tgetent_accepts_null,
 705 [AC_TRY_RUN([
 706 main()
 707 {
 708     char buf[4096];
 709     int r1 = tgetent(buf, "vt100");
 710     int r2 = tgetent((char*)0,"vt100");
 711     if (r1 >= 0 && r1 == r2) {
 712         char tbuf[1024], *u;
 713         u = tbuf;
 714         tgetstr("cl", &u);
 715         creat("conftest.tgetent", 0640);
 716     }
 717     exit((r1 != r2) || r2 == -1);
 718 }
 719 ],
 720   if test -f conftest.tgetent; then
 721     nmh_cv_func_tgetent_accepts_null=yes
 722   else
 723     nmh_cv_func_tgetent_accepts_null=no
 724   fi,
 725   nmh_cv_func_tgetent_accepts_null=no,
 726   nmh_cv_func_tgetent_accepts_null=no)])
 727 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 728   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 729 fi
 730 AC_CACHE_CHECK(if tgetent returns 0 on success,
 731 nmh_cv_func_tgetent_zero_success,
 732 [AC_TRY_RUN([
 733 main()
 734 {
 735     char buf[4096];
 736     int r1 = tgetent(buf, "!@#$%^&*");
 737     int r2 = tgetent(buf, "vt100");
 738     if (r1 < 0 && r2 == 0) {
 739         char tbuf[1024], *u;
 740         u = tbuf;
 741         tgetstr("cl", &u);
 742         creat("conftest.tgetent0", 0640);
 743     }
 744     exit(r1 == r2);
 745 }
 746 ],
 747   if test -f conftest.tgetent0; then
 748     nmh_cv_func_tgetent_zero_success=yes
 749   else
 750     nmh_cv_func_tgetent_zero_success=no
 751   fi,
 752   nmh_cv_func_tgetent_zero_success=no,
 753   nmh_cv_func_tgetent_zero_success=no)])
 754 AH_TEMPLATE([TGETENT_SUCCESS],
 755 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 756 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 757   AC_DEFINE(TGETENT_SUCCESS, 0)
 758 else
 759   AC_DEFINE(TGETENT_SUCCESS, 1)
 760 fi
 761
 762 dnl Now put the libraries back to what it was before we
 763 dnl starting checking the termcap library.
 764 LIBS="$nmh_save_LIBS"
 765
 766 dnl --------------
 767 dnl CHECK TYPEDEFS
 768 dnl --------------
 769 AC_TYPE_SIGNAL
 770 AC_TYPE_PID_T
 771 AC_TYPE_OFF_T
 772 AC_TYPE_UID_T
 773 AC_TYPE_MODE_T
 774 AC_TYPE_SIZE_T
 775
 776 dnl Check for sigset_t.  Currently I'm looking in
 777 dnl <sys/types.h> and <signal.h>.  Others might need
 778 dnl to be added.
 779 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 780 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 781 #include <signal.h>]], [[sigset_t tempsigset;]])],
 782 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 783 if test $nmh_cv_type_sigset_t = no; then
 784   AC_DEFINE(sigset_t, unsigned int,
 785     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 786 fi
 787
 788 dnl ----------------
 789 dnl CHECK STRUCTURES
 790 dnl ----------------
 791 AC_CHECK_MEMBERS(struct stat.st_blksize)
 792
 793 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 794   [#ifdef TIME_WITH_SYS_TIME
 795 # include <sys/time.h>
 796 # include <time.h>
 797 #else
 798 # ifdef TM_IN_SYS_TIME
 799 #  include <sys/time.h>
 800 # else
 801 #  include <time.h>
 802 # endif
 803 #endif])
 804
 805 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 806
 807 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 808
 809 dnl -------------
 810 dnl CHECK SIGNALS
 811 dnl -------------
 812 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 813 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 814 AC_MSG_CHECKING(what style of signals to use)
 815 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 816   signals_style=POSIX_SIGNALS
 817   AC_DEFINE(POSIX_SIGNALS, 1,
 818     [Define to 1 if you use POSIX style signal handling.])
 819   AC_DEFINE(RELIABLE_SIGNALS)
 820 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 821   signals_style=BSD_SIGNALS
 822   AC_DEFINE(BSD_SIGNALS,1,
 823     [Define to 1 if you use BSD style signal handling (and can block signals).])
 824   AC_DEFINE(RELIABLE_SIGNALS)
 825 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 826   signals_style=SYSV_SIGNALS
 827   AC_DEFINE(SYSV_SIGNALS,1,
 828     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 829 else
 830   signals_style=NO_SIGNAL_BLOCKING
 831   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 832     [Define to 1 if you have no signal blocking at all (bummer).])
 833 fi
 834
 835 AC_MSG_RESULT($signals_style)
 836
 837 dnl Where is <signal.h> located?  Needed as input for signames.awk
 838 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 839 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 840                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 841                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 842                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 843                  /usr/include/sys/signal.h      dnl Almost everybody else
 844                  /dev/null;                     dnl Just in case we fall through
 845 do
 846   test -f $SIGNAL_H && \
 847   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 848   break
 849 done
 850 nmh_cv_path_signal_h=$SIGNAL_H
 851 ])
 852 SIGNAL_H=$nmh_cv_path_signal_h
 853 AC_SUBST(SIGNAL_H)dnl
 854
 855 dnl ----------------
 856 dnl OS SPECIFIC DEFINES
 857 dnl ----------------
 858 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 859 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 860 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 861 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 862 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 863
 864 case "$target_os" in
 865
 866   solaris2*)
 867     AC_DEFINE(SYS5)
 868     AC_DEFINE(SVR4)
 869     ;;
 870   irix*)
 871     AC_DEFINE(SYS5)
 872     AC_DEFINE(SVR4)
 873     ;;
 874   osf*)
 875     AC_DEFINE(SYS5)
 876     AC_DEFINE(SVR4)
 877     ;;
 878   aix*)
 879     AC_DEFINE(SYS5)
 880     AC_DEFINE(SVR4)
 881     ;;
 882   sunos4*)
 883     AC_DEFINE(BSD42)
 884     ;;
 885   freebsd*)
 886     AC_DEFINE(BSD42)
 887     AC_DEFINE(BSD44)
 888     ;;
 889   netbsd*)
 890     AC_DEFINE(BSD42)
 891     AC_DEFINE(BSD44)
 892     ;;
 893   openbsd*)
 894     AC_DEFINE(BSD42)
 895     AC_DEFINE(BSD44)
 896     ;;
 897   bsd/os*)
 898     AC_DEFINE(BSD42)
 899     AC_DEFINE(BSD44)
 900     ;;
 901   sco5*)
 902     AC_DEFINE(SYS5)
 903     AC_DEFINE(SCO_5_STDIO)
 904     ;;
 905 esac
 906
 907
 908 dnl ----------------
 909 dnl OUTPUT MAKEFILES
 910 dnl ----------------
 911 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 912                 mts/Makefile mts/smtp/Makefile \
 913                 etc/Makefile docs/Makefile man/Makefile)
 914 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 915 AC_OUTPUT
 916
 917 dnl These odd looking assignments are done to expand out unexpanded
 918 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 919 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 920 dnl again to get the final answer.
 921 dnl We only use the expanded versions to print the install paths in
 922 dnl the final summary and should use them nowhere else (see the autoconf
 923 dnl docs for the rationale for bindir etc being unexpanded).
 924 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 925 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 926 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 927 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 928 eval "nmhrpm=${nmhrpm}";
 929
 930 pop_kinds=no
 931 if test x"$enable_pop" = x"yes"; then
 932   pop_kinds="yes ("
 933
 934   if test x"$enable_apop" = x"yes"; then
 935     pop_kinds="${pop_kinds}APOP "
 936   fi
 937
 938   pop_kinds="${pop_kinds}POP3)"
 939 fi
 940
 941 echo "
 942 nmh configuration
 943 -----------------
 944 nmh version                : AC_PACKAGE_VERSION
 945 target os                  : ${target}
 946 compiler                   : ${CC}
 947 compiler flags             : ${CFLAGS}
 948 linker flags               : ${LDFLAGS}
 949 definitions                : ${OURDEFS}
 950 source code location       : ${srcdir}
 951 binary install path        : ${nmhbin}
 952 library install path       : ${nmhlib}
 953 config files install path  : ${nmhsysconf}
 954 man page install path      : ${nmhman}
 955 RPM build root             : ${nmhrpm}
 956 backup prefix              : ${backup_prefix}
 957 transport system           : ${MTS}
 958 file locking type          : ${LOCKTYPE}
 959 default smtp servers       : ${smtpservers}
 960 default editor             : ${editorpath}
 961 default pager              : ${pagerpath}
 962 email address masquerading : ${masquerade}
 963 pop is enabled             : ${pop_kinds}
 964 SASL support               : ${sasl_support}
 965 TLS support                : ${tls_support}"
 966 echo ""