git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want mhe support?
  60 AC_ARG_ENABLE(mhe,
  61   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  62
  63 dnl mhe support is on by default, so define it unless --disable-mhe or the
  64 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  65 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  66   AC_DEFINE(MHE, 1,
  67     [Define to compile in support for the Emacs front-end mh-e.])dnl
  68 fi
  69
  70 dnl Do you want client-side support for pop?
  71 AC_ARG_ENABLE(pop,
  72   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  73 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  74 if test x"$enable_nmh_pop" = x"yes"; then
  75   enable_pop=yes
  76 fi
  77
  78 dnl Do you want to disable use of locale functions
  79 AH_TEMPLATE([LOCALE],
  80 [Undefine if you don't want locale features.  By default this is defined.])
  81 AC_ARG_ENABLE([locale],
  82 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  83 [if test x$enableval = xyes; then
  84   AC_DEFINE(LOCALE)
  85 fi],
  86 AC_DEFINE(LOCALE)
  87 )
  88
  89 dnl Do you want client-side support for using SASL for authentication?
  90 dnl Note that this code will be enabled for both POP and SMTP
  91 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
  92   [Enable SASL support via the Cyrus SASL library]))
  93 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  94   AC_DEFINE(CYRUS_SASL, 1,
  95     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  96   if test x"$with_cyrus_sasl" != xyes; then
  97     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  98     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  99   fi
 100   sasl_support=yes
 101 else
 102   sasl_support=no
 103 fi
 104
 105 dnl Do you want client-side support for encryption with TLS?
 106 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
 107 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
 108   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
 109   tls_support=yes
 110 else
 111   tls_support=no
 112 fi
 113
 114 dnl What should be the default editor?
 115 AC_ARG_WITH(editor,
 116   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 117
 118 if test -n "$with_editor"; then
 119   editorpath="$with_editor"
 120 fi
 121
 122 dnl Set the backup prefix
 123 AC_ARG_WITH([hash-backup],
 124   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 125 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 126   backup_prefix="#"
 127 else
 128   backup_prefix=","
 129 fi
 130 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 131     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 132
 133 dnl After we know if we're including apop and kpop support, do pop stuff
 134 if test x"$enable_pop" = x"yes"; then
 135   AC_DEFINE(POP, 1,
 136     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 137   POPLIB=popsbr.o
 138   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 139 else
 140   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 141 fi
 142 AC_SUBST(POPLIB)dnl
 143 AC_SUBST(POPSED)dnl
 144
 145 dnl What method of locking to use?
 146 AC_ARG_WITH(locking,
 147   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 148   [specify the file locking method]))
 149
 150 if test x"$with_locking" = x"dot"; then
 151   LOCKTYPE="dot"
 152   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 153 elif test x"$with_locking" = x"flock"; then
 154   LOCKTYPE="flock"
 155   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 156 elif test x"$with_locking" = x"lockf"; then
 157   LOCKTYPE="lockf"
 158   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 159 elif test x"$with_locking" = x"fcntl"; then
 160   LOCKTYPE="fcntl"
 161   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 162 else
 163   LOCKTYPE="dot"
 164   AC_DEFINE(DOT_LOCKING)dnl
 165 fi
 166
 167 dnl What method of posting should post use?
 168 AC_ARG_WITH(mts,
 169   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 170   [specify the default mail transport agent/service]))
 171
 172 if test x"$with_mts" = x"smtp"; then
 173   MTS="smtp"
 174 elif test x"$with_mts" = x"sendmail"; then
 175   MTS="sendmail"
 176 else
 177   MTS="smtp"
 178 fi
 179 AC_SUBST(MTS)dnl
 180
 181 dnl Both the smtp and sendmail mail transport services use the smtp code
 182 AC_DEFINE(SMTPMTS, 1,
 183   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 184
 185 dnl What should be the default pager?
 186 AC_ARG_WITH(pager,
 187   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 188
 189 if test -n "$with_pager"; then
 190   pagerpath="$with_pager"
 191 fi
 192
 193 dnl What should be the default mail server(s)?
 194 AC_ARG_WITH(smtpservers,
 195   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 196   [specify the default SMTP server(s) @<:@localhost@:>@]))
 197 if test -n "$with_smtpservers"; then
 198   smtpservers="$with_smtpservers"
 199 else
 200   smtpservers="localhost"
 201 fi
 202 AC_SUBST(smtpservers)dnl
 203
 204 dnl ----------------------------------------------------
 205 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 206 dnl ----------------------------------------------------
 207 AC_PREFIX_DEFAULT(/usr/local/nmh)
 208
 209 dnl ------------------
 210 dnl CHECK THE COMPILER
 211 dnl ------------------
 212 dnl We want these before the checks,
 213 dnl so the checks can modify their values.
 214 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 215 if test x"$enable_debug" = x"yes"; then
 216   test -z "$LDFLAGS" && LDFLAGS=-g
 217 fi
 218
 219 AC_PROG_CC
 220
 221 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 222 [nmh_saved_cflags="$CFLAGS"
 223  CFLAGS="$CFLAGS -Wno-pointer-sign"
 224  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 225  CFLAGS="$nmh_saved_cflags"])
 226
 227 dnl if the user hasn't specified CFLAGS, then
 228 dnl   if compiler is gcc, then
 229 dnl     use -O2 and some warning flags
 230 dnl   else use -O
 231 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 232 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 233 dnl spurious and which in any case we don't want to deal with now.
 234 if test "$nmh_cv_has_noptrsign" = "yes"; then
 235         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 236 else
 237         nmh_gcc_warnflags="-Wall"
 238 fi
 239
 240 if test -n "$auto_cflags"; then
 241   if test x"$enable_debug" = x"yes"; then
 242     if test -n "$GCC"; then
 243       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 244     else
 245       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 246     fi
 247   else
 248     if test -z "$LDFLAGS"; then
 249       case "$build_os" in
 250         darwin*)
 251           LDFLAGS=
 252           ;;
 253         *)
 254           LDFLAGS=-s
 255           ;;
 256       esac
 257     fi
 258     if test -n "$GCC"; then
 259       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 260     else
 261       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 262     fi
 263   fi
 264 fi
 265
 266 AC_C_CONST              dnl Does compiler support `const'.
 267
 268 dnl ------------------
 269 dnl CHECK FOR PROGRAMS
 270 dnl ------------------
 271 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 272 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 273 AC_PROG_RANLIB          dnl Check for `ranlib'
 274 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 275 AC_PROG_LEX             dnl Check for lex/flex
 276
 277 dnl Look for `cut'
 278 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 279 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 280
 281 dnl ----------------------------------------------
 282 dnl check for lclint, and lint if it doesn't exist
 283 dnl ----------------------------------------------
 284 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 285 if test x$ac_cv_prog_linttmp1 != xno ; then
 286   LINT=$ac_cv_prog_linttmp1
 287   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 288 else
 289   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 290   if test x$ac_cv_prog_linttmp2 != xno ; then
 291     LINT=$ac_cv_prog_linttmp2
 292     LINTFLAGS=""
 293   else
 294     LINT="echo 'No lint program found'"
 295     LINTFLAGS=""
 296   fi
 297 fi
 298 AC_SUBST(LINT)dnl
 299 AC_SUBST(LINTFLAGS)dnl
 300
 301 dnl try to figure out which one we've got
 302 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 303 NMH_PROG_GNU_LIBTOOL
 304
 305 dnl Check for lorder and tsort commands
 306 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 307 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 308
 309 dnl If either doesn't exist, replace them with echo and cat
 310 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 311   LORDER=echo
 312   TSORT=cat
 313   AC_SUBST(LORDER)dnl
 314   AC_SUBST(TSORT)dnl
 315 dnl Mac OS X has lorder, but sh is too broken for it to work
 316 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 317 dnl   LORDER=echo
 318 dnl   TSORT=cat
 319 dnl   AC_SUBST(LORDER)dnl
 320 dnl   AC_SUBST(TSORT)dnl
 321 fi
 322
 323 dnl Check whether tsort can deal with loops
 324 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 325   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 326     nmh_cv_tsort_loop=no
 327   else
 328     nmh_cv_tsort_loop=yes
 329   fi])
 330 if test x$nmh_cv_tsort_loop = xno ; then
 331   LORDER=echo
 332   TSORT=cat
 333   AC_SUBST(LORDER)dnl
 334   AC_SUBST(TSORT)dnl
 335 fi
 336
 337 dnl Look for `ls'
 338 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 339 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 340
 341 dnl See how we get ls to display the owner and the group
 342 if test "$lspath" != "no"; then
 343   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 344                  nmh_cv_ls_grpopt,
 345   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 346     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 347     dnl ls, it would seem -l gave us both the user and group.  On this type of
 348     dnl ls, -g makes _only_ the group be displayed (and not the user).
 349     nmh_cv_ls_grpopt="-l"
 350   else
 351     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 352     nmh_cv_ls_grpopt="-lg"
 353   fi])
 354 fi
 355
 356 dnl Look for `more'
 357 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 358 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 359
 360 dnl If pager is not specified yet,
 361 dnl then use `more' as the default.
 362 if test -z "$pagerpath"; then
 363   pagerpath="$morepath"
 364 fi
 365 AC_SUBST(pagerpath)dnl
 366
 367 dnl Look for `sendmail'
 368 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 369 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 370
 371 dnl Look for `vi'
 372 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 373 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 374
 375 dnl If editor is not specified yet,
 376 dnl then use `vi' as the default.
 377 if test -z "$editorpath"; then
 378   editorpath="$vipath"
 379 fi
 380 AC_SUBST(editorpath)dnl
 381
 382 dnl ----------------------------------------------------------
 383 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 384 dnl ----------------------------------------------------------
 385 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 386 [for mailspool in /var/mail        dnl
 387                   /var/spool/mail  dnl
 388                   /usr/spool/mail  dnl
 389                   /dev/null;       dnl Just in case we fall through
 390 do
 391   test -d $mailspool && break
 392 done
 393 nmh_cv_mailspool=$mailspool
 394 ])
 395 mailspool=$nmh_cv_mailspool
 396 AC_SUBST(mailspool)dnl
 397
 398 dnl See whether the mail spool directory is world-writable.
 399 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 400   AC_CACHE_CHECK(whether the mail spool is world-writable,
 401                  nmh_cv_mailspool_world_writable,
 402   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 403     nmh_cv_mailspool_world_writable=no
 404   else
 405     nmh_cv_mailspool_world_writable=yes
 406   fi])
 407 fi
 408
 409 dnl Also, check for liblockfile (as found on Debian systems)
 410 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 411
 412 dnl and whether its companion program dotlockfile is setgid
 413 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 414 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 415   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 416     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 417     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 418         nmh_cv_dotlockfile_setgid=yes
 419       else
 420         nmh_cv_dotlockfile_setgid=no
 421       fi])
 422   fi
 423 fi
 424
 425 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 426 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 427 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 428   dnl do we really need both of these?
 429   AC_DEFINE(MAILGROUP,1,
 430     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 431   SETGID_MAIL=1
 432 fi
 433 AC_SUBST(SETGID_MAIL)dnl
 434
 435 dnl Use ls to see which group owns the mail spool directory.
 436 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 437 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 438 ])
 439 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 440 AC_SUBST(MAIL_SPOOL_GRP)dnl
 441
 442 dnl ------------------
 443 dnl CHECK HEADER FILES
 444 dnl ------------------
 445
 446 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 447 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 448 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 449 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 450 dnl declared; if so they should have an entry added to this case statement.
 451 dnl NB that we must define this on the compiler command line, not in config.h,
 452 dnl because it must be set before any system header is included and there's no
 453 dnl portable way to make sure that files generated by lex include config.h
 454 dnl before system header files.
 455
 456 case "$target_os" in
 457   linux*)
 458     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 459     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 460     ;;
 461 esac
 462 AC_SUBST(OURDEFS)
 463
 464 AC_HEADER_STDC
 465 AC_HEADER_TIME
 466 AC_HEADER_TIOCGWINSZ
 467 AC_CHECK_HEADERS(errno.h fcntl.h crypt.h termcap.h \
 468                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 469                  sys/param.h sys/time.h sys/stream.h)
 470
 471 dnl
 472 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 473 dnl really use a whole set of them, but this check should be
 474 dnl sufficient.
 475 dnl
 476 AC_CHECK_HEADER(libio.h, [
 477   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 478     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 479
 480 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 481   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 482 [[#if HAVE_SYS_STREAM_H
 483 #  include <sys/stream.h>
 484 #endif
 485 ]])
 486
 487 dnl ---------------
 488 dnl CHECK FUNCTIONS
 489 dnl ---------------
 490 AC_CHECK_FUNCS(writev lstat tzset getutent nl_langinfo)
 491
 492 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 493 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 494 dnl any system header.
 495 dnl
 496 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 497 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 498 dnl need to check?
 499 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 500 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 501                 AC_EGREP_HEADER(initgroups, unistd.h,
 502                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 503
 504 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 505 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 506 dnl seems to work perfectly and IBM apparently uses it in internal code).
 507 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 508 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 509 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 510 dnl prototype.
 511 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 512   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 513
 514 dnl Check for multibyte character set support
 515 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 516     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 517   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 518     [Define to enable support for multibyte character sets.])
 519 fi
 520
 521 dnl -------------------
 522 dnl CHECK FOR LIBRARIES
 523 dnl -------------------
 524 dnl Check location of modf
 525 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 526
 527 dnl Checks for network libraries (nsl, socket)
 528 AC_CHECK_NETLIBS
 529
 530 termcap_curses_order="termcap curses ncurses"
 531 for lib in $termcap_curses_order; do
 532   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 533 done
 534 AC_SUBST(TERMLIB)dnl
 535
 536 dnl ---------------
 537 dnl CHECK FOR ICONV
 538 dnl ---------------
 539
 540 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 541 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 542   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 543   if test "x$ac_found_iconv" = "xno"; then
 544     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 545     if test "x$ac_found_iconv" = "xno"; then
 546       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 547     fi
 548     if test "x$ac_found_iconv" != "xno"; then
 549       LIBS="-liconv $LIBS"
 550     fi
 551   else
 552     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 553     AC_CHECK_DECL(_libiconv_version,
 554       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 555       [ #include <iconv.h> ])
 556   fi
 557 fi
 558 if test "x$ac_found_iconv" = xyes; then
 559   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 560 fi
 561
 562 dnl Check if iconv uses const in prototype declaration
 563 if test "x$ac_found_iconv" = "xyes"; then
 564   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 565     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 566         #include <iconv.h>]],
 567         [[#ifdef __cplusplus
 568           "C"
 569           #endif
 570           #if defined(__STDC__) || defined(__cplusplus)
 571           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 572           #else
 573           size_t iconv();
 574           #endif]])],
 575       [ac_cv_iconv_const=],
 576       [ac_cv_iconv_const=const])])
 577   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 578     [Define as const if the declaration of iconv() needs const.])
 579 fi
 580
 581 dnl --------------
 582 dnl CHECK FOR NDBM
 583 dnl --------------
 584
 585 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 586             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 587 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 588             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 589
 590 if test "$nmh_ndbm" = "autodetect"; then
 591   if test "$nmh_ndbmheader" != "autodetect"; then
 592     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 593   else
 594
 595     dnl There are at least four implementations of ndbm, and
 596     dnl several of those can be in different places at the whim
 597     dnl of the system integrator. A good summary of this mess
 598     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 599
 600     dnl Classic ndbm with no library required (eg NetBSD): try this
 601     dnl first so we don't accidentally link in a pointless but harmless
 602     dnl library in one of the later ndbm.h+libfoo tests:
 603     NMH_CHECK_NDBM(ndbm.h,,,
 604     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 605       NMH_CHECK_NDBM(db.h,db,,
 606     dnl Berkeley DBv1 emulating ndbm:
 607         NMH_CHECK_NDBM(ndbm.h,db,,
 608           NMH_CHECK_NDBM(ndbm.h,db1,,
 609     dnl Classic ndbm:
 610             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 611     dnl glibc2.1 systems put db1 in a subdir:
 612               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 613     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 614     dnl and possibly needing gbdm_compat library:
 615                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 616                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 617                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 618                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 619
 620   fi
 621 else
 622   dnl We don't really need to check that the user-specified values work,
 623   dnl but it is a convenience to the user to bomb out early rather than
 624   dnl after configure and half the compile process.
 625   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 626 fi
 627
 628 if test "$nmh_ndbm_found" = "no"; then
 629   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 630 else
 631   dnl Now export the lib/header to our makefile/config.h:
 632   if test x"$nmh_ndbmheader" != x; then
 633     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 634       [Define to the header containing the ndbm API prototypes.])
 635   fi
 636   if test x"$nmh_ndbm" != x; then
 637     NDBM_LIBS="-l$nmh_ndbm"
 638   else
 639     NDBM_LIBS=
 640   fi
 641   AC_SUBST(NDBM_LIBS)
 642 fi
 643
 644 dnl ------------------
 645 dnl Set RPM build root
 646 dnl ------------------
 647 dnl nmhrpm is used in the final summary, see below.  The default value is
 648 dnl reported there as ./RPM, consistent with the reporting of the default
 649 dnl source code location as ., but its absolute path is used in the Makefile.
 650 AC_ARG_WITH(rpmdir,
 651   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 652   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 653           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 654 AC_SUBST(rpmdir)
 655
 656
 657 dnl --------------------
 658 dnl CHECK FOR CYRUS-SASL
 659 dnl --------------------
 660
 661 AS_IF([test x"$sasl_support" = x"yes"],[
 662   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 663   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 664     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 665
 666 dnl -----------------
 667 dnl CHECK FOR OPENSSL
 668 dnl -----------------
 669
 670 AS_IF([test x"$tls_support" = x"yes"],[
 671   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 672   AC_CHECK_LIB([crypto], [BIO_write], ,
 673     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 674   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 675     [AC_MSG_ERROR([OpenSSL library not found])])])
 676
 677 dnl ---------------------
 678 dnl CHECK TERMCAP LIBRARY
 679 dnl ---------------------
 680
 681 dnl Add the termcap library, so that the following configure
 682 dnl tests will find it when it tries to link test programs.
 683 nmh_save_LIBS="$LIBS"
 684 LIBS="$TERMLIB $LIBS"
 685
 686 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 687 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 688 dnl in tgetstr().
 689 dnl Under Cygwin test program crashes but exit code is still 0. So,
 690 dnl we test for a file that porgram should create
 691 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 692 [Define to 1 if tgetent() accepts NULL as a buffer.])
 693 AC_CACHE_CHECK(if tgetent accepts NULL,
 694 nmh_cv_func_tgetent_accepts_null,
 695 [AC_TRY_RUN([
 696 main()
 697 {
 698     char buf[4096];
 699     int r1 = tgetent(buf, "vt100");
 700     int r2 = tgetent((char*)0,"vt100");
 701     if (r1 >= 0 && r1 == r2) {
 702         char tbuf[1024], *u;
 703         u = tbuf;
 704         tgetstr("cl", &u);
 705         creat("conftest.tgetent", 0640);
 706     }
 707     exit((r1 != r2) || r2 == -1);
 708 }
 709 ],
 710   if test -f conftest.tgetent; then
 711     nmh_cv_func_tgetent_accepts_null=yes
 712   else
 713     nmh_cv_func_tgetent_accepts_null=no
 714   fi,
 715   nmh_cv_func_tgetent_accepts_null=no,
 716   nmh_cv_func_tgetent_accepts_null=no)])
 717 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 718   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 719 fi
 720 AC_CACHE_CHECK(if tgetent returns 0 on success,
 721 nmh_cv_func_tgetent_zero_success,
 722 [AC_TRY_RUN([
 723 main()
 724 {
 725     char buf[4096];
 726     int r1 = tgetent(buf, "!@#$%^&*");
 727     int r2 = tgetent(buf, "vt100");
 728     if (r1 < 0 && r2 == 0) {
 729         char tbuf[1024], *u;
 730         u = tbuf;
 731         tgetstr("cl", &u);
 732         creat("conftest.tgetent0", 0640);
 733     }
 734     exit(r1 == r2);
 735 }
 736 ],
 737   if test -f conftest.tgetent0; then
 738     nmh_cv_func_tgetent_zero_success=yes
 739   else
 740     nmh_cv_func_tgetent_zero_success=no
 741   fi,
 742   nmh_cv_func_tgetent_zero_success=no,
 743   nmh_cv_func_tgetent_zero_success=no)])
 744 AH_TEMPLATE([TGETENT_SUCCESS],
 745 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 746 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 747   AC_DEFINE(TGETENT_SUCCESS, 0)
 748 else
 749   AC_DEFINE(TGETENT_SUCCESS, 1)
 750 fi
 751
 752 dnl Now put the libraries back to what it was before we
 753 dnl starting checking the termcap library.
 754 LIBS="$nmh_save_LIBS"
 755
 756 dnl --------------
 757 dnl CHECK TYPEDEFS
 758 dnl --------------
 759 AC_TYPE_SIGNAL
 760 AC_TYPE_PID_T
 761 AC_TYPE_OFF_T
 762 AC_TYPE_UID_T
 763 AC_TYPE_MODE_T
 764 AC_TYPE_SIZE_T
 765
 766 dnl Check for sigset_t.  Currently I'm looking in
 767 dnl <sys/types.h> and <signal.h>.  Others might need
 768 dnl to be added.
 769 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 770 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 771 #include <signal.h>]], [[sigset_t tempsigset;]])],
 772 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 773 if test $nmh_cv_type_sigset_t = no; then
 774   AC_DEFINE(sigset_t, unsigned int,
 775     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 776 fi
 777
 778 dnl ----------------
 779 dnl CHECK STRUCTURES
 780 dnl ----------------
 781 AC_CHECK_MEMBERS(struct stat.st_blksize)
 782
 783 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 784   [#ifdef TIME_WITH_SYS_TIME
 785 # include <sys/time.h>
 786 # include <time.h>
 787 #else
 788 # ifdef TM_IN_SYS_TIME
 789 #  include <sys/time.h>
 790 # else
 791 #  include <time.h>
 792 # endif
 793 #endif])
 794
 795 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 796
 797 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 798
 799 dnl -------------
 800 dnl CHECK SIGNALS
 801 dnl -------------
 802 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 803 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 804 AC_MSG_CHECKING(what style of signals to use)
 805 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 806   signals_style=POSIX_SIGNALS
 807   AC_DEFINE(POSIX_SIGNALS, 1,
 808     [Define to 1 if you use POSIX style signal handling.])
 809   AC_DEFINE(RELIABLE_SIGNALS)
 810 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 811   signals_style=BSD_SIGNALS
 812   AC_DEFINE(BSD_SIGNALS,1,
 813     [Define to 1 if you use BSD style signal handling (and can block signals).])
 814   AC_DEFINE(RELIABLE_SIGNALS)
 815 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 816   signals_style=SYSV_SIGNALS
 817   AC_DEFINE(SYSV_SIGNALS,1,
 818     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 819 else
 820   signals_style=NO_SIGNAL_BLOCKING
 821   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 822     [Define to 1 if you have no signal blocking at all (bummer).])
 823 fi
 824
 825 AC_MSG_RESULT($signals_style)
 826
 827 dnl Where is <signal.h> located?  Needed as input for signames.awk
 828 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 829 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 830                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 831                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 832                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 833                  /usr/include/sys/signal.h      dnl Almost everybody else
 834                  /dev/null;                     dnl Just in case we fall through
 835 do
 836   test -f $SIGNAL_H && \
 837   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 838   break
 839 done
 840 nmh_cv_path_signal_h=$SIGNAL_H
 841 ])
 842 SIGNAL_H=$nmh_cv_path_signal_h
 843 AC_SUBST(SIGNAL_H)dnl
 844
 845 dnl ----------------
 846 dnl OS SPECIFIC DEFINES
 847 dnl ----------------
 848 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 849 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 850 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 851 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 852 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 853
 854 case "$target_os" in
 855
 856   solaris2*)
 857     AC_DEFINE(SYS5)
 858     AC_DEFINE(SVR4)
 859     ;;
 860   irix*)
 861     AC_DEFINE(SYS5)
 862     AC_DEFINE(SVR4)
 863     ;;
 864   osf*)
 865     AC_DEFINE(SYS5)
 866     AC_DEFINE(SVR4)
 867     ;;
 868   aix*)
 869     AC_DEFINE(SYS5)
 870     AC_DEFINE(SVR4)
 871     ;;
 872   sunos4*)
 873     AC_DEFINE(BSD42)
 874     ;;
 875   freebsd*)
 876     AC_DEFINE(BSD42)
 877     AC_DEFINE(BSD44)
 878     ;;
 879   netbsd*)
 880     AC_DEFINE(BSD42)
 881     AC_DEFINE(BSD44)
 882     ;;
 883   openbsd*)
 884     AC_DEFINE(BSD42)
 885     AC_DEFINE(BSD44)
 886     ;;
 887   bsd/os*)
 888     AC_DEFINE(BSD42)
 889     AC_DEFINE(BSD44)
 890     ;;
 891   sco5*)
 892     AC_DEFINE(SYS5)
 893     AC_DEFINE(SCO_5_STDIO)
 894     ;;
 895 esac
 896
 897
 898 dnl ----------------
 899 dnl OUTPUT MAKEFILES
 900 dnl ----------------
 901 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 902                 mts/Makefile mts/smtp/Makefile \
 903                 etc/Makefile docs/Makefile man/Makefile)
 904 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 905 AC_OUTPUT
 906
 907 dnl These odd looking assignments are done to expand out unexpanded
 908 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 909 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 910 dnl again to get the final answer.
 911 dnl We only use the expanded versions to print the install paths in
 912 dnl the final summary and should use them nowhere else (see the autoconf
 913 dnl docs for the rationale for bindir etc being unexpanded).
 914 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 915 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 916 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 917 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 918 eval "nmhrpm=${nmhrpm}";
 919
 920 pop_kinds=no
 921 if test x"$enable_pop" = x"yes"; then
 922   pop_kinds="yes ("
 923
 924   if test x"$enable_apop" = x"yes"; then
 925     pop_kinds="${pop_kinds}APOP "
 926   fi
 927
 928   pop_kinds="${pop_kinds}POP3)"
 929 fi
 930
 931 echo "
 932 nmh configuration
 933 -----------------
 934 nmh version                : AC_PACKAGE_VERSION
 935 target os                  : ${target}
 936 compiler                   : ${CC}
 937 compiler flags             : ${CFLAGS}
 938 linker flags               : ${LDFLAGS}
 939 definitions                : ${OURDEFS}
 940 source code location       : ${srcdir}
 941 binary install path        : ${nmhbin}
 942 library install path       : ${nmhlib}
 943 config files install path  : ${nmhsysconf}
 944 man page install path      : ${nmhman}
 945 RPM build root             : ${nmhrpm}
 946 backup prefix              : ${backup_prefix}
 947 transport system           : ${MTS}
 948 file locking type          : ${LOCKTYPE}
 949 default smtp servers       : ${smtpservers}
 950 default editor             : ${editorpath}
 951 default pager              : ${pagerpath}
 952 email address masquerading : ${masquerade}
 953 pop is enabled             : ${pop_kinds}
 954 SASL support               : ${sasl_support}
 955 TLS support                : ${tls_support}"
 956 echo ""