9fd84c85228e64697fee89db630321a2c84e5c15
[mmh] / configure.ac
1 dnl
2 dnl configure.ac -- autoconf template for mmh
3 dnl
4
5 dnl Move this up a bit
6 AC_PREREQ(2.61)
7 dnl (I was able to configure with autoconf-2.59 --meillo 2012-03-22)
8
9 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
10 AC_CONFIG_SRCDIR(h/nmh.h)
11 AC_CONFIG_HEADER(config.h)
12
13 AC_CANONICAL_TARGET
14
15 dnl ---------------------
16 dnl define a macro or two
17 dnl ---------------------
18
19 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
20 if test -n "$LIBTOOL" ; then
21   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
22   if test x"$tmptest" != x  ; then
23     GNU_LIBTOOL=1
24     AC_SUBST(GNU_LIBTOOL)dnl
25   fi
26 fi
27 ] )
28
29 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
30 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
31
32 dnl What date of mmh are we building?
33 DATE=`cat ${srcdir}/DATE`
34 echo "configuring for mmh dated $DATE"
35 AC_SUBST(DATE)dnl
36
37 dnl --------------------------
38 dnl CHECK COMMAND LINE OPTIONS
39 dnl --------------------------
40
41 dnl Do you want to debug mmh?
42 AC_ARG_ENABLE(debug,
43   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
44 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
45 if test x"$enable_nmh_debug" = x"yes"; then
46   enable_debug=yes
47 fi
48
49 dnl Do you want mhe support?
50 AC_ARG_ENABLE(mhe,
51   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
52
53 dnl mhe support is on by default, so define it unless --disable-mhe or the
54 dnl deprecated, undocumented --disable-nmh-mhe are specified.
55 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
56   AC_DEFINE(MHE, 1,
57     [Define to compile in support for the Emacs front-end mh-e.])dnl
58 fi
59
60 dnl Do you want to disable use of locale functions
61 AH_TEMPLATE([LOCALE],
62 [Undefine if you don't want locale features.  By default this is defined.])
63 AC_ARG_ENABLE([locale],
64 AC_HELP_STRING([--disable-locale], [turn off locale features]),
65 [if test x$enableval = xyes; then
66   AC_DEFINE(LOCALE)
67 fi],
68 AC_DEFINE(LOCALE)
69 )
70
71 dnl What method of locking to use?
72 AC_ARG_WITH(locking,
73   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
74   [specify the file locking method]))
75
76 if test x"$with_locking" = x"dot"; then
77   LOCKTYPE="dot"
78   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
79 elif test x"$with_locking" = x"flock"; then
80   LOCKTYPE="flock"
81   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
82 elif test x"$with_locking" = x"lockf"; then
83   LOCKTYPE="lockf"
84   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
85 elif test x"$with_locking" = x"fcntl"; then
86   LOCKTYPE="fcntl"
87   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
88 else
89   LOCKTYPE="dot"
90   AC_DEFINE(DOT_LOCKING)dnl
91 fi
92
93
94 dnl ----------------------------------------------------
95 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
96 dnl ----------------------------------------------------
97 AC_PREFIX_DEFAULT(/usr/local/mmh)
98
99
100 dnl ------------------
101 dnl CHECK THE COMPILER
102 dnl ------------------
103 dnl We want these before the checks,
104 dnl so the checks can modify their values.
105 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
106 if test x"$enable_debug" = x"yes"; then
107   test -z "$LDFLAGS" && LDFLAGS=-g
108 fi
109
110 AC_PROG_CC
111
112 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
113 [nmh_saved_cflags="$CFLAGS"
114  CFLAGS="$CFLAGS -Wno-pointer-sign"
115  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
116  CFLAGS="$nmh_saved_cflags"])
117
118 dnl if the user hasn't specified CFLAGS, then
119 dnl   if compiler is gcc, then
120 dnl     use -O2 and some warning flags
121 dnl   else use -O
122 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
123 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
124 dnl spurious and which in any case we don't want to deal with now.
125 if test "$nmh_cv_has_noptrsign" = "yes"; then
126   nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
127 else
128   nmh_gcc_warnflags="-Wall"
129 fi
130
131 if test -n "$auto_cflags"; then
132   if test x"$enable_debug" = x"yes"; then
133     if test -n "$GCC"; then
134       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
135     else
136       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
137     fi
138   else
139     if test -z "$LDFLAGS"; then
140       case "$build_os" in
141         darwin*)
142           LDFLAGS=
143           ;;
144         *)
145           LDFLAGS=-s
146           ;;
147       esac
148     fi
149     if test -n "$GCC"; then
150       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
151     else
152       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
153     fi
154   fi
155 fi
156
157 AC_C_CONST          dnl Does compiler support `const'.
158
159 dnl ------------------
160 dnl CHECK FOR PROGRAMS
161 dnl ------------------
162 AC_PROG_MAKE_SET    dnl Does make define $MAKE
163 AC_PROG_INSTALL     dnl Check for BSD compatible `install'
164 AC_PROG_RANLIB      dnl Check for `ranlib'
165 AC_PROG_AWK         dnl Check for mawk,gawk,nawk, then awk
166 AC_PROG_LEX         dnl Check for lex/flex
167
168 dnl Look for `cut'
169 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
170 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
171
172 dnl ----------------------------------------------
173 dnl check for lclint, and lint if it doesn't exist
174 dnl ----------------------------------------------
175 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
176 if test x$ac_cv_prog_linttmp1 != xno ; then
177   LINT=$ac_cv_prog_linttmp1
178   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
179 else
180   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
181   if test x$ac_cv_prog_linttmp2 != xno ; then
182     LINT=$ac_cv_prog_linttmp2
183     LINTFLAGS=""
184   else
185     LINT="echo 'No lint program found'"
186     LINTFLAGS=""
187   fi
188 fi
189 AC_SUBST(LINT)dnl
190 AC_SUBST(LINTFLAGS)dnl
191
192 dnl try to figure out which one we've got
193 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
194 NMH_PROG_GNU_LIBTOOL
195
196 dnl Check for lorder and tsort commands
197 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
198 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
199
200 dnl If either doesn't exist, replace them with echo and cat
201 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
202   LORDER=echo
203   TSORT=cat
204   AC_SUBST(LORDER)dnl
205   AC_SUBST(TSORT)dnl
206 dnl Mac OS X has lorder, but sh is too broken for it to work
207 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
208 dnl   LORDER=echo
209 dnl   TSORT=cat
210 dnl   AC_SUBST(LORDER)dnl
211 dnl   AC_SUBST(TSORT)dnl
212 fi
213
214 dnl Check whether tsort can deal with loops
215 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
216   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
217     nmh_cv_tsort_loop=no
218   else
219     nmh_cv_tsort_loop=yes
220   fi])
221 if test x$nmh_cv_tsort_loop = xno ; then
222   LORDER=echo
223   TSORT=cat
224   AC_SUBST(LORDER)dnl
225   AC_SUBST(TSORT)dnl
226 fi
227
228 dnl Look for `ls'
229 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
230 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
231
232 dnl See how we get ls to display the owner and the group
233 if test "$lspath" != "no"; then
234   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
235                  nmh_cv_ls_grpopt,
236   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
237     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
238     dnl ls, it would seem -l gave us both the user and group.  On this type of
239     dnl ls, -g makes _only_ the group be displayed (and not the user).
240     nmh_cv_ls_grpopt="-l"
241   else
242     dnl Looks like -l only gave us the user, so we need -g to get the group too.
243     nmh_cv_ls_grpopt="-lg"
244   fi])
245 fi
246
247 dnl Look for `sendmail'
248 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
249 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
250
251 dnl Look for `vi'
252 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
253 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
254
255 dnl ----------------------------------------------------------
256 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
257 dnl ----------------------------------------------------------
258 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
259 [for mailspool in /var/mail        dnl
260                   /var/spool/mail  dnl
261                   /usr/spool/mail  dnl
262                   /dev/null;       dnl Just in case we fall through
263 do
264   test -d $mailspool && break
265 done
266 nmh_cv_mailspool=$mailspool
267 ])
268 mailspool=$nmh_cv_mailspool
269 AC_SUBST(mailspool)dnl
270
271 dnl See whether the mail spool directory is world-writable.
272 if test "$lspath" != "no" -a "$cutpath" != "no"; then
273   AC_CACHE_CHECK(whether the mail spool is world-writable,
274                  nmh_cv_mailspool_world_writable,
275   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
276     nmh_cv_mailspool_world_writable=no
277   else
278     nmh_cv_mailspool_world_writable=yes
279   fi])
280 fi
281
282 dnl Also, check for liblockfile (as found on Debian systems)
283 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
284
285 dnl and whether its companion program dotlockfile is setgid
286 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
287 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
288   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
289     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
290     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
291         nmh_cv_dotlockfile_setgid=yes
292       else
293         nmh_cv_dotlockfile_setgid=no
294       fi])
295   fi
296 fi
297
298 dnl If mailspool is not world-writable and dotlockfile is not setgid,
299 dnl we need to #define MAILGROUP to 1 and make inc setgid.
300 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
301   dnl do we really need both of these?
302   AC_DEFINE(MAILGROUP,1,
303     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
304   SETGID_MAIL=1
305 fi
306 AC_SUBST(SETGID_MAIL)dnl
307
308 dnl Use ls to see which group owns the mail spool directory.
309 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
310 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
311 ])
312 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
313 AC_SUBST(MAIL_SPOOL_GRP)dnl
314
315 dnl ------------------
316 dnl CHECK HEADER FILES
317 dnl ------------------
318
319 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
320 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
321 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
322 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
323 dnl declared; if so they should have an entry added to this case statement.
324 dnl NB that we must define this on the compiler command line, not in config.h,
325 dnl because it must be set before any system header is included and there's no
326 dnl portable way to make sure that files generated by lex include config.h
327 dnl before system header files.
328
329 case "$target_os" in
330   linux*)
331     # Like DEFS, but doesn't get stomped on by configure when using config.h:
332     OURDEFS="$OURDEFS -D_GNU_SOURCE"
333     ;;
334 esac
335 AC_SUBST(OURDEFS)
336
337 AC_HEADER_DIRENT
338 AC_HEADER_STDC
339 AC_HEADER_TIME
340 AC_HEADER_STAT
341 AC_HEADER_TIOCGWINSZ
342 AC_CHECK_HEADERS(fcntl.h crypt.h termcap.h \
343                  langinfo.h wchar.h wctype.h iconv.h \
344                  sys/param.h sys/time.h sys/stream.h )
345
346 dnl
347 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
348 dnl really use a whole set of them, but this check should be
349 dnl sufficient.
350 dnl
351 AC_CHECK_HEADER(libio.h, [
352   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
353     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
354
355 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
356   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
357 [[#if HAVE_SYS_STREAM_H
358 #  include <sys/stream.h>
359 #endif
360 ]])
361
362 dnl ---------------
363 dnl CHECK FUNCTIONS
364 dnl ---------------
365 AC_CHECK_FUNCS(sigaction sigprocmask sigblock sigsetmask \
366                sighold sigrelse lstat tzset \
367                getutent nl_langinfo mbtowc wcwidth)
368
369 dnl sigsetjmp may be a macro
370 AC_MSG_CHECKING(for sigsetjmp)
371 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
372   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
373     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
374   [AC_MSG_RESULT(no)])
375
376 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
377 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
378 dnl any system header.
379 dnl
380 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
381 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
382 dnl need to check?
383 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
384 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
385                 AC_EGREP_HEADER(initgroups, unistd.h,
386                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
387
388 dnl Check for multibyte character set support
389 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
390     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
391   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
392     [Define to enable support for multibyte character sets.])
393 fi
394
395 dnl -------------------
396 dnl CHECK FOR LIBRARIES
397 dnl -------------------
398 dnl Check location of modf
399 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
400
401 dnl Checks for network libraries (nsl, socket)
402 AC_CHECK_NETLIBS
403
404 termcap_curses_order="termcap curses ncurses"
405 for lib in $termcap_curses_order; do
406   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
407 done
408 AC_SUBST(TERMLIB)dnl
409
410 dnl ---------------
411 dnl CHECK FOR ICONV
412 dnl ---------------
413
414 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
415 if test "x$ac_cv_header_iconv_h" = "xyes"; then
416   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
417   if test "x$ac_found_iconv" = "xno"; then
418     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
419     if test "x$ac_found_iconv" = "xno"; then
420       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
421     fi
422     if test "x$ac_found_iconv" != "xno"; then
423       LIBS="-liconv $LIBS"
424     fi
425   else
426     dnl Handle case where there is a native iconv but iconv.h is from libiconv
427     AC_CHECK_DECL(_libiconv_version,
428       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
429       [ #include <iconv.h> ])
430   fi
431 fi
432 if test "x$ac_found_iconv" = xyes; then
433   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
434 fi
435
436 dnl Check if iconv uses const in prototype declaration
437 if test "x$ac_found_iconv" = "xyes"; then
438   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
439     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
440         #include <iconv.h>]],
441         [[#ifdef __cplusplus
442           "C"
443           #endif
444           #if defined(__STDC__) || defined(__cplusplus)
445           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
446           #else
447           size_t iconv();
448           #endif]])],
449       [ac_cv_iconv_const=],
450       [ac_cv_iconv_const=const])])
451   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
452     [Define as const if the declaration of iconv() needs const.])
453 fi
454
455
456 dnl ---------------------
457 dnl CHECK TERMCAP LIBRARY
458 dnl ---------------------
459
460 dnl Add the termcap library, so that the following configure
461 dnl tests will find it when it tries to link test programs.
462 nmh_save_LIBS="$LIBS"
463 LIBS="$TERMLIB $LIBS"
464
465 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
466 dnl Some termcaps reportedly accept a zero buffer, but then dump core
467 dnl in tgetstr().
468 dnl Under Cygwin test program crashes but exit code is still 0. So,
469 dnl we test for a file that porgram should create
470 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
471 [Define to 1 if tgetent() accepts NULL as a buffer.])
472 AC_CACHE_CHECK(if tgetent accepts NULL,
473 nmh_cv_func_tgetent_accepts_null,
474 [AC_TRY_RUN([
475 main()
476 {
477         char buf[4096];
478         int r1 = tgetent(buf, "vt100");
479         int r2 = tgetent(NULL,"vt100");
480         if (r1 >= 0 && r1 == r2) {
481                 char tbuf[1024], *u;
482                 u = tbuf;
483                         tgetstr("cl", &u);
484                 creat("conftest.tgetent", 0640);
485         }
486         exit((r1 != r2) || r2 == -1);
487 }
488 ],
489   if test -f conftest.tgetent; then
490     nmh_cv_func_tgetent_accepts_null=yes
491   else
492     nmh_cv_func_tgetent_accepts_null=no
493   fi,
494   nmh_cv_func_tgetent_accepts_null=no,
495   nmh_cv_func_tgetent_accepts_null=no)])
496 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
497   AC_DEFINE(TGETENT_ACCEPTS_NULL)
498 fi
499 AC_CACHE_CHECK(if tgetent returns 0 on success,
500 nmh_cv_func_tgetent_zero_success,
501 [AC_TRY_RUN([
502 main()
503 {
504         char buf[4096];
505         int r1 = tgetent(buf, "!@#$%^&*");
506         int r2 = tgetent(buf, "vt100");
507         if (r1 < 0 && r2 == 0) {
508                 char tbuf[1024], *u;
509                 u = tbuf;
510                         tgetstr("cl", &u);
511                 creat("conftest.tgetent0", 0640);
512         }
513         exit(r1 == r2);
514 }
515 ],
516   if test -f conftest.tgetent0; then
517     nmh_cv_func_tgetent_zero_success=yes
518   else
519     nmh_cv_func_tgetent_zero_success=no
520   fi,
521   nmh_cv_func_tgetent_zero_success=no,
522   nmh_cv_func_tgetent_zero_success=no)])
523 AH_TEMPLATE([TGETENT_SUCCESS],
524 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
525 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
526   AC_DEFINE(TGETENT_SUCCESS, 0)
527 else
528   AC_DEFINE(TGETENT_SUCCESS, 1)
529 fi
530
531 dnl Now put the libraries back to what it was before we
532 dnl starting checking the termcap library.
533 LIBS="$nmh_save_LIBS"
534
535 dnl --------------
536 dnl CHECK TYPEDEFS
537 dnl --------------
538 AC_TYPE_SIGNAL
539 AC_TYPE_PID_T
540 AC_TYPE_OFF_T
541 AC_TYPE_UID_T
542 AC_TYPE_MODE_T
543 AC_TYPE_SIZE_T
544
545 dnl Check for sigset_t.  Currently I'm looking in
546 dnl <sys/types.h> and <signal.h>.  Others might need
547 dnl to be added.
548 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
549 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
550 #include <signal.h>]], [[sigset_t tempsigset;]])],
551 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
552 if test $nmh_cv_type_sigset_t = no; then
553   AC_DEFINE(sigset_t, unsigned int,
554     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
555 fi
556
557 dnl ----------------
558 dnl CHECK STRUCTURES
559 dnl ----------------
560 AC_CHECK_MEMBERS(struct stat.st_blksize)
561
562 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
563   [#ifdef TIME_WITH_SYS_TIME
564 # include <sys/time.h>
565 # include <time.h>
566 #else
567 # ifdef TM_IN_SYS_TIME
568 #  include <sys/time.h>
569 # else
570 #  include <time.h>
571 # endif
572 #endif])
573
574 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
575
576 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
577
578 dnl -------------
579 dnl CHECK SIGNALS
580 dnl -------------
581 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
582 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
583 AC_MSG_CHECKING(what style of signals to use)
584 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
585   signals_style=POSIX_SIGNALS
586   AC_DEFINE(POSIX_SIGNALS, 1,
587     [Define to 1 if you use POSIX style signal handling.])
588   AC_DEFINE(RELIABLE_SIGNALS)
589 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
590   signals_style=BSD_SIGNALS
591   AC_DEFINE(BSD_SIGNALS,1,
592     [Define to 1 if you use BSD style signal handling (and can block signals).])
593   AC_DEFINE(RELIABLE_SIGNALS)
594 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
595   signals_style=SYSV_SIGNALS
596   AC_DEFINE(SYSV_SIGNALS,1,
597     [Define to 1 if you use SYSV style signal handling (and can block signals).])
598 else
599   signals_style=NO_SIGNAL_BLOCKING
600   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
601     [Define to 1 if you have no signal blocking at all (bummer).])
602 fi
603
604 AC_MSG_RESULT($signals_style)
605
606 dnl Where is <signal.h> located?  Needed as input for signames.awk
607 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
608 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
609                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
610                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
611                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
612                  /usr/include/sys/signal.h      dnl Almost everybody else
613                  /dev/null;                     dnl Just in case we fall through
614 do
615   test -f $SIGNAL_H && \
616   grep '#[         ]*define[         ][         ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
617   break
618 done
619 nmh_cv_path_signal_h=$SIGNAL_H
620 ])
621 SIGNAL_H=$nmh_cv_path_signal_h
622 AC_SUBST(SIGNAL_H)dnl
623
624 dnl ----------------
625 dnl OS SPECIFIC DEFINES
626 dnl ----------------
627 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
628 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
629
630 case "$target_os" in
631
632   sunos4*)
633     AC_DEFINE(BSD42)
634     ;;
635   freebsd*)
636     AC_DEFINE(BSD42)
637     ;;
638   netbsd*)
639     AC_DEFINE(BSD42)
640     ;;
641   openbsd*)
642     AC_DEFINE(BSD42)
643     ;;
644   bsd/os*)
645     AC_DEFINE(BSD42)
646     ;;
647   sco5*)
648     AC_DEFINE(SCO_5_STDIO)
649     ;;
650 esac
651
652
653 dnl ----------------
654 dnl OUTPUT MAKEFILES
655 dnl ----------------
656 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
657                 etc/Makefile docs/Makefile man/Makefile)
658 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
659 AC_OUTPUT
660
661 dnl These odd looking assignments are done to expand out unexpanded
662 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
663 dnl but expanding that gives '${prefix}/share/man', so we need to expand
664 dnl again to get the final answer.
665 dnl We only use the expanded versions to print the install paths in
666 dnl the final summary and should use them nowhere else (see the autoconf
667 dnl docs for the rationale for bindir etc being unexpanded).
668 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
669 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
670 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
671 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
672
673 echo "
674 mmh configuration
675 -----------------
676 mmh version            : AC_PACKAGE_VERSION
677 target os              : ${target}
678 compiler               : ${CC}
679 compiler flags         : ${CFLAGS}
680 linker flags           : ${LDFLAGS}
681 definitions            : ${OURDEFS}
682 source code location   : ${srcdir}
683
684 binary install path    : ${nmhbin}
685 library install path   : ${nmhlib}
686 config install path    : ${nmhsysconf}
687 man page install path  : ${nmhman}
688
689 sendmail path          : ${sendmailpath}
690 mail spool             : ${mailspool}
691
692 file locking type      : ${LOCKTYPE}
693 "