git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want mhe support?
  60 AC_ARG_ENABLE(mhe,
  61   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  62
  63 dnl mhe support is on by default, so define it unless --disable-mhe or the
  64 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  65 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  66   AC_DEFINE(MHE, 1,
  67     [Define to compile in support for the Emacs front-end mh-e.])dnl
  68 fi
  69
  70 dnl Do you want client-side support for pop?
  71 AC_ARG_ENABLE(pop,
  72   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  73 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  74 if test x"$enable_nmh_pop" = x"yes"; then
  75   enable_pop=yes
  76 fi
  77
  78 dnl Do you want to disable use of locale functions
  79 AH_TEMPLATE([LOCALE],
  80 [Undefine if you don't want locale features.  By default this is defined.])
  81 AC_ARG_ENABLE([locale],
  82 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  83 [if test x$enableval = xyes; then
  84   AC_DEFINE(LOCALE)
  85 fi],
  86 AC_DEFINE(LOCALE)
  87 )
  88
  89 dnl Do you want client-side support for using SASL for authentication?
  90 dnl Note that this code will be enabled for both POP and SMTP
  91 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
  92   [Enable SASL support via the Cyrus SASL library]))
  93 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  94   AC_DEFINE(CYRUS_SASL, 1,
  95     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  96   if test x"$with_cyrus_sasl" != xyes; then
  97     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  98     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  99   fi
 100   sasl_support=yes
 101 else
 102   sasl_support=no
 103 fi
 104
 105 dnl Do you want client-side support for encryption with TLS?
 106 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
 107 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
 108   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
 109   tls_support=yes
 110 else
 111   tls_support=no
 112 fi
 113
 114 dnl What should be the default editor?
 115 AC_ARG_WITH(editor,
 116   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 117
 118 if test -n "$with_editor"; then
 119   editorpath="$with_editor"
 120 fi
 121
 122 dnl Set the backup prefix
 123 AC_ARG_WITH([hash-backup],
 124   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 125 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 126   backup_prefix="#"
 127 else
 128   backup_prefix=","
 129 fi
 130 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 131     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 132
 133 dnl After we know if we're including apop and kpop support, do pop stuff
 134 if test x"$enable_pop" = x"yes"; then
 135   AC_DEFINE(POP, 1,
 136     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 137   POPLIB=popsbr.o
 138   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 139 else
 140   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 141 fi
 142 AC_SUBST(POPLIB)dnl
 143 AC_SUBST(POPSED)dnl
 144
 145 dnl What method of locking to use?
 146 AC_ARG_WITH(locking,
 147   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 148   [specify the file locking method]))
 149
 150 if test x"$with_locking" = x"dot"; then
 151   LOCKTYPE="dot"
 152   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 153 elif test x"$with_locking" = x"flock"; then
 154   LOCKTYPE="flock"
 155   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 156 elif test x"$with_locking" = x"lockf"; then
 157   LOCKTYPE="lockf"
 158   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 159 elif test x"$with_locking" = x"fcntl"; then
 160   LOCKTYPE="fcntl"
 161   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 162 else
 163   LOCKTYPE="dot"
 164   AC_DEFINE(DOT_LOCKING)dnl
 165 fi
 166
 167 dnl What method of posting should post use?
 168 AC_ARG_WITH(mts,
 169   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 170   [specify the default mail transport agent/service]))
 171
 172 if test x"$with_mts" = x"smtp"; then
 173   MTS="smtp"
 174 elif test x"$with_mts" = x"sendmail"; then
 175   MTS="sendmail"
 176 else
 177   MTS="smtp"
 178 fi
 179 AC_SUBST(MTS)dnl
 180
 181 dnl Both the smtp and sendmail mail transport services use the smtp code
 182 AC_DEFINE(SMTPMTS, 1,
 183   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 184
 185 dnl What should be the default pager?
 186 AC_ARG_WITH(pager,
 187   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 188
 189 if test -n "$with_pager"; then
 190   pagerpath="$with_pager"
 191 fi
 192
 193 dnl What should be the default mail server(s)?
 194 AC_ARG_WITH(smtpservers,
 195   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 196   [specify the default SMTP server(s) @<:@localhost@:>@]))
 197 if test -n "$with_smtpservers"; then
 198   smtpservers="$with_smtpservers"
 199 else
 200   smtpservers="localhost"
 201 fi
 202 AC_SUBST(smtpservers)dnl
 203
 204 dnl ----------------------------------------------------
 205 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 206 dnl ----------------------------------------------------
 207 AC_PREFIX_DEFAULT(/usr/local/nmh)
 208
 209 dnl ------------------
 210 dnl CHECK THE COMPILER
 211 dnl ------------------
 212 dnl We want these before the checks,
 213 dnl so the checks can modify their values.
 214 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 215 if test x"$enable_debug" = x"yes"; then
 216   test -z "$LDFLAGS" && LDFLAGS=-g
 217 fi
 218
 219 AC_PROG_CC
 220
 221 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 222 [nmh_saved_cflags="$CFLAGS"
 223  CFLAGS="$CFLAGS -Wno-pointer-sign"
 224  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 225  CFLAGS="$nmh_saved_cflags"])
 226
 227 dnl if the user hasn't specified CFLAGS, then
 228 dnl   if compiler is gcc, then
 229 dnl     use -O2 and some warning flags
 230 dnl   else use -O
 231 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 232 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 233 dnl spurious and which in any case we don't want to deal with now.
 234 if test "$nmh_cv_has_noptrsign" = "yes"; then
 235         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 236 else
 237         nmh_gcc_warnflags="-Wall"
 238 fi
 239
 240 if test -n "$auto_cflags"; then
 241   if test x"$enable_debug" = x"yes"; then
 242     if test -n "$GCC"; then
 243       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 244     else
 245       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 246     fi
 247   else
 248     if test -z "$LDFLAGS"; then
 249       case "$build_os" in
 250         darwin*)
 251           LDFLAGS=
 252           ;;
 253         *)
 254           LDFLAGS=-s
 255           ;;
 256       esac
 257     fi
 258     if test -n "$GCC"; then
 259       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 260     else
 261       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 262     fi
 263   fi
 264 fi
 265
 266 AC_C_CONST              dnl Does compiler support `const'.
 267
 268 dnl ------------------
 269 dnl CHECK FOR PROGRAMS
 270 dnl ------------------
 271 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 272 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 273 AC_PROG_RANLIB          dnl Check for `ranlib'
 274 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 275 AC_PROG_LEX             dnl Check for lex/flex
 276
 277 dnl Look for `cut'
 278 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 279 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 280
 281 dnl ----------------------------------------------
 282 dnl check for lclint, and lint if it doesn't exist
 283 dnl ----------------------------------------------
 284 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 285 if test x$ac_cv_prog_linttmp1 != xno ; then
 286   LINT=$ac_cv_prog_linttmp1
 287   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 288 else
 289   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 290   if test x$ac_cv_prog_linttmp2 != xno ; then
 291     LINT=$ac_cv_prog_linttmp2
 292     LINTFLAGS=""
 293   else
 294     LINT="echo 'No lint program found'"
 295     LINTFLAGS=""
 296   fi
 297 fi
 298 AC_SUBST(LINT)dnl
 299 AC_SUBST(LINTFLAGS)dnl
 300
 301 dnl try to figure out which one we've got
 302 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 303 NMH_PROG_GNU_LIBTOOL
 304
 305 dnl Check for lorder and tsort commands
 306 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 307 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 308
 309 dnl If either doesn't exist, replace them with echo and cat
 310 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 311   LORDER=echo
 312   TSORT=cat
 313   AC_SUBST(LORDER)dnl
 314   AC_SUBST(TSORT)dnl
 315 dnl Mac OS X has lorder, but sh is too broken for it to work
 316 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 317 dnl   LORDER=echo
 318 dnl   TSORT=cat
 319 dnl   AC_SUBST(LORDER)dnl
 320 dnl   AC_SUBST(TSORT)dnl
 321 fi
 322
 323 dnl Check whether tsort can deal with loops
 324 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 325   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 326     nmh_cv_tsort_loop=no
 327   else
 328     nmh_cv_tsort_loop=yes
 329   fi])
 330 if test x$nmh_cv_tsort_loop = xno ; then
 331   LORDER=echo
 332   TSORT=cat
 333   AC_SUBST(LORDER)dnl
 334   AC_SUBST(TSORT)dnl
 335 fi
 336
 337 dnl Look for `ls'
 338 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 339 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 340
 341 dnl See how we get ls to display the owner and the group
 342 if test "$lspath" != "no"; then
 343   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 344                  nmh_cv_ls_grpopt,
 345   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 346     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 347     dnl ls, it would seem -l gave us both the user and group.  On this type of
 348     dnl ls, -g makes _only_ the group be displayed (and not the user).
 349     nmh_cv_ls_grpopt="-l"
 350   else
 351     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 352     nmh_cv_ls_grpopt="-lg"
 353   fi])
 354 fi
 355
 356 dnl Look for `more'
 357 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 358 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 359
 360 dnl If pager is not specified yet,
 361 dnl then use `more' as the default.
 362 if test -z "$pagerpath"; then
 363   pagerpath="$morepath"
 364 fi
 365 AC_SUBST(pagerpath)dnl
 366
 367 dnl Look for `sendmail'
 368 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 369 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 370
 371 dnl Look for `vi'
 372 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 373 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 374
 375 dnl If editor is not specified yet,
 376 dnl then use `vi' as the default.
 377 if test -z "$editorpath"; then
 378   editorpath="$vipath"
 379 fi
 380 AC_SUBST(editorpath)dnl
 381
 382 dnl ----------------------------------------------------------
 383 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 384 dnl ----------------------------------------------------------
 385 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 386 [for mailspool in /var/mail        dnl
 387                   /var/spool/mail  dnl
 388                   /usr/spool/mail  dnl
 389                   /dev/null;       dnl Just in case we fall through
 390 do
 391   test -d $mailspool && break
 392 done
 393 nmh_cv_mailspool=$mailspool
 394 ])
 395 mailspool=$nmh_cv_mailspool
 396 AC_SUBST(mailspool)dnl
 397
 398 dnl See whether the mail spool directory is world-writable.
 399 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 400   AC_CACHE_CHECK(whether the mail spool is world-writable,
 401                  nmh_cv_mailspool_world_writable,
 402   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 403     nmh_cv_mailspool_world_writable=no
 404   else
 405     nmh_cv_mailspool_world_writable=yes
 406   fi])
 407 fi
 408
 409 dnl Also, check for liblockfile (as found on Debian systems)
 410 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 411
 412 dnl and whether its companion program dotlockfile is setgid
 413 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 414 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 415   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 416     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 417     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 418         nmh_cv_dotlockfile_setgid=yes
 419       else
 420         nmh_cv_dotlockfile_setgid=no
 421       fi])
 422   fi
 423 fi
 424
 425 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 426 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 427 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 428   dnl do we really need both of these?
 429   AC_DEFINE(MAILGROUP,1,
 430     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 431   SETGID_MAIL=1
 432 fi
 433 AC_SUBST(SETGID_MAIL)dnl
 434
 435 dnl Use ls to see which group owns the mail spool directory.
 436 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 437 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 438 ])
 439 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 440 AC_SUBST(MAIL_SPOOL_GRP)dnl
 441
 442 dnl ------------------
 443 dnl CHECK HEADER FILES
 444 dnl ------------------
 445
 446 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 447 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 448 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 449 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 450 dnl declared; if so they should have an entry added to this case statement.
 451 dnl NB that we must define this on the compiler command line, not in config.h,
 452 dnl because it must be set before any system header is included and there's no
 453 dnl portable way to make sure that files generated by lex include config.h
 454 dnl before system header files.
 455
 456 case "$target_os" in
 457   linux*)
 458     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 459     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 460     ;;
 461 esac
 462 AC_SUBST(OURDEFS)
 463
 464 AC_HEADER_STDC
 465 AC_HEADER_TIME
 466 AC_HEADER_TIOCGWINSZ
 467 AC_CHECK_HEADERS(errno.h fcntl.h crypt.h termcap.h \
 468                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 469                  sys/param.h sys/time.h sys/stream.h)
 470
 471 dnl
 472 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 473 dnl really use a whole set of them, but this check should be
 474 dnl sufficient.
 475 dnl
 476 AC_CHECK_HEADER(libio.h, [
 477   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 478     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 479
 480 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 481   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 482 [[#if HAVE_SYS_STREAM_H
 483 #  include <sys/stream.h>
 484 #endif
 485 ]])
 486
 487 dnl ---------------
 488 dnl CHECK FUNCTIONS
 489 dnl ---------------
 490 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 491                sighold sigrelse writev lstat uname tzset mkstemp \
 492                getutent nl_langinfo mbtowc wcwidth)
 493
 494 dnl sigsetjmp may be a macro
 495 AC_MSG_CHECKING(for sigsetjmp)
 496 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 497   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 498     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 499   [AC_MSG_RESULT(no)])
 500
 501 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 502 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 503 dnl any system header.
 504 dnl
 505 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 506 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 507 dnl need to check?
 508 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 509 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 510                 AC_EGREP_HEADER(initgroups, unistd.h,
 511                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 512
 513 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 514 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 515 dnl seems to work perfectly and IBM apparently uses it in internal code).
 516 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 517 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 518 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 519 dnl prototype.
 520 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 521   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 522
 523 dnl Check for multibyte character set support
 524 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 525     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 526   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 527     [Define to enable support for multibyte character sets.])
 528 fi
 529
 530 dnl -------------------
 531 dnl CHECK FOR LIBRARIES
 532 dnl -------------------
 533 dnl Check location of modf
 534 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 535
 536 dnl Checks for network libraries (nsl, socket)
 537 AC_CHECK_NETLIBS
 538
 539 termcap_curses_order="termcap curses ncurses"
 540 for lib in $termcap_curses_order; do
 541   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 542 done
 543 AC_SUBST(TERMLIB)dnl
 544
 545 dnl ---------------
 546 dnl CHECK FOR ICONV
 547 dnl ---------------
 548
 549 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 550 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 551   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 552   if test "x$ac_found_iconv" = "xno"; then
 553     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 554     if test "x$ac_found_iconv" = "xno"; then
 555       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 556     fi
 557     if test "x$ac_found_iconv" != "xno"; then
 558       LIBS="-liconv $LIBS"
 559     fi
 560   else
 561     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 562     AC_CHECK_DECL(_libiconv_version,
 563       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 564       [ #include <iconv.h> ])
 565   fi
 566 fi
 567 if test "x$ac_found_iconv" = xyes; then
 568   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 569 fi
 570
 571 dnl Check if iconv uses const in prototype declaration
 572 if test "x$ac_found_iconv" = "xyes"; then
 573   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 574     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 575         #include <iconv.h>]],
 576         [[#ifdef __cplusplus
 577           "C"
 578           #endif
 579           #if defined(__STDC__) || defined(__cplusplus)
 580           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 581           #else
 582           size_t iconv();
 583           #endif]])],
 584       [ac_cv_iconv_const=],
 585       [ac_cv_iconv_const=const])])
 586   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 587     [Define as const if the declaration of iconv() needs const.])
 588 fi
 589
 590 dnl --------------
 591 dnl CHECK FOR NDBM
 592 dnl --------------
 593
 594 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 595             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 596 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 597             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 598
 599 if test "$nmh_ndbm" = "autodetect"; then
 600   if test "$nmh_ndbmheader" != "autodetect"; then
 601     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 602   else
 603
 604     dnl There are at least four implementations of ndbm, and
 605     dnl several of those can be in different places at the whim
 606     dnl of the system integrator. A good summary of this mess
 607     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 608
 609     dnl Classic ndbm with no library required (eg NetBSD): try this
 610     dnl first so we don't accidentally link in a pointless but harmless
 611     dnl library in one of the later ndbm.h+libfoo tests:
 612     NMH_CHECK_NDBM(ndbm.h,,,
 613     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 614       NMH_CHECK_NDBM(db.h,db,,
 615     dnl Berkeley DBv1 emulating ndbm:
 616         NMH_CHECK_NDBM(ndbm.h,db,,
 617           NMH_CHECK_NDBM(ndbm.h,db1,,
 618     dnl Classic ndbm:
 619             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 620     dnl glibc2.1 systems put db1 in a subdir:
 621               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 622     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 623     dnl and possibly needing gbdm_compat library:
 624                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 625                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 626                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 627                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 628
 629   fi
 630 else
 631   dnl We don't really need to check that the user-specified values work,
 632   dnl but it is a convenience to the user to bomb out early rather than
 633   dnl after configure and half the compile process.
 634   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 635 fi
 636
 637 if test "$nmh_ndbm_found" = "no"; then
 638   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 639 else
 640   dnl Now export the lib/header to our makefile/config.h:
 641   if test x"$nmh_ndbmheader" != x; then
 642     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 643       [Define to the header containing the ndbm API prototypes.])
 644   fi
 645   if test x"$nmh_ndbm" != x; then
 646     NDBM_LIBS="-l$nmh_ndbm"
 647   else
 648     NDBM_LIBS=
 649   fi
 650   AC_SUBST(NDBM_LIBS)
 651 fi
 652
 653 dnl ------------------
 654 dnl Set RPM build root
 655 dnl ------------------
 656 dnl nmhrpm is used in the final summary, see below.  The default value is
 657 dnl reported there as ./RPM, consistent with the reporting of the default
 658 dnl source code location as ., but its absolute path is used in the Makefile.
 659 AC_ARG_WITH(rpmdir,
 660   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 661   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 662           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 663 AC_SUBST(rpmdir)
 664
 665
 666 dnl --------------------
 667 dnl CHECK FOR CYRUS-SASL
 668 dnl --------------------
 669
 670 AS_IF([test x"$sasl_support" = x"yes"],[
 671   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 672   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 673     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 674
 675 dnl -----------------
 676 dnl CHECK FOR OPENSSL
 677 dnl -----------------
 678
 679 AS_IF([test x"$tls_support" = x"yes"],[
 680   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 681   AC_CHECK_LIB([crypto], [BIO_write], ,
 682     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 683   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 684     [AC_MSG_ERROR([OpenSSL library not found])])])
 685
 686 dnl ---------------------
 687 dnl CHECK TERMCAP LIBRARY
 688 dnl ---------------------
 689
 690 dnl Add the termcap library, so that the following configure
 691 dnl tests will find it when it tries to link test programs.
 692 nmh_save_LIBS="$LIBS"
 693 LIBS="$TERMLIB $LIBS"
 694
 695 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 696 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 697 dnl in tgetstr().
 698 dnl Under Cygwin test program crashes but exit code is still 0. So,
 699 dnl we test for a file that porgram should create
 700 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 701 [Define to 1 if tgetent() accepts NULL as a buffer.])
 702 AC_CACHE_CHECK(if tgetent accepts NULL,
 703 nmh_cv_func_tgetent_accepts_null,
 704 [AC_TRY_RUN([
 705 main()
 706 {
 707     char buf[4096];
 708     int r1 = tgetent(buf, "vt100");
 709     int r2 = tgetent((char*)0,"vt100");
 710     if (r1 >= 0 && r1 == r2) {
 711         char tbuf[1024], *u;
 712         u = tbuf;
 713         tgetstr("cl", &u);
 714         creat("conftest.tgetent", 0640);
 715     }
 716     exit((r1 != r2) || r2 == -1);
 717 }
 718 ],
 719   if test -f conftest.tgetent; then
 720     nmh_cv_func_tgetent_accepts_null=yes
 721   else
 722     nmh_cv_func_tgetent_accepts_null=no
 723   fi,
 724   nmh_cv_func_tgetent_accepts_null=no,
 725   nmh_cv_func_tgetent_accepts_null=no)])
 726 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 727   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 728 fi
 729 AC_CACHE_CHECK(if tgetent returns 0 on success,
 730 nmh_cv_func_tgetent_zero_success,
 731 [AC_TRY_RUN([
 732 main()
 733 {
 734     char buf[4096];
 735     int r1 = tgetent(buf, "!@#$%^&*");
 736     int r2 = tgetent(buf, "vt100");
 737     if (r1 < 0 && r2 == 0) {
 738         char tbuf[1024], *u;
 739         u = tbuf;
 740         tgetstr("cl", &u);
 741         creat("conftest.tgetent0", 0640);
 742     }
 743     exit(r1 == r2);
 744 }
 745 ],
 746   if test -f conftest.tgetent0; then
 747     nmh_cv_func_tgetent_zero_success=yes
 748   else
 749     nmh_cv_func_tgetent_zero_success=no
 750   fi,
 751   nmh_cv_func_tgetent_zero_success=no,
 752   nmh_cv_func_tgetent_zero_success=no)])
 753 AH_TEMPLATE([TGETENT_SUCCESS],
 754 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 755 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 756   AC_DEFINE(TGETENT_SUCCESS, 0)
 757 else
 758   AC_DEFINE(TGETENT_SUCCESS, 1)
 759 fi
 760
 761 dnl Now put the libraries back to what it was before we
 762 dnl starting checking the termcap library.
 763 LIBS="$nmh_save_LIBS"
 764
 765 dnl --------------
 766 dnl CHECK TYPEDEFS
 767 dnl --------------
 768 AC_TYPE_SIGNAL
 769 AC_TYPE_PID_T
 770 AC_TYPE_OFF_T
 771 AC_TYPE_UID_T
 772 AC_TYPE_MODE_T
 773 AC_TYPE_SIZE_T
 774
 775 dnl Check for sigset_t.  Currently I'm looking in
 776 dnl <sys/types.h> and <signal.h>.  Others might need
 777 dnl to be added.
 778 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 779 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 780 #include <signal.h>]], [[sigset_t tempsigset;]])],
 781 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 782 if test $nmh_cv_type_sigset_t = no; then
 783   AC_DEFINE(sigset_t, unsigned int,
 784     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 785 fi
 786
 787 dnl ----------------
 788 dnl CHECK STRUCTURES
 789 dnl ----------------
 790 AC_CHECK_MEMBERS(struct stat.st_blksize)
 791
 792 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 793   [#ifdef TIME_WITH_SYS_TIME
 794 # include <sys/time.h>
 795 # include <time.h>
 796 #else
 797 # ifdef TM_IN_SYS_TIME
 798 #  include <sys/time.h>
 799 # else
 800 #  include <time.h>
 801 # endif
 802 #endif])
 803
 804 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 805
 806 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 807
 808 dnl -------------
 809 dnl CHECK SIGNALS
 810 dnl -------------
 811 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 812 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 813 AC_MSG_CHECKING(what style of signals to use)
 814 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 815   signals_style=POSIX_SIGNALS
 816   AC_DEFINE(POSIX_SIGNALS, 1,
 817     [Define to 1 if you use POSIX style signal handling.])
 818   AC_DEFINE(RELIABLE_SIGNALS)
 819 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 820   signals_style=BSD_SIGNALS
 821   AC_DEFINE(BSD_SIGNALS,1,
 822     [Define to 1 if you use BSD style signal handling (and can block signals).])
 823   AC_DEFINE(RELIABLE_SIGNALS)
 824 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 825   signals_style=SYSV_SIGNALS
 826   AC_DEFINE(SYSV_SIGNALS,1,
 827     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 828 else
 829   signals_style=NO_SIGNAL_BLOCKING
 830   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 831     [Define to 1 if you have no signal blocking at all (bummer).])
 832 fi
 833
 834 AC_MSG_RESULT($signals_style)
 835
 836 dnl Where is <signal.h> located?  Needed as input for signames.awk
 837 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 838 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 839                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 840                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 841                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 842                  /usr/include/sys/signal.h      dnl Almost everybody else
 843                  /dev/null;                     dnl Just in case we fall through
 844 do
 845   test -f $SIGNAL_H && \
 846   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 847   break
 848 done
 849 nmh_cv_path_signal_h=$SIGNAL_H
 850 ])
 851 SIGNAL_H=$nmh_cv_path_signal_h
 852 AC_SUBST(SIGNAL_H)dnl
 853
 854 dnl ----------------
 855 dnl OS SPECIFIC DEFINES
 856 dnl ----------------
 857 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 858 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 859 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 860 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 861 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 862
 863 case "$target_os" in
 864
 865   solaris2*)
 866     AC_DEFINE(SYS5)
 867     AC_DEFINE(SVR4)
 868     ;;
 869   irix*)
 870     AC_DEFINE(SYS5)
 871     AC_DEFINE(SVR4)
 872     ;;
 873   osf*)
 874     AC_DEFINE(SYS5)
 875     AC_DEFINE(SVR4)
 876     ;;
 877   aix*)
 878     AC_DEFINE(SYS5)
 879     AC_DEFINE(SVR4)
 880     ;;
 881   sunos4*)
 882     AC_DEFINE(BSD42)
 883     ;;
 884   freebsd*)
 885     AC_DEFINE(BSD42)
 886     AC_DEFINE(BSD44)
 887     ;;
 888   netbsd*)
 889     AC_DEFINE(BSD42)
 890     AC_DEFINE(BSD44)
 891     ;;
 892   openbsd*)
 893     AC_DEFINE(BSD42)
 894     AC_DEFINE(BSD44)
 895     ;;
 896   bsd/os*)
 897     AC_DEFINE(BSD42)
 898     AC_DEFINE(BSD44)
 899     ;;
 900   sco5*)
 901     AC_DEFINE(SYS5)
 902     AC_DEFINE(SCO_5_STDIO)
 903     ;;
 904 esac
 905
 906
 907 dnl ----------------
 908 dnl OUTPUT MAKEFILES
 909 dnl ----------------
 910 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 911                 mts/Makefile mts/smtp/Makefile \
 912                 etc/Makefile docs/Makefile man/Makefile)
 913 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 914 AC_OUTPUT
 915
 916 dnl These odd looking assignments are done to expand out unexpanded
 917 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 918 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 919 dnl again to get the final answer.
 920 dnl We only use the expanded versions to print the install paths in
 921 dnl the final summary and should use them nowhere else (see the autoconf
 922 dnl docs for the rationale for bindir etc being unexpanded).
 923 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 924 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 925 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 926 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 927 eval "nmhrpm=${nmhrpm}";
 928
 929 pop_kinds=no
 930 if test x"$enable_pop" = x"yes"; then
 931   pop_kinds="yes ("
 932
 933   if test x"$enable_apop" = x"yes"; then
 934     pop_kinds="${pop_kinds}APOP "
 935   fi
 936
 937   pop_kinds="${pop_kinds}POP3)"
 938 fi
 939
 940 echo "
 941 nmh configuration
 942 -----------------
 943 nmh version                : AC_PACKAGE_VERSION
 944 target os                  : ${target}
 945 compiler                   : ${CC}
 946 compiler flags             : ${CFLAGS}
 947 linker flags               : ${LDFLAGS}
 948 definitions                : ${OURDEFS}
 949 source code location       : ${srcdir}
 950 binary install path        : ${nmhbin}
 951 library install path       : ${nmhlib}
 952 config files install path  : ${nmhsysconf}
 953 man page install path      : ${nmhman}
 954 RPM build root             : ${nmhrpm}
 955 backup prefix              : ${backup_prefix}
 956 transport system           : ${MTS}
 957 file locking type          : ${LOCKTYPE}
 958 default smtp servers       : ${smtpservers}
 959 default editor             : ${editorpath}
 960 default pager              : ${pagerpath}
 961 email address masquerading : ${masquerade}
 962 pop is enabled             : ${pop_kinds}
 963 SASL support               : ${sasl_support}
 964 TLS support                : ${tls_support}"
 965 echo ""