git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Allow users to send email from addresses other than their default?
  34 AC_ARG_ENABLE(masquerade,
  35   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  36     [enable up to 3 types of address masquerading]),
  37   [AS_IF([test x"$enable_masquerade" = x"yes"],
  38          [masquerade="draft_from mmailid username_extension"],
  39          [masquerade="$enable_masquerade"])],
  40   [masquerade="draft_from mmailid username_extension"])
  41 AC_SUBST(masquerade)dnl
  42
  43 dnl Do you want to disable use of locale functions
  44 AH_TEMPLATE([LOCALE],
  45 [Undefine if you don't want locale features.  By default this is defined.])
  46 AC_ARG_ENABLE([locale],
  47   [AC_HELP_STRING([--disable-locale], [turn off locale features])],
  48   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  49   [AC_DEFINE(LOCALE)])
  50
  51 dnl Do you want client-side support for using SASL for authentication?
  52 dnl Note that this code will be enabled for both POP and SMTP
  53 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  54   [Enable SASL support via the Cyrus SASL library]))
  55 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  56       AC_DEFINE([CYRUS_SASL], [1],
  57                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  58       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  59             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  60             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  61       sasl_support=yes], [sasl_support=no])
  62
  63 dnl Do you want client-side support for encryption with TLS?
  64 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  65 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  66       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  67       tls_support=yes],[tls_support=no])
  68
  69 dnl What should be the default editor?
  70 AC_ARG_WITH([editor],
  71   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  72
  73 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  74
  75 dnl Set the backup prefix
  76 AC_ARG_WITH([hash-backup],
  77   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  78 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  79       [backup_prefix="#"], [backup_prefix=","])
  80 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  81     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  82
  83 dnl What method of locking to use?
  84 AC_ARG_WITH(locking,
  85   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  86   [specify the file locking method]))
  87
  88 if test x"$with_locking" = x"dot"; then
  89   LOCKTYPE="dot"
  90   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  91 elif test x"$with_locking" = x"flock"; then
  92   LOCKTYPE="flock"
  93   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  94 elif test x"$with_locking" = x"lockf"; then
  95   LOCKTYPE="lockf"
  96   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  97 elif test x"$with_locking" = x"fcntl"; then
  98   LOCKTYPE="fcntl"
  99   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 100 else
 101   LOCKTYPE="dot"
 102   AC_DEFINE(DOT_LOCKING)dnl
 103 fi
 104
 105 dnl Should we use a locking directory?
 106 AC_ARG_ENABLE([lockdir], [
 107   AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 108   AS_IF([test "x$enableval" = xyes],[
 109     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 110   AS_IF([test "x$LOCKTYPE" != xdot],[
 111     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 112   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 113                      [Directory to store dot-locking lock files])
 114 ])
 115
 116 dnl What method of posting should post use?
 117 AC_ARG_WITH([mts],
 118   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 119   [specify the default mail transport agent/service]))
 120
 121 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 122       [test x"$with_mts" = x"sendmail"], [MTS="sendmail"],
 123       [MTS="smtp"])
 124 AC_SUBST([MTS])dnl
 125
 126 dnl What should be the default pager?
 127 AC_ARG_WITH([pager],
 128   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 129
 130 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 131
 132 dnl What should be the default mail server(s)?
 133 AC_ARG_WITH(smtpservers,
 134   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 135   [specify the default SMTP server(s) @<:@localhost@:>@]))
 136 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 137       [smtpservers="localhost"])
 138 AC_SUBST([smtpservers])dnl
 139
 140 dnl ----------------------------------------------------
 141 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 142 dnl ----------------------------------------------------
 143 AC_PREFIX_DEFAULT([/usr/local/nmh])
 144
 145 dnl ------------------
 146 dnl CHECK THE COMPILER
 147 dnl ------------------
 148 dnl We want these before the checks,
 149 dnl so the checks can modify their values.
 150 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 151 if test x"$enable_debug" = x"yes"; then
 152   test -z "$LDFLAGS" && LDFLAGS=-g
 153 fi
 154
 155 AC_PROG_CC
 156 AM_PROG_CC_C_O
 157
 158 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 159   [nmh_cv_has_unusedmacros],
 160   [nmh_saved_cppflags="$CPPFLAGS"
 161    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 162    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 163    CPPFLAGS="$nmh_saved_cppflags"])
 164
 165 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 166   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 167                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 168   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 169 fi
 170 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 171
 172 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 173 [nmh_saved_cflags="$CFLAGS"
 174  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 175  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 176  CFLAGS="$nmh_saved_cflags"])
 177
 178 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 179 [nmh_saved_cflags="$CFLAGS"
 180  CFLAGS="$CFLAGS -Wno-pointer-sign"
 181  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 182  CFLAGS="$nmh_saved_cflags"])
 183
 184 dnl if the user hasn't specified CFLAGS, then
 185 dnl   if compiler is gcc, then
 186 dnl    use -O2 and some warning flags
 187 dnl   else use -O
 188 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 189 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 190 dnl warnings which are probably mostly spurious and which in any case we
 191 dnl don't want to deal with now.
 192 if test "$nmh_cv_has_noptrsign" = "yes"; then
 193     if test "$nmh_cv_has_wextra" = "yes"; then
 194         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered -Wno-pointer-sign"
 195     else
 196         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 197     fi
 198 else
 199     if test "$nmh_cv_has_wextra" = "yes"; then
 200         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered"
 201     else
 202         nmh_gcc_warnflags="-Wall"
 203     fi
 204 fi
 205
 206 if test -n "$auto_cflags"; then
 207   if test x"$enable_debug" = x"yes"; then
 208     if test -n "$GCC"; then
 209       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 210     else
 211       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 212     fi
 213   else
 214     if test -z "$LDFLAGS"; then
 215       case "$build_os" in
 216         darwin*)
 217           LDFLAGS=
 218           ;;
 219         *)
 220           LDFLAGS=-s
 221           ;;
 222       esac
 223     fi
 224     if test -n "$GCC"; then
 225       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 226     else
 227       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 228     fi
 229   fi
 230 fi
 231
 232 AC_C_CONST              dnl Does compiler support `const'.
 233
 234 dnl ------------------
 235 dnl CHECK FOR PROGRAMS
 236 dnl ------------------
 237 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 238 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 239 AC_PROG_RANLIB          dnl Check for `ranlib'
 240 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 241 AC_PROG_SED             dnl Check for Posix-compliant sed
 242 AC_PROG_LEX             dnl Check for lex/flex
 243
 244 dnl Look for `cut'
 245 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 246 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 247
 248 dnl
 249 dnl Check for MD5 program and formatting command
 250 dnl
 251 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 252 AS_CASE(["${MD5SUM}"],
 253         [md5sum], [MD5FMT="cat"],
 254         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 255         [MD5FMT="missing"])
 256 AC_SUBST([MD5FMT])
 257
 258 dnl ----------------------------------------------
 259 dnl check for lclint, and lint if it doesn't exist
 260 dnl ----------------------------------------------
 261 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 262 if test x$ac_cv_prog_linttmp1 != xno ; then
 263   LINT=$ac_cv_prog_linttmp1
 264   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 265 else
 266   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 267   if test x$ac_cv_prog_linttmp2 != xno ; then
 268     LINT=$ac_cv_prog_linttmp2
 269     LINTFLAGS=""
 270   else
 271     LINT="echo 'No lint program found'"
 272     LINTFLAGS=""
 273   fi
 274 fi
 275 AC_SUBST([LINT])dnl
 276 AC_SUBST([LINTFLAGS])dnl
 277
 278 dnl Look for `ls'
 279 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 280 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 281
 282 dnl See how we get ls to display the owner and the group
 283 if test "$lspath" != "no"; then
 284   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 285                  [nmh_cv_ls_grpopt],
 286   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 287     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 288     dnl ls, it would seem -l gave us both the user and group.  On this type of
 289     dnl ls, -g makes _only_ the group be displayed (and not the user).
 290     nmh_cv_ls_grpopt="-l"
 291   else
 292     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 293     nmh_cv_ls_grpopt="-lg"
 294   fi])
 295 fi
 296
 297 dnl Look for `more'
 298 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 299 AC_PATH_PROG([morepath], [more], [no], [$pathtmp])
 300
 301 dnl If pager is not specified yet,
 302 dnl then use `more' as the default.
 303 if test -z "$pagerpath"; then
 304   pagerpath="$morepath"
 305 fi
 306 AC_SUBST(pagerpath)dnl
 307
 308 dnl Look for `sendmail'
 309 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 310 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 311
 312 dnl Look for `vi'
 313 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 314 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 315
 316 dnl If editor is not specified yet,
 317 dnl then use `vi' as the default.
 318 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 319 AC_SUBST([editorpath])dnl
 320
 321 dnl ----------------------------------------------------------
 322 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 323 dnl ----------------------------------------------------------
 324 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 325 [for mailspool in /var/mail        dnl
 326                   /var/spool/mail  dnl
 327                   /usr/spool/mail  dnl
 328                   /dev/null;       dnl Just in case we fall through
 329 do
 330   test -d $mailspool && break
 331 done
 332 nmh_cv_mailspool=$mailspool
 333 ])
 334 mailspool=$nmh_cv_mailspool
 335 AC_SUBST([mailspool])dnl
 336
 337 dnl See whether the mail spool directory is world-writable.
 338 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 339   AC_CACHE_CHECK(whether the mail spool is world-writable,
 340                  nmh_cv_mailspool_world_writable,
 341   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 342     nmh_cv_mailspool_world_writable=no
 343   else
 344     nmh_cv_mailspool_world_writable=yes
 345   fi])
 346 fi
 347
 348 dnl Also, check for liblockfile (as found on Debian systems)
 349 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 350
 351 dnl and whether its companion program dotlockfile is setgid
 352 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 353 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 354   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 355     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 356     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 357         nmh_cv_dotlockfile_setgid=yes
 358       else
 359         nmh_cv_dotlockfile_setgid=no
 360       fi])
 361   fi
 362 fi
 363
 364 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 365 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 366 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 367   dnl do we really need both of these?
 368   AC_DEFINE(MAILGROUP,1,
 369     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 370   SETGID_MAIL=1
 371 fi
 372 AC_SUBST(SETGID_MAIL)dnl
 373
 374 dnl Use ls to see which group owns the mail spool directory.
 375 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 376 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 377 ])
 378 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 379 AC_SUBST(MAIL_SPOOL_GRP)dnl
 380
 381 dnl ------------------
 382 dnl CHECK HEADER FILES
 383 dnl ------------------
 384
 385 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 386 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 387 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 388 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 389 dnl declared; if so they should have an entry added to this case statement.
 390 dnl NB that we must define this on the compiler command line, not in config.h,
 391 dnl because it must be set before any system header is included and there's no
 392 dnl portable way to make sure that files generated by lex include config.h
 393 dnl before system header files.
 394
 395 AS_CASE(["$host_os"],
 396         [linux*],
 397         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 398           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 399                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 400
 401 AC_HEADER_STDC
 402 AC_HEADER_TIOCGWINSZ
 403 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 404                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 405                   sys/param.h sys/time.h sys/stream.h])
 406
 407 dnl
 408 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 409 dnl really use a whole set of them, but this check should be
 410 dnl sufficient.
 411 dnl
 412 AC_CHECK_HEADER(libio.h, [
 413   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 414     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 415
 416 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 417   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 418 [[#if HAVE_SYS_STREAM_H
 419 #  include <sys/stream.h>
 420 #endif
 421 ]])
 422
 423 dnl ---------------
 424 dnl CHECK FUNCTIONS
 425 dnl ---------------
 426 AC_CHECK_FUNCS([writev lstat nl_langinfo])
 427
 428 dnl Check for multibyte character set support
 429 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 430     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 431   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 432     [Define to enable support for multibyte character sets.])
 433 fi
 434
 435 dnl -------------------
 436 dnl CHECK FOR LIBRARIES
 437 dnl -------------------
 438 dnl Check location of modf
 439 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 440
 441 dnl Checks for network libraries (nsl, socket)
 442 NMH_CHECK_NETLIBS
 443
 444 termcap_curses_order="termcap curses ncurses"
 445 for lib in $termcap_curses_order; do
 446   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 447 done
 448 AC_SUBST([TERMLIB])dnl
 449 AS_IF([test "x$TERMLIB" = "x"],
 450       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 451 or ncurses library or package that you can install?])])
 452
 453
 454 dnl ---------------
 455 dnl CHECK FOR ICONV
 456 dnl ---------------
 457
 458 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 459 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 460   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 461   if test "x$ac_found_iconv" = "xno"; then
 462     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 463     if test "x$ac_found_iconv" = "xno"; then
 464       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 465     fi
 466     if test "x$ac_found_iconv" != "xno"; then
 467       ICONVLIB="-liconv"
 468     fi
 469   else
 470     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 471     AC_CHECK_DECL(_libiconv_version,
 472       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 473       [ #include <iconv.h> ])
 474   fi
 475 fi
 476 if test "x$ac_found_iconv" = xyes; then
 477   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 478 fi
 479 AC_SUBST([ICONVLIB])
 480
 481 dnl Check if iconv uses const in prototype declaration
 482 if test "x$ac_found_iconv" = "xyes"; then
 483   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 484     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 485         #include <iconv.h>]],
 486         [[#ifdef __cplusplus
 487           "C"
 488           #endif
 489           #if defined(__STDC__) || defined(__cplusplus)
 490           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 491           #else
 492           size_t iconv();
 493           #endif]])],
 494       [ac_cv_iconv_const=],
 495       [ac_cv_iconv_const=const])])
 496   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 497     [Define as const if the declaration of iconv() needs const.])
 498 fi
 499
 500 dnl --------------
 501 dnl CHECK FOR NDBM
 502 dnl --------------
 503
 504 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 505             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 506 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 507             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 508
 509 if test "$nmh_ndbm" = "autodetect"; then
 510   if test "$nmh_ndbmheader" != "autodetect"; then
 511     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 512   else
 513
 514     dnl There are at least four implementations of ndbm, and
 515     dnl several of those can be in different places at the whim
 516     dnl of the system integrator. A good summary of this mess
 517     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 518
 519     dnl Classic ndbm with no library required (eg NetBSD): try this
 520     dnl first so we don't accidentally link in a pointless but harmless
 521     dnl library in one of the later ndbm.h+libfoo tests:
 522     NMH_CHECK_NDBM(ndbm.h,,,
 523     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 524       NMH_CHECK_NDBM(db.h,db,,
 525     dnl Berkeley DBv1 emulating ndbm:
 526         NMH_CHECK_NDBM(ndbm.h,db,,
 527           NMH_CHECK_NDBM(ndbm.h,db1,,
 528     dnl Classic ndbm:
 529             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 530     dnl glibc2.1 systems put db1 in a subdir:
 531               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 532     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 533     dnl and possibly needing gbdm_compat library:
 534                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 535                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 536                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 537                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 538
 539   fi
 540 else
 541   dnl We don't really need to check that the user-specified values work,
 542   dnl but it is a convenience to the user to bomb out early rather than
 543   dnl after configure and half the compile process.
 544   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 545 fi
 546
 547 if test "$nmh_ndbm_found" = "no"; then
 548   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 549 else
 550   dnl Now export the lib/header to our makefile/config.h:
 551   if test x"$nmh_ndbmheader" != x; then
 552     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 553       [Define to the header containing the ndbm API prototypes.])
 554   fi
 555   if test x"$nmh_ndbm" != x; then
 556     NDBM_LIBS="-l$nmh_ndbm"
 557   else
 558     NDBM_LIBS=
 559   fi
 560   AC_SUBST([NDBM_LIBS])
 561 fi
 562
 563 dnl ------------------
 564 dnl Set RPM build root
 565 dnl ------------------
 566 dnl nmhrpm is used in the final summary, see below.  The default value is
 567 dnl reported there as ./RPM, consistent with the reporting of the default
 568 dnl source code location as ., but its absolute path is used in the Makefile.
 569 AC_ARG_WITH(rpmdir,
 570   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 571   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 572           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 573 AC_SUBST([rpmdir])
 574
 575
 576 dnl --------------------
 577 dnl CHECK FOR CYRUS-SASL
 578 dnl --------------------
 579
 580 AS_IF([test x"$sasl_support" = x"yes"],[
 581   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 582   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 583     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 584 AC_SUBST([SASLLIB])
 585
 586 dnl -----------------
 587 dnl CHECK FOR OPENSSL
 588 dnl -----------------
 589
 590 AS_IF([test x"$tls_support" = x"yes"],[
 591   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 592   AC_CHECK_LIB([crypto], [BIO_write], ,
 593     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 594   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 595     [AC_MSG_ERROR([OpenSSL library not found])])])
 596
 597 dnl ---------------------
 598 dnl CHECK TERMCAP LIBRARY
 599 dnl ---------------------
 600
 601 dnl Add the termcap library, so that the following configure
 602 dnl tests will find it when it tries to link test programs.
 603 nmh_save_LIBS="$LIBS"
 604 LIBS="$TERMLIB $LIBS"
 605
 606 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 607 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 608 dnl in tgetstr().
 609 dnl Under Cygwin test program crashes but exit code is still 0. So,
 610 dnl we test for a file that porgram should create
 611 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 612 [Define to 1 if tgetent() accepts NULL as a buffer.])
 613 AC_CACHE_CHECK(if tgetent accepts NULL,
 614 nmh_cv_func_tgetent_accepts_null,
 615 [AC_TRY_RUN([
 616 main()
 617 {
 618     char buf[4096];
 619     int r1 = tgetent(buf, "vt100");
 620     int r2 = tgetent((char*)0,"vt100");
 621     if (r1 >= 0 && r1 == r2) {
 622         char tbuf[1024], *u;
 623         u = tbuf;
 624         tgetstr("cl", &u);
 625         creat("conftest.tgetent", 0640);
 626     }
 627     exit((r1 != r2) || r2 == -1);
 628 }
 629 ],
 630   if test -f conftest.tgetent; then
 631     nmh_cv_func_tgetent_accepts_null=yes
 632   else
 633     nmh_cv_func_tgetent_accepts_null=no
 634   fi,
 635   nmh_cv_func_tgetent_accepts_null=no,
 636   nmh_cv_func_tgetent_accepts_null=no)])
 637 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 638   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 639 fi
 640 AC_CACHE_CHECK(if tgetent returns 0 on success,
 641 nmh_cv_func_tgetent_zero_success,
 642 [AC_TRY_RUN([
 643 main()
 644 {
 645     char buf[4096];
 646     int r1 = tgetent(buf, "!@#$%^&*");
 647     int r2 = tgetent(buf, "vt100");
 648     if (r1 < 0 && r2 == 0) {
 649         char tbuf[1024], *u;
 650         u = tbuf;
 651         tgetstr("cl", &u);
 652         creat("conftest.tgetent0", 0640);
 653     }
 654     exit(r1 == r2);
 655 }
 656 ],
 657   if test -f conftest.tgetent0; then
 658     nmh_cv_func_tgetent_zero_success=yes
 659   else
 660     nmh_cv_func_tgetent_zero_success=no
 661   fi,
 662   nmh_cv_func_tgetent_zero_success=no,
 663   nmh_cv_func_tgetent_zero_success=no)])
 664 AH_TEMPLATE([TGETENT_SUCCESS],
 665 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 666 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 667   AC_DEFINE(TGETENT_SUCCESS, 0)
 668 else
 669   AC_DEFINE(TGETENT_SUCCESS, 1)
 670 fi
 671
 672 dnl Now put the libraries back to what it was before we
 673 dnl starting checking the termcap library.
 674 LIBS="$nmh_save_LIBS"
 675
 676 dnl --------------
 677 dnl CHECK TYPEDEFS
 678 dnl --------------
 679 AC_TYPE_PID_T
 680 AC_TYPE_OFF_T
 681 AC_TYPE_UID_T
 682 AC_TYPE_MODE_T
 683 AC_TYPE_SIZE_T
 684
 685 dnl ----------------
 686 dnl CHECK STRUCTURES
 687 dnl ----------------
 688
 689 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 690 dnl (FreeBSD has a timezone() function but not a timezone global
 691 dnl variable that is visible).
 692 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 693
 694 AC_STRUCT_DIRENT_D_TYPE
 695
 696 dnl Where is <signal.h> located?  Needed as input for signames.awk
 697 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 698 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 699                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 700                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 701                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 702                  /usr/include/sys/signal.h      dnl Almost everybody else
 703                  /dev/null;                     dnl Just in case we fall through
 704 do
 705   test -f $SIGNAL_H && \
 706   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 707   break
 708 done
 709 nmh_cv_path_signal_h=$SIGNAL_H
 710 ])
 711 SIGNAL_H=$nmh_cv_path_signal_h
 712 AC_SUBST(SIGNAL_H)dnl
 713
 714 dnl
 715 dnl Sigh, this is required because under the new world order autoconf has
 716 dnl nothing to create in a few of the build directories when doing an object
 717 dnl tree build.  So make sure we created certain directories if they don't
 718 dnl exist.
 719 dnl
 720
 721 AC_CONFIG_COMMANDS([build-directories],
 722 [test -d etc || ${MKDIR_P} etc
 723 test -d man || ${MKDIR_P} man])
 724
 725 AC_CONFIG_COMMANDS_POST([
 726
 727 dnl These odd looking assignments are done to expand out unexpanded
 728 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 729 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 730 dnl again to get the final answer.
 731 dnl We only use the expanded versions to print the install paths in
 732 dnl the final summary and should use them nowhere else (see the autoconf
 733 dnl docs for the rationale for bindir etc being unexpanded).
 734 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 735 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 736 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 737 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 738 eval "nmhrpm=${nmhrpm}";
 739
 740 AC_MSG_NOTICE([
 741 nmh configuration
 742 -----------------
 743 nmh version                : AC_PACKAGE_VERSION
 744 host os                    : ${host}
 745 compiler                   : ${CC}
 746 compiler flags             : ${CFLAGS}
 747 linker flags               : ${LDFLAGS}
 748 preprocessor flags         : ${CPPFLAGS}
 749 source code location       : ${srcdir}
 750 binary install path        : ${nmhbin}
 751 library install path       : ${nmhlib}
 752 config files install path  : ${nmhsysconf}
 753 man page install path      : ${nmhman}
 754 RPM build root             : ${nmhrpm}
 755 backup prefix              : ${backup_prefix}
 756 transport system           : ${MTS}
 757 file locking type          : ${LOCKTYPE}
 758 default smtp servers       : ${smtpservers}
 759 default editor             : ${editorpath}
 760 default pager              : ${pagerpath}
 761 email address masquerading : ${masquerade}
 762 SASL support               : ${sasl_support}
 763 TLS support                : ${tls_support}
 764 ])])dnl
 765
 766 dnl ---------------
 767 dnl OUTPUT MAKEFILE
 768 dnl ---------------
 769 AC_CONFIG_FILES([Makefile test/common.sh])
 770 AC_OUTPUT