git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want mhe support?
  60 AC_ARG_ENABLE(mhe,
  61   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  62
  63 dnl mhe support is on by default, so define it unless --disable-mhe or the
  64 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  65 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  66   AC_DEFINE(MHE, 1,
  67     [Define to compile in support for the Emacs front-end mh-e.])dnl
  68 fi
  69
  70 dnl Do you want client-side support for pop?
  71 AC_ARG_ENABLE(pop,
  72   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  73 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  74 if test x"$enable_nmh_pop" = x"yes"; then
  75   enable_pop=yes
  76 fi
  77
  78 dnl Do you want to disable use of locale functions
  79 AH_TEMPLATE([LOCALE],
  80 [Undefine if you don't want locale features.  By default this is defined.])
  81 AC_ARG_ENABLE([locale],
  82 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  83 [if test x$enableval = xyes; then
  84   AC_DEFINE(LOCALE)
  85 fi],
  86 AC_DEFINE(LOCALE)
  87 )
  88
  89 dnl Do you want client-side support for using SASL for authentication?
  90 dnl Note that this code will be enabled for both POP and SMTP
  91 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
  92   [Enable SASL support via the Cyrus SASL library]))
  93 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  94   AC_DEFINE(CYRUS_SASL, 1,
  95     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  96   if test x"$with_cyrus_sasl" != xyes; then
  97     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  98     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  99   fi
 100   sasl_support=yes
 101 else
 102   sasl_support=no
 103 fi
 104
 105 dnl Do you want client-side support for encryption with TLS?
 106 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
 107 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
 108   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
 109   tls_support=yes
 110 else
 111   tls_support=no
 112 fi
 113
 114 dnl What should be the default editor?
 115 AC_ARG_WITH(editor,
 116   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 117
 118 if test -n "$with_editor"; then
 119   editorpath="$with_editor"
 120 fi
 121
 122 dnl Set the backup prefix
 123 AC_ARG_WITH([hash-backup],
 124   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 125 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 126   backup_prefix="#"
 127 else
 128   backup_prefix=","
 129 fi
 130 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 131     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 132
 133 dnl After we know if we're including apop and kpop support, do pop stuff
 134 if test x"$enable_pop" = x"yes"; then
 135   AC_DEFINE(POP, 1,
 136     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 137   POPLIB=popsbr.o
 138   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 139 else
 140   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 141 fi
 142 AC_SUBST(POPLIB)dnl
 143 AC_SUBST(POPSED)dnl
 144
 145 dnl What method of locking to use?
 146 AC_ARG_WITH(locking,
 147   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 148   [specify the file locking method]))
 149
 150 if test x"$with_locking" = x"dot"; then
 151   LOCKTYPE="dot"
 152   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 153 elif test x"$with_locking" = x"flock"; then
 154   LOCKTYPE="flock"
 155   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 156 elif test x"$with_locking" = x"lockf"; then
 157   LOCKTYPE="lockf"
 158   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 159 elif test x"$with_locking" = x"fcntl"; then
 160   LOCKTYPE="fcntl"
 161   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 162 else
 163   LOCKTYPE="dot"
 164   AC_DEFINE(DOT_LOCKING)dnl
 165 fi
 166
 167 dnl What method of posting should post use?
 168 AC_ARG_WITH(mts,
 169   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 170   [specify the default mail transport agent/service]))
 171
 172 if test x"$with_mts" = x"smtp"; then
 173   MTS="smtp"
 174 elif test x"$with_mts" = x"sendmail"; then
 175   MTS="sendmail"
 176 else
 177   MTS="smtp"
 178 fi
 179 AC_SUBST(MTS)dnl
 180
 181 dnl Both the smtp and sendmail mail transport services use the smtp code
 182 AC_DEFINE(SMTPMTS, 1,
 183   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 184
 185 dnl What should be the default pager?
 186 AC_ARG_WITH(pager,
 187   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 188
 189 if test -n "$with_pager"; then
 190   pagerpath="$with_pager"
 191 fi
 192
 193 dnl What should be the default mail server(s)?
 194 AC_ARG_WITH(smtpservers,
 195   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 196   [specify the default SMTP server(s) @<:@localhost@:>@]))
 197 if test -n "$with_smtpservers"; then
 198   smtpservers="$with_smtpservers"
 199 else
 200   smtpservers="localhost"
 201 fi
 202 AC_SUBST(smtpservers)dnl
 203
 204 dnl ----------------------------------------------------
 205 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 206 dnl ----------------------------------------------------
 207 AC_PREFIX_DEFAULT(/usr/local/nmh)
 208
 209 dnl ------------------
 210 dnl CHECK THE COMPILER
 211 dnl ------------------
 212 dnl We want these before the checks,
 213 dnl so the checks can modify their values.
 214 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 215 if test x"$enable_debug" = x"yes"; then
 216   test -z "$LDFLAGS" && LDFLAGS=-g
 217 fi
 218
 219 AC_PROG_CC
 220
 221 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 222 [nmh_saved_cflags="$CFLAGS"
 223  CFLAGS="$CFLAGS -Wno-pointer-sign"
 224  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 225  CFLAGS="$nmh_saved_cflags"])
 226
 227 dnl if the user hasn't specified CFLAGS, then
 228 dnl   if compiler is gcc, then
 229 dnl     use -O2 and some warning flags
 230 dnl   else use -O
 231 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 232 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 233 dnl spurious and which in any case we don't want to deal with now.
 234 if test "$nmh_cv_has_noptrsign" = "yes"; then
 235         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 236 else
 237         nmh_gcc_warnflags="-Wall"
 238 fi
 239
 240 if test -n "$auto_cflags"; then
 241   if test x"$enable_debug" = x"yes"; then
 242     if test -n "$GCC"; then
 243       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 244     else
 245       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 246     fi
 247   else
 248     if test -z "$LDFLAGS"; then
 249       case "$build_os" in
 250         darwin*)
 251           LDFLAGS=
 252           ;;
 253         *)
 254           LDFLAGS=-s
 255           ;;
 256       esac
 257     fi
 258     if test -n "$GCC"; then
 259       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 260     else
 261       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 262     fi
 263   fi
 264 fi
 265
 266 AC_C_CONST              dnl Does compiler support `const'.
 267
 268 dnl ------------------
 269 dnl CHECK FOR PROGRAMS
 270 dnl ------------------
 271 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 272 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 273 AC_PROG_RANLIB          dnl Check for `ranlib'
 274 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 275 AC_PROG_LEX             dnl Check for lex/flex
 276
 277 dnl Look for `cut'
 278 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 279 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 280
 281 dnl ----------------------------------------------
 282 dnl check for lclint, and lint if it doesn't exist
 283 dnl ----------------------------------------------
 284 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 285 if test x$ac_cv_prog_linttmp1 != xno ; then
 286   LINT=$ac_cv_prog_linttmp1
 287   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 288 else
 289   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 290   if test x$ac_cv_prog_linttmp2 != xno ; then
 291     LINT=$ac_cv_prog_linttmp2
 292     LINTFLAGS=""
 293   else
 294     LINT="echo 'No lint program found'"
 295     LINTFLAGS=""
 296   fi
 297 fi
 298 AC_SUBST(LINT)dnl
 299 AC_SUBST(LINTFLAGS)dnl
 300
 301 dnl try to figure out which one we've got
 302 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 303 NMH_PROG_GNU_LIBTOOL
 304
 305 dnl Check for lorder and tsort commands
 306 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 307 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 308
 309 dnl If either doesn't exist, replace them with echo and cat
 310 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 311   LORDER=echo
 312   TSORT=cat
 313   AC_SUBST(LORDER)dnl
 314   AC_SUBST(TSORT)dnl
 315 dnl Mac OS X has lorder, but sh is too broken for it to work
 316 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 317 dnl   LORDER=echo
 318 dnl   TSORT=cat
 319 dnl   AC_SUBST(LORDER)dnl
 320 dnl   AC_SUBST(TSORT)dnl
 321 fi
 322
 323 dnl Check whether tsort can deal with loops
 324 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 325   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 326     nmh_cv_tsort_loop=no
 327   else
 328     nmh_cv_tsort_loop=yes
 329   fi])
 330 if test x$nmh_cv_tsort_loop = xno ; then
 331   LORDER=echo
 332   TSORT=cat
 333   AC_SUBST(LORDER)dnl
 334   AC_SUBST(TSORT)dnl
 335 fi
 336
 337 dnl Look for `ls'
 338 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 339 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 340
 341 dnl See how we get ls to display the owner and the group
 342 if test "$lspath" != "no"; then
 343   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 344                  nmh_cv_ls_grpopt,
 345   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 346     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 347     dnl ls, it would seem -l gave us both the user and group.  On this type of
 348     dnl ls, -g makes _only_ the group be displayed (and not the user).
 349     nmh_cv_ls_grpopt="-l"
 350   else
 351     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 352     nmh_cv_ls_grpopt="-lg"
 353   fi])
 354 fi
 355
 356 dnl Look for `more'
 357 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 358 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 359
 360 dnl If pager is not specified yet,
 361 dnl then use `more' as the default.
 362 if test -z "$pagerpath"; then
 363   pagerpath="$morepath"
 364 fi
 365 AC_SUBST(pagerpath)dnl
 366
 367 dnl Look for `sendmail'
 368 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 369 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 370
 371 dnl Look for `vi'
 372 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 373 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 374
 375 dnl If editor is not specified yet,
 376 dnl then use `vi' as the default.
 377 if test -z "$editorpath"; then
 378   editorpath="$vipath"
 379 fi
 380 AC_SUBST(editorpath)dnl
 381
 382 dnl ----------------------------------------------------------
 383 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 384 dnl ----------------------------------------------------------
 385 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 386 [for mailspool in /var/mail        dnl
 387                   /var/spool/mail  dnl
 388                   /usr/spool/mail  dnl
 389                   /dev/null;       dnl Just in case we fall through
 390 do
 391   test -d $mailspool && break
 392 done
 393 nmh_cv_mailspool=$mailspool
 394 ])
 395 mailspool=$nmh_cv_mailspool
 396 AC_SUBST(mailspool)dnl
 397
 398 dnl See whether the mail spool directory is world-writable.
 399 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 400   AC_CACHE_CHECK(whether the mail spool is world-writable,
 401                  nmh_cv_mailspool_world_writable,
 402   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 403     nmh_cv_mailspool_world_writable=no
 404   else
 405     nmh_cv_mailspool_world_writable=yes
 406   fi])
 407 fi
 408
 409 dnl Also, check for liblockfile (as found on Debian systems)
 410 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 411
 412 dnl and whether its companion program dotlockfile is setgid
 413 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 414 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 415   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 416     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 417     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 418         nmh_cv_dotlockfile_setgid=yes
 419       else
 420         nmh_cv_dotlockfile_setgid=no
 421       fi])
 422   fi
 423 fi
 424
 425 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 426 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 427 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 428   dnl do we really need both of these?
 429   AC_DEFINE(MAILGROUP,1,
 430     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 431   SETGID_MAIL=1
 432 fi
 433 AC_SUBST(SETGID_MAIL)dnl
 434
 435 dnl Use ls to see which group owns the mail spool directory.
 436 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 437 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 438 ])
 439 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 440 AC_SUBST(MAIL_SPOOL_GRP)dnl
 441
 442 dnl ------------------
 443 dnl CHECK HEADER FILES
 444 dnl ------------------
 445
 446 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 447 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 448 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 449 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 450 dnl declared; if so they should have an entry added to this case statement.
 451 dnl NB that we must define this on the compiler command line, not in config.h,
 452 dnl because it must be set before any system header is included and there's no
 453 dnl portable way to make sure that files generated by lex include config.h
 454 dnl before system header files.
 455
 456 case "$target_os" in
 457   linux*)
 458     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 459     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 460     ;;
 461 esac
 462 AC_SUBST(OURDEFS)
 463
 464 AC_HEADER_DIRENT
 465 AC_HEADER_STDC
 466 AC_HEADER_TIME
 467 AC_HEADER_SYS_WAIT
 468 AC_HEADER_STAT
 469 AC_HEADER_TIOCGWINSZ
 470 AC_CHECK_HEADERS(errno.h fcntl.h crypt.h termcap.h \
 471                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 472                  sys/param.h sys/time.h sys/stream.h arpa/ftp.h)
 473
 474 dnl
 475 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 476 dnl really use a whole set of them, but this check should be
 477 dnl sufficient.
 478 dnl
 479 AC_CHECK_HEADER(libio.h, [
 480   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 481     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 482
 483 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 484   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 485 [[#if HAVE_SYS_STREAM_H
 486 #  include <sys/stream.h>
 487 #endif
 488 ]])
 489
 490 dnl ---------------
 491 dnl CHECK FUNCTIONS
 492 dnl ---------------
 493 AC_FUNC_VFORK
 494 AC_CHECK_LIB(mkstemp,mkstemp)
 495 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 496                sighold sigrelse writev lstat uname tzset mkstemp \
 497                getutent nl_langinfo mbtowc wcwidth)
 498
 499 dnl sigsetjmp may be a macro
 500 AC_MSG_CHECKING(for sigsetjmp)
 501 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 502   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 503     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 504   [AC_MSG_RESULT(no)])
 505
 506 AC_REPLACE_FUNCS(memmove snprintf strerror strdup)
 507
 508 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 509 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 510 dnl any system header.
 511 dnl
 512 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 513 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 514 dnl need to check?
 515 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 516 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 517                 AC_EGREP_HEADER(initgroups, unistd.h,
 518                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 519
 520 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 521 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 522 dnl seems to work perfectly and IBM apparently uses it in internal code).
 523 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 524 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 525 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 526 dnl prototype.
 527 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 528   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 529
 530 dnl Check for multibyte character set support
 531 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 532     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 533   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 534     [Define to enable support for multibyte character sets.])
 535 fi
 536
 537 dnl -------------------
 538 dnl CHECK FOR LIBRARIES
 539 dnl -------------------
 540 dnl Check location of modf
 541 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 542
 543 dnl Checks for network libraries (nsl, socket)
 544 AC_CHECK_NETLIBS
 545
 546 termcap_curses_order="termcap curses ncurses"
 547 for lib in $termcap_curses_order; do
 548   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 549 done
 550 AC_SUBST(TERMLIB)dnl
 551
 552 dnl ---------------
 553 dnl CHECK FOR ICONV
 554 dnl ---------------
 555
 556 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 557 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 558   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 559   if test "x$ac_found_iconv" = "xno"; then
 560     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 561     if test "x$ac_found_iconv" = "xno"; then
 562       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 563     fi
 564     if test "x$ac_found_iconv" != "xno"; then
 565       LIBS="-liconv $LIBS"
 566     fi
 567   else
 568     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 569     AC_CHECK_DECL(_libiconv_version,
 570       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 571       [ #include <iconv.h> ])
 572   fi
 573 fi
 574 if test "x$ac_found_iconv" = xyes; then
 575   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 576 fi
 577
 578 dnl Check if iconv uses const in prototype declaration
 579 if test "x$ac_found_iconv" = "xyes"; then
 580   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 581     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 582         #include <iconv.h>]],
 583         [[#ifdef __cplusplus
 584           "C"
 585           #endif
 586           #if defined(__STDC__) || defined(__cplusplus)
 587           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 588           #else
 589           size_t iconv();
 590           #endif]])],
 591       [ac_cv_iconv_const=],
 592       [ac_cv_iconv_const=const])])
 593   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 594     [Define as const if the declaration of iconv() needs const.])
 595 fi
 596
 597 dnl --------------
 598 dnl CHECK FOR NDBM
 599 dnl --------------
 600
 601 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 602             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 603 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 604             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 605
 606 if test "$nmh_ndbm" = "autodetect"; then
 607   if test "$nmh_ndbmheader" != "autodetect"; then
 608     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 609   else
 610
 611     dnl There are at least four implementations of ndbm, and
 612     dnl several of those can be in different places at the whim
 613     dnl of the system integrator. A good summary of this mess
 614     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 615
 616     dnl Classic ndbm with no library required (eg NetBSD): try this
 617     dnl first so we don't accidentally link in a pointless but harmless
 618     dnl library in one of the later ndbm.h+libfoo tests:
 619     NMH_CHECK_NDBM(ndbm.h,,,
 620     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 621       NMH_CHECK_NDBM(db.h,db,,
 622     dnl Berkeley DBv1 emulating ndbm:
 623         NMH_CHECK_NDBM(ndbm.h,db,,
 624           NMH_CHECK_NDBM(ndbm.h,db1,,
 625     dnl Classic ndbm:
 626             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 627     dnl glibc2.1 systems put db1 in a subdir:
 628               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 629     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 630     dnl and possibly needing gbdm_compat library:
 631                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 632                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 633                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 634                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 635
 636   fi
 637 else
 638   dnl We don't really need to check that the user-specified values work,
 639   dnl but it is a convenience to the user to bomb out early rather than
 640   dnl after configure and half the compile process.
 641   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 642 fi
 643
 644 if test "$nmh_ndbm_found" = "no"; then
 645   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 646 else
 647   dnl Now export the lib/header to our makefile/config.h:
 648   if test x"$nmh_ndbmheader" != x; then
 649     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 650       [Define to the header containing the ndbm API prototypes.])
 651   fi
 652   if test x"$nmh_ndbm" != x; then
 653     NDBM_LIBS="-l$nmh_ndbm"
 654   else
 655     NDBM_LIBS=
 656   fi
 657   AC_SUBST(NDBM_LIBS)
 658 fi
 659
 660 dnl ------------------
 661 dnl Set RPM build root
 662 dnl ------------------
 663 dnl nmhrpm is used in the final summary, see below.  The default value is
 664 dnl reported there as ./RPM, consistent with the reporting of the default
 665 dnl source code location as ., but its absolute path is used in the Makefile.
 666 AC_ARG_WITH(rpmdir,
 667   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 668   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 669           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 670 AC_SUBST(rpmdir)
 671
 672
 673 dnl --------------------
 674 dnl CHECK FOR CYRUS-SASL
 675 dnl --------------------
 676
 677 AS_IF([test x"$sasl_support" = x"yes"],[
 678   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 679   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 680     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 681
 682 dnl -----------------
 683 dnl CHECK FOR OPENSSL
 684 dnl -----------------
 685
 686 AS_IF([test x"$tls_support" = x"yes"],[
 687   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 688   AC_CHECK_LIB([crypto], [BIO_write], ,
 689     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 690   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 691     [AC_MSG_ERROR([OpenSSL library not found])])])
 692
 693 dnl ---------------------
 694 dnl CHECK TERMCAP LIBRARY
 695 dnl ---------------------
 696
 697 dnl Add the termcap library, so that the following configure
 698 dnl tests will find it when it tries to link test programs.
 699 nmh_save_LIBS="$LIBS"
 700 LIBS="$TERMLIB $LIBS"
 701
 702 dnl Checks for external variable ospeed in the termcap library.
 703 AC_CACHE_CHECK(if an include file defines ospeed,
 704 nmh_cv_decl_ospeed_include_defines,
 705 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 706 #if HAVE_TERMIOS_H
 707 #include <termios.h>
 708 #endif
 709 #if HAVE_TERMCAP_H
 710 #include <termcap.h>
 711 #endif]], [[ospeed = 0;]])],
 712 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 713
 714 if test $nmh_cv_decl_ospeed_include_defines = no; then
 715   AC_CACHE_CHECK(if you must define ospeed,
 716   nmh_cv_decl_ospeed_must_define,
 717   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 718   [[extern short ospeed; ospeed = 0;]])],
 719   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 720 fi
 721
 722 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 723 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 724   AC_DEFINE(HAVE_OSPEED)dnl
 725 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 726   AC_DEFINE(HAVE_OSPEED)
 727   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 728     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 729 fi
 730
 731 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 732 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 733 dnl in tgetstr().
 734 dnl Under Cygwin test program crashes but exit code is still 0. So,
 735 dnl we test for a file that porgram should create
 736 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 737 [Define to 1 if tgetent() accepts NULL as a buffer.])
 738 AC_CACHE_CHECK(if tgetent accepts NULL,
 739 nmh_cv_func_tgetent_accepts_null,
 740 [AC_TRY_RUN([
 741 main()
 742 {
 743     char buf[4096];
 744     int r1 = tgetent(buf, "vt100");
 745     int r2 = tgetent((char*)0,"vt100");
 746     if (r1 >= 0 && r1 == r2) {
 747         char tbuf[1024], *u;
 748         u = tbuf;
 749         tgetstr("cl", &u);
 750         creat("conftest.tgetent", 0640);
 751     }
 752     exit((r1 != r2) || r2 == -1);
 753 }
 754 ],
 755   if test -f conftest.tgetent; then
 756     nmh_cv_func_tgetent_accepts_null=yes
 757   else
 758     nmh_cv_func_tgetent_accepts_null=no
 759   fi,
 760   nmh_cv_func_tgetent_accepts_null=no,
 761   nmh_cv_func_tgetent_accepts_null=no)])
 762 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 763   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 764 fi
 765 AC_CACHE_CHECK(if tgetent returns 0 on success,
 766 nmh_cv_func_tgetent_zero_success,
 767 [AC_TRY_RUN([
 768 main()
 769 {
 770     char buf[4096];
 771     int r1 = tgetent(buf, "!@#$%^&*");
 772     int r2 = tgetent(buf, "vt100");
 773     if (r1 < 0 && r2 == 0) {
 774         char tbuf[1024], *u;
 775         u = tbuf;
 776         tgetstr("cl", &u);
 777         creat("conftest.tgetent0", 0640);
 778     }
 779     exit(r1 == r2);
 780 }
 781 ],
 782   if test -f conftest.tgetent0; then
 783     nmh_cv_func_tgetent_zero_success=yes
 784   else
 785     nmh_cv_func_tgetent_zero_success=no
 786   fi,
 787   nmh_cv_func_tgetent_zero_success=no,
 788   nmh_cv_func_tgetent_zero_success=no)])
 789 AH_TEMPLATE([TGETENT_SUCCESS],
 790 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 791 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 792   AC_DEFINE(TGETENT_SUCCESS, 0)
 793 else
 794   AC_DEFINE(TGETENT_SUCCESS, 1)
 795 fi
 796
 797 dnl Now put the libraries back to what it was before we
 798 dnl starting checking the termcap library.
 799 LIBS="$nmh_save_LIBS"
 800
 801 dnl --------------
 802 dnl CHECK TYPEDEFS
 803 dnl --------------
 804 AC_TYPE_SIGNAL
 805 AC_TYPE_PID_T
 806 AC_TYPE_OFF_T
 807 AC_TYPE_UID_T
 808 AC_TYPE_MODE_T
 809 AC_TYPE_SIZE_T
 810
 811 dnl Check for sigset_t.  Currently I'm looking in
 812 dnl <sys/types.h> and <signal.h>.  Others might need
 813 dnl to be added.
 814 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 815 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 816 #include <signal.h>]], [[sigset_t tempsigset;]])],
 817 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 818 if test $nmh_cv_type_sigset_t = no; then
 819   AC_DEFINE(sigset_t, unsigned int,
 820     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 821 fi
 822
 823 dnl ----------------
 824 dnl CHECK STRUCTURES
 825 dnl ----------------
 826 AC_CHECK_MEMBERS(struct stat.st_blksize)
 827
 828 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 829   [#ifdef TIME_WITH_SYS_TIME
 830 # include <sys/time.h>
 831 # include <time.h>
 832 #else
 833 # ifdef TM_IN_SYS_TIME
 834 #  include <sys/time.h>
 835 # else
 836 #  include <time.h>
 837 # endif
 838 #endif])
 839
 840 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 841
 842 AC_MSG_CHECKING(for union wait)
 843 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 844   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 845 #include <sys/wait.h>]],
 846     [[union wait status; int pid; pid = wait (&status);
 847 #ifdef WEXITSTATUS
 848 /* Some POSIXoid systems have both the new-style macros and the old
 849    union wait type, and they do not work together.  If union wait
 850    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 851         if (WEXITSTATUS (status) != 0) pid = -1;
 852 #ifdef WTERMSIG
 853         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 854         -- blow chunks here --
 855 #endif
 856 #endif
 857 #ifdef HAVE_WAITPID
 858         /* Make sure union wait works with waitpid.  */
 859         pid = waitpid (-1, &status, 0);
 860 #endif
 861       ]])],
 862     [nmh_cv_union_wait=yes],
 863     [nmh_cv_union_wait=no])])
 864 if test "$nmh_cv_union_wait" = yes; then
 865   AC_DEFINE(HAVE_UNION_WAIT, 1,
 866     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 867 fi
 868 AC_MSG_RESULT($nmh_cv_union_wait)
 869
 870 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 871
 872 dnl -------------
 873 dnl CHECK SIGNALS
 874 dnl -------------
 875 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 876 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 877 AC_MSG_CHECKING(what style of signals to use)
 878 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 879   signals_style=POSIX_SIGNALS
 880   AC_DEFINE(POSIX_SIGNALS, 1,
 881     [Define to 1 if you use POSIX style signal handling.])
 882   AC_DEFINE(RELIABLE_SIGNALS)
 883 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 884   signals_style=BSD_SIGNALS
 885   AC_DEFINE(BSD_SIGNALS,1,
 886     [Define to 1 if you use BSD style signal handling (and can block signals).])
 887   AC_DEFINE(RELIABLE_SIGNALS)
 888 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 889   signals_style=SYSV_SIGNALS
 890   AC_DEFINE(SYSV_SIGNALS,1,
 891     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 892 else
 893   signals_style=NO_SIGNAL_BLOCKING
 894   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 895     [Define to 1 if you have no signal blocking at all (bummer).])
 896 fi
 897
 898 AC_MSG_RESULT($signals_style)
 899
 900 dnl Where is <signal.h> located?  Needed as input for signames.awk
 901 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 902 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 903                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 904                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 905                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 906                  /usr/include/sys/signal.h      dnl Almost everybody else
 907                  /dev/null;                     dnl Just in case we fall through
 908 do
 909   test -f $SIGNAL_H && \
 910   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 911   break
 912 done
 913 nmh_cv_path_signal_h=$SIGNAL_H
 914 ])
 915 SIGNAL_H=$nmh_cv_path_signal_h
 916 AC_SUBST(SIGNAL_H)dnl
 917
 918 dnl ----------------
 919 dnl OS SPECIFIC DEFINES
 920 dnl ----------------
 921 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 922 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 923 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 924 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 925 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 926
 927 case "$target_os" in
 928
 929   solaris2*)
 930     AC_DEFINE(SYS5)
 931     AC_DEFINE(SVR4)
 932     ;;
 933   irix*)
 934     AC_DEFINE(SYS5)
 935     AC_DEFINE(SVR4)
 936     ;;
 937   osf*)
 938     AC_DEFINE(SYS5)
 939     AC_DEFINE(SVR4)
 940     ;;
 941   aix*)
 942     AC_DEFINE(SYS5)
 943     AC_DEFINE(SVR4)
 944     ;;
 945   sunos4*)
 946     AC_DEFINE(BSD42)
 947     ;;
 948   freebsd*)
 949     AC_DEFINE(BSD42)
 950     AC_DEFINE(BSD44)
 951     ;;
 952   netbsd*)
 953     AC_DEFINE(BSD42)
 954     AC_DEFINE(BSD44)
 955     ;;
 956   openbsd*)
 957     AC_DEFINE(BSD42)
 958     AC_DEFINE(BSD44)
 959     ;;
 960   bsd/os*)
 961     AC_DEFINE(BSD42)
 962     AC_DEFINE(BSD44)
 963     ;;
 964   sco5*)
 965     AC_DEFINE(SYS5)
 966     AC_DEFINE(SCO_5_STDIO)
 967     ;;
 968 esac
 969
 970
 971 dnl ----------------
 972 dnl OUTPUT MAKEFILES
 973 dnl ----------------
 974 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 975                 mts/Makefile mts/smtp/Makefile \
 976                 etc/Makefile docs/Makefile man/Makefile)
 977 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 978 AC_OUTPUT
 979
 980 dnl These odd looking assignments are done to expand out unexpanded
 981 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 982 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 983 dnl again to get the final answer.
 984 dnl We only use the expanded versions to print the install paths in
 985 dnl the final summary and should use them nowhere else (see the autoconf
 986 dnl docs for the rationale for bindir etc being unexpanded).
 987 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 988 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 989 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 990 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 991 eval "nmhrpm=${nmhrpm}";
 992
 993 pop_kinds=no
 994 if test x"$enable_pop" = x"yes"; then
 995   pop_kinds="yes ("
 996
 997   if test x"$enable_apop" = x"yes"; then
 998     pop_kinds="${pop_kinds}APOP "
 999   fi
1000
1001   pop_kinds="${pop_kinds}POP3)"
1002 fi
1003
1004 echo "
1005 nmh configuration
1006 -----------------
1007 nmh version                : AC_PACKAGE_VERSION
1008 target os                  : ${target}
1009 compiler                   : ${CC}
1010 compiler flags             : ${CFLAGS}
1011 linker flags               : ${LDFLAGS}
1012 definitions                : ${OURDEFS}
1013 source code location       : ${srcdir}
1014 binary install path        : ${nmhbin}
1015 library install path       : ${nmhlib}
1016 config files install path  : ${nmhsysconf}
1017 man page install path      : ${nmhman}
1018 RPM build root             : ${nmhrpm}
1019 backup prefix              : ${backup_prefix}
1020 transport system           : ${MTS}
1021 file locking type          : ${LOCKTYPE}
1022 default smtp servers       : ${smtpservers}
1023 default editor             : ${editorpath}
1024 default pager              : ${pagerpath}
1025 email address masquerading : ${masquerade}
1026 pop is enabled             : ${pop_kinds}
1027 SASL support               : ${sasl_support}
1028 TLS support                : ${tls_support}"
1029 echo ""