git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Do you want to disable use of locale functions
  34 AH_TEMPLATE([LOCALE],
  35 [Undefine if you don't want locale features.  By default this is defined.])
  36 AC_ARG_ENABLE([locale],
  37   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  38   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  39   [AC_DEFINE(LOCALE)])
  40
  41 dnl Do you want client-side support for using SASL for authentication?
  42 dnl Note that this code will be enabled for both POP and SMTP
  43 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  44   [Enable SASL support via the Cyrus SASL library]))
  45 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  46       AC_DEFINE([CYRUS_SASL], [1],
  47                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  48       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  49             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  50             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  51       sasl_support=yes], [sasl_support=no])
  52
  53 dnl Do you want client-side support for encryption with TLS?
  54 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  55 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  56       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  57       tls_support=yes],[tls_support=no])
  58
  59 dnl What should be the default editor?
  60 AC_ARG_WITH([editor],
  61   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  62
  63 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  64
  65 dnl Set the backup prefix
  66 AC_ARG_WITH([hash-backup],
  67   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  68 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  69       [backup_prefix="#"], [backup_prefix=","])
  70 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  71     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  72
  73 dnl What method of locking to use?
  74 AS_CASE(["$host_os"],
  75   [aix*|cygwin*|linux*],
  76     [default_locktype="fcntl"; default_locking=FCNTL_LOCKING],
  77   [freebsd*], [default_locktype="flock"; default_locking=FLOCK_LOCKING],
  78   [default_locktype="dot"; default_locking=DOT_LOCKING])
  79
  80 AC_ARG_WITH(locking,
  81   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  82   [specify the file locking method]))
  83
  84 if test x"$with_locking" = x"dot"; then
  85   LOCKTYPE="dot"
  86   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  87 elif test x"$with_locking" = x"flock"; then
  88   LOCKTYPE="flock"
  89   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  90 elif test x"$with_locking" = x"lockf"; then
  91   LOCKTYPE="lockf"
  92   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  93 elif test x"$with_locking" = x"fcntl"; then
  94   LOCKTYPE="fcntl"
  95   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  96 else
  97   LOCKTYPE="$default_locktype"
  98   AC_DEFINE_UNQUOTED($default_locking, 1)dnl
  99 fi
 100
 101 dnl Should we use a locking directory?
 102 AC_ARG_ENABLE([lockdir],
 103   [AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 104   AS_IF([test "x$enableval" = xyes],[
 105     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 106   AS_IF([test "x$LOCKTYPE" != xdot],[
 107     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 108   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 109                      [Directory to store dot-locking lock files])
 110 ])
 111
 112 dnl What method of posting should post use?
 113 AC_ARG_WITH([mts],
 114   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 115   [specify the default mail transport agent/service]))
 116
 117 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 118       [test x"$with_mts" = x"sendmail"], [MTS="sendmail"],
 119       [MTS="smtp"])
 120 AC_SUBST([MTS])dnl
 121
 122 dnl What should be the default pager?
 123 AC_ARG_WITH([pager],
 124   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 125
 126 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 127
 128 dnl If a pager is not explicitly specified, then look for one.
 129 dnl Fall back to `cat', to avoid catastrophic failure of
 130 dnl `mhshow', et al., if pagerpath is set to `no'.
 131 if test -z "$pagerpath"; then
 132   pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 133   AC_PATH_PROGS([pagerpath], [more less most cat], [no], [$pathtmp])
 134 fi
 135 AC_SUBST(pagerpath)dnl
 136
 137 dnl What should be the default mail server(s)?
 138 AC_ARG_WITH(smtpservers,
 139   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 140   [specify the default SMTP server(s) @<:@localhost@:>@]))
 141 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 142       [smtpservers="localhost"])
 143 AC_SUBST([smtpservers])dnl
 144
 145 dnl ----------------------------------------------------
 146 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 147 dnl ----------------------------------------------------
 148 AC_PREFIX_DEFAULT([/usr/local/nmh])
 149
 150 dnl ------------------
 151 dnl CHECK THE COMPILER
 152 dnl ------------------
 153 dnl We want these before the checks,
 154 dnl so the checks can modify their values.
 155 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 156 if test x"$enable_debug" = x"yes"; then
 157   test -z "$LDFLAGS" && LDFLAGS=-g
 158 fi
 159
 160 AC_PROG_CC
 161 AM_PROG_CC_C_O
 162
 163 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 164   [nmh_cv_has_unusedmacros],
 165   [nmh_saved_cppflags="$CPPFLAGS"
 166    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 167    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 168    CPPFLAGS="$nmh_saved_cppflags"])
 169
 170 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 171   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 172                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 173   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 174 fi
 175 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 176
 177 AC_CACHE_CHECK([whether compiler supports -Wno-sign-compare],
 178   [nmh_cv_has_nosigncompare],
 179   [nmh_saved_cppflags="$CPPFLAGS"
 180    CPPFLAGS="$CPPFLAGS -Wno-sign-compare"
 181    AC_TRY_COMPILE([],[],nmh_cv_has_nosigncompare=yes,
 182                   nmh_cv_has_nosigncompare=no)
 183    CPPFLAGS="$nmh_saved_cppflags"])
 184
 185 if test "$nmh_cv_has_nosigncompare" = 'yes'; then
 186   DISABLE_SIGN_COMPARE_WARNING=-Wno-sign-compare
 187 fi
 188 AC_SUBST(DISABLE_SIGN_COMPARE_WARNING)dnl
 189
 190 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 191 [nmh_saved_cflags="$CFLAGS"
 192  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 193  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 194  CFLAGS="$nmh_saved_cflags"])
 195
 196 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 197 [nmh_saved_cflags="$CFLAGS"
 198  CFLAGS="$CFLAGS -Wno-pointer-sign"
 199  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 200  CFLAGS="$nmh_saved_cflags"])
 201
 202 dnl if the user hasn't specified CFLAGS, then
 203 dnl   if compiler is gcc, then
 204 dnl    use -O2 and some warning flags
 205 dnl   else use -O
 206 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 207 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 208 dnl warnings which are probably mostly spurious and which in any case we
 209 dnl don't want to deal with now.
 210 if test "$nmh_cv_has_noptrsign" = "yes"; then
 211     nmh_gcc_common_flags="-ansi -pedantic -Wall"
 212     if test "$nmh_cv_has_wextra" = "yes"; then
 213         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered "\
 214 "-Wno-pointer-sign"
 215     else
 216         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wno-pointer-sign"
 217     fi
 218 else
 219     if test "$nmh_cv_has_wextra" = "yes"; then
 220         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered"
 221     else
 222         nmh_gcc_warnflags="${nmh_gcc_common_flags}"
 223     fi
 224 fi
 225
 226 if test -n "$auto_cflags"; then
 227   if test x"$enable_debug" = x"yes"; then
 228     if test -n "$GCC"; then
 229       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 230     else
 231       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 232     fi
 233   else
 234     if test -z "$LDFLAGS"; then
 235       case "$build_os" in
 236         darwin*)
 237           LDFLAGS=
 238           ;;
 239         *)
 240           LDFLAGS=-s
 241           ;;
 242       esac
 243     fi
 244     if test -n "$GCC"; then
 245       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 246     else
 247       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 248     fi
 249   fi
 250 fi
 251
 252 AC_C_CONST              dnl Does compiler support `const'.
 253
 254 dnl ------------------
 255 dnl CHECK FOR PROGRAMS
 256 dnl ------------------
 257 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 258 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 259 AC_PROG_RANLIB          dnl Check for `ranlib'
 260 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 261 AC_PROG_SED             dnl Check for Posix-compliant sed
 262 AC_PROG_LEX             dnl Check for lex/flex
 263
 264 dnl Look for `cut'
 265 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 266 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 267
 268 dnl
 269 dnl Check for MD5 program and formatting command
 270 dnl
 271 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 272 AS_CASE(["${MD5SUM}"],
 273         [md5sum], [MD5FMT="cat"],
 274         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 275         [MD5FMT="missing"])
 276 AC_SUBST([MD5FMT])
 277
 278 dnl ----------------------------------------------
 279 dnl check for lclint, and lint if it doesn't exist
 280 dnl ----------------------------------------------
 281 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 282 if test x$ac_cv_prog_linttmp1 != xno ; then
 283   LINT=$ac_cv_prog_linttmp1
 284   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 285 else
 286   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 287   if test x$ac_cv_prog_linttmp2 != xno ; then
 288     LINT=$ac_cv_prog_linttmp2
 289     LINTFLAGS=""
 290   else
 291     LINT="echo 'No lint program found'"
 292     LINTFLAGS=""
 293   fi
 294 fi
 295 AC_SUBST([LINT])dnl
 296 AC_SUBST([LINTFLAGS])dnl
 297
 298 dnl Look for `ls'
 299 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 300 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 301
 302 dnl See how we get ls to display the owner and the group
 303 if test "$lspath" != "no"; then
 304   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 305                  [nmh_cv_ls_grpopt],
 306   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 307     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 308     dnl ls, it would seem -l gave us both the user and group.  On this type of
 309     dnl ls, -g makes _only_ the group be displayed (and not the user).
 310     nmh_cv_ls_grpopt="-l"
 311   else
 312     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 313     nmh_cv_ls_grpopt="-lg"
 314   fi])
 315 fi
 316
 317 dnl Look for `sendmail'
 318 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 319 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 320
 321 dnl Look for `vi'
 322 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 323 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 324
 325 dnl If editor is not specified yet,
 326 dnl then use `vi' as the default.
 327 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 328 AC_SUBST([editorpath])dnl
 329
 330 dnl ----------------------------------------------------------
 331 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 332 dnl ----------------------------------------------------------
 333 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 334 [for mailspool in /var/mail        dnl
 335                   /var/spool/mail  dnl
 336                   /usr/spool/mail  dnl
 337                   /dev/null;       dnl Just in case we fall through
 338 do
 339   test -d $mailspool && break
 340 done
 341 nmh_cv_mailspool=$mailspool
 342 ])
 343 mailspool=$nmh_cv_mailspool
 344 AC_SUBST([mailspool])dnl
 345
 346 dnl See whether the mail spool directory is world-writable.
 347 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 348   AC_CACHE_CHECK(whether the mail spool is world-writable,
 349                  nmh_cv_mailspool_world_writable,
 350   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 351     nmh_cv_mailspool_world_writable=no
 352   else
 353     nmh_cv_mailspool_world_writable=yes
 354   fi])
 355 fi
 356
 357 dnl Also, check for liblockfile (as found on Debian systems)
 358 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 359
 360 dnl and whether its companion program dotlockfile is setgid
 361 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 362 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 363   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 364     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 365     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 366         nmh_cv_dotlockfile_setgid=yes
 367       else
 368         nmh_cv_dotlockfile_setgid=no
 369       fi])
 370   fi
 371 fi
 372
 373 dnl Provide a way for distcheck to disable setgid_mail via
 374 dnl DISTCHECK_CONFIGURE_FLAGS.
 375 if test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0; then
 376   nmh_cv_dotlockfile_setgid=yes
 377 fi
 378
 379 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 380 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 381 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 382   dnl do we really need both of these?
 383   AC_DEFINE(MAILGROUP,1,
 384     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 385   SETGID_MAIL=1
 386 fi
 387 AC_SUBST(SETGID_MAIL)dnl
 388
 389 dnl Use ls to see which group owns the mail spool directory.
 390 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 391 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 392 ])
 393 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 394 AC_SUBST(MAIL_SPOOL_GRP)dnl
 395
 396 dnl ------------------
 397 dnl CHECK HEADER FILES
 398 dnl ------------------
 399
 400 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 401 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 402 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 403 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 404 dnl declared; if so they should have an entry added to this case statement.
 405 dnl NB that we must define this on the compiler command line, not in config.h,
 406 dnl because it must be set before any system header is included and there's no
 407 dnl portable way to make sure that files generated by lex include config.h
 408 dnl before system header files.
 409
 410 AS_CASE(["$host_os"],
 411         [linux*],
 412         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 413           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 414                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 415
 416 AC_HEADER_STDC
 417 AC_HEADER_TIOCGWINSZ
 418 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 419                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 420                   sys/param.h sys/time.h sys/stream.h])
 421
 422 dnl
 423 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 424 dnl really use a whole set of them, but this check should be
 425 dnl sufficient.
 426 dnl
 427 AC_CHECK_HEADER(libio.h, [
 428   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 429     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 430
 431 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 432   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 433 [[#if HAVE_SYS_STREAM_H
 434 #  include <sys/stream.h>
 435 #endif
 436 ]])
 437
 438 dnl ---------------
 439 dnl CHECK FUNCTIONS
 440 dnl ---------------
 441 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 442
 443 dnl Check for multibyte character set support
 444 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 445             "x$ac_cv_header_wctype_h" = "xyes" -a \
 446             "x$ac_cv_func_wcwidth" = "xyes" -a \
 447             "x$ac_cv_func_mbtowc" = "xyes"],
 448       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 449                  [Define to enable support for multibyte character sets.])
 450        MULTIBYTE_ENABLED=1],
 451       [MULTIBYTE_ENABLED=0])
 452 AC_SUBST([MULTIBYTE_ENABLED])
 453
 454 dnl -------------------
 455 dnl CHECK FOR LIBRARIES
 456 dnl -------------------
 457 dnl Check location of modf
 458 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 459
 460 dnl Checks for network libraries (nsl, socket)
 461 NMH_CHECK_NETLIBS
 462
 463 NMH_READLINE
 464
 465 termcap_curses_order="termcap curses ncurses"
 466 for lib in $termcap_curses_order; do
 467   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 468 done
 469 AC_SUBST([TERMLIB])dnl
 470 AS_IF([test "x$TERMLIB" = "x"],
 471       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 472 or ncurses library or package that you can install?])])
 473
 474
 475 dnl ---------------
 476 dnl CHECK FOR ICONV
 477 dnl ---------------
 478
 479 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 480 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 481   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 482   if test "x$ac_found_iconv" = "xno"; then
 483     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 484     if test "x$ac_found_iconv" = "xno"; then
 485       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 486     fi
 487     if test "x$ac_found_iconv" != "xno"; then
 488       ICONVLIB="-liconv"
 489     fi
 490   else
 491     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 492     AC_CHECK_DECL(_libiconv_version,
 493       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 494       [ #include <iconv.h> ])
 495   fi
 496 fi
 497 if test "x$ac_found_iconv" = xyes; then
 498   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 499 fi
 500 AC_SUBST([ICONVLIB])
 501
 502 dnl Check if iconv uses const in prototype declaration
 503 if test "x$ac_found_iconv" = "xyes"; then
 504   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 505     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 506         #include <iconv.h>]],
 507         [[#ifdef __cplusplus
 508           "C"
 509           #endif
 510           #if defined(__STDC__) || defined(__cplusplus)
 511           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 512           #else
 513           size_t iconv();
 514           #endif]])],
 515       [ac_cv_iconv_const=],
 516       [ac_cv_iconv_const=const])])
 517   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 518     [Define as const if the declaration of iconv() needs const.])
 519 fi
 520
 521 dnl --------------
 522 dnl CHECK FOR NDBM
 523 dnl --------------
 524
 525 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 526             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 527 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 528             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 529
 530 if test "$nmh_ndbm" = "autodetect"; then
 531   if test "$nmh_ndbmheader" != "autodetect"; then
 532     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 533   else
 534
 535     dnl There are at least four implementations of ndbm, and
 536     dnl several of those can be in different places at the whim
 537     dnl of the system integrator. A good summary of this mess
 538     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 539
 540     dnl Classic ndbm with no library required (eg NetBSD): try this
 541     dnl first so we don't accidentally link in a pointless but harmless
 542     dnl library in one of the later ndbm.h+libfoo tests:
 543     NMH_CHECK_NDBM(ndbm.h,,,
 544     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 545       NMH_CHECK_NDBM(db.h,db,,
 546     dnl Berkeley DBv1 emulating ndbm:
 547         NMH_CHECK_NDBM(ndbm.h,db,,
 548           NMH_CHECK_NDBM(ndbm.h,db1,,
 549     dnl Classic ndbm:
 550             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 551     dnl glibc2.1 systems put db1 in a subdir:
 552               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 553     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 554     dnl and possibly needing gbdm_compat library:
 555                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 556                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 557                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 558                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 559
 560   fi
 561 else
 562   dnl We don't really need to check that the user-specified values work,
 563   dnl but it is a convenience to the user to bomb out early rather than
 564   dnl after configure and half the compile process.
 565   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 566 fi
 567
 568 if test "$nmh_ndbm_found" = "no"; then
 569   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 570 else
 571   dnl Now export the lib/header to our makefile/config.h:
 572   if test x"$nmh_ndbmheader" != x; then
 573     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 574       [Define to the header containing the ndbm API prototypes.])
 575   fi
 576   if test x"$nmh_ndbm" != x; then
 577     NDBM_LIBS="-l$nmh_ndbm"
 578   else
 579     NDBM_LIBS=
 580   fi
 581   AC_SUBST([NDBM_LIBS])
 582 fi
 583
 584 dnl ------------------
 585 dnl Set RPM build root
 586 dnl ------------------
 587 dnl nmhrpm is used in the final summary, see below.  The default value is
 588 dnl reported there as ./RPM, consistent with the reporting of the default
 589 dnl source code location as ., but its absolute path is used in the Makefile.
 590 AC_ARG_WITH(rpmdir,
 591   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 592   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 593           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 594 AC_SUBST([rpmdir])
 595
 596
 597 dnl --------------------
 598 dnl CHECK FOR CYRUS-SASL
 599 dnl --------------------
 600
 601 AS_IF([test x"$sasl_support" = x"yes"],[
 602   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 603   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 604     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 605 AC_SUBST([SASLLIB])
 606
 607 dnl -----------------
 608 dnl CHECK FOR OPENSSL
 609 dnl -----------------
 610
 611 AS_IF([test x"$tls_support" = x"yes"],[
 612   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 613   AC_CHECK_LIB([crypto], [BIO_write], ,
 614     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 615   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 616     [AC_MSG_ERROR([OpenSSL library not found])])])
 617
 618 dnl ---------------------
 619 dnl CHECK TERMCAP LIBRARY
 620 dnl ---------------------
 621
 622 dnl Add the termcap library, so that the following configure
 623 dnl tests will find it when it tries to link test programs.
 624 nmh_save_LIBS="$LIBS"
 625 LIBS="$TERMLIB $LIBS"
 626
 627 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 628 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 629 dnl in tgetstr().
 630 dnl Under Cygwin test program crashes but exit code is still 0. So,
 631 dnl we test for a file that porgram should create
 632 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 633 [Define to 1 if tgetent() accepts NULL as a buffer.])
 634 AC_CACHE_CHECK(if tgetent accepts NULL,
 635 nmh_cv_func_tgetent_accepts_null,
 636 [AC_TRY_RUN([
 637 main()
 638 {
 639     char buf[4096];
 640     int r1 = tgetent(buf, "vt100");
 641     int r2 = tgetent((char*)0,"vt100");
 642     if (r1 >= 0 && r1 == r2) {
 643         char tbuf[1024], *u;
 644         u = tbuf;
 645         tgetstr("cl", &u);
 646         creat("conftest.tgetent", 0640);
 647     }
 648     exit((r1 != r2) || r2 == -1);
 649 }
 650 ],
 651   if test -f conftest.tgetent; then
 652     nmh_cv_func_tgetent_accepts_null=yes
 653   else
 654     nmh_cv_func_tgetent_accepts_null=no
 655   fi,
 656   nmh_cv_func_tgetent_accepts_null=no,
 657   nmh_cv_func_tgetent_accepts_null=no)])
 658 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 659   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 660 fi
 661 AC_CACHE_CHECK(if tgetent returns 0 on success,
 662 nmh_cv_func_tgetent_zero_success,
 663 [AC_TRY_RUN([
 664 main()
 665 {
 666     char buf[4096];
 667     int r1 = tgetent(buf, "!@#$%^&*");
 668     int r2 = tgetent(buf, "vt100");
 669     if (r1 < 0 && r2 == 0) {
 670         char tbuf[1024], *u;
 671         u = tbuf;
 672         tgetstr("cl", &u);
 673         creat("conftest.tgetent0", 0640);
 674     }
 675     exit(r1 == r2);
 676 }
 677 ],
 678   if test -f conftest.tgetent0; then
 679     nmh_cv_func_tgetent_zero_success=yes
 680   else
 681     nmh_cv_func_tgetent_zero_success=no
 682   fi,
 683   nmh_cv_func_tgetent_zero_success=no,
 684   nmh_cv_func_tgetent_zero_success=no)])
 685 AH_TEMPLATE([TGETENT_SUCCESS],
 686 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 687 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 688   AC_DEFINE(TGETENT_SUCCESS, 0)
 689 else
 690   AC_DEFINE(TGETENT_SUCCESS, 1)
 691 fi
 692
 693 dnl Now put the libraries back to what it was before we
 694 dnl starting checking the termcap library.
 695 LIBS="$nmh_save_LIBS"
 696
 697 dnl --------------
 698 dnl CHECK TYPEDEFS
 699 dnl --------------
 700 AC_TYPE_PID_T
 701 AC_TYPE_OFF_T
 702 AC_TYPE_UID_T
 703 AC_TYPE_MODE_T
 704 AC_TYPE_SIZE_T
 705
 706 dnl ----------------
 707 dnl CHECK STRUCTURES
 708 dnl ----------------
 709
 710 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 711 dnl (FreeBSD has a timezone() function but not a timezone global
 712 dnl variable that is visible).
 713 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 714
 715 AC_STRUCT_DIRENT_D_TYPE
 716
 717 dnl Where is <signal.h> located?  Needed as input for signames.awk
 718 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 719 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 720                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 721                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 722                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 723                  /usr/include/sys/signal.h      dnl Almost everybody else
 724                  /dev/null;                     dnl Just in case we fall through
 725 do
 726   test -f $SIGNAL_H && \
 727   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 728   break
 729 done
 730 nmh_cv_path_signal_h=$SIGNAL_H
 731 ])
 732 SIGNAL_H=$nmh_cv_path_signal_h
 733 AC_SUBST(SIGNAL_H)dnl
 734
 735 dnl
 736 dnl Sigh, this is required because under the new world order autoconf has
 737 dnl nothing to create in a few of the build directories when doing an object
 738 dnl tree build.  So make sure we created certain directories if they don't
 739 dnl exist.
 740 dnl
 741
 742 AC_CONFIG_COMMANDS([build-directories],
 743 [test -d etc || ${MKDIR_P} etc
 744 test -d man || ${MKDIR_P} man])
 745
 746 AC_CONFIG_COMMANDS_POST([
 747
 748 dnl These odd looking assignments are done to expand out unexpanded
 749 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 750 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 751 dnl again to get the final answer.
 752 dnl We only use the expanded versions to print the install paths in
 753 dnl the final summary and should use them nowhere else (see the autoconf
 754 dnl docs for the rationale for bindir etc being unexpanded).
 755 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 756 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 757 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 758 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 759 eval "nmhrpm=${nmhrpm}";
 760
 761 AC_MSG_NOTICE([
 762 nmh configuration
 763 -----------------
 764 nmh version                : AC_PACKAGE_VERSION
 765 host os                    : ${host}
 766 compiler                   : ${CC}
 767 compiler flags             : ${CFLAGS}
 768 linker flags               : ${LDFLAGS}
 769 preprocessor flags         : ${CPPFLAGS}
 770 source code location       : ${srcdir}
 771 binary install path        : ${nmhbin}
 772 library install path       : ${nmhlib}
 773 config files install path  : ${nmhsysconf}
 774 man page install path      : ${nmhman}
 775 RPM build root             : ${nmhrpm}
 776 backup prefix              : ${backup_prefix}
 777 transport system           : ${MTS}
 778 file locking type          : ${LOCKTYPE}
 779 default smtp servers       : ${smtpservers}
 780 default editor             : ${editorpath}
 781 default pager              : ${pagerpath}
 782 SASL support               : ${sasl_support}
 783 TLS support                : ${tls_support}
 784 ])])dnl
 785
 786 dnl ---------------
 787 dnl OUTPUT MAKEFILE
 788 dnl ---------------
 789 AC_CONFIG_FILES([Makefile test/common.sh])
 790 AC_OUTPUT