git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want client-side support for pop?
  60 AC_ARG_ENABLE(pop,
  61   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  62 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  63 if test x"$enable_nmh_pop" = x"yes"; then
  64   enable_pop=yes
  65 fi
  66
  67 dnl Do you want to disable use of locale functions
  68 AH_TEMPLATE([LOCALE],
  69 [Undefine if you don't want locale features.  By default this is defined.])
  70 AC_ARG_ENABLE([locale],
  71 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  72 [if test x$enableval = xyes; then
  73   AC_DEFINE(LOCALE)
  74 fi],
  75 AC_DEFINE(LOCALE)
  76 )
  77
  78 dnl Do you want client-side support for using SASL for authentication?
  79 dnl Note that this code will be enabled for both POP and SMTP
  80 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
  81   [Enable SASL support via the Cyrus SASL library]))
  82 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  83   AC_DEFINE(CYRUS_SASL, 1,
  84     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  85   if test x"$with_cyrus_sasl" != xyes; then
  86     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  87     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  88   fi
  89   sasl_support=yes
  90 else
  91   sasl_support=no
  92 fi
  93
  94 dnl Do you want client-side support for encryption with TLS?
  95 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
  96 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
  97   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
  98   tls_support=yes
  99 else
 100   tls_support=no
 101 fi
 102
 103 dnl What should be the default editor?
 104 AC_ARG_WITH(editor,
 105   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 106
 107 if test -n "$with_editor"; then
 108   editorpath="$with_editor"
 109 fi
 110
 111 dnl Set the backup prefix
 112 AC_ARG_WITH([hash-backup],
 113   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 114 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 115   backup_prefix="#"
 116 else
 117   backup_prefix=","
 118 fi
 119 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 120     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 121
 122 dnl After we know if we're including apop and kpop support, do pop stuff
 123 if test x"$enable_pop" = x"yes"; then
 124   AC_DEFINE(POP, 1,
 125     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 126   POPLIB=popsbr.o
 127   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 128 else
 129   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 130 fi
 131 AC_SUBST(POPLIB)dnl
 132 AC_SUBST(POPSED)dnl
 133
 134 dnl What method of locking to use?
 135 AC_ARG_WITH(locking,
 136   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 137   [specify the file locking method]))
 138
 139 if test x"$with_locking" = x"dot"; then
 140   LOCKTYPE="dot"
 141   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 142 elif test x"$with_locking" = x"flock"; then
 143   LOCKTYPE="flock"
 144   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 145 elif test x"$with_locking" = x"lockf"; then
 146   LOCKTYPE="lockf"
 147   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 148 elif test x"$with_locking" = x"fcntl"; then
 149   LOCKTYPE="fcntl"
 150   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 151 else
 152   LOCKTYPE="dot"
 153   AC_DEFINE(DOT_LOCKING)dnl
 154 fi
 155
 156 dnl What method of posting should post use?
 157 AC_ARG_WITH(mts,
 158   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 159   [specify the default mail transport agent/service]))
 160
 161 if test x"$with_mts" = x"smtp"; then
 162   MTS="smtp"
 163 elif test x"$with_mts" = x"sendmail"; then
 164   MTS="sendmail"
 165 else
 166   MTS="smtp"
 167 fi
 168 AC_SUBST(MTS)dnl
 169
 170 dnl Both the smtp and sendmail mail transport services use the smtp code
 171 AC_DEFINE(SMTPMTS, 1,
 172   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 173
 174 dnl What should be the default pager?
 175 AC_ARG_WITH(pager,
 176   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 177
 178 if test -n "$with_pager"; then
 179   pagerpath="$with_pager"
 180 fi
 181
 182 dnl What should be the default mail server(s)?
 183 AC_ARG_WITH(smtpservers,
 184   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 185   [specify the default SMTP server(s) @<:@localhost@:>@]))
 186 if test -n "$with_smtpservers"; then
 187   smtpservers="$with_smtpservers"
 188 else
 189   smtpservers="localhost"
 190 fi
 191 AC_SUBST(smtpservers)dnl
 192
 193 dnl ----------------------------------------------------
 194 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 195 dnl ----------------------------------------------------
 196 AC_PREFIX_DEFAULT(/usr/local/nmh)
 197
 198 dnl ------------------
 199 dnl CHECK THE COMPILER
 200 dnl ------------------
 201 dnl We want these before the checks,
 202 dnl so the checks can modify their values.
 203 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 204 if test x"$enable_debug" = x"yes"; then
 205   test -z "$LDFLAGS" && LDFLAGS=-g
 206 fi
 207
 208 AC_PROG_CC
 209
 210 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 211 [nmh_saved_cflags="$CFLAGS"
 212  CFLAGS="$CFLAGS -Wno-pointer-sign"
 213  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 214  CFLAGS="$nmh_saved_cflags"])
 215
 216 dnl if the user hasn't specified CFLAGS, then
 217 dnl   if compiler is gcc, then
 218 dnl     use -O2 and some warning flags
 219 dnl   else use -O
 220 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 221 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 222 dnl spurious and which in any case we don't want to deal with now.
 223 if test "$nmh_cv_has_noptrsign" = "yes"; then
 224         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 225 else
 226         nmh_gcc_warnflags="-Wall"
 227 fi
 228
 229 if test -n "$auto_cflags"; then
 230   if test x"$enable_debug" = x"yes"; then
 231     if test -n "$GCC"; then
 232       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 233     else
 234       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 235     fi
 236   else
 237     if test -z "$LDFLAGS"; then
 238       case "$build_os" in
 239         darwin*)
 240           LDFLAGS=
 241           ;;
 242         *)
 243           LDFLAGS=-s
 244           ;;
 245       esac
 246     fi
 247     if test -n "$GCC"; then
 248       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 249     else
 250       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 251     fi
 252   fi
 253 fi
 254
 255 AC_C_CONST              dnl Does compiler support `const'.
 256
 257 dnl ------------------
 258 dnl CHECK FOR PROGRAMS
 259 dnl ------------------
 260 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 261 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 262 AC_PROG_RANLIB          dnl Check for `ranlib'
 263 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 264 AC_PROG_LEX             dnl Check for lex/flex
 265
 266 dnl Look for `cut'
 267 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 268 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 269
 270 dnl ----------------------------------------------
 271 dnl check for lclint, and lint if it doesn't exist
 272 dnl ----------------------------------------------
 273 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 274 if test x$ac_cv_prog_linttmp1 != xno ; then
 275   LINT=$ac_cv_prog_linttmp1
 276   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 277 else
 278   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 279   if test x$ac_cv_prog_linttmp2 != xno ; then
 280     LINT=$ac_cv_prog_linttmp2
 281     LINTFLAGS=""
 282   else
 283     LINT="echo 'No lint program found'"
 284     LINTFLAGS=""
 285   fi
 286 fi
 287 AC_SUBST(LINT)dnl
 288 AC_SUBST(LINTFLAGS)dnl
 289
 290 dnl try to figure out which one we've got
 291 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 292 NMH_PROG_GNU_LIBTOOL
 293
 294 dnl Check for lorder and tsort commands
 295 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 296 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 297
 298 dnl If either doesn't exist, replace them with echo and cat
 299 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 300   LORDER=echo
 301   TSORT=cat
 302   AC_SUBST(LORDER)dnl
 303   AC_SUBST(TSORT)dnl
 304 dnl Mac OS X has lorder, but sh is too broken for it to work
 305 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 306 dnl   LORDER=echo
 307 dnl   TSORT=cat
 308 dnl   AC_SUBST(LORDER)dnl
 309 dnl   AC_SUBST(TSORT)dnl
 310 fi
 311
 312 dnl Check whether tsort can deal with loops
 313 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 314   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 315     nmh_cv_tsort_loop=no
 316   else
 317     nmh_cv_tsort_loop=yes
 318   fi])
 319 if test x$nmh_cv_tsort_loop = xno ; then
 320   LORDER=echo
 321   TSORT=cat
 322   AC_SUBST(LORDER)dnl
 323   AC_SUBST(TSORT)dnl
 324 fi
 325
 326 dnl Look for `ls'
 327 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 328 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 329
 330 dnl See how we get ls to display the owner and the group
 331 if test "$lspath" != "no"; then
 332   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 333                  nmh_cv_ls_grpopt,
 334   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 335     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 336     dnl ls, it would seem -l gave us both the user and group.  On this type of
 337     dnl ls, -g makes _only_ the group be displayed (and not the user).
 338     nmh_cv_ls_grpopt="-l"
 339   else
 340     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 341     nmh_cv_ls_grpopt="-lg"
 342   fi])
 343 fi
 344
 345 dnl Look for `more'
 346 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 347 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 348
 349 dnl If pager is not specified yet,
 350 dnl then use `more' as the default.
 351 if test -z "$pagerpath"; then
 352   pagerpath="$morepath"
 353 fi
 354 AC_SUBST(pagerpath)dnl
 355
 356 dnl Look for `sendmail'
 357 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 358 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 359
 360 dnl Look for `vi'
 361 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 362 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 363
 364 dnl If editor is not specified yet,
 365 dnl then use `vi' as the default.
 366 if test -z "$editorpath"; then
 367   editorpath="$vipath"
 368 fi
 369 AC_SUBST(editorpath)dnl
 370
 371 dnl ----------------------------------------------------------
 372 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 373 dnl ----------------------------------------------------------
 374 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 375 [for mailspool in /var/mail        dnl
 376                   /var/spool/mail  dnl
 377                   /usr/spool/mail  dnl
 378                   /dev/null;       dnl Just in case we fall through
 379 do
 380   test -d $mailspool && break
 381 done
 382 nmh_cv_mailspool=$mailspool
 383 ])
 384 mailspool=$nmh_cv_mailspool
 385 AC_SUBST(mailspool)dnl
 386
 387 dnl See whether the mail spool directory is world-writable.
 388 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 389   AC_CACHE_CHECK(whether the mail spool is world-writable,
 390                  nmh_cv_mailspool_world_writable,
 391   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 392     nmh_cv_mailspool_world_writable=no
 393   else
 394     nmh_cv_mailspool_world_writable=yes
 395   fi])
 396 fi
 397
 398 dnl Also, check for liblockfile (as found on Debian systems)
 399 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 400
 401 dnl and whether its companion program dotlockfile is setgid
 402 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 403 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 404   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 405     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 406     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 407         nmh_cv_dotlockfile_setgid=yes
 408       else
 409         nmh_cv_dotlockfile_setgid=no
 410       fi])
 411   fi
 412 fi
 413
 414 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 415 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 416 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 417   dnl do we really need both of these?
 418   AC_DEFINE(MAILGROUP,1,
 419     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 420   SETGID_MAIL=1
 421 fi
 422 AC_SUBST(SETGID_MAIL)dnl
 423
 424 dnl Use ls to see which group owns the mail spool directory.
 425 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 426 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 427 ])
 428 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 429 AC_SUBST(MAIL_SPOOL_GRP)dnl
 430
 431 dnl ------------------
 432 dnl CHECK HEADER FILES
 433 dnl ------------------
 434
 435 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 436 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 437 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 438 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 439 dnl declared; if so they should have an entry added to this case statement.
 440 dnl NB that we must define this on the compiler command line, not in config.h,
 441 dnl because it must be set before any system header is included and there's no
 442 dnl portable way to make sure that files generated by lex include config.h
 443 dnl before system header files.
 444
 445 case "$target_os" in
 446   linux*)
 447     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 448     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 449     ;;
 450 esac
 451 AC_SUBST(OURDEFS)
 452
 453 AC_HEADER_STDC
 454 AC_HEADER_TIME
 455 AC_HEADER_TIOCGWINSZ
 456 AC_CHECK_HEADERS(errno.h fcntl.h crypt.h termcap.h \
 457                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 458                  sys/param.h sys/time.h sys/stream.h)
 459
 460 dnl
 461 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 462 dnl really use a whole set of them, but this check should be
 463 dnl sufficient.
 464 dnl
 465 AC_CHECK_HEADER(libio.h, [
 466   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 467     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 468
 469 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 470   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 471 [[#if HAVE_SYS_STREAM_H
 472 #  include <sys/stream.h>
 473 #endif
 474 ]])
 475
 476 dnl ---------------
 477 dnl CHECK FUNCTIONS
 478 dnl ---------------
 479 AC_CHECK_FUNCS(writev lstat tzset getutent nl_langinfo sigaction sigprocmask \
 480                sigblock sigsetmask sighold sigrelse)
 481
 482 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 483 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 484 dnl any system header.
 485 dnl
 486 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 487 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 488 dnl need to check?
 489 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 490 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 491                 AC_EGREP_HEADER(initgroups, unistd.h,
 492                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 493
 494 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 495 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 496 dnl seems to work perfectly and IBM apparently uses it in internal code).
 497 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 498 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 499 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 500 dnl prototype.
 501 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 502   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 503
 504 dnl Check for multibyte character set support
 505 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 506     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 507   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 508     [Define to enable support for multibyte character sets.])
 509 fi
 510
 511 dnl -------------------
 512 dnl CHECK FOR LIBRARIES
 513 dnl -------------------
 514 dnl Check location of modf
 515 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 516
 517 dnl Checks for network libraries (nsl, socket)
 518 AC_CHECK_NETLIBS
 519
 520 termcap_curses_order="termcap curses ncurses"
 521 for lib in $termcap_curses_order; do
 522   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 523 done
 524 AC_SUBST(TERMLIB)dnl
 525
 526 dnl ---------------
 527 dnl CHECK FOR ICONV
 528 dnl ---------------
 529
 530 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 531 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 532   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 533   if test "x$ac_found_iconv" = "xno"; then
 534     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 535     if test "x$ac_found_iconv" = "xno"; then
 536       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 537     fi
 538     if test "x$ac_found_iconv" != "xno"; then
 539       LIBS="-liconv $LIBS"
 540     fi
 541   else
 542     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 543     AC_CHECK_DECL(_libiconv_version,
 544       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 545       [ #include <iconv.h> ])
 546   fi
 547 fi
 548 if test "x$ac_found_iconv" = xyes; then
 549   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 550 fi
 551
 552 dnl Check if iconv uses const in prototype declaration
 553 if test "x$ac_found_iconv" = "xyes"; then
 554   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 555     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 556         #include <iconv.h>]],
 557         [[#ifdef __cplusplus
 558           "C"
 559           #endif
 560           #if defined(__STDC__) || defined(__cplusplus)
 561           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 562           #else
 563           size_t iconv();
 564           #endif]])],
 565       [ac_cv_iconv_const=],
 566       [ac_cv_iconv_const=const])])
 567   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 568     [Define as const if the declaration of iconv() needs const.])
 569 fi
 570
 571 dnl --------------
 572 dnl CHECK FOR NDBM
 573 dnl --------------
 574
 575 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 576             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 577 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 578             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 579
 580 if test "$nmh_ndbm" = "autodetect"; then
 581   if test "$nmh_ndbmheader" != "autodetect"; then
 582     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 583   else
 584
 585     dnl There are at least four implementations of ndbm, and
 586     dnl several of those can be in different places at the whim
 587     dnl of the system integrator. A good summary of this mess
 588     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 589
 590     dnl Classic ndbm with no library required (eg NetBSD): try this
 591     dnl first so we don't accidentally link in a pointless but harmless
 592     dnl library in one of the later ndbm.h+libfoo tests:
 593     NMH_CHECK_NDBM(ndbm.h,,,
 594     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 595       NMH_CHECK_NDBM(db.h,db,,
 596     dnl Berkeley DBv1 emulating ndbm:
 597         NMH_CHECK_NDBM(ndbm.h,db,,
 598           NMH_CHECK_NDBM(ndbm.h,db1,,
 599     dnl Classic ndbm:
 600             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 601     dnl glibc2.1 systems put db1 in a subdir:
 602               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 603     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 604     dnl and possibly needing gbdm_compat library:
 605                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 606                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 607                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 608                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 609
 610   fi
 611 else
 612   dnl We don't really need to check that the user-specified values work,
 613   dnl but it is a convenience to the user to bomb out early rather than
 614   dnl after configure and half the compile process.
 615   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 616 fi
 617
 618 if test "$nmh_ndbm_found" = "no"; then
 619   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 620 else
 621   dnl Now export the lib/header to our makefile/config.h:
 622   if test x"$nmh_ndbmheader" != x; then
 623     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 624       [Define to the header containing the ndbm API prototypes.])
 625   fi
 626   if test x"$nmh_ndbm" != x; then
 627     NDBM_LIBS="-l$nmh_ndbm"
 628   else
 629     NDBM_LIBS=
 630   fi
 631   AC_SUBST(NDBM_LIBS)
 632 fi
 633
 634 dnl ------------------
 635 dnl Set RPM build root
 636 dnl ------------------
 637 dnl nmhrpm is used in the final summary, see below.  The default value is
 638 dnl reported there as ./RPM, consistent with the reporting of the default
 639 dnl source code location as ., but its absolute path is used in the Makefile.
 640 AC_ARG_WITH(rpmdir,
 641   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 642   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 643           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 644 AC_SUBST(rpmdir)
 645
 646
 647 dnl --------------------
 648 dnl CHECK FOR CYRUS-SASL
 649 dnl --------------------
 650
 651 AS_IF([test x"$sasl_support" = x"yes"],[
 652   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 653   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 654     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 655
 656 dnl -----------------
 657 dnl CHECK FOR OPENSSL
 658 dnl -----------------
 659
 660 AS_IF([test x"$tls_support" = x"yes"],[
 661   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 662   AC_CHECK_LIB([crypto], [BIO_write], ,
 663     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 664   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 665     [AC_MSG_ERROR([OpenSSL library not found])])])
 666
 667 dnl ---------------------
 668 dnl CHECK TERMCAP LIBRARY
 669 dnl ---------------------
 670
 671 dnl Add the termcap library, so that the following configure
 672 dnl tests will find it when it tries to link test programs.
 673 nmh_save_LIBS="$LIBS"
 674 LIBS="$TERMLIB $LIBS"
 675
 676 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 677 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 678 dnl in tgetstr().
 679 dnl Under Cygwin test program crashes but exit code is still 0. So,
 680 dnl we test for a file that porgram should create
 681 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 682 [Define to 1 if tgetent() accepts NULL as a buffer.])
 683 AC_CACHE_CHECK(if tgetent accepts NULL,
 684 nmh_cv_func_tgetent_accepts_null,
 685 [AC_TRY_RUN([
 686 main()
 687 {
 688     char buf[4096];
 689     int r1 = tgetent(buf, "vt100");
 690     int r2 = tgetent((char*)0,"vt100");
 691     if (r1 >= 0 && r1 == r2) {
 692         char tbuf[1024], *u;
 693         u = tbuf;
 694         tgetstr("cl", &u);
 695         creat("conftest.tgetent", 0640);
 696     }
 697     exit((r1 != r2) || r2 == -1);
 698 }
 699 ],
 700   if test -f conftest.tgetent; then
 701     nmh_cv_func_tgetent_accepts_null=yes
 702   else
 703     nmh_cv_func_tgetent_accepts_null=no
 704   fi,
 705   nmh_cv_func_tgetent_accepts_null=no,
 706   nmh_cv_func_tgetent_accepts_null=no)])
 707 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 708   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 709 fi
 710 AC_CACHE_CHECK(if tgetent returns 0 on success,
 711 nmh_cv_func_tgetent_zero_success,
 712 [AC_TRY_RUN([
 713 main()
 714 {
 715     char buf[4096];
 716     int r1 = tgetent(buf, "!@#$%^&*");
 717     int r2 = tgetent(buf, "vt100");
 718     if (r1 < 0 && r2 == 0) {
 719         char tbuf[1024], *u;
 720         u = tbuf;
 721         tgetstr("cl", &u);
 722         creat("conftest.tgetent0", 0640);
 723     }
 724     exit(r1 == r2);
 725 }
 726 ],
 727   if test -f conftest.tgetent0; then
 728     nmh_cv_func_tgetent_zero_success=yes
 729   else
 730     nmh_cv_func_tgetent_zero_success=no
 731   fi,
 732   nmh_cv_func_tgetent_zero_success=no,
 733   nmh_cv_func_tgetent_zero_success=no)])
 734 AH_TEMPLATE([TGETENT_SUCCESS],
 735 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 736 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 737   AC_DEFINE(TGETENT_SUCCESS, 0)
 738 else
 739   AC_DEFINE(TGETENT_SUCCESS, 1)
 740 fi
 741
 742 dnl Now put the libraries back to what it was before we
 743 dnl starting checking the termcap library.
 744 LIBS="$nmh_save_LIBS"
 745
 746 dnl --------------
 747 dnl CHECK TYPEDEFS
 748 dnl --------------
 749 AC_TYPE_SIGNAL
 750 AC_TYPE_PID_T
 751 AC_TYPE_OFF_T
 752 AC_TYPE_UID_T
 753 AC_TYPE_MODE_T
 754 AC_TYPE_SIZE_T
 755
 756 dnl Check for sigset_t.  Currently I'm looking in
 757 dnl <sys/types.h> and <signal.h>.  Others might need
 758 dnl to be added.
 759 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 760 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 761 #include <signal.h>]], [[sigset_t tempsigset;]])],
 762 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 763 if test $nmh_cv_type_sigset_t = no; then
 764   AC_DEFINE(sigset_t, unsigned int,
 765     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 766 fi
 767
 768 dnl ----------------
 769 dnl CHECK STRUCTURES
 770 dnl ----------------
 771 AC_CHECK_MEMBERS(struct stat.st_blksize)
 772
 773 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 774   [#ifdef TIME_WITH_SYS_TIME
 775 # include <sys/time.h>
 776 # include <time.h>
 777 #else
 778 # ifdef TM_IN_SYS_TIME
 779 #  include <sys/time.h>
 780 # else
 781 #  include <time.h>
 782 # endif
 783 #endif])
 784
 785 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 786
 787 AC_STRUCT_DIRENT_D_TYPE
 788
 789 dnl -------------
 790 dnl CHECK SIGNALS
 791 dnl -------------
 792 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 793 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 794 AC_MSG_CHECKING(what style of signals to use)
 795 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 796   signals_style=POSIX_SIGNALS
 797   AC_DEFINE(POSIX_SIGNALS, 1,
 798     [Define to 1 if you use POSIX style signal handling.])
 799   AC_DEFINE(RELIABLE_SIGNALS)
 800 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 801   signals_style=BSD_SIGNALS
 802   AC_DEFINE(BSD_SIGNALS,1,
 803     [Define to 1 if you use BSD style signal handling (and can block signals).])
 804   AC_DEFINE(RELIABLE_SIGNALS)
 805 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 806   signals_style=SYSV_SIGNALS
 807   AC_DEFINE(SYSV_SIGNALS,1,
 808     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 809 else
 810   signals_style=NO_SIGNAL_BLOCKING
 811   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 812     [Define to 1 if you have no signal blocking at all (bummer).])
 813 fi
 814
 815 AC_MSG_RESULT($signals_style)
 816
 817 dnl Where is <signal.h> located?  Needed as input for signames.awk
 818 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 819 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 820                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 821                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 822                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 823                  /usr/include/sys/signal.h      dnl Almost everybody else
 824                  /dev/null;                     dnl Just in case we fall through
 825 do
 826   test -f $SIGNAL_H && \
 827   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 828   break
 829 done
 830 nmh_cv_path_signal_h=$SIGNAL_H
 831 ])
 832 SIGNAL_H=$nmh_cv_path_signal_h
 833 AC_SUBST(SIGNAL_H)dnl
 834
 835 dnl ----------------
 836 dnl OS SPECIFIC DEFINES
 837 dnl ----------------
 838 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 839 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 840 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 841 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 842 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 843
 844 case "$target_os" in
 845
 846   solaris2*)
 847     AC_DEFINE(SYS5)
 848     AC_DEFINE(SVR4)
 849     ;;
 850   irix*)
 851     AC_DEFINE(SYS5)
 852     AC_DEFINE(SVR4)
 853     ;;
 854   osf*)
 855     AC_DEFINE(SYS5)
 856     AC_DEFINE(SVR4)
 857     ;;
 858   aix*)
 859     AC_DEFINE(SYS5)
 860     AC_DEFINE(SVR4)
 861     ;;
 862   sunos4*)
 863     AC_DEFINE(BSD42)
 864     ;;
 865   freebsd*)
 866     AC_DEFINE(BSD42)
 867     AC_DEFINE(BSD44)
 868     ;;
 869   netbsd*)
 870     AC_DEFINE(BSD42)
 871     AC_DEFINE(BSD44)
 872     ;;
 873   openbsd*)
 874     AC_DEFINE(BSD42)
 875     AC_DEFINE(BSD44)
 876     ;;
 877   bsd/os*)
 878     AC_DEFINE(BSD42)
 879     AC_DEFINE(BSD44)
 880     ;;
 881   sco5*)
 882     AC_DEFINE(SYS5)
 883     AC_DEFINE(SCO_5_STDIO)
 884     ;;
 885 esac
 886
 887
 888 dnl ----------------
 889 dnl OUTPUT MAKEFILES
 890 dnl ----------------
 891 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 892                 mts/Makefile mts/smtp/Makefile \
 893                 etc/Makefile docs/Makefile man/Makefile)
 894 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 895 AC_OUTPUT
 896
 897 dnl These odd looking assignments are done to expand out unexpanded
 898 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 899 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 900 dnl again to get the final answer.
 901 dnl We only use the expanded versions to print the install paths in
 902 dnl the final summary and should use them nowhere else (see the autoconf
 903 dnl docs for the rationale for bindir etc being unexpanded).
 904 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 905 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 906 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 907 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 908 eval "nmhrpm=${nmhrpm}";
 909
 910 pop_kinds=no
 911 if test x"$enable_pop" = x"yes"; then
 912   pop_kinds="yes ("
 913
 914   if test x"$enable_apop" = x"yes"; then
 915     pop_kinds="${pop_kinds}APOP "
 916   fi
 917
 918   pop_kinds="${pop_kinds}POP3)"
 919 fi
 920
 921 echo "
 922 nmh configuration
 923 -----------------
 924 nmh version                : AC_PACKAGE_VERSION
 925 target os                  : ${target}
 926 compiler                   : ${CC}
 927 compiler flags             : ${CFLAGS}
 928 linker flags               : ${LDFLAGS}
 929 definitions                : ${OURDEFS}
 930 source code location       : ${srcdir}
 931 binary install path        : ${nmhbin}
 932 library install path       : ${nmhlib}
 933 config files install path  : ${nmhsysconf}
 934 man page install path      : ${nmhman}
 935 RPM build root             : ${nmhrpm}
 936 backup prefix              : ${backup_prefix}
 937 transport system           : ${MTS}
 938 file locking type          : ${LOCKTYPE}
 939 default smtp servers       : ${smtpservers}
 940 default editor             : ${editorpath}
 941 default pager              : ${pagerpath}
 942 email address masquerading : ${masquerade}
 943 pop is enabled             : ${pop_kinds}
 944 SASL support               : ${sasl_support}
 945 TLS support                : ${tls_support}"
 946 echo ""