git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Do you want to disable use of locale functions
  34 AH_TEMPLATE([LOCALE],
  35 [Undefine if you don't want locale features.  By default this is defined.])
  36 AC_ARG_ENABLE([locale],
  37   [AC_HELP_STRING([--disable-locale], [turn off locale features])],
  38   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  39   [AC_DEFINE(LOCALE)])
  40
  41 dnl Do you want client-side support for using SASL for authentication?
  42 dnl Note that this code will be enabled for both POP and SMTP
  43 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  44   [Enable SASL support via the Cyrus SASL library]))
  45 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  46       AC_DEFINE([CYRUS_SASL], [1],
  47                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  48       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  49             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  50             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  51       sasl_support=yes], [sasl_support=no])
  52
  53 dnl Do you want client-side support for encryption with TLS?
  54 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  55 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  56       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  57       tls_support=yes],[tls_support=no])
  58
  59 dnl What should be the default editor?
  60 AC_ARG_WITH([editor],
  61   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  62
  63 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  64
  65 dnl Set the backup prefix
  66 AC_ARG_WITH([hash-backup],
  67   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  68 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  69       [backup_prefix="#"], [backup_prefix=","])
  70 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  71     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  72
  73 dnl What method of locking to use?
  74 AC_ARG_WITH(locking,
  75   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  76   [specify the file locking method]))
  77
  78 if test x"$with_locking" = x"dot"; then
  79   LOCKTYPE="dot"
  80   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  81 elif test x"$with_locking" = x"flock"; then
  82   LOCKTYPE="flock"
  83   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  84 elif test x"$with_locking" = x"lockf"; then
  85   LOCKTYPE="lockf"
  86   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  87 elif test x"$with_locking" = x"fcntl"; then
  88   LOCKTYPE="fcntl"
  89   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  90 else
  91   LOCKTYPE="dot"
  92   AC_DEFINE(DOT_LOCKING)dnl
  93 fi
  94
  95 dnl Should we use a locking directory?
  96 AC_ARG_ENABLE([lockdir], [
  97   AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
  98   AS_IF([test "x$enableval" = xyes],[
  99     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 100   AS_IF([test "x$LOCKTYPE" != xdot],[
 101     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 102   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 103                      [Directory to store dot-locking lock files])
 104 ])
 105
 106 dnl What method of posting should post use?
 107 AC_ARG_WITH([mts],
 108   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 109   [specify the default mail transport agent/service]))
 110
 111 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 112       [test x"$with_mts" = x"sendmail"], [MTS="sendmail"],
 113       [MTS="smtp"])
 114 AC_SUBST([MTS])dnl
 115
 116 NMH_READLINE
 117
 118 dnl What should be the default pager?
 119 AC_ARG_WITH([pager],
 120   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 121
 122 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 123
 124 dnl What should be the default mail server(s)?
 125 AC_ARG_WITH(smtpservers,
 126   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 127   [specify the default SMTP server(s) @<:@localhost@:>@]))
 128 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 129       [smtpservers="localhost"])
 130 AC_SUBST([smtpservers])dnl
 131
 132 dnl ----------------------------------------------------
 133 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 134 dnl ----------------------------------------------------
 135 AC_PREFIX_DEFAULT([/usr/local/nmh])
 136
 137 dnl ------------------
 138 dnl CHECK THE COMPILER
 139 dnl ------------------
 140 dnl We want these before the checks,
 141 dnl so the checks can modify their values.
 142 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 143 if test x"$enable_debug" = x"yes"; then
 144   test -z "$LDFLAGS" && LDFLAGS=-g
 145 fi
 146
 147 AC_PROG_CC
 148 AM_PROG_CC_C_O
 149
 150 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 151   [nmh_cv_has_unusedmacros],
 152   [nmh_saved_cppflags="$CPPFLAGS"
 153    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 154    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 155    CPPFLAGS="$nmh_saved_cppflags"])
 156
 157 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 158   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 159                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 160   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 161 fi
 162 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 163
 164 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 165 [nmh_saved_cflags="$CFLAGS"
 166  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 167  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 168  CFLAGS="$nmh_saved_cflags"])
 169
 170 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 171 [nmh_saved_cflags="$CFLAGS"
 172  CFLAGS="$CFLAGS -Wno-pointer-sign"
 173  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 174  CFLAGS="$nmh_saved_cflags"])
 175
 176 dnl if the user hasn't specified CFLAGS, then
 177 dnl   if compiler is gcc, then
 178 dnl    use -O2 and some warning flags
 179 dnl   else use -O
 180 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 181 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 182 dnl warnings which are probably mostly spurious and which in any case we
 183 dnl don't want to deal with now.
 184 if test "$nmh_cv_has_noptrsign" = "yes"; then
 185     if test "$nmh_cv_has_wextra" = "yes"; then
 186         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered -Wno-pointer-sign"
 187     else
 188         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 189     fi
 190 else
 191     if test "$nmh_cv_has_wextra" = "yes"; then
 192         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered"
 193     else
 194         nmh_gcc_warnflags="-Wall"
 195     fi
 196 fi
 197
 198 if test -n "$auto_cflags"; then
 199   if test x"$enable_debug" = x"yes"; then
 200     if test -n "$GCC"; then
 201       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 202     else
 203       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 204     fi
 205   else
 206     if test -z "$LDFLAGS"; then
 207       case "$build_os" in
 208         darwin*)
 209           LDFLAGS=
 210           ;;
 211         *)
 212           LDFLAGS=-s
 213           ;;
 214       esac
 215     fi
 216     if test -n "$GCC"; then
 217       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 218     else
 219       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 220     fi
 221   fi
 222 fi
 223
 224 AC_C_CONST              dnl Does compiler support `const'.
 225
 226 dnl ------------------
 227 dnl CHECK FOR PROGRAMS
 228 dnl ------------------
 229 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 230 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 231 AC_PROG_RANLIB          dnl Check for `ranlib'
 232 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 233 AC_PROG_SED             dnl Check for Posix-compliant sed
 234 AC_PROG_LEX             dnl Check for lex/flex
 235
 236 dnl Look for `cut'
 237 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 238 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 239
 240 dnl
 241 dnl Check for MD5 program and formatting command
 242 dnl
 243 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 244 AS_CASE(["${MD5SUM}"],
 245         [md5sum], [MD5FMT="cat"],
 246         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 247         [MD5FMT="missing"])
 248 AC_SUBST([MD5FMT])
 249
 250 dnl ----------------------------------------------
 251 dnl check for lclint, and lint if it doesn't exist
 252 dnl ----------------------------------------------
 253 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 254 if test x$ac_cv_prog_linttmp1 != xno ; then
 255   LINT=$ac_cv_prog_linttmp1
 256   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 257 else
 258   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 259   if test x$ac_cv_prog_linttmp2 != xno ; then
 260     LINT=$ac_cv_prog_linttmp2
 261     LINTFLAGS=""
 262   else
 263     LINT="echo 'No lint program found'"
 264     LINTFLAGS=""
 265   fi
 266 fi
 267 AC_SUBST([LINT])dnl
 268 AC_SUBST([LINTFLAGS])dnl
 269
 270 dnl Look for `ls'
 271 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 272 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 273
 274 dnl See how we get ls to display the owner and the group
 275 if test "$lspath" != "no"; then
 276   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 277                  [nmh_cv_ls_grpopt],
 278   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 279     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 280     dnl ls, it would seem -l gave us both the user and group.  On this type of
 281     dnl ls, -g makes _only_ the group be displayed (and not the user).
 282     nmh_cv_ls_grpopt="-l"
 283   else
 284     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 285     nmh_cv_ls_grpopt="-lg"
 286   fi])
 287 fi
 288
 289 dnl Look for `more'
 290 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 291 AC_PATH_PROG([morepath], [more], [no], [$pathtmp])
 292
 293 dnl If pager is not specified yet,
 294 dnl then use `more' as the default.
 295 if test -z "$pagerpath"; then
 296   pagerpath="$morepath"
 297 fi
 298 AC_SUBST(pagerpath)dnl
 299
 300 dnl Look for `sendmail'
 301 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 302 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 303
 304 dnl Look for `vi'
 305 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 306 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 307
 308 dnl If editor is not specified yet,
 309 dnl then use `vi' as the default.
 310 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 311 AC_SUBST([editorpath])dnl
 312
 313 dnl ----------------------------------------------------------
 314 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 315 dnl ----------------------------------------------------------
 316 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 317 [for mailspool in /var/mail        dnl
 318                   /var/spool/mail  dnl
 319                   /usr/spool/mail  dnl
 320                   /dev/null;       dnl Just in case we fall through
 321 do
 322   test -d $mailspool && break
 323 done
 324 nmh_cv_mailspool=$mailspool
 325 ])
 326 mailspool=$nmh_cv_mailspool
 327 AC_SUBST([mailspool])dnl
 328
 329 dnl See whether the mail spool directory is world-writable.
 330 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 331   AC_CACHE_CHECK(whether the mail spool is world-writable,
 332                  nmh_cv_mailspool_world_writable,
 333   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 334     nmh_cv_mailspool_world_writable=no
 335   else
 336     nmh_cv_mailspool_world_writable=yes
 337   fi])
 338 fi
 339
 340 dnl Also, check for liblockfile (as found on Debian systems)
 341 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 342
 343 dnl and whether its companion program dotlockfile is setgid
 344 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 345 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 346   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 347     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 348     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 349         nmh_cv_dotlockfile_setgid=yes
 350       else
 351         nmh_cv_dotlockfile_setgid=no
 352       fi])
 353   fi
 354 fi
 355
 356 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 357 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 358 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 359   dnl do we really need both of these?
 360   AC_DEFINE(MAILGROUP,1,
 361     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 362   SETGID_MAIL=1
 363 fi
 364 AC_SUBST(SETGID_MAIL)dnl
 365
 366 dnl Use ls to see which group owns the mail spool directory.
 367 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 368 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 369 ])
 370 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 371 AC_SUBST(MAIL_SPOOL_GRP)dnl
 372
 373 dnl ------------------
 374 dnl CHECK HEADER FILES
 375 dnl ------------------
 376
 377 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 378 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 379 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 380 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 381 dnl declared; if so they should have an entry added to this case statement.
 382 dnl NB that we must define this on the compiler command line, not in config.h,
 383 dnl because it must be set before any system header is included and there's no
 384 dnl portable way to make sure that files generated by lex include config.h
 385 dnl before system header files.
 386
 387 AS_CASE(["$host_os"],
 388         [linux*],
 389         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 390           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 391                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 392
 393 AC_HEADER_STDC
 394 AC_HEADER_TIOCGWINSZ
 395 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 396                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 397                   sys/param.h sys/time.h sys/stream.h])
 398
 399 dnl
 400 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 401 dnl really use a whole set of them, but this check should be
 402 dnl sufficient.
 403 dnl
 404 AC_CHECK_HEADER(libio.h, [
 405   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 406     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 407
 408 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 409   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 410 [[#if HAVE_SYS_STREAM_H
 411 #  include <sys/stream.h>
 412 #endif
 413 ]])
 414
 415 dnl ---------------
 416 dnl CHECK FUNCTIONS
 417 dnl ---------------
 418 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo])
 419
 420 dnl Check for multibyte character set support
 421 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 422     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 423   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 424     [Define to enable support for multibyte character sets.])
 425 fi
 426
 427 dnl -------------------
 428 dnl CHECK FOR LIBRARIES
 429 dnl -------------------
 430 dnl Check location of modf
 431 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 432
 433 dnl Checks for network libraries (nsl, socket)
 434 NMH_CHECK_NETLIBS
 435
 436 termcap_curses_order="termcap curses ncurses"
 437 for lib in $termcap_curses_order; do
 438   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 439 done
 440 AC_SUBST([TERMLIB])dnl
 441 AS_IF([test "x$TERMLIB" = "x"],
 442       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 443 or ncurses library or package that you can install?])])
 444
 445
 446 dnl ---------------
 447 dnl CHECK FOR ICONV
 448 dnl ---------------
 449
 450 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 451 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 452   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 453   if test "x$ac_found_iconv" = "xno"; then
 454     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 455     if test "x$ac_found_iconv" = "xno"; then
 456       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 457     fi
 458     if test "x$ac_found_iconv" != "xno"; then
 459       ICONVLIB="-liconv"
 460     fi
 461   else
 462     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 463     AC_CHECK_DECL(_libiconv_version,
 464       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 465       [ #include <iconv.h> ])
 466   fi
 467 fi
 468 if test "x$ac_found_iconv" = xyes; then
 469   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 470 fi
 471 AC_SUBST([ICONVLIB])
 472
 473 dnl Check if iconv uses const in prototype declaration
 474 if test "x$ac_found_iconv" = "xyes"; then
 475   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 476     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 477         #include <iconv.h>]],
 478         [[#ifdef __cplusplus
 479           "C"
 480           #endif
 481           #if defined(__STDC__) || defined(__cplusplus)
 482           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 483           #else
 484           size_t iconv();
 485           #endif]])],
 486       [ac_cv_iconv_const=],
 487       [ac_cv_iconv_const=const])])
 488   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 489     [Define as const if the declaration of iconv() needs const.])
 490 fi
 491
 492 dnl --------------
 493 dnl CHECK FOR NDBM
 494 dnl --------------
 495
 496 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 497             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 498 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 499             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 500
 501 if test "$nmh_ndbm" = "autodetect"; then
 502   if test "$nmh_ndbmheader" != "autodetect"; then
 503     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 504   else
 505
 506     dnl There are at least four implementations of ndbm, and
 507     dnl several of those can be in different places at the whim
 508     dnl of the system integrator. A good summary of this mess
 509     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 510
 511     dnl Classic ndbm with no library required (eg NetBSD): try this
 512     dnl first so we don't accidentally link in a pointless but harmless
 513     dnl library in one of the later ndbm.h+libfoo tests:
 514     NMH_CHECK_NDBM(ndbm.h,,,
 515     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 516       NMH_CHECK_NDBM(db.h,db,,
 517     dnl Berkeley DBv1 emulating ndbm:
 518         NMH_CHECK_NDBM(ndbm.h,db,,
 519           NMH_CHECK_NDBM(ndbm.h,db1,,
 520     dnl Classic ndbm:
 521             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 522     dnl glibc2.1 systems put db1 in a subdir:
 523               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 524     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 525     dnl and possibly needing gbdm_compat library:
 526                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 527                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 528                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 529                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 530
 531   fi
 532 else
 533   dnl We don't really need to check that the user-specified values work,
 534   dnl but it is a convenience to the user to bomb out early rather than
 535   dnl after configure and half the compile process.
 536   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 537 fi
 538
 539 if test "$nmh_ndbm_found" = "no"; then
 540   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 541 else
 542   dnl Now export the lib/header to our makefile/config.h:
 543   if test x"$nmh_ndbmheader" != x; then
 544     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 545       [Define to the header containing the ndbm API prototypes.])
 546   fi
 547   if test x"$nmh_ndbm" != x; then
 548     NDBM_LIBS="-l$nmh_ndbm"
 549   else
 550     NDBM_LIBS=
 551   fi
 552   AC_SUBST([NDBM_LIBS])
 553 fi
 554
 555 dnl ------------------
 556 dnl Set RPM build root
 557 dnl ------------------
 558 dnl nmhrpm is used in the final summary, see below.  The default value is
 559 dnl reported there as ./RPM, consistent with the reporting of the default
 560 dnl source code location as ., but its absolute path is used in the Makefile.
 561 AC_ARG_WITH(rpmdir,
 562   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 563   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 564           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 565 AC_SUBST([rpmdir])
 566
 567
 568 dnl --------------------
 569 dnl CHECK FOR CYRUS-SASL
 570 dnl --------------------
 571
 572 AS_IF([test x"$sasl_support" = x"yes"],[
 573   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 574   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 575     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 576 AC_SUBST([SASLLIB])
 577
 578 dnl -----------------
 579 dnl CHECK FOR OPENSSL
 580 dnl -----------------
 581
 582 AS_IF([test x"$tls_support" = x"yes"],[
 583   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 584   AC_CHECK_LIB([crypto], [BIO_write], ,
 585     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 586   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 587     [AC_MSG_ERROR([OpenSSL library not found])])])
 588
 589 dnl ---------------------
 590 dnl CHECK TERMCAP LIBRARY
 591 dnl ---------------------
 592
 593 dnl Add the termcap library, so that the following configure
 594 dnl tests will find it when it tries to link test programs.
 595 nmh_save_LIBS="$LIBS"
 596 LIBS="$TERMLIB $LIBS"
 597
 598 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 599 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 600 dnl in tgetstr().
 601 dnl Under Cygwin test program crashes but exit code is still 0. So,
 602 dnl we test for a file that porgram should create
 603 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 604 [Define to 1 if tgetent() accepts NULL as a buffer.])
 605 AC_CACHE_CHECK(if tgetent accepts NULL,
 606 nmh_cv_func_tgetent_accepts_null,
 607 [AC_TRY_RUN([
 608 main()
 609 {
 610     char buf[4096];
 611     int r1 = tgetent(buf, "vt100");
 612     int r2 = tgetent((char*)0,"vt100");
 613     if (r1 >= 0 && r1 == r2) {
 614         char tbuf[1024], *u;
 615         u = tbuf;
 616         tgetstr("cl", &u);
 617         creat("conftest.tgetent", 0640);
 618     }
 619     exit((r1 != r2) || r2 == -1);
 620 }
 621 ],
 622   if test -f conftest.tgetent; then
 623     nmh_cv_func_tgetent_accepts_null=yes
 624   else
 625     nmh_cv_func_tgetent_accepts_null=no
 626   fi,
 627   nmh_cv_func_tgetent_accepts_null=no,
 628   nmh_cv_func_tgetent_accepts_null=no)])
 629 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 630   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 631 fi
 632 AC_CACHE_CHECK(if tgetent returns 0 on success,
 633 nmh_cv_func_tgetent_zero_success,
 634 [AC_TRY_RUN([
 635 main()
 636 {
 637     char buf[4096];
 638     int r1 = tgetent(buf, "!@#$%^&*");
 639     int r2 = tgetent(buf, "vt100");
 640     if (r1 < 0 && r2 == 0) {
 641         char tbuf[1024], *u;
 642         u = tbuf;
 643         tgetstr("cl", &u);
 644         creat("conftest.tgetent0", 0640);
 645     }
 646     exit(r1 == r2);
 647 }
 648 ],
 649   if test -f conftest.tgetent0; then
 650     nmh_cv_func_tgetent_zero_success=yes
 651   else
 652     nmh_cv_func_tgetent_zero_success=no
 653   fi,
 654   nmh_cv_func_tgetent_zero_success=no,
 655   nmh_cv_func_tgetent_zero_success=no)])
 656 AH_TEMPLATE([TGETENT_SUCCESS],
 657 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 658 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 659   AC_DEFINE(TGETENT_SUCCESS, 0)
 660 else
 661   AC_DEFINE(TGETENT_SUCCESS, 1)
 662 fi
 663
 664 dnl Now put the libraries back to what it was before we
 665 dnl starting checking the termcap library.
 666 LIBS="$nmh_save_LIBS"
 667
 668 dnl --------------
 669 dnl CHECK TYPEDEFS
 670 dnl --------------
 671 AC_TYPE_PID_T
 672 AC_TYPE_OFF_T
 673 AC_TYPE_UID_T
 674 AC_TYPE_MODE_T
 675 AC_TYPE_SIZE_T
 676
 677 dnl ----------------
 678 dnl CHECK STRUCTURES
 679 dnl ----------------
 680
 681 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 682 dnl (FreeBSD has a timezone() function but not a timezone global
 683 dnl variable that is visible).
 684 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 685
 686 AC_STRUCT_DIRENT_D_TYPE
 687
 688 dnl Where is <signal.h> located?  Needed as input for signames.awk
 689 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 690 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 691                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 692                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 693                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 694                  /usr/include/sys/signal.h      dnl Almost everybody else
 695                  /dev/null;                     dnl Just in case we fall through
 696 do
 697   test -f $SIGNAL_H && \
 698   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 699   break
 700 done
 701 nmh_cv_path_signal_h=$SIGNAL_H
 702 ])
 703 SIGNAL_H=$nmh_cv_path_signal_h
 704 AC_SUBST(SIGNAL_H)dnl
 705
 706 dnl
 707 dnl Sigh, this is required because under the new world order autoconf has
 708 dnl nothing to create in a few of the build directories when doing an object
 709 dnl tree build.  So make sure we created certain directories if they don't
 710 dnl exist.
 711 dnl
 712
 713 AC_CONFIG_COMMANDS([build-directories],
 714 [test -d etc || ${MKDIR_P} etc
 715 test -d man || ${MKDIR_P} man])
 716
 717 AC_CONFIG_COMMANDS_POST([
 718
 719 dnl These odd looking assignments are done to expand out unexpanded
 720 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 721 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 722 dnl again to get the final answer.
 723 dnl We only use the expanded versions to print the install paths in
 724 dnl the final summary and should use them nowhere else (see the autoconf
 725 dnl docs for the rationale for bindir etc being unexpanded).
 726 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 727 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 728 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 729 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 730 eval "nmhrpm=${nmhrpm}";
 731
 732 AC_MSG_NOTICE([
 733 nmh configuration
 734 -----------------
 735 nmh version                : AC_PACKAGE_VERSION
 736 host os                    : ${host}
 737 compiler                   : ${CC}
 738 compiler flags             : ${CFLAGS}
 739 linker flags               : ${LDFLAGS}
 740 preprocessor flags         : ${CPPFLAGS}
 741 source code location       : ${srcdir}
 742 binary install path        : ${nmhbin}
 743 library install path       : ${nmhlib}
 744 config files install path  : ${nmhsysconf}
 745 man page install path      : ${nmhman}
 746 RPM build root             : ${nmhrpm}
 747 backup prefix              : ${backup_prefix}
 748 transport system           : ${MTS}
 749 file locking type          : ${LOCKTYPE}
 750 default smtp servers       : ${smtpservers}
 751 default editor             : ${editorpath}
 752 default pager              : ${pagerpath}
 753 SASL support               : ${sasl_support}
 754 TLS support                : ${tls_support}
 755 ])])dnl
 756
 757 dnl ---------------
 758 dnl OUTPUT MAKEFILE
 759 dnl ---------------
 760 AC_CONFIG_FILES([Makefile test/common.sh])
 761 AC_OUTPUT