git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for mmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of mmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for mmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug mmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Do you want mhe support?
  49 AC_ARG_ENABLE(mhe,
  50   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  51
  52 dnl mhe support is on by default, so define it unless --disable-mhe or the
  53 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  54 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  55   AC_DEFINE(MHE, 1,
  56     [Define to compile in support for the Emacs front-end mh-e.])dnl
  57 fi
  58
  59 dnl Do you want to disable use of locale functions
  60 AH_TEMPLATE([LOCALE],
  61 [Undefine if you don't want locale features.  By default this is defined.])
  62 AC_ARG_ENABLE([locale],
  63 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  64 [if test x$enableval = xyes; then
  65   AC_DEFINE(LOCALE)
  66 fi],
  67 AC_DEFINE(LOCALE)
  68 )
  69
  70 dnl What method of locking to use?
  71 AC_ARG_WITH(locking,
  72   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  73   [specify the file locking method]))
  74
  75 if test x"$with_locking" = x"dot"; then
  76   LOCKTYPE="dot"
  77   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  78 elif test x"$with_locking" = x"flock"; then
  79   LOCKTYPE="flock"
  80   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  81 elif test x"$with_locking" = x"lockf"; then
  82   LOCKTYPE="lockf"
  83   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  84 elif test x"$with_locking" = x"fcntl"; then
  85   LOCKTYPE="fcntl"
  86   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  87 else
  88   LOCKTYPE="dot"
  89   AC_DEFINE(DOT_LOCKING)dnl
  90 fi
  91
  92
  93 dnl ----------------------------------------------------
  94 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
  95 dnl ----------------------------------------------------
  96 AC_PREFIX_DEFAULT(/usr/local/mmh)
  97
  98
  99 dnl ------------------
 100 dnl CHECK THE COMPILER
 101 dnl ------------------
 102 dnl We want these before the checks,
 103 dnl so the checks can modify their values.
 104 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 105 if test x"$enable_debug" = x"yes"; then
 106   test -z "$LDFLAGS" && LDFLAGS=-g
 107 fi
 108
 109 AC_PROG_CC
 110
 111 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 112 [nmh_saved_cflags="$CFLAGS"
 113  CFLAGS="$CFLAGS -Wno-pointer-sign"
 114  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 115  CFLAGS="$nmh_saved_cflags"])
 116
 117 dnl if the user hasn't specified CFLAGS, then
 118 dnl   if compiler is gcc, then
 119 dnl     use -O2 and some warning flags
 120 dnl   else use -O
 121 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 122 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 123 dnl spurious and which in any case we don't want to deal with now.
 124 if test "$nmh_cv_has_noptrsign" = "yes"; then
 125   nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 126 else
 127   nmh_gcc_warnflags="-Wall"
 128 fi
 129
 130 if test -n "$auto_cflags"; then
 131   if test x"$enable_debug" = x"yes"; then
 132     if test -n "$GCC"; then
 133       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 134     else
 135       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 136     fi
 137   else
 138     if test -z "$LDFLAGS"; then
 139       case "$build_os" in
 140         darwin*)
 141           LDFLAGS=
 142           ;;
 143         *)
 144           LDFLAGS=-s
 145           ;;
 146       esac
 147     fi
 148     if test -n "$GCC"; then
 149       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 150     else
 151       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 152     fi
 153   fi
 154 fi
 155
 156 AC_C_CONST          dnl Does compiler support `const'.
 157
 158 dnl ------------------
 159 dnl CHECK FOR PROGRAMS
 160 dnl ------------------
 161 AC_PROG_MAKE_SET    dnl Does make define $MAKE
 162 AC_PROG_INSTALL     dnl Check for BSD compatible `install'
 163 AC_PROG_RANLIB      dnl Check for `ranlib'
 164 AC_PROG_AWK         dnl Check for mawk,gawk,nawk, then awk
 165 AC_PROG_LEX         dnl Check for lex/flex
 166
 167 dnl Look for `cut'
 168 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 169 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 170
 171 dnl ----------------------------------------------
 172 dnl check for lclint, and lint if it doesn't exist
 173 dnl ----------------------------------------------
 174 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 175 if test x$ac_cv_prog_linttmp1 != xno ; then
 176   LINT=$ac_cv_prog_linttmp1
 177   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 178 else
 179   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 180   if test x$ac_cv_prog_linttmp2 != xno ; then
 181     LINT=$ac_cv_prog_linttmp2
 182     LINTFLAGS=""
 183   else
 184     LINT="echo 'No lint program found'"
 185     LINTFLAGS=""
 186   fi
 187 fi
 188 AC_SUBST(LINT)dnl
 189 AC_SUBST(LINTFLAGS)dnl
 190
 191 dnl try to figure out which one we've got
 192 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 193 NMH_PROG_GNU_LIBTOOL
 194
 195 dnl Check for lorder and tsort commands
 196 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 197 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 198
 199 dnl If either doesn't exist, replace them with echo and cat
 200 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 201   LORDER=echo
 202   TSORT=cat
 203   AC_SUBST(LORDER)dnl
 204   AC_SUBST(TSORT)dnl
 205 dnl Mac OS X has lorder, but sh is too broken for it to work
 206 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 207 dnl   LORDER=echo
 208 dnl   TSORT=cat
 209 dnl   AC_SUBST(LORDER)dnl
 210 dnl   AC_SUBST(TSORT)dnl
 211 fi
 212
 213 dnl Check whether tsort can deal with loops
 214 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 215   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 216     nmh_cv_tsort_loop=no
 217   else
 218     nmh_cv_tsort_loop=yes
 219   fi])
 220 if test x$nmh_cv_tsort_loop = xno ; then
 221   LORDER=echo
 222   TSORT=cat
 223   AC_SUBST(LORDER)dnl
 224   AC_SUBST(TSORT)dnl
 225 fi
 226
 227 dnl Look for `ls'
 228 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 229 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 230
 231 dnl See how we get ls to display the owner and the group
 232 if test "$lspath" != "no"; then
 233   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 234                  nmh_cv_ls_grpopt,
 235   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 236     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 237     dnl ls, it would seem -l gave us both the user and group.  On this type of
 238     dnl ls, -g makes _only_ the group be displayed (and not the user).
 239     nmh_cv_ls_grpopt="-l"
 240   else
 241     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 242     nmh_cv_ls_grpopt="-lg"
 243   fi])
 244 fi
 245
 246 dnl Look for `sendmail'
 247 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 248 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 249
 250 dnl Look for `vi'
 251 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 252 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 253
 254 dnl ----------------------------------------------------------
 255 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 256 dnl ----------------------------------------------------------
 257 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 258 [for mailspool in /var/mail        dnl
 259                   /var/spool/mail  dnl
 260                   /usr/spool/mail  dnl
 261                   /dev/null;       dnl Just in case we fall through
 262 do
 263   test -d $mailspool && break
 264 done
 265 nmh_cv_mailspool=$mailspool
 266 ])
 267 mailspool=$nmh_cv_mailspool
 268 AC_SUBST(mailspool)dnl
 269
 270 dnl See whether the mail spool directory is world-writable.
 271 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 272   AC_CACHE_CHECK(whether the mail spool is world-writable,
 273                  nmh_cv_mailspool_world_writable,
 274   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 275     nmh_cv_mailspool_world_writable=no
 276   else
 277     nmh_cv_mailspool_world_writable=yes
 278   fi])
 279 fi
 280
 281 dnl Also, check for liblockfile (as found on Debian systems)
 282 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 283
 284 dnl and whether its companion program dotlockfile is setgid
 285 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 286 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 287   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 288     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 289     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 290         nmh_cv_dotlockfile_setgid=yes
 291       else
 292         nmh_cv_dotlockfile_setgid=no
 293       fi])
 294   fi
 295 fi
 296
 297 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 298 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 299 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 300   dnl do we really need both of these?
 301   AC_DEFINE(MAILGROUP,1,
 302     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 303   SETGID_MAIL=1
 304 fi
 305 AC_SUBST(SETGID_MAIL)dnl
 306
 307 dnl Use ls to see which group owns the mail spool directory.
 308 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 309 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 310 ])
 311 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 312 AC_SUBST(MAIL_SPOOL_GRP)dnl
 313
 314 dnl ------------------
 315 dnl CHECK HEADER FILES
 316 dnl ------------------
 317
 318 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 319 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 320 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 321 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 322 dnl declared; if so they should have an entry added to this case statement.
 323 dnl NB that we must define this on the compiler command line, not in config.h,
 324 dnl because it must be set before any system header is included and there's no
 325 dnl portable way to make sure that files generated by lex include config.h
 326 dnl before system header files.
 327
 328 case "$target_os" in
 329   linux*)
 330     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 331     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 332     ;;
 333 esac
 334 AC_SUBST(OURDEFS)
 335
 336 AC_HEADER_DIRENT
 337 AC_HEADER_STDC
 338 AC_HEADER_TIME
 339 AC_HEADER_SYS_WAIT
 340 AC_HEADER_STAT
 341 AC_HEADER_TIOCGWINSZ
 342 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 343                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 344                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 345                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 346                  arpa/inet.h arpa/ftp.h)
 347
 348 dnl
 349 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 350 dnl really use a whole set of them, but this check should be
 351 dnl sufficient.
 352 dnl
 353 AC_CHECK_HEADER(libio.h, [
 354   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 355     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 356
 357 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 358   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 359 [[#if HAVE_SYS_STREAM_H
 360 #  include <sys/stream.h>
 361 #endif
 362 ]])
 363
 364 dnl ---------------
 365 dnl CHECK FUNCTIONS
 366 dnl ---------------
 367 AC_FUNC_VFORK
 368 AC_CHECK_LIB(mkstemp,mkstemp)
 369 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 370                sighold sigrelse lstat uname tzset killpg mkstemp \
 371                getutent nl_langinfo mbtowc wcwidth)
 372
 373 dnl sigsetjmp may be a macro
 374 AC_MSG_CHECKING(for sigsetjmp)
 375 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 376   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 377     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 378   [AC_MSG_RESULT(no)])
 379
 380 AC_REPLACE_FUNCS(snprintf strdup)
 381
 382 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 383 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 384 dnl any system header.
 385 dnl
 386 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 387 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 388 dnl need to check?
 389 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 390 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 391                 AC_EGREP_HEADER(initgroups, unistd.h,
 392                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 393
 394 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 395 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 396 dnl seems to work perfectly and IBM apparently uses it in internal code).
 397 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 398 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 399 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 400 dnl prototype.
 401 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 402   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 403
 404 dnl Check for multibyte character set support
 405 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 406     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 407   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 408     [Define to enable support for multibyte character sets.])
 409 fi
 410
 411 dnl -------------------
 412 dnl CHECK FOR LIBRARIES
 413 dnl -------------------
 414 dnl Check location of modf
 415 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 416
 417 dnl Checks for network libraries (nsl, socket)
 418 AC_CHECK_NETLIBS
 419
 420 termcap_curses_order="termcap curses ncurses"
 421 for lib in $termcap_curses_order; do
 422   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 423 done
 424 AC_SUBST(TERMLIB)dnl
 425
 426 dnl ---------------
 427 dnl CHECK FOR ICONV
 428 dnl ---------------
 429
 430 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 431 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 432   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 433   if test "x$ac_found_iconv" = "xno"; then
 434     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 435     if test "x$ac_found_iconv" = "xno"; then
 436       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 437     fi
 438     if test "x$ac_found_iconv" != "xno"; then
 439       LIBS="-liconv $LIBS"
 440     fi
 441   else
 442     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 443     AC_CHECK_DECL(_libiconv_version,
 444       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 445       [ #include <iconv.h> ])
 446   fi
 447 fi
 448 if test "x$ac_found_iconv" = xyes; then
 449   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 450 fi
 451
 452 dnl Check if iconv uses const in prototype declaration
 453 if test "x$ac_found_iconv" = "xyes"; then
 454   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 455     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 456         #include <iconv.h>]],
 457         [[#ifdef __cplusplus
 458           "C"
 459           #endif
 460           #if defined(__STDC__) || defined(__cplusplus)
 461           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 462           #else
 463           size_t iconv();
 464           #endif]])],
 465       [ac_cv_iconv_const=],
 466       [ac_cv_iconv_const=const])])
 467   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 468     [Define as const if the declaration of iconv() needs const.])
 469 fi
 470
 471 dnl --------------
 472 dnl CHECK FOR NDBM
 473 dnl --------------
 474
 475 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 476             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 477 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 478             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 479
 480 if test "$nmh_ndbm" = "autodetect"; then
 481   if test "$nmh_ndbmheader" != "autodetect"; then
 482     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 483   else
 484
 485     dnl There are at least four implementations of ndbm, and
 486     dnl several of those can be in different places at the whim
 487     dnl of the system integrator. A good summary of this mess
 488     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 489
 490     dnl Classic ndbm with no library required (eg NetBSD): try this
 491     dnl first so we don't accidentally link in a pointless but harmless
 492     dnl library in one of the later ndbm.h+libfoo tests:
 493     NMH_CHECK_NDBM(ndbm.h,,,
 494     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 495       NMH_CHECK_NDBM(db.h,db,,
 496     dnl Berkeley DBv1 emulating ndbm:
 497         NMH_CHECK_NDBM(ndbm.h,db,,
 498           NMH_CHECK_NDBM(ndbm.h,db1,,
 499     dnl Classic ndbm:
 500             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 501     dnl glibc2.1 systems put db1 in a subdir:
 502               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 503     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 504     dnl and possibly needing gbdm_compat library:
 505                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 506                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 507                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 508                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 509
 510   fi
 511 else
 512   dnl We don't really need to check that the user-specified values work,
 513   dnl but it is a convenience to the user to bomb out early rather than
 514   dnl after configure and half the compile process.
 515   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 516 fi
 517
 518 if test "$nmh_ndbm_found" = "no"; then
 519   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 520 else
 521   dnl Now export the lib/header to our makefile/config.h:
 522   if test x"$nmh_ndbmheader" != x; then
 523     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 524       [Define to the header containing the ndbm API prototypes.])
 525   fi
 526   if test x"$nmh_ndbm" != x; then
 527     NDBM_LIBS="-l$nmh_ndbm"
 528   else
 529     NDBM_LIBS=
 530   fi
 531   AC_SUBST(NDBM_LIBS)
 532 fi
 533
 534
 535 dnl ---------------------
 536 dnl CHECK TERMCAP LIBRARY
 537 dnl ---------------------
 538
 539 dnl Add the termcap library, so that the following configure
 540 dnl tests will find it when it tries to link test programs.
 541 nmh_save_LIBS="$LIBS"
 542 LIBS="$TERMLIB $LIBS"
 543
 544 dnl Checks for external variable ospeed in the termcap library.
 545 AC_CACHE_CHECK(if an include file defines ospeed,
 546 nmh_cv_decl_ospeed_include_defines,
 547 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 548 #if HAVE_TERMIOS_H
 549 # include <termios.h>
 550 #endif
 551 #if HAVE_TERMCAP_H
 552 # include <termcap.h>
 553 #endif]], [[ospeed = 0;]])],
 554 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 555
 556 if test $nmh_cv_decl_ospeed_include_defines = no; then
 557   AC_CACHE_CHECK(if you must define ospeed,
 558   nmh_cv_decl_ospeed_must_define,
 559   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 560   [[extern short ospeed; ospeed = 0;]])],
 561   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 562 fi
 563
 564 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 565 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 566   AC_DEFINE(HAVE_OSPEED)dnl
 567 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 568   AC_DEFINE(HAVE_OSPEED)
 569   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 570     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 571 fi
 572
 573 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 574 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 575 dnl in tgetstr().
 576 dnl Under Cygwin test program crashes but exit code is still 0. So,
 577 dnl we test for a file that porgram should create
 578 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 579 [Define to 1 if tgetent() accepts NULL as a buffer.])
 580 AC_CACHE_CHECK(if tgetent accepts NULL,
 581 nmh_cv_func_tgetent_accepts_null,
 582 [AC_TRY_RUN([
 583 main()
 584 {
 585         char buf[4096];
 586         int r1 = tgetent(buf, "vt100");
 587         int r2 = tgetent(NULL,"vt100");
 588         if (r1 >= 0 && r1 == r2) {
 589                 char tbuf[1024], *u;
 590                 u = tbuf;
 591                         tgetstr("cl", &u);
 592                 creat("conftest.tgetent", 0640);
 593         }
 594         exit((r1 != r2) || r2 == -1);
 595 }
 596 ],
 597   if test -f conftest.tgetent; then
 598     nmh_cv_func_tgetent_accepts_null=yes
 599   else
 600     nmh_cv_func_tgetent_accepts_null=no
 601   fi,
 602   nmh_cv_func_tgetent_accepts_null=no,
 603   nmh_cv_func_tgetent_accepts_null=no)])
 604 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 605   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 606 fi
 607 AC_CACHE_CHECK(if tgetent returns 0 on success,
 608 nmh_cv_func_tgetent_zero_success,
 609 [AC_TRY_RUN([
 610 main()
 611 {
 612         char buf[4096];
 613         int r1 = tgetent(buf, "!@#$%^&*");
 614         int r2 = tgetent(buf, "vt100");
 615         if (r1 < 0 && r2 == 0) {
 616                 char tbuf[1024], *u;
 617                 u = tbuf;
 618                         tgetstr("cl", &u);
 619                 creat("conftest.tgetent0", 0640);
 620         }
 621         exit(r1 == r2);
 622 }
 623 ],
 624   if test -f conftest.tgetent0; then
 625     nmh_cv_func_tgetent_zero_success=yes
 626   else
 627     nmh_cv_func_tgetent_zero_success=no
 628   fi,
 629   nmh_cv_func_tgetent_zero_success=no,
 630   nmh_cv_func_tgetent_zero_success=no)])
 631 AH_TEMPLATE([TGETENT_SUCCESS],
 632 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 633 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 634   AC_DEFINE(TGETENT_SUCCESS, 0)
 635 else
 636   AC_DEFINE(TGETENT_SUCCESS, 1)
 637 fi
 638
 639 dnl Now put the libraries back to what it was before we
 640 dnl starting checking the termcap library.
 641 LIBS="$nmh_save_LIBS"
 642
 643 dnl --------------
 644 dnl CHECK TYPEDEFS
 645 dnl --------------
 646 AC_TYPE_SIGNAL
 647 AC_TYPE_PID_T
 648 AC_TYPE_OFF_T
 649 AC_TYPE_UID_T
 650 AC_TYPE_MODE_T
 651 AC_TYPE_SIZE_T
 652
 653 dnl Check for sigset_t.  Currently I'm looking in
 654 dnl <sys/types.h> and <signal.h>.  Others might need
 655 dnl to be added.
 656 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 657 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 658 #include <signal.h>]], [[sigset_t tempsigset;]])],
 659 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 660 if test $nmh_cv_type_sigset_t = no; then
 661   AC_DEFINE(sigset_t, unsigned int,
 662     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 663 fi
 664
 665 dnl ----------------
 666 dnl CHECK STRUCTURES
 667 dnl ----------------
 668 AC_CHECK_MEMBERS(struct stat.st_blksize)
 669
 670 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 671   [#ifdef TIME_WITH_SYS_TIME
 672 # include <sys/time.h>
 673 # include <time.h>
 674 #else
 675 # ifdef TM_IN_SYS_TIME
 676 #  include <sys/time.h>
 677 # else
 678 #  include <time.h>
 679 # endif
 680 #endif])
 681
 682 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 683
 684 AC_MSG_CHECKING(for union wait)
 685 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 686   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 687 #include <sys/wait.h>]],
 688     [[union wait status; int pid; pid = wait (&status);
 689 #ifdef WEXITSTATUS
 690 /* Some POSIXoid systems have both the new-style macros and the old
 691    union wait type, and they do not work together.  If union wait
 692    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 693         if (WEXITSTATUS (status) != 0) pid = -1;
 694 #ifdef WTERMSIG
 695         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 696         -- blow chunks here --
 697 #endif
 698 #endif
 699 #ifdef HAVE_WAITPID
 700         /* Make sure union wait works with waitpid.  */
 701         pid = waitpid (-1, &status, 0);
 702 #endif
 703       ]])],
 704     [nmh_cv_union_wait=yes],
 705     [nmh_cv_union_wait=no])])
 706 if test "$nmh_cv_union_wait" = yes; then
 707   AC_DEFINE(HAVE_UNION_WAIT, 1,
 708     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 709 fi
 710 AC_MSG_RESULT($nmh_cv_union_wait)
 711
 712 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 713
 714 dnl -------------
 715 dnl CHECK SIGNALS
 716 dnl -------------
 717 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 718 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 719 AC_MSG_CHECKING(what style of signals to use)
 720 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 721   signals_style=POSIX_SIGNALS
 722   AC_DEFINE(POSIX_SIGNALS, 1,
 723     [Define to 1 if you use POSIX style signal handling.])
 724   AC_DEFINE(RELIABLE_SIGNALS)
 725 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 726   signals_style=BSD_SIGNALS
 727   AC_DEFINE(BSD_SIGNALS,1,
 728     [Define to 1 if you use BSD style signal handling (and can block signals).])
 729   AC_DEFINE(RELIABLE_SIGNALS)
 730 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 731   signals_style=SYSV_SIGNALS
 732   AC_DEFINE(SYSV_SIGNALS,1,
 733     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 734 else
 735   signals_style=NO_SIGNAL_BLOCKING
 736   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 737     [Define to 1 if you have no signal blocking at all (bummer).])
 738 fi
 739
 740 AC_MSG_RESULT($signals_style)
 741
 742 dnl Where is <signal.h> located?  Needed as input for signames.awk
 743 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 744 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 745                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 746                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 747                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 748                  /usr/include/sys/signal.h      dnl Almost everybody else
 749                  /dev/null;                     dnl Just in case we fall through
 750 do
 751   test -f $SIGNAL_H && \
 752   grep '#[         ]*define[         ][         ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 753   break
 754 done
 755 nmh_cv_path_signal_h=$SIGNAL_H
 756 ])
 757 SIGNAL_H=$nmh_cv_path_signal_h
 758 AC_SUBST(SIGNAL_H)dnl
 759
 760 dnl ----------------
 761 dnl OS SPECIFIC DEFINES
 762 dnl ----------------
 763 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 764 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 765
 766 case "$target_os" in
 767
 768   sunos4*)
 769     AC_DEFINE(BSD42)
 770     ;;
 771   freebsd*)
 772     AC_DEFINE(BSD42)
 773     ;;
 774   netbsd*)
 775     AC_DEFINE(BSD42)
 776     ;;
 777   openbsd*)
 778     AC_DEFINE(BSD42)
 779     ;;
 780   bsd/os*)
 781     AC_DEFINE(BSD42)
 782     ;;
 783   sco5*)
 784     AC_DEFINE(SCO_5_STDIO)
 785     ;;
 786 esac
 787
 788
 789 dnl ----------------
 790 dnl OUTPUT MAKEFILES
 791 dnl ----------------
 792 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 793                 etc/Makefile docs/Makefile man/Makefile)
 794 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 795 AC_OUTPUT
 796
 797 dnl These odd looking assignments are done to expand out unexpanded
 798 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 799 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 800 dnl again to get the final answer.
 801 dnl We only use the expanded versions to print the install paths in
 802 dnl the final summary and should use them nowhere else (see the autoconf
 803 dnl docs for the rationale for bindir etc being unexpanded).
 804 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 805 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 806 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 807 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 808
 809 echo "
 810 mmh configuration
 811 -----------------
 812 mmh version            : AC_PACKAGE_VERSION
 813 target os              : ${target}
 814 compiler               : ${CC}
 815 compiler flags         : ${CFLAGS}
 816 linker flags           : ${LDFLAGS}
 817 definitions            : ${OURDEFS}
 818 source code location   : ${srcdir}
 819
 820 binary install path    : ${nmhbin}
 821 library install path   : ${nmhlib}
 822 config install path    : ${nmhsysconf}
 823 man page install path  : ${nmhman}
 824
 825 sendmail path          : ${sendmailpath}
 826 mail spool             : ${mailspool}
 827
 828 file locking type      : ${LOCKTYPE}
 829 "