git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for mmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7 dnl (I was able to configure with autoconf-2.59 --meillo 2012-03-22)
   8
   9 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
  10 AC_CONFIG_SRCDIR(h/nmh.h)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 AC_CANONICAL_TARGET
  14
  15 dnl ---------------------
  16 dnl define a macro or two
  17 dnl ---------------------
  18
  19 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  20 if test -n "$LIBTOOL" ; then
  21   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  22   if test x"$tmptest" != x  ; then
  23     GNU_LIBTOOL=1
  24     AC_SUBST(GNU_LIBTOOL)dnl
  25   fi
  26 fi
  27 ] )
  28
  29 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  30 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  31
  32 dnl What date of mmh are we building?
  33 DATE=`cat ${srcdir}/DATE`
  34 echo "configuring for mmh dated $DATE"
  35 AC_SUBST(DATE)dnl
  36
  37 dnl --------------------------
  38 dnl CHECK COMMAND LINE OPTIONS
  39 dnl --------------------------
  40
  41 dnl Do you want to debug mmh?
  42 AC_ARG_ENABLE(debug,
  43   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  44 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  45 if test x"$enable_nmh_debug" = x"yes"; then
  46   enable_debug=yes
  47 fi
  48
  49 dnl Do you want mhe support?
  50 AC_ARG_ENABLE(mhe,
  51   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  52
  53 dnl mhe support is on by default, so define it unless --disable-mhe or the
  54 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  55 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  56   AC_DEFINE(MHE, 1,
  57     [Define to compile in support for the Emacs front-end mh-e.])dnl
  58 fi
  59
  60 dnl Do you want to disable use of locale functions
  61 AH_TEMPLATE([LOCALE],
  62 [Undefine if you don't want locale features.  By default this is defined.])
  63 AC_ARG_ENABLE([locale],
  64 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  65 [if test x$enableval = xyes; then
  66   AC_DEFINE(LOCALE)
  67 fi],
  68 AC_DEFINE(LOCALE)
  69 )
  70
  71 dnl What method of locking to use?
  72 AC_ARG_WITH(locking,
  73   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  74   [specify the file locking method]))
  75
  76 if test x"$with_locking" = x"dot"; then
  77   LOCKTYPE="dot"
  78   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  79 elif test x"$with_locking" = x"flock"; then
  80   LOCKTYPE="flock"
  81   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  82 elif test x"$with_locking" = x"lockf"; then
  83   LOCKTYPE="lockf"
  84   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  85 elif test x"$with_locking" = x"fcntl"; then
  86   LOCKTYPE="fcntl"
  87   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  88 else
  89   LOCKTYPE="dot"
  90   AC_DEFINE(DOT_LOCKING)dnl
  91 fi
  92
  93
  94 dnl ----------------------------------------------------
  95 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
  96 dnl ----------------------------------------------------
  97 AC_PREFIX_DEFAULT(/usr/local/mmh)
  98
  99
 100 dnl ------------------
 101 dnl CHECK THE COMPILER
 102 dnl ------------------
 103 dnl We want these before the checks,
 104 dnl so the checks can modify their values.
 105 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 106 if test x"$enable_debug" = x"yes"; then
 107   test -z "$LDFLAGS" && LDFLAGS=-g
 108 fi
 109
 110 AC_PROG_CC
 111
 112 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 113 [nmh_saved_cflags="$CFLAGS"
 114  CFLAGS="$CFLAGS -Wno-pointer-sign"
 115  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 116  CFLAGS="$nmh_saved_cflags"])
 117
 118 dnl if the user hasn't specified CFLAGS, then
 119 dnl   if compiler is gcc, then
 120 dnl     use -O2 and some warning flags
 121 dnl   else use -O
 122 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 123 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 124 dnl spurious and which in any case we don't want to deal with now.
 125 if test "$nmh_cv_has_noptrsign" = "yes"; then
 126   nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 127 else
 128   nmh_gcc_warnflags="-Wall"
 129 fi
 130
 131 if test -n "$auto_cflags"; then
 132   if test x"$enable_debug" = x"yes"; then
 133     if test -n "$GCC"; then
 134       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 135     else
 136       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 137     fi
 138   else
 139     if test -z "$LDFLAGS"; then
 140       case "$build_os" in
 141         darwin*)
 142           LDFLAGS=
 143           ;;
 144         *)
 145           LDFLAGS=-s
 146           ;;
 147       esac
 148     fi
 149     if test -n "$GCC"; then
 150       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 151     else
 152       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 153     fi
 154   fi
 155 fi
 156
 157 AC_C_CONST          dnl Does compiler support `const'.
 158
 159 dnl ------------------
 160 dnl CHECK FOR PROGRAMS
 161 dnl ------------------
 162 AC_PROG_MAKE_SET    dnl Does make define $MAKE
 163 AC_PROG_INSTALL     dnl Check for BSD compatible `install'
 164 AC_PROG_RANLIB      dnl Check for `ranlib'
 165 AC_PROG_AWK         dnl Check for mawk,gawk,nawk, then awk
 166 AC_PROG_LEX         dnl Check for lex/flex
 167
 168 dnl Look for `cut'
 169 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 170 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 171
 172 dnl ----------------------------------------------
 173 dnl check for lclint, and lint if it doesn't exist
 174 dnl ----------------------------------------------
 175 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 176 if test x$ac_cv_prog_linttmp1 != xno ; then
 177   LINT=$ac_cv_prog_linttmp1
 178   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 179 else
 180   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 181   if test x$ac_cv_prog_linttmp2 != xno ; then
 182     LINT=$ac_cv_prog_linttmp2
 183     LINTFLAGS=""
 184   else
 185     LINT="echo 'No lint program found'"
 186     LINTFLAGS=""
 187   fi
 188 fi
 189 AC_SUBST(LINT)dnl
 190 AC_SUBST(LINTFLAGS)dnl
 191
 192 dnl try to figure out which one we've got
 193 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 194 NMH_PROG_GNU_LIBTOOL
 195
 196 dnl Check for lorder and tsort commands
 197 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 198 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 199
 200 dnl If either doesn't exist, replace them with echo and cat
 201 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 202   LORDER=echo
 203   TSORT=cat
 204   AC_SUBST(LORDER)dnl
 205   AC_SUBST(TSORT)dnl
 206 dnl Mac OS X has lorder, but sh is too broken for it to work
 207 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 208 dnl   LORDER=echo
 209 dnl   TSORT=cat
 210 dnl   AC_SUBST(LORDER)dnl
 211 dnl   AC_SUBST(TSORT)dnl
 212 fi
 213
 214 dnl Check whether tsort can deal with loops
 215 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 216   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 217     nmh_cv_tsort_loop=no
 218   else
 219     nmh_cv_tsort_loop=yes
 220   fi])
 221 if test x$nmh_cv_tsort_loop = xno ; then
 222   LORDER=echo
 223   TSORT=cat
 224   AC_SUBST(LORDER)dnl
 225   AC_SUBST(TSORT)dnl
 226 fi
 227
 228 dnl Look for `ls'
 229 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 230 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 231
 232 dnl See how we get ls to display the owner and the group
 233 if test "$lspath" != "no"; then
 234   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 235                  nmh_cv_ls_grpopt,
 236   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 237     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 238     dnl ls, it would seem -l gave us both the user and group.  On this type of
 239     dnl ls, -g makes _only_ the group be displayed (and not the user).
 240     nmh_cv_ls_grpopt="-l"
 241   else
 242     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 243     nmh_cv_ls_grpopt="-lg"
 244   fi])
 245 fi
 246
 247 dnl Look for `sendmail'
 248 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 249 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 250
 251 dnl Look for `vi'
 252 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 253 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 254
 255 dnl ----------------------------------------------------------
 256 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 257 dnl ----------------------------------------------------------
 258 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 259 [for mailspool in /var/mail        dnl
 260                   /var/spool/mail  dnl
 261                   /usr/spool/mail  dnl
 262                   /dev/null;       dnl Just in case we fall through
 263 do
 264   test -d $mailspool && break
 265 done
 266 nmh_cv_mailspool=$mailspool
 267 ])
 268 mailspool=$nmh_cv_mailspool
 269 AC_SUBST(mailspool)dnl
 270
 271 dnl See whether the mail spool directory is world-writable.
 272 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 273   AC_CACHE_CHECK(whether the mail spool is world-writable,
 274                  nmh_cv_mailspool_world_writable,
 275   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 276     nmh_cv_mailspool_world_writable=no
 277   else
 278     nmh_cv_mailspool_world_writable=yes
 279   fi])
 280 fi
 281
 282 dnl Also, check for liblockfile (as found on Debian systems)
 283 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 284
 285 dnl and whether its companion program dotlockfile is setgid
 286 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 287 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 288   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 289     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 290     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 291         nmh_cv_dotlockfile_setgid=yes
 292       else
 293         nmh_cv_dotlockfile_setgid=no
 294       fi])
 295   fi
 296 fi
 297
 298 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 299 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 300 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 301   dnl do we really need both of these?
 302   AC_DEFINE(MAILGROUP,1,
 303     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 304   SETGID_MAIL=1
 305 fi
 306 AC_SUBST(SETGID_MAIL)dnl
 307
 308 dnl Use ls to see which group owns the mail spool directory.
 309 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 310 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 311 ])
 312 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 313 AC_SUBST(MAIL_SPOOL_GRP)dnl
 314
 315 dnl ------------------
 316 dnl CHECK HEADER FILES
 317 dnl ------------------
 318
 319 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 320 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 321 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 322 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 323 dnl declared; if so they should have an entry added to this case statement.
 324 dnl NB that we must define this on the compiler command line, not in config.h,
 325 dnl because it must be set before any system header is included and there's no
 326 dnl portable way to make sure that files generated by lex include config.h
 327 dnl before system header files.
 328
 329 case "$target_os" in
 330   linux*)
 331     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 332     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 333     ;;
 334 esac
 335 AC_SUBST(OURDEFS)
 336
 337 AC_HEADER_DIRENT
 338 AC_HEADER_STDC
 339 AC_HEADER_TIME
 340 AC_HEADER_SYS_WAIT
 341 AC_HEADER_STAT
 342 AC_HEADER_TIOCGWINSZ
 343 AC_CHECK_HEADERS(fcntl.h crypt.h termcap.h \
 344                  langinfo.h wchar.h wctype.h iconv.h \
 345                  sys/param.h sys/time.h sys/stream.h )
 346
 347 dnl
 348 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 349 dnl really use a whole set of them, but this check should be
 350 dnl sufficient.
 351 dnl
 352 AC_CHECK_HEADER(libio.h, [
 353   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 354     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 355
 356 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 357   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 358 [[#if HAVE_SYS_STREAM_H
 359 #  include <sys/stream.h>
 360 #endif
 361 ]])
 362
 363 dnl ---------------
 364 dnl CHECK FUNCTIONS
 365 dnl ---------------
 366 AC_CHECK_LIB(mkstemp,mkstemp)
 367 AC_CHECK_FUNCS(waitpid sigaction sigprocmask sigblock sigsetmask \
 368                sighold sigrelse lstat tzset mkstemp \
 369                getutent nl_langinfo mbtowc wcwidth)
 370
 371 dnl sigsetjmp may be a macro
 372 AC_MSG_CHECKING(for sigsetjmp)
 373 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 374   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 375     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 376   [AC_MSG_RESULT(no)])
 377
 378 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 379 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 380 dnl any system header.
 381 dnl
 382 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 383 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 384 dnl need to check?
 385 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 386 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 387                 AC_EGREP_HEADER(initgroups, unistd.h,
 388                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 389
 390 dnl Check for multibyte character set support
 391 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 392     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 393   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 394     [Define to enable support for multibyte character sets.])
 395 fi
 396
 397 dnl -------------------
 398 dnl CHECK FOR LIBRARIES
 399 dnl -------------------
 400 dnl Check location of modf
 401 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 402
 403 dnl Checks for network libraries (nsl, socket)
 404 AC_CHECK_NETLIBS
 405
 406 termcap_curses_order="termcap curses ncurses"
 407 for lib in $termcap_curses_order; do
 408   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 409 done
 410 AC_SUBST(TERMLIB)dnl
 411
 412 dnl ---------------
 413 dnl CHECK FOR ICONV
 414 dnl ---------------
 415
 416 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 417 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 418   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 419   if test "x$ac_found_iconv" = "xno"; then
 420     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 421     if test "x$ac_found_iconv" = "xno"; then
 422       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 423     fi
 424     if test "x$ac_found_iconv" != "xno"; then
 425       LIBS="-liconv $LIBS"
 426     fi
 427   else
 428     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 429     AC_CHECK_DECL(_libiconv_version,
 430       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 431       [ #include <iconv.h> ])
 432   fi
 433 fi
 434 if test "x$ac_found_iconv" = xyes; then
 435   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 436 fi
 437
 438 dnl Check if iconv uses const in prototype declaration
 439 if test "x$ac_found_iconv" = "xyes"; then
 440   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 441     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 442         #include <iconv.h>]],
 443         [[#ifdef __cplusplus
 444           "C"
 445           #endif
 446           #if defined(__STDC__) || defined(__cplusplus)
 447           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 448           #else
 449           size_t iconv();
 450           #endif]])],
 451       [ac_cv_iconv_const=],
 452       [ac_cv_iconv_const=const])])
 453   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 454     [Define as const if the declaration of iconv() needs const.])
 455 fi
 456
 457
 458 dnl ---------------------
 459 dnl CHECK TERMCAP LIBRARY
 460 dnl ---------------------
 461
 462 dnl Add the termcap library, so that the following configure
 463 dnl tests will find it when it tries to link test programs.
 464 nmh_save_LIBS="$LIBS"
 465 LIBS="$TERMLIB $LIBS"
 466
 467 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 468 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 469 dnl in tgetstr().
 470 dnl Under Cygwin test program crashes but exit code is still 0. So,
 471 dnl we test for a file that porgram should create
 472 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 473 [Define to 1 if tgetent() accepts NULL as a buffer.])
 474 AC_CACHE_CHECK(if tgetent accepts NULL,
 475 nmh_cv_func_tgetent_accepts_null,
 476 [AC_TRY_RUN([
 477 main()
 478 {
 479         char buf[4096];
 480         int r1 = tgetent(buf, "vt100");
 481         int r2 = tgetent(NULL,"vt100");
 482         if (r1 >= 0 && r1 == r2) {
 483                 char tbuf[1024], *u;
 484                 u = tbuf;
 485                         tgetstr("cl", &u);
 486                 creat("conftest.tgetent", 0640);
 487         }
 488         exit((r1 != r2) || r2 == -1);
 489 }
 490 ],
 491   if test -f conftest.tgetent; then
 492     nmh_cv_func_tgetent_accepts_null=yes
 493   else
 494     nmh_cv_func_tgetent_accepts_null=no
 495   fi,
 496   nmh_cv_func_tgetent_accepts_null=no,
 497   nmh_cv_func_tgetent_accepts_null=no)])
 498 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 499   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 500 fi
 501 AC_CACHE_CHECK(if tgetent returns 0 on success,
 502 nmh_cv_func_tgetent_zero_success,
 503 [AC_TRY_RUN([
 504 main()
 505 {
 506         char buf[4096];
 507         int r1 = tgetent(buf, "!@#$%^&*");
 508         int r2 = tgetent(buf, "vt100");
 509         if (r1 < 0 && r2 == 0) {
 510                 char tbuf[1024], *u;
 511                 u = tbuf;
 512                         tgetstr("cl", &u);
 513                 creat("conftest.tgetent0", 0640);
 514         }
 515         exit(r1 == r2);
 516 }
 517 ],
 518   if test -f conftest.tgetent0; then
 519     nmh_cv_func_tgetent_zero_success=yes
 520   else
 521     nmh_cv_func_tgetent_zero_success=no
 522   fi,
 523   nmh_cv_func_tgetent_zero_success=no,
 524   nmh_cv_func_tgetent_zero_success=no)])
 525 AH_TEMPLATE([TGETENT_SUCCESS],
 526 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 527 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 528   AC_DEFINE(TGETENT_SUCCESS, 0)
 529 else
 530   AC_DEFINE(TGETENT_SUCCESS, 1)
 531 fi
 532
 533 dnl Now put the libraries back to what it was before we
 534 dnl starting checking the termcap library.
 535 LIBS="$nmh_save_LIBS"
 536
 537 dnl --------------
 538 dnl CHECK TYPEDEFS
 539 dnl --------------
 540 AC_TYPE_SIGNAL
 541 AC_TYPE_PID_T
 542 AC_TYPE_OFF_T
 543 AC_TYPE_UID_T
 544 AC_TYPE_MODE_T
 545 AC_TYPE_SIZE_T
 546
 547 dnl Check for sigset_t.  Currently I'm looking in
 548 dnl <sys/types.h> and <signal.h>.  Others might need
 549 dnl to be added.
 550 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 551 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 552 #include <signal.h>]], [[sigset_t tempsigset;]])],
 553 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 554 if test $nmh_cv_type_sigset_t = no; then
 555   AC_DEFINE(sigset_t, unsigned int,
 556     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 557 fi
 558
 559 dnl ----------------
 560 dnl CHECK STRUCTURES
 561 dnl ----------------
 562 AC_CHECK_MEMBERS(struct stat.st_blksize)
 563
 564 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 565   [#ifdef TIME_WITH_SYS_TIME
 566 # include <sys/time.h>
 567 # include <time.h>
 568 #else
 569 # ifdef TM_IN_SYS_TIME
 570 #  include <sys/time.h>
 571 # else
 572 #  include <time.h>
 573 # endif
 574 #endif])
 575
 576 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 577
 578 AC_MSG_CHECKING(for union wait)
 579 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 580   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 581 #include <sys/wait.h>]],
 582     [[union wait status; int pid; pid = wait (&status);
 583 #ifdef WEXITSTATUS
 584 /* Some POSIXoid systems have both the new-style macros and the old
 585    union wait type, and they do not work together.  If union wait
 586    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 587         if (WEXITSTATUS (status) != 0) pid = -1;
 588 #ifdef WTERMSIG
 589         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 590         -- blow chunks here --
 591 #endif
 592 #endif
 593 #ifdef HAVE_WAITPID
 594         /* Make sure union wait works with waitpid.  */
 595         pid = waitpid (-1, &status, 0);
 596 #endif
 597       ]])],
 598     [nmh_cv_union_wait=yes],
 599     [nmh_cv_union_wait=no])])
 600 if test "$nmh_cv_union_wait" = yes; then
 601   AC_DEFINE(HAVE_UNION_WAIT, 1,
 602     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 603 fi
 604 AC_MSG_RESULT($nmh_cv_union_wait)
 605
 606 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 607
 608 dnl -------------
 609 dnl CHECK SIGNALS
 610 dnl -------------
 611 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 612 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 613 AC_MSG_CHECKING(what style of signals to use)
 614 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 615   signals_style=POSIX_SIGNALS
 616   AC_DEFINE(POSIX_SIGNALS, 1,
 617     [Define to 1 if you use POSIX style signal handling.])
 618   AC_DEFINE(RELIABLE_SIGNALS)
 619 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 620   signals_style=BSD_SIGNALS
 621   AC_DEFINE(BSD_SIGNALS,1,
 622     [Define to 1 if you use BSD style signal handling (and can block signals).])
 623   AC_DEFINE(RELIABLE_SIGNALS)
 624 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 625   signals_style=SYSV_SIGNALS
 626   AC_DEFINE(SYSV_SIGNALS,1,
 627     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 628 else
 629   signals_style=NO_SIGNAL_BLOCKING
 630   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 631     [Define to 1 if you have no signal blocking at all (bummer).])
 632 fi
 633
 634 AC_MSG_RESULT($signals_style)
 635
 636 dnl Where is <signal.h> located?  Needed as input for signames.awk
 637 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 638 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 639                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 640                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 641                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 642                  /usr/include/sys/signal.h      dnl Almost everybody else
 643                  /dev/null;                     dnl Just in case we fall through
 644 do
 645   test -f $SIGNAL_H && \
 646   grep '#[         ]*define[         ][         ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 647   break
 648 done
 649 nmh_cv_path_signal_h=$SIGNAL_H
 650 ])
 651 SIGNAL_H=$nmh_cv_path_signal_h
 652 AC_SUBST(SIGNAL_H)dnl
 653
 654 dnl ----------------
 655 dnl OS SPECIFIC DEFINES
 656 dnl ----------------
 657 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 658 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 659
 660 case "$target_os" in
 661
 662   sunos4*)
 663     AC_DEFINE(BSD42)
 664     ;;
 665   freebsd*)
 666     AC_DEFINE(BSD42)
 667     ;;
 668   netbsd*)
 669     AC_DEFINE(BSD42)
 670     ;;
 671   openbsd*)
 672     AC_DEFINE(BSD42)
 673     ;;
 674   bsd/os*)
 675     AC_DEFINE(BSD42)
 676     ;;
 677   sco5*)
 678     AC_DEFINE(SCO_5_STDIO)
 679     ;;
 680 esac
 681
 682
 683 dnl ----------------
 684 dnl OUTPUT MAKEFILES
 685 dnl ----------------
 686 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 687                 etc/Makefile docs/Makefile man/Makefile)
 688 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 689 AC_OUTPUT
 690
 691 dnl These odd looking assignments are done to expand out unexpanded
 692 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 693 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 694 dnl again to get the final answer.
 695 dnl We only use the expanded versions to print the install paths in
 696 dnl the final summary and should use them nowhere else (see the autoconf
 697 dnl docs for the rationale for bindir etc being unexpanded).
 698 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 699 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 700 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 701 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 702
 703 echo "
 704 mmh configuration
 705 -----------------
 706 mmh version            : AC_PACKAGE_VERSION
 707 target os              : ${target}
 708 compiler               : ${CC}
 709 compiler flags         : ${CFLAGS}
 710 linker flags           : ${LDFLAGS}
 711 definitions            : ${OURDEFS}
 712 source code location   : ${srcdir}
 713
 714 binary install path    : ${nmhbin}
 715 library install path   : ${nmhlib}
 716 config install path    : ${nmhsysconf}
 717 man page install path  : ${nmhman}
 718
 719 sendmail path          : ${sendmailpath}
 720 mail spool             : ${mailspool}
 721
 722 file locking type      : ${LOCKTYPE}
 723 "