git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Do you want to disable use of locale functions
  34 AH_TEMPLATE([LOCALE],
  35 [Undefine if you don't want locale features.  By default this is defined.])
  36 AC_ARG_ENABLE([locale],
  37   [AC_HELP_STRING([--disable-locale], [turn off locale features])],
  38   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  39   [AC_DEFINE(LOCALE)])
  40
  41 dnl Do you want client-side support for using SASL for authentication?
  42 dnl Note that this code will be enabled for both POP and SMTP
  43 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  44   [Enable SASL support via the Cyrus SASL library]))
  45 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  46       AC_DEFINE([CYRUS_SASL], [1],
  47                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  48       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  49             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  50             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  51       sasl_support=yes], [sasl_support=no])
  52
  53 dnl Do you want client-side support for encryption with TLS?
  54 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  55 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  56       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  57       tls_support=yes],[tls_support=no])
  58
  59 dnl What should be the default editor?
  60 AC_ARG_WITH([editor],
  61   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  62
  63 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  64
  65 dnl Set the backup prefix
  66 AC_ARG_WITH([hash-backup],
  67   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  68 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  69       [backup_prefix="#"], [backup_prefix=","])
  70 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  71     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  72
  73 dnl What method of locking to use?
  74 AC_ARG_WITH(locking,
  75   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  76   [specify the file locking method]))
  77
  78 if test x"$with_locking" = x"dot"; then
  79   LOCKTYPE="dot"
  80   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  81 elif test x"$with_locking" = x"flock"; then
  82   LOCKTYPE="flock"
  83   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  84 elif test x"$with_locking" = x"lockf"; then
  85   LOCKTYPE="lockf"
  86   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  87 elif test x"$with_locking" = x"fcntl"; then
  88   LOCKTYPE="fcntl"
  89   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  90 else
  91   LOCKTYPE="dot"
  92   AC_DEFINE(DOT_LOCKING)dnl
  93 fi
  94
  95 dnl Should we use a locking directory?
  96 AC_ARG_ENABLE([lockdir], [
  97   AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
  98   AS_IF([test "x$enableval" = xyes],[
  99     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 100   AS_IF([test "x$LOCKTYPE" != xdot],[
 101     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 102   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 103                      [Directory to store dot-locking lock files])
 104 ])
 105
 106 dnl What method of posting should post use?
 107 AC_ARG_WITH([mts],
 108   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 109   [specify the default mail transport agent/service]))
 110
 111 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 112       [test x"$with_mts" = x"sendmail"], [MTS="sendmail"],
 113       [MTS="smtp"])
 114 AC_SUBST([MTS])dnl
 115
 116 dnl What should be the default pager?
 117 AC_ARG_WITH([pager],
 118   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 119
 120 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 121
 122 dnl If a pager is not explicitly specified, then look for one.
 123 dnl Fall back to `cat', to avoid catastrophic failure of
 124 dnl `mhshow', et al., if pagerpath is set to `no'.
 125 if test -z "$pagerpath"; then
 126   pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 127   AC_PATH_PROGS([pagerpath], [more less most cat], [no], [$pathtmp])
 128 fi
 129 AC_SUBST(pagerpath)dnl
 130
 131 dnl What should be the default mail server(s)?
 132 AC_ARG_WITH(smtpservers,
 133   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 134   [specify the default SMTP server(s) @<:@localhost@:>@]))
 135 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 136       [smtpservers="localhost"])
 137 AC_SUBST([smtpservers])dnl
 138
 139 dnl ----------------------------------------------------
 140 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 141 dnl ----------------------------------------------------
 142 AC_PREFIX_DEFAULT([/usr/local/nmh])
 143
 144 dnl ------------------
 145 dnl CHECK THE COMPILER
 146 dnl ------------------
 147 dnl We want these before the checks,
 148 dnl so the checks can modify their values.
 149 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 150 if test x"$enable_debug" = x"yes"; then
 151   test -z "$LDFLAGS" && LDFLAGS=-g
 152 fi
 153
 154 AC_PROG_CC
 155 AM_PROG_CC_C_O
 156
 157 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 158   [nmh_cv_has_unusedmacros],
 159   [nmh_saved_cppflags="$CPPFLAGS"
 160    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 161    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 162    CPPFLAGS="$nmh_saved_cppflags"])
 163
 164 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 165   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 166                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 167   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 168 fi
 169 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 170
 171 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 172 [nmh_saved_cflags="$CFLAGS"
 173  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 174  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 175  CFLAGS="$nmh_saved_cflags"])
 176
 177 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 178 [nmh_saved_cflags="$CFLAGS"
 179  CFLAGS="$CFLAGS -Wno-pointer-sign"
 180  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 181  CFLAGS="$nmh_saved_cflags"])
 182
 183 dnl if the user hasn't specified CFLAGS, then
 184 dnl   if compiler is gcc, then
 185 dnl    use -O2 and some warning flags
 186 dnl   else use -O
 187 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 188 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 189 dnl warnings which are probably mostly spurious and which in any case we
 190 dnl don't want to deal with now.
 191 if test "$nmh_cv_has_noptrsign" = "yes"; then
 192     if test "$nmh_cv_has_wextra" = "yes"; then
 193         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered -Wno-pointer-sign"
 194     else
 195         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 196     fi
 197 else
 198     if test "$nmh_cv_has_wextra" = "yes"; then
 199         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered"
 200     else
 201         nmh_gcc_warnflags="-Wall"
 202     fi
 203 fi
 204
 205 if test -n "$auto_cflags"; then
 206   if test x"$enable_debug" = x"yes"; then
 207     if test -n "$GCC"; then
 208       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 209     else
 210       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 211     fi
 212   else
 213     if test -z "$LDFLAGS"; then
 214       case "$build_os" in
 215         darwin*)
 216           LDFLAGS=
 217           ;;
 218         *)
 219           LDFLAGS=-s
 220           ;;
 221       esac
 222     fi
 223     if test -n "$GCC"; then
 224       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 225     else
 226       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 227     fi
 228   fi
 229 fi
 230
 231 AC_C_CONST              dnl Does compiler support `const'.
 232
 233 dnl ------------------
 234 dnl CHECK FOR PROGRAMS
 235 dnl ------------------
 236 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 237 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 238 AC_PROG_RANLIB          dnl Check for `ranlib'
 239 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 240 AC_PROG_SED             dnl Check for Posix-compliant sed
 241 AC_PROG_LEX             dnl Check for lex/flex
 242
 243 dnl Look for `cut'
 244 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 245 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 246
 247 dnl
 248 dnl Check for MD5 program and formatting command
 249 dnl
 250 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 251 AS_CASE(["${MD5SUM}"],
 252         [md5sum], [MD5FMT="cat"],
 253         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 254         [MD5FMT="missing"])
 255 AC_SUBST([MD5FMT])
 256
 257 dnl ----------------------------------------------
 258 dnl check for lclint, and lint if it doesn't exist
 259 dnl ----------------------------------------------
 260 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 261 if test x$ac_cv_prog_linttmp1 != xno ; then
 262   LINT=$ac_cv_prog_linttmp1
 263   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 264 else
 265   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 266   if test x$ac_cv_prog_linttmp2 != xno ; then
 267     LINT=$ac_cv_prog_linttmp2
 268     LINTFLAGS=""
 269   else
 270     LINT="echo 'No lint program found'"
 271     LINTFLAGS=""
 272   fi
 273 fi
 274 AC_SUBST([LINT])dnl
 275 AC_SUBST([LINTFLAGS])dnl
 276
 277 dnl Look for `ls'
 278 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 279 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 280
 281 dnl See how we get ls to display the owner and the group
 282 if test "$lspath" != "no"; then
 283   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 284                  [nmh_cv_ls_grpopt],
 285   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 286     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 287     dnl ls, it would seem -l gave us both the user and group.  On this type of
 288     dnl ls, -g makes _only_ the group be displayed (and not the user).
 289     nmh_cv_ls_grpopt="-l"
 290   else
 291     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 292     nmh_cv_ls_grpopt="-lg"
 293   fi])
 294 fi
 295
 296 dnl Look for `sendmail'
 297 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 298 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 299
 300 dnl Look for `vi'
 301 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 302 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 303
 304 dnl If editor is not specified yet,
 305 dnl then use `vi' as the default.
 306 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 307 AC_SUBST([editorpath])dnl
 308
 309 dnl ----------------------------------------------------------
 310 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 311 dnl ----------------------------------------------------------
 312 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 313 [for mailspool in /var/mail        dnl
 314                   /var/spool/mail  dnl
 315                   /usr/spool/mail  dnl
 316                   /dev/null;       dnl Just in case we fall through
 317 do
 318   test -d $mailspool && break
 319 done
 320 nmh_cv_mailspool=$mailspool
 321 ])
 322 mailspool=$nmh_cv_mailspool
 323 AC_SUBST([mailspool])dnl
 324
 325 dnl See whether the mail spool directory is world-writable.
 326 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 327   AC_CACHE_CHECK(whether the mail spool is world-writable,
 328                  nmh_cv_mailspool_world_writable,
 329   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 330     nmh_cv_mailspool_world_writable=no
 331   else
 332     nmh_cv_mailspool_world_writable=yes
 333   fi])
 334 fi
 335
 336 dnl Also, check for liblockfile (as found on Debian systems)
 337 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 338
 339 dnl and whether its companion program dotlockfile is setgid
 340 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 341 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 342   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 343     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 344     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 345         nmh_cv_dotlockfile_setgid=yes
 346       else
 347         nmh_cv_dotlockfile_setgid=no
 348       fi])
 349   fi
 350 fi
 351
 352 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 353 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 354 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 355   dnl do we really need both of these?
 356   AC_DEFINE(MAILGROUP,1,
 357     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 358   SETGID_MAIL=1
 359 fi
 360 AC_SUBST(SETGID_MAIL)dnl
 361
 362 dnl Use ls to see which group owns the mail spool directory.
 363 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 364 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 365 ])
 366 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 367 AC_SUBST(MAIL_SPOOL_GRP)dnl
 368
 369 dnl ------------------
 370 dnl CHECK HEADER FILES
 371 dnl ------------------
 372
 373 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 374 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 375 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 376 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 377 dnl declared; if so they should have an entry added to this case statement.
 378 dnl NB that we must define this on the compiler command line, not in config.h,
 379 dnl because it must be set before any system header is included and there's no
 380 dnl portable way to make sure that files generated by lex include config.h
 381 dnl before system header files.
 382
 383 AS_CASE(["$host_os"],
 384         [linux*],
 385         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 386           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 387                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 388
 389 AC_HEADER_STDC
 390 AC_HEADER_TIOCGWINSZ
 391 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 392                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 393                   sys/param.h sys/time.h sys/stream.h])
 394
 395 dnl
 396 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 397 dnl really use a whole set of them, but this check should be
 398 dnl sufficient.
 399 dnl
 400 AC_CHECK_HEADER(libio.h, [
 401   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 402     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 403
 404 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 405   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 406 [[#if HAVE_SYS_STREAM_H
 407 #  include <sys/stream.h>
 408 #endif
 409 ]])
 410
 411 dnl ---------------
 412 dnl CHECK FUNCTIONS
 413 dnl ---------------
 414 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo])
 415
 416 dnl Check for multibyte character set support
 417 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 418     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 419   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 420     [Define to enable support for multibyte character sets.])
 421 fi
 422
 423 dnl -------------------
 424 dnl CHECK FOR LIBRARIES
 425 dnl -------------------
 426 dnl Check location of modf
 427 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 428
 429 dnl Checks for network libraries (nsl, socket)
 430 NMH_CHECK_NETLIBS
 431
 432 NMH_READLINE
 433
 434 termcap_curses_order="termcap curses ncurses"
 435 for lib in $termcap_curses_order; do
 436   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 437 done
 438 AC_SUBST([TERMLIB])dnl
 439 AS_IF([test "x$TERMLIB" = "x"],
 440       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 441 or ncurses library or package that you can install?])])
 442
 443
 444 dnl ---------------
 445 dnl CHECK FOR ICONV
 446 dnl ---------------
 447
 448 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 449 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 450   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 451   if test "x$ac_found_iconv" = "xno"; then
 452     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 453     if test "x$ac_found_iconv" = "xno"; then
 454       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 455     fi
 456     if test "x$ac_found_iconv" != "xno"; then
 457       ICONVLIB="-liconv"
 458     fi
 459   else
 460     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 461     AC_CHECK_DECL(_libiconv_version,
 462       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 463       [ #include <iconv.h> ])
 464   fi
 465 fi
 466 if test "x$ac_found_iconv" = xyes; then
 467   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 468 fi
 469 AC_SUBST([ICONVLIB])
 470
 471 dnl Check if iconv uses const in prototype declaration
 472 if test "x$ac_found_iconv" = "xyes"; then
 473   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 474     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 475         #include <iconv.h>]],
 476         [[#ifdef __cplusplus
 477           "C"
 478           #endif
 479           #if defined(__STDC__) || defined(__cplusplus)
 480           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 481           #else
 482           size_t iconv();
 483           #endif]])],
 484       [ac_cv_iconv_const=],
 485       [ac_cv_iconv_const=const])])
 486   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 487     [Define as const if the declaration of iconv() needs const.])
 488 fi
 489
 490 dnl --------------
 491 dnl CHECK FOR NDBM
 492 dnl --------------
 493
 494 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 495             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 496 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 497             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 498
 499 if test "$nmh_ndbm" = "autodetect"; then
 500   if test "$nmh_ndbmheader" != "autodetect"; then
 501     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 502   else
 503
 504     dnl There are at least four implementations of ndbm, and
 505     dnl several of those can be in different places at the whim
 506     dnl of the system integrator. A good summary of this mess
 507     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 508
 509     dnl Classic ndbm with no library required (eg NetBSD): try this
 510     dnl first so we don't accidentally link in a pointless but harmless
 511     dnl library in one of the later ndbm.h+libfoo tests:
 512     NMH_CHECK_NDBM(ndbm.h,,,
 513     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 514       NMH_CHECK_NDBM(db.h,db,,
 515     dnl Berkeley DBv1 emulating ndbm:
 516         NMH_CHECK_NDBM(ndbm.h,db,,
 517           NMH_CHECK_NDBM(ndbm.h,db1,,
 518     dnl Classic ndbm:
 519             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 520     dnl glibc2.1 systems put db1 in a subdir:
 521               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 522     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 523     dnl and possibly needing gbdm_compat library:
 524                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 525                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 526                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 527                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 528
 529   fi
 530 else
 531   dnl We don't really need to check that the user-specified values work,
 532   dnl but it is a convenience to the user to bomb out early rather than
 533   dnl after configure and half the compile process.
 534   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 535 fi
 536
 537 if test "$nmh_ndbm_found" = "no"; then
 538   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 539 else
 540   dnl Now export the lib/header to our makefile/config.h:
 541   if test x"$nmh_ndbmheader" != x; then
 542     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 543       [Define to the header containing the ndbm API prototypes.])
 544   fi
 545   if test x"$nmh_ndbm" != x; then
 546     NDBM_LIBS="-l$nmh_ndbm"
 547   else
 548     NDBM_LIBS=
 549   fi
 550   AC_SUBST([NDBM_LIBS])
 551 fi
 552
 553 dnl ------------------
 554 dnl Set RPM build root
 555 dnl ------------------
 556 dnl nmhrpm is used in the final summary, see below.  The default value is
 557 dnl reported there as ./RPM, consistent with the reporting of the default
 558 dnl source code location as ., but its absolute path is used in the Makefile.
 559 AC_ARG_WITH(rpmdir,
 560   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 561   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 562           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 563 AC_SUBST([rpmdir])
 564
 565
 566 dnl --------------------
 567 dnl CHECK FOR CYRUS-SASL
 568 dnl --------------------
 569
 570 AS_IF([test x"$sasl_support" = x"yes"],[
 571   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 572   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 573     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 574 AC_SUBST([SASLLIB])
 575
 576 dnl -----------------
 577 dnl CHECK FOR OPENSSL
 578 dnl -----------------
 579
 580 AS_IF([test x"$tls_support" = x"yes"],[
 581   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 582   AC_CHECK_LIB([crypto], [BIO_write], ,
 583     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 584   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 585     [AC_MSG_ERROR([OpenSSL library not found])])])
 586
 587 dnl ---------------------
 588 dnl CHECK TERMCAP LIBRARY
 589 dnl ---------------------
 590
 591 dnl Add the termcap library, so that the following configure
 592 dnl tests will find it when it tries to link test programs.
 593 nmh_save_LIBS="$LIBS"
 594 LIBS="$TERMLIB $LIBS"
 595
 596 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 597 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 598 dnl in tgetstr().
 599 dnl Under Cygwin test program crashes but exit code is still 0. So,
 600 dnl we test for a file that porgram should create
 601 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 602 [Define to 1 if tgetent() accepts NULL as a buffer.])
 603 AC_CACHE_CHECK(if tgetent accepts NULL,
 604 nmh_cv_func_tgetent_accepts_null,
 605 [AC_TRY_RUN([
 606 main()
 607 {
 608     char buf[4096];
 609     int r1 = tgetent(buf, "vt100");
 610     int r2 = tgetent((char*)0,"vt100");
 611     if (r1 >= 0 && r1 == r2) {
 612         char tbuf[1024], *u;
 613         u = tbuf;
 614         tgetstr("cl", &u);
 615         creat("conftest.tgetent", 0640);
 616     }
 617     exit((r1 != r2) || r2 == -1);
 618 }
 619 ],
 620   if test -f conftest.tgetent; then
 621     nmh_cv_func_tgetent_accepts_null=yes
 622   else
 623     nmh_cv_func_tgetent_accepts_null=no
 624   fi,
 625   nmh_cv_func_tgetent_accepts_null=no,
 626   nmh_cv_func_tgetent_accepts_null=no)])
 627 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 628   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 629 fi
 630 AC_CACHE_CHECK(if tgetent returns 0 on success,
 631 nmh_cv_func_tgetent_zero_success,
 632 [AC_TRY_RUN([
 633 main()
 634 {
 635     char buf[4096];
 636     int r1 = tgetent(buf, "!@#$%^&*");
 637     int r2 = tgetent(buf, "vt100");
 638     if (r1 < 0 && r2 == 0) {
 639         char tbuf[1024], *u;
 640         u = tbuf;
 641         tgetstr("cl", &u);
 642         creat("conftest.tgetent0", 0640);
 643     }
 644     exit(r1 == r2);
 645 }
 646 ],
 647   if test -f conftest.tgetent0; then
 648     nmh_cv_func_tgetent_zero_success=yes
 649   else
 650     nmh_cv_func_tgetent_zero_success=no
 651   fi,
 652   nmh_cv_func_tgetent_zero_success=no,
 653   nmh_cv_func_tgetent_zero_success=no)])
 654 AH_TEMPLATE([TGETENT_SUCCESS],
 655 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 656 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 657   AC_DEFINE(TGETENT_SUCCESS, 0)
 658 else
 659   AC_DEFINE(TGETENT_SUCCESS, 1)
 660 fi
 661
 662 dnl Now put the libraries back to what it was before we
 663 dnl starting checking the termcap library.
 664 LIBS="$nmh_save_LIBS"
 665
 666 dnl --------------
 667 dnl CHECK TYPEDEFS
 668 dnl --------------
 669 AC_TYPE_PID_T
 670 AC_TYPE_OFF_T
 671 AC_TYPE_UID_T
 672 AC_TYPE_MODE_T
 673 AC_TYPE_SIZE_T
 674
 675 dnl ----------------
 676 dnl CHECK STRUCTURES
 677 dnl ----------------
 678
 679 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 680 dnl (FreeBSD has a timezone() function but not a timezone global
 681 dnl variable that is visible).
 682 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 683
 684 AC_STRUCT_DIRENT_D_TYPE
 685
 686 dnl Where is <signal.h> located?  Needed as input for signames.awk
 687 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 688 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 689                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 690                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 691                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 692                  /usr/include/sys/signal.h      dnl Almost everybody else
 693                  /dev/null;                     dnl Just in case we fall through
 694 do
 695   test -f $SIGNAL_H && \
 696   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 697   break
 698 done
 699 nmh_cv_path_signal_h=$SIGNAL_H
 700 ])
 701 SIGNAL_H=$nmh_cv_path_signal_h
 702 AC_SUBST(SIGNAL_H)dnl
 703
 704 dnl
 705 dnl Sigh, this is required because under the new world order autoconf has
 706 dnl nothing to create in a few of the build directories when doing an object
 707 dnl tree build.  So make sure we created certain directories if they don't
 708 dnl exist.
 709 dnl
 710
 711 AC_CONFIG_COMMANDS([build-directories],
 712 [test -d etc || ${MKDIR_P} etc
 713 test -d man || ${MKDIR_P} man])
 714
 715 AC_CONFIG_COMMANDS_POST([
 716
 717 dnl These odd looking assignments are done to expand out unexpanded
 718 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 719 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 720 dnl again to get the final answer.
 721 dnl We only use the expanded versions to print the install paths in
 722 dnl the final summary and should use them nowhere else (see the autoconf
 723 dnl docs for the rationale for bindir etc being unexpanded).
 724 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 725 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 726 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 727 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 728 eval "nmhrpm=${nmhrpm}";
 729
 730 AC_MSG_NOTICE([
 731 nmh configuration
 732 -----------------
 733 nmh version                : AC_PACKAGE_VERSION
 734 host os                    : ${host}
 735 compiler                   : ${CC}
 736 compiler flags             : ${CFLAGS}
 737 linker flags               : ${LDFLAGS}
 738 preprocessor flags         : ${CPPFLAGS}
 739 source code location       : ${srcdir}
 740 binary install path        : ${nmhbin}
 741 library install path       : ${nmhlib}
 742 config files install path  : ${nmhsysconf}
 743 man page install path      : ${nmhman}
 744 RPM build root             : ${nmhrpm}
 745 backup prefix              : ${backup_prefix}
 746 transport system           : ${MTS}
 747 file locking type          : ${LOCKTYPE}
 748 default smtp servers       : ${smtpservers}
 749 default editor             : ${editorpath}
 750 default pager              : ${pagerpath}
 751 SASL support               : ${sasl_support}
 752 TLS support                : ${tls_support}
 753 ])])dnl
 754
 755 dnl ---------------
 756 dnl OUTPUT MAKEFILE
 757 dnl ---------------
 758 AC_CONFIG_FILES([Makefile test/common.sh])
 759 AC_OUTPUT