git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for mmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7 dnl (I was able to configure with autoconf-2.59 --meillo 2012-03-22)
   8
   9 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
  10 AC_CONFIG_SRCDIR(h/mh.h)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 AC_CANONICAL_TARGET
  14
  15 dnl ---------------------
  16 dnl define a macro or two
  17 dnl ---------------------
  18
  19 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  20 if test -n "$LIBTOOL" ; then
  21   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  22   if test x"$tmptest" != x  ; then
  23     GNU_LIBTOOL=1
  24     AC_SUBST(GNU_LIBTOOL)dnl
  25   fi
  26 fi
  27 ] )
  28
  29 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  30 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  31
  32 dnl What date of mmh are we building?
  33 DATE=`cat ${srcdir}/DATE`
  34 echo "configuring for mmh dated $DATE"
  35 AC_SUBST(DATE)dnl
  36
  37 dnl --------------------------
  38 dnl CHECK COMMAND LINE OPTIONS
  39 dnl --------------------------
  40
  41 dnl Do you want to debug mmh?
  42 AC_ARG_ENABLE(debug,
  43   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  44 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  45 if test x"$enable_nmh_debug" = x"yes"; then
  46   enable_debug=yes
  47 fi
  48
  49 dnl What method of locking to use?
  50 AC_ARG_WITH(locking,
  51   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  52   [specify the file locking method]))
  53
  54 if test x"$with_locking" = x"dot"; then
  55   LOCKTYPE="dot"
  56   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  57 elif test x"$with_locking" = x"flock"; then
  58   LOCKTYPE="flock"
  59   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  60 elif test x"$with_locking" = x"lockf"; then
  61   LOCKTYPE="lockf"
  62   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  63 elif test x"$with_locking" = x"fcntl"; then
  64   LOCKTYPE="fcntl"
  65   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  66 else
  67   LOCKTYPE="dot"
  68   AC_DEFINE(DOT_LOCKING)dnl
  69 fi
  70
  71
  72 dnl ----------------------------------------------------
  73 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
  74 dnl ----------------------------------------------------
  75 AC_PREFIX_DEFAULT(/usr/local/mmh)
  76
  77
  78 dnl ------------------
  79 dnl CHECK THE COMPILER
  80 dnl ------------------
  81 dnl We want these before the checks,
  82 dnl so the checks can modify their values.
  83 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
  84 if test x"$enable_debug" = x"yes"; then
  85   test -z "$LDFLAGS" && LDFLAGS=-g
  86 fi
  87
  88 AC_PROG_CC
  89
  90 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
  91 [nmh_saved_cflags="$CFLAGS"
  92  CFLAGS="$CFLAGS -Wno-pointer-sign"
  93  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
  94  CFLAGS="$nmh_saved_cflags"])
  95
  96 dnl if the user hasn't specified CFLAGS, then
  97 dnl   if compiler is gcc, then
  98 dnl     use -O2 and some warning flags
  99 dnl   else use -O
 100 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 101 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 102 dnl spurious and which in any case we don't want to deal with now.
 103 if test "$nmh_cv_has_noptrsign" = "yes"; then
 104   nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 105 else
 106   nmh_gcc_warnflags="-Wall"
 107 fi
 108
 109 if test -n "$auto_cflags"; then
 110   if test x"$enable_debug" = x"yes"; then
 111     if test -n "$GCC"; then
 112       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 113     else
 114       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 115     fi
 116   else
 117     if test -z "$LDFLAGS"; then
 118       case "$build_os" in
 119         darwin*)
 120           LDFLAGS=
 121           ;;
 122         *)
 123           LDFLAGS=-s
 124           ;;
 125       esac
 126     fi
 127     if test -n "$GCC"; then
 128       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 129     else
 130       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 131     fi
 132   fi
 133 fi
 134
 135 AC_C_CONST          dnl Does compiler support `const'.
 136
 137 dnl ------------------
 138 dnl CHECK FOR PROGRAMS
 139 dnl ------------------
 140 AC_PROG_MAKE_SET    dnl Does make define $MAKE
 141 AC_PROG_INSTALL     dnl Check for BSD compatible `install'
 142 AC_PROG_RANLIB      dnl Check for `ranlib'
 143 AC_PROG_AWK         dnl Check for mawk,gawk,nawk, then awk
 144 AC_PROG_LEX         dnl Check for lex/flex
 145
 146 dnl Look for `cut'
 147 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 148 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 149
 150 dnl ----------------------------------------------
 151 dnl check for lclint, and lint if it doesn't exist
 152 dnl ----------------------------------------------
 153 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 154 if test x$ac_cv_prog_linttmp1 != xno ; then
 155   LINT=$ac_cv_prog_linttmp1
 156   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 157 else
 158   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 159   if test x$ac_cv_prog_linttmp2 != xno ; then
 160     LINT=$ac_cv_prog_linttmp2
 161     LINTFLAGS=""
 162   else
 163     LINT="echo 'No lint program found'"
 164     LINTFLAGS=""
 165   fi
 166 fi
 167 AC_SUBST(LINT)dnl
 168 AC_SUBST(LINTFLAGS)dnl
 169
 170 dnl try to figure out which one we've got
 171 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 172 NMH_PROG_GNU_LIBTOOL
 173
 174 dnl Check for lorder and tsort commands
 175 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 176 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 177
 178 dnl If either doesn't exist, replace them with echo and cat
 179 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 180   LORDER=echo
 181   TSORT=cat
 182   AC_SUBST(LORDER)dnl
 183   AC_SUBST(TSORT)dnl
 184 dnl Mac OS X has lorder, but sh is too broken for it to work
 185 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 186 dnl   LORDER=echo
 187 dnl   TSORT=cat
 188 dnl   AC_SUBST(LORDER)dnl
 189 dnl   AC_SUBST(TSORT)dnl
 190 fi
 191
 192 dnl Check whether tsort can deal with loops
 193 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 194   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 195     nmh_cv_tsort_loop=no
 196   else
 197     nmh_cv_tsort_loop=yes
 198   fi])
 199 if test x$nmh_cv_tsort_loop = xno ; then
 200   LORDER=echo
 201   TSORT=cat
 202   AC_SUBST(LORDER)dnl
 203   AC_SUBST(TSORT)dnl
 204 fi
 205
 206 dnl Look for `ls'
 207 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 208 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 209
 210 dnl See how we get ls to display the owner and the group
 211 if test "$lspath" != "no"; then
 212   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 213                  nmh_cv_ls_grpopt,
 214   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 215     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 216     dnl ls, it would seem -l gave us both the user and group.  On this type of
 217     dnl ls, -g makes _only_ the group be displayed (and not the user).
 218     nmh_cv_ls_grpopt="-l"
 219   else
 220     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 221     nmh_cv_ls_grpopt="-lg"
 222   fi])
 223 fi
 224
 225 dnl Look for `sendmail'
 226 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 227 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 228
 229 dnl Look for `vi'
 230 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 231 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 232
 233 dnl ----------------------------------------------------------
 234 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 235 dnl ----------------------------------------------------------
 236 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 237 [for mailspool in /var/mail        dnl
 238                   /var/spool/mail  dnl
 239                   /usr/spool/mail  dnl
 240                   /dev/null;       dnl Just in case we fall through
 241 do
 242   test -d $mailspool && break
 243 done
 244 nmh_cv_mailspool=$mailspool
 245 ])
 246 mailspool=$nmh_cv_mailspool
 247 AC_SUBST(mailspool)dnl
 248
 249 dnl See whether the mail spool directory is world-writable.
 250 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 251   AC_CACHE_CHECK(whether the mail spool is world-writable,
 252                  nmh_cv_mailspool_world_writable,
 253   [if test "`$lspath -dl $mailspool/ | $cutpath -c9`" = "-"; then
 254     nmh_cv_mailspool_world_writable=no
 255   else
 256     nmh_cv_mailspool_world_writable=yes
 257   fi])
 258 fi
 259
 260 dnl Also, check for liblockfile (as found on Debian systems)
 261 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 262
 263 dnl and whether its companion program dotlockfile is setgid
 264 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 265 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 266   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 267     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 268     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 269         nmh_cv_dotlockfile_setgid=yes
 270       else
 271         nmh_cv_dotlockfile_setgid=no
 272       fi])
 273   fi
 274 fi
 275
 276 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 277 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 278 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 279   dnl do we really need both of these?
 280   AC_DEFINE(MAILGROUP,1,
 281     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 282   SETGID_MAIL=1
 283 fi
 284 AC_SUBST(SETGID_MAIL)dnl
 285
 286 dnl Use ls to see which group owns the mail spool directory.
 287 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 288 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 289 ])
 290 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 291 AC_SUBST(MAIL_SPOOL_GRP)dnl
 292
 293 dnl ------------------
 294 dnl CHECK HEADER FILES
 295 dnl ------------------
 296
 297 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 298 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 299 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 300 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 301 dnl declared; if so they should have an entry added to this case statement.
 302 dnl NB that we must define this on the compiler command line, not in config.h,
 303 dnl because it must be set before any system header is included and there's no
 304 dnl portable way to make sure that files generated by lex include config.h
 305 dnl before system header files.
 306
 307 case "$target_os" in
 308   linux*)
 309     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 310     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 311     ;;
 312 esac
 313 AC_SUBST(OURDEFS)
 314
 315 AC_HEADER_STDC
 316 AC_HEADER_TIOCGWINSZ
 317 AC_CHECK_HEADERS(fcntl.h crypt.h termcap.h \
 318                  langinfo.h wchar.h wctype.h iconv.h \
 319                  sys/param.h sys/time.h sys/stream.h )
 320
 321 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 322   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 323 [[#if HAVE_SYS_STREAM_H
 324 #  include <sys/stream.h>
 325 #endif
 326 ]])
 327
 328 dnl ---------------
 329 dnl CHECK FUNCTIONS
 330 dnl ---------------
 331 AC_CHECK_FUNCS(nl_langinfo mbtowc wcwidth)
 332
 333 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 334 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 335 dnl any system header.
 336 dnl
 337 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 338 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 339 dnl need to check?
 340 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 341 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 342                 AC_EGREP_HEADER(initgroups, unistd.h,
 343                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 344
 345 dnl Check for multibyte character set support
 346 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 347     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 348   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 349     [Define to enable support for multibyte character sets.])
 350 fi
 351
 352 dnl -------------------
 353 dnl CHECK FOR LIBRARIES
 354 dnl -------------------
 355 dnl Check location of modf
 356 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 357
 358 dnl Checks for network libraries (nsl, socket)
 359 NMH_CHECK_NETLIBS
 360
 361 termcap_curses_order="termcap curses ncurses"
 362 for lib in $termcap_curses_order; do
 363   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 364 done
 365 AC_SUBST(TERMLIB)dnl
 366 if test "x$TERMLIB" = "x"; then
 367         echo 'Could not find tgetent() in any library.'
 368         echo 'Is there a ncurses-devel package that you can install?'
 369         exit 1
 370 fi
 371
 372
 373 dnl ---------------
 374 dnl CHECK FOR ICONV
 375 dnl ---------------
 376
 377 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 378 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 379   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 380   if test "x$ac_found_iconv" = "xno"; then
 381     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 382     if test "x$ac_found_iconv" = "xno"; then
 383       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 384     fi
 385     if test "x$ac_found_iconv" != "xno"; then
 386       LIBS="-liconv $LIBS"
 387     fi
 388   else
 389     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 390     AC_CHECK_DECL(_libiconv_version,
 391       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 392       [ #include <iconv.h> ])
 393   fi
 394 fi
 395 if test "x$ac_found_iconv" = xyes; then
 396   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 397 fi
 398
 399 dnl Check if iconv uses const in prototype declaration
 400 if test "x$ac_found_iconv" = "xyes"; then
 401   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 402     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 403         #include <iconv.h>]],
 404         [[#ifdef __cplusplus
 405           "C"
 406           #endif
 407           #if defined(__STDC__) || defined(__cplusplus)
 408           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 409           #else
 410           size_t iconv();
 411           #endif]])],
 412       [ac_cv_iconv_const=],
 413       [ac_cv_iconv_const=const])])
 414   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 415     [Define as const if the declaration of iconv() needs const.])
 416 fi
 417
 418
 419 dnl ---------------------
 420 dnl CHECK TERMCAP LIBRARY
 421 dnl ---------------------
 422
 423 dnl Add the termcap library, so that the following configure
 424 dnl tests will find it when it tries to link test programs.
 425 nmh_save_LIBS="$LIBS"
 426 LIBS="$TERMLIB $LIBS"
 427
 428 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 429 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 430 dnl in tgetstr().
 431 dnl Under Cygwin test program crashes but exit code is still 0. So,
 432 dnl we test for a file that porgram should create
 433 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 434 [Define to 1 if tgetent() accepts NULL as a buffer.])
 435 AC_CACHE_CHECK(if tgetent accepts NULL,
 436 nmh_cv_func_tgetent_accepts_null,
 437 [AC_TRY_RUN([
 438 main()
 439 {
 440         char buf[4096];
 441         int r1 = tgetent(buf, "vt100");
 442         int r2 = tgetent(NULL,"vt100");
 443         if (r1 >= 0 && r1 == r2) {
 444                 char tbuf[1024], *u;
 445                 u = tbuf;
 446                         tgetstr("cl", &u);
 447                 creat("conftest.tgetent", 0640);
 448         }
 449         exit((r1 != r2) || r2 == -1);
 450 }
 451 ],
 452   if test -f conftest.tgetent; then
 453     nmh_cv_func_tgetent_accepts_null=yes
 454   else
 455     nmh_cv_func_tgetent_accepts_null=no
 456   fi,
 457   nmh_cv_func_tgetent_accepts_null=no,
 458   nmh_cv_func_tgetent_accepts_null=no)])
 459 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 460   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 461 fi
 462 AC_CACHE_CHECK(if tgetent returns 0 on success,
 463 nmh_cv_func_tgetent_zero_success,
 464 [AC_TRY_RUN([
 465 main()
 466 {
 467         char buf[4096];
 468         int r1 = tgetent(buf, "!@#$%^&*");
 469         int r2 = tgetent(buf, "vt100");
 470         if (r1 < 0 && r2 == 0) {
 471                 char tbuf[1024], *u;
 472                 u = tbuf;
 473                         tgetstr("cl", &u);
 474                 creat("conftest.tgetent0", 0640);
 475         }
 476         exit(r1 == r2);
 477 }
 478 ],
 479   if test -f conftest.tgetent0; then
 480     nmh_cv_func_tgetent_zero_success=yes
 481   else
 482     nmh_cv_func_tgetent_zero_success=no
 483   fi,
 484   nmh_cv_func_tgetent_zero_success=no,
 485   nmh_cv_func_tgetent_zero_success=no)])
 486 AH_TEMPLATE([TGETENT_SUCCESS],
 487 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 488 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 489   AC_DEFINE(TGETENT_SUCCESS, 0)
 490 else
 491   AC_DEFINE(TGETENT_SUCCESS, 1)
 492 fi
 493
 494 dnl Now put the libraries back to what it was before we
 495 dnl starting checking the termcap library.
 496 LIBS="$nmh_save_LIBS"
 497
 498 dnl --------------
 499 dnl CHECK TYPEDEFS
 500 dnl --------------
 501 AC_TYPE_PID_T
 502 AC_TYPE_OFF_T
 503 AC_TYPE_UID_T
 504 AC_TYPE_MODE_T
 505 AC_TYPE_SIZE_T
 506
 507 dnl ----------------
 508 dnl CHECK STRUCTURES
 509 dnl ----------------
 510
 511 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 512 dnl (FreeBSD has a timezone() function but not a timezone global
 513 dnl variable that is visible).
 514 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 515
 516 AC_STRUCT_DIRENT_D_TYPE
 517
 518 dnl Where is <signal.h> located?  Needed as input for signames.awk
 519 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 520 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 521                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 522                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 523                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 524                  /usr/include/sys/signal.h      dnl Almost everybody else
 525                  /dev/null;                     dnl Just in case we fall through
 526 do
 527   test -f $SIGNAL_H && \
 528   grep '#[         ]*define[         ][         ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 529   break
 530 done
 531 nmh_cv_path_signal_h=$SIGNAL_H
 532 ])
 533 SIGNAL_H=$nmh_cv_path_signal_h
 534 AC_SUBST(SIGNAL_H)dnl
 535
 536
 537 dnl ----------------
 538 dnl OUTPUT MAKEFILES
 539 dnl ----------------
 540 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 541                 etc/Makefile docs/Makefile man/Makefile)
 542 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 543 AC_OUTPUT
 544
 545 dnl These odd looking assignments are done to expand out unexpanded
 546 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 547 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 548 dnl again to get the final answer.
 549 dnl We only use the expanded versions to print the install paths in
 550 dnl the final summary and should use them nowhere else (see the autoconf
 551 dnl docs for the rationale for bindir etc being unexpanded).
 552 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 553 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 554 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 555 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 556
 557 echo "
 558 mmh configuration
 559 -----------------
 560 mmh version            : AC_PACKAGE_VERSION
 561 target os              : ${target}
 562 compiler               : ${CC}
 563 compiler flags         : ${CFLAGS}
 564 linker flags           : ${LDFLAGS}
 565 definitions            : ${OURDEFS}
 566 source code location   : ${srcdir}
 567
 568 binary install path    : ${nmhbin}
 569 library install path   : ${nmhlib}
 570 config install path    : ${nmhsysconf}
 571 man page install path  : ${nmhman}
 572
 573 sendmail path          : ${sendmailpath}
 574 mail spool             : ${mailspool}
 575
 576 file locking type      : ${LOCKTYPE}
 577 "