git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Do you want to disable use of locale functions
  34 AH_TEMPLATE([LOCALE],
  35 [Undefine if you don't want locale features.  By default this is defined.])
  36 AC_ARG_ENABLE([locale],
  37   [AS_HELP_STRING([--disable-locale], [turn off locale features])],
  38   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  39   [AC_DEFINE(LOCALE)])
  40
  41 dnl Do you want client-side support for using SASL for authentication?
  42 dnl Note that this code will be enabled for both POP and SMTP
  43 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  44   [Enable SASL support via the Cyrus SASL library]))
  45 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  46       AC_DEFINE([CYRUS_SASL], [1],
  47                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  48       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  49             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  50             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  51       sasl_support=yes], [sasl_support=no])
  52
  53 dnl Do you want client-side support for encryption with TLS?
  54 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  55 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  56       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  57       tls_support=yes],[tls_support=no])
  58
  59 dnl What should be the default editor?
  60 AC_ARG_WITH([editor],
  61   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  62
  63 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  64
  65 dnl Set the backup prefix
  66 AC_ARG_WITH([hash-backup],
  67   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  68 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  69       [backup_prefix="#"], [backup_prefix=","])
  70 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  71     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  72
  73 dnl What method of locking to use?
  74 AS_CASE(["$host_os"],
  75   [aix*|cygwin*|linux*],
  76     [default_locktype="fcntl"; default_locking=FCNTL_LOCKING],
  77   [freebsd*], [default_locktype="flock"; default_locking=FLOCK_LOCKING],
  78   [default_locktype="dot"; default_locking=DOT_LOCKING])
  79
  80 AC_ARG_WITH(locking,
  81   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  82   [specify the file locking method]))
  83
  84 if test x"$with_locking" = x"dot"; then
  85   LOCKTYPE="dot"
  86   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  87 elif test x"$with_locking" = x"flock"; then
  88   LOCKTYPE="flock"
  89   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  90 elif test x"$with_locking" = x"lockf"; then
  91   LOCKTYPE="lockf"
  92   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  93 elif test x"$with_locking" = x"fcntl"; then
  94   LOCKTYPE="fcntl"
  95   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
  96 else
  97   LOCKTYPE="$default_locktype"
  98   AC_DEFINE_UNQUOTED($default_locking, 1)dnl
  99 fi
 100
 101 dnl Should we use a locking directory?
 102 AC_ARG_ENABLE([lockdir],
 103   [AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 104   AS_IF([test "x$enableval" = xyes],[
 105     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 106   AS_IF([test "x$LOCKTYPE" != xdot],[
 107     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 108   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 109                      [Directory to store dot-locking lock files])
 110 ])
 111
 112 dnl What method of posting should post use?
 113 AC_ARG_WITH([mts],
 114   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 115   [specify the default mail transport agent/service]))
 116
 117 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 118       [test x"$with_mts" = x"sendmail"], [MTS="sendmail"],
 119       [MTS="smtp"])
 120 AC_SUBST([MTS])dnl
 121
 122 dnl What should be the default pager?
 123 AC_ARG_WITH([pager],
 124   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 125
 126 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 127
 128 dnl If a pager is not explicitly specified, then look for one.
 129 dnl Fall back to `cat', to avoid catastrophic failure of
 130 dnl `mhshow', et al., if pagerpath is set to `no'.
 131 if test -z "$pagerpath"; then
 132   pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 133   AC_PATH_PROGS([pagerpath], [more less most cat], [no], [$pathtmp])
 134 fi
 135 AC_SUBST(pagerpath)dnl
 136
 137 dnl What should be the default mail server(s)?
 138 AC_ARG_WITH(smtpservers,
 139   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 140   [specify the default SMTP server(s) @<:@localhost@:>@]))
 141 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 142       [smtpservers="localhost"])
 143 AC_SUBST([smtpservers])dnl
 144
 145 dnl ----------------------------------------------------
 146 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 147 dnl ----------------------------------------------------
 148 AC_PREFIX_DEFAULT([/usr/local/nmh])
 149
 150 dnl ------------------
 151 dnl CHECK THE COMPILER
 152 dnl ------------------
 153 dnl We want these before the checks,
 154 dnl so the checks can modify their values.
 155 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 156 if test x"$enable_debug" = x"yes"; then
 157   test -z "$LDFLAGS" && LDFLAGS=-g
 158 fi
 159
 160 AC_PROG_CC
 161 AM_PROG_CC_C_O
 162
 163 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 164   [nmh_cv_has_unusedmacros],
 165   [nmh_saved_cppflags="$CPPFLAGS"
 166    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 167    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 168    CPPFLAGS="$nmh_saved_cppflags"])
 169
 170 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 171   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 172                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 173   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 174 fi
 175 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 176
 177 AC_CACHE_CHECK([whether compiler supports -Wno-sign-compare],
 178   [nmh_cv_has_nosigncompare],
 179   [nmh_saved_cppflags="$CPPFLAGS"
 180    CPPFLAGS="$CPPFLAGS -Wno-sign-compare"
 181    AC_TRY_COMPILE([],[],nmh_cv_has_nosigncompare=yes,
 182                   nmh_cv_has_nosigncompare=no)
 183    CPPFLAGS="$nmh_saved_cppflags"])
 184
 185 if test "$nmh_cv_has_nosigncompare" = 'yes'; then
 186   DISABLE_SIGN_COMPARE_WARNING=-Wno-sign-compare
 187 fi
 188 AC_SUBST(DISABLE_SIGN_COMPARE_WARNING)dnl
 189
 190 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 191 [nmh_saved_cflags="$CFLAGS"
 192  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 193  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 194  CFLAGS="$nmh_saved_cflags"])
 195
 196 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 197 [nmh_saved_cflags="$CFLAGS"
 198  CFLAGS="$CFLAGS -Wno-pointer-sign"
 199  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 200  CFLAGS="$nmh_saved_cflags"])
 201
 202 dnl if the user hasn't specified CFLAGS, then
 203 dnl   if compiler is gcc, then
 204 dnl    use -O2 and some warning flags
 205 dnl   else use -O
 206 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 207 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 208 dnl warnings which are probably mostly spurious and which in any case we
 209 dnl don't want to deal with now.
 210 if test "$nmh_cv_has_noptrsign" = "yes"; then
 211     nmh_gcc_common_flags="-ansi -pedantic -Wall"
 212     if test "$nmh_cv_has_wextra" = "yes"; then
 213         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered "\
 214 "-Wno-pointer-sign"
 215     else
 216         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wno-pointer-sign"
 217     fi
 218 else
 219     if test "$nmh_cv_has_wextra" = "yes"; then
 220         nmh_gcc_warnflags="${nmh_gcc_common_flags} -Wextra -Wno-clobbered"
 221     else
 222         nmh_gcc_warnflags="${nmh_gcc_common_flags}"
 223     fi
 224 fi
 225
 226 if test -n "$auto_cflags"; then
 227   if test x"$enable_debug" = x"yes"; then
 228     if test -n "$GCC"; then
 229       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 230     else
 231       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 232     fi
 233   else
 234     if test -z "$LDFLAGS"; then
 235       case "$build_os" in
 236         darwin*)
 237           LDFLAGS=
 238           ;;
 239         *)
 240           LDFLAGS=-s
 241           ;;
 242       esac
 243     fi
 244     if test -n "$GCC"; then
 245       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 246     else
 247       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 248     fi
 249   fi
 250 fi
 251
 252 AC_C_CONST              dnl Does compiler support `const'.
 253
 254 dnl ------------------
 255 dnl CHECK FOR PROGRAMS
 256 dnl ------------------
 257 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 258 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 259 AC_PROG_RANLIB          dnl Check for `ranlib'
 260 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 261 AC_PROG_SED             dnl Check for Posix-compliant sed
 262 AC_PROG_LEX             dnl Check for lex/flex
 263
 264 dnl Look for `cut'
 265 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 266 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 267
 268 dnl
 269 dnl Check for MD5 program and formatting command
 270 dnl
 271 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 272 AS_CASE(["${MD5SUM}"],
 273         [md5sum], [MD5FMT="cat"],
 274         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 275         [MD5FMT="missing"])
 276 AC_SUBST([MD5FMT])
 277
 278 dnl ----------------------------------------------
 279 dnl check for lclint, and lint if it doesn't exist
 280 dnl ----------------------------------------------
 281 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 282 if test x$ac_cv_prog_linttmp1 != xno ; then
 283   LINT=$ac_cv_prog_linttmp1
 284   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 285 else
 286   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 287   if test x$ac_cv_prog_linttmp2 != xno ; then
 288     LINT=$ac_cv_prog_linttmp2
 289     LINTFLAGS=""
 290   else
 291     LINT="echo 'No lint program found'"
 292     LINTFLAGS=""
 293   fi
 294 fi
 295 AC_SUBST([LINT])dnl
 296 AC_SUBST([LINTFLAGS])dnl
 297
 298 dnl Look for `ls'
 299 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 300 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 301
 302 dnl See how we get ls to display the owner and the group
 303 if test "$lspath" != "no"; then
 304   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 305                  [nmh_cv_ls_grpopt],
 306   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 307     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 308     dnl ls, it would seem -l gave us both the user and group.  On this type of
 309     dnl ls, -g makes _only_ the group be displayed (and not the user).
 310     nmh_cv_ls_grpopt="-l"
 311   else
 312     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 313     nmh_cv_ls_grpopt="-lg"
 314   fi])
 315 fi
 316
 317 dnl Look for `sendmail'
 318 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 319 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 320
 321 dnl Look for `vi'
 322 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 323 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 324
 325 dnl If editor is not specified yet,
 326 dnl then use `vi' as the default.
 327 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 328 AC_SUBST([editorpath])dnl
 329
 330 dnl Cygwin FAT filesystems do not support hard links.  So use cp instead,
 331 dnl even if running on an NTFS or other filesystem.
 332 AS_CASE(["$host_os"],
 333   [cygwin*],[LINK_FILE=cp],
 334   [LINK_FILE=ln])
 335 AC_SUBST([LINK_FILE])
 336
 337 dnl ----------------------------------------------------------
 338 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 339 dnl ----------------------------------------------------------
 340 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 341 [for mailspool in /var/mail        dnl
 342                   /var/spool/mail  dnl
 343                   /usr/spool/mail  dnl
 344                   /dev/null;       dnl Just in case we fall through
 345 do
 346   test -d $mailspool && break
 347 done
 348 nmh_cv_mailspool=$mailspool
 349 ])
 350 mailspool=$nmh_cv_mailspool
 351 AC_SUBST([mailspool])dnl
 352
 353 dnl See whether the mail spool directory is world-writable.
 354 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 355   AC_CACHE_CHECK(whether the mail spool is world-writable,
 356                  nmh_cv_mailspool_world_writable,
 357   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 358     nmh_cv_mailspool_world_writable=no
 359   else
 360     nmh_cv_mailspool_world_writable=yes
 361   fi])
 362 fi
 363
 364 dnl Also, check for liblockfile (as found on Debian systems)
 365 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 366
 367 dnl and whether its companion program dotlockfile is setgid
 368 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 369 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 370   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 371     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 372     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 373         nmh_cv_dotlockfile_setgid=yes
 374       else
 375         nmh_cv_dotlockfile_setgid=no
 376       fi])
 377   fi
 378 fi
 379
 380 dnl Provide a way for distcheck to disable setgid_mail via
 381 dnl DISTCHECK_CONFIGURE_FLAGS.
 382 if test x"$DISABLE_SETGID_MAIL" != x -a x"$DISABLE_SETGID_MAIL" != x0; then
 383   nmh_cv_dotlockfile_setgid=yes
 384 fi
 385
 386 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 387 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 388 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 389   dnl do we really need both of these?
 390   AC_DEFINE(MAILGROUP,1,
 391     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 392   SETGID_MAIL=1
 393 fi
 394 AC_SUBST(SETGID_MAIL)dnl
 395
 396 dnl Use ls to see which group owns the mail spool directory.
 397 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 398 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 399 ])
 400 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 401 AC_SUBST(MAIL_SPOOL_GRP)dnl
 402
 403 dnl ------------------
 404 dnl CHECK HEADER FILES
 405 dnl ------------------
 406
 407 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 408 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 409 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 410 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 411 dnl declared; if so they should have an entry added to this case statement.
 412 dnl NB that we must define this on the compiler command line, not in config.h,
 413 dnl because it must be set before any system header is included and there's no
 414 dnl portable way to make sure that files generated by lex include config.h
 415 dnl before system header files.
 416
 417 AS_CASE(["$host_os"],
 418         [linux*],
 419         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 420           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 421                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 422
 423 AC_HEADER_STDC
 424 AC_HEADER_TIOCGWINSZ
 425 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 426                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 427                   sys/param.h sys/time.h sys/stream.h])
 428
 429 dnl
 430 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 431 dnl really use a whole set of them, but this check should be
 432 dnl sufficient.
 433 dnl
 434 AC_CHECK_HEADER(libio.h, [
 435   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 436     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 437
 438 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 439   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 440 [[#if HAVE_SYS_STREAM_H
 441 #  include <sys/stream.h>
 442 #endif
 443 ]])
 444
 445 dnl ---------------
 446 dnl CHECK FUNCTIONS
 447 dnl ---------------
 448 AC_CHECK_FUNCS([wcwidth mbtowc writev lstat nl_langinfo getutxent])
 449
 450 dnl Check for multibyte character set support
 451 AS_IF([test "x$ac_cv_header_wchar_h" = "xyes" -a \
 452             "x$ac_cv_header_wctype_h" = "xyes" -a \
 453             "x$ac_cv_func_wcwidth" = "xyes" -a \
 454             "x$ac_cv_func_mbtowc" = "xyes"],
 455       [AC_DEFINE([MULTIBYTE_SUPPORT], [1],
 456                  [Define to enable support for multibyte character sets.])
 457        MULTIBYTE_ENABLED=1],
 458       [MULTIBYTE_ENABLED=0])
 459 AC_SUBST([MULTIBYTE_ENABLED])
 460
 461 dnl -------------------
 462 dnl CHECK FOR LIBRARIES
 463 dnl -------------------
 464 dnl Check location of modf
 465 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 466
 467 dnl Checks for network libraries (nsl, socket)
 468 NMH_CHECK_NETLIBS
 469
 470 NMH_READLINE
 471
 472 termcap_curses_order="termcap curses ncurses"
 473 for lib in $termcap_curses_order; do
 474   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 475 done
 476 AC_SUBST([TERMLIB])dnl
 477 AS_IF([test "x$TERMLIB" = "x"],
 478       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 479 or ncurses library or package that you can install?])])
 480
 481
 482 dnl ---------------
 483 dnl CHECK FOR ICONV
 484 dnl ---------------
 485
 486 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 487 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 488   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 489   if test "x$ac_found_iconv" = "xno"; then
 490     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 491     if test "x$ac_found_iconv" = "xno"; then
 492       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 493     fi
 494     if test "x$ac_found_iconv" != "xno"; then
 495       ICONVLIB="-liconv"
 496     fi
 497   else
 498     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 499     AC_CHECK_DECL(_libiconv_version,
 500       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 501       [ #include <iconv.h> ])
 502   fi
 503 fi
 504 if test "x$ac_found_iconv" = xyes; then
 505   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 506 fi
 507 AC_SUBST([ICONVLIB])
 508
 509 dnl Check if iconv uses const in prototype declaration
 510 if test "x$ac_found_iconv" = "xyes"; then
 511   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 512     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 513         #include <iconv.h>]],
 514         [[#ifdef __cplusplus
 515           "C"
 516           #endif
 517           #if defined(__STDC__) || defined(__cplusplus)
 518           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 519           #else
 520           size_t iconv();
 521           #endif]])],
 522       [ac_cv_iconv_const=],
 523       [ac_cv_iconv_const=const])])
 524   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 525     [Define as const if the declaration of iconv() needs const.])
 526 fi
 527
 528 dnl --------------
 529 dnl CHECK FOR NDBM
 530 dnl --------------
 531
 532 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 533             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 534 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 535             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 536
 537 if test "$nmh_ndbm" = "autodetect"; then
 538   if test "$nmh_ndbmheader" != "autodetect"; then
 539     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 540   else
 541
 542     dnl There are at least four implementations of ndbm, and
 543     dnl several of those can be in different places at the whim
 544     dnl of the system integrator. A good summary of this mess
 545     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 546
 547     dnl Classic ndbm with no library required (eg NetBSD): try this
 548     dnl first so we don't accidentally link in a pointless but harmless
 549     dnl library in one of the later ndbm.h+libfoo tests:
 550     NMH_CHECK_NDBM(ndbm.h,,,
 551     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 552       NMH_CHECK_NDBM(db.h,db,,
 553     dnl Berkeley DBv1 emulating ndbm:
 554         NMH_CHECK_NDBM(ndbm.h,db,,
 555           NMH_CHECK_NDBM(ndbm.h,db1,,
 556     dnl Classic ndbm:
 557             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 558     dnl glibc2.1 systems put db1 in a subdir:
 559               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 560     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 561     dnl and possibly needing gbdm_compat library:
 562                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 563                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 564                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 565                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 566
 567   fi
 568 else
 569   dnl We don't really need to check that the user-specified values work,
 570   dnl but it is a convenience to the user to bomb out early rather than
 571   dnl after configure and half the compile process.
 572   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 573 fi
 574
 575 if test "$nmh_ndbm_found" = "no"; then
 576   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 577 else
 578   dnl Now export the lib/header to our makefile/config.h:
 579   if test x"$nmh_ndbmheader" != x; then
 580     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 581       [Define to the header containing the ndbm API prototypes.])
 582   fi
 583   if test x"$nmh_ndbm" != x; then
 584     NDBM_LIBS="-l$nmh_ndbm"
 585   else
 586     NDBM_LIBS=
 587   fi
 588   AC_SUBST([NDBM_LIBS])
 589 fi
 590
 591 dnl ------------------
 592 dnl Set RPM build root
 593 dnl ------------------
 594 dnl nmhrpm is used in the final summary, see below.  The default value is
 595 dnl reported there as ./RPM, consistent with the reporting of the default
 596 dnl source code location as ., but its absolute path is used in the Makefile.
 597 AC_ARG_WITH(rpmdir,
 598   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 599   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 600           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 601 AC_SUBST([rpmdir])
 602
 603
 604 dnl --------------------
 605 dnl CHECK FOR CYRUS-SASL
 606 dnl --------------------
 607
 608 AS_IF([test x"$sasl_support" = x"yes"],[
 609   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 610   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 611     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 612 AC_SUBST([SASLLIB])
 613
 614 dnl -----------------
 615 dnl CHECK FOR OPENSSL
 616 dnl -----------------
 617
 618 AS_IF([test x"$tls_support" = x"yes"],[
 619   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 620   AC_CHECK_LIB([crypto], [BIO_write], ,
 621     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 622   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 623     [AC_MSG_ERROR([OpenSSL library not found])])])
 624
 625 dnl ---------------------
 626 dnl CHECK TERMCAP LIBRARY
 627 dnl ---------------------
 628
 629 dnl Add the termcap library, so that the following configure
 630 dnl tests will find it when it tries to link test programs.
 631 nmh_save_LIBS="$LIBS"
 632 LIBS="$TERMLIB $LIBS"
 633
 634 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 635 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 636 dnl in tgetstr().
 637 dnl Under Cygwin test program crashes but exit code is still 0. So,
 638 dnl we test for a file that porgram should create
 639 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 640 [Define to 1 if tgetent() accepts NULL as a buffer.])
 641 AC_CACHE_CHECK(if tgetent accepts NULL,
 642 nmh_cv_func_tgetent_accepts_null,
 643 [AC_TRY_RUN([
 644 main()
 645 {
 646     char buf[4096];
 647     int r1 = tgetent(buf, "vt100");
 648     int r2 = tgetent((char*)0,"vt100");
 649     if (r1 >= 0 && r1 == r2) {
 650         char tbuf[1024], *u;
 651         u = tbuf;
 652         tgetstr("cl", &u);
 653         creat("conftest.tgetent", 0640);
 654     }
 655     exit((r1 != r2) || r2 == -1);
 656 }
 657 ],
 658   if test -f conftest.tgetent; then
 659     nmh_cv_func_tgetent_accepts_null=yes
 660   else
 661     nmh_cv_func_tgetent_accepts_null=no
 662   fi,
 663   nmh_cv_func_tgetent_accepts_null=no,
 664   nmh_cv_func_tgetent_accepts_null=no)])
 665 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 666   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 667 fi
 668 AC_CACHE_CHECK(if tgetent returns 0 on success,
 669 nmh_cv_func_tgetent_zero_success,
 670 [AC_TRY_RUN([
 671 main()
 672 {
 673     char buf[4096];
 674     int r1 = tgetent(buf, "!@#$%^&*");
 675     int r2 = tgetent(buf, "vt100");
 676     if (r1 < 0 && r2 == 0) {
 677         char tbuf[1024], *u;
 678         u = tbuf;
 679         tgetstr("cl", &u);
 680         creat("conftest.tgetent0", 0640);
 681     }
 682     exit(r1 == r2);
 683 }
 684 ],
 685   if test -f conftest.tgetent0; then
 686     nmh_cv_func_tgetent_zero_success=yes
 687   else
 688     nmh_cv_func_tgetent_zero_success=no
 689   fi,
 690   nmh_cv_func_tgetent_zero_success=no,
 691   nmh_cv_func_tgetent_zero_success=no)])
 692 AH_TEMPLATE([TGETENT_SUCCESS],
 693 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 694 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 695   AC_DEFINE(TGETENT_SUCCESS, 0)
 696 else
 697   AC_DEFINE(TGETENT_SUCCESS, 1)
 698 fi
 699
 700 dnl Now put the libraries back to what it was before we
 701 dnl starting checking the termcap library.
 702 LIBS="$nmh_save_LIBS"
 703
 704 dnl --------------
 705 dnl CHECK TYPEDEFS
 706 dnl --------------
 707 AC_TYPE_PID_T
 708 AC_TYPE_OFF_T
 709 AC_TYPE_UID_T
 710 AC_TYPE_MODE_T
 711 AC_TYPE_SIZE_T
 712
 713 dnl ----------------
 714 dnl CHECK STRUCTURES
 715 dnl ----------------
 716
 717 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 718 dnl (FreeBSD has a timezone() function but not a timezone global
 719 dnl variable that is visible).
 720 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 721
 722 AC_STRUCT_DIRENT_D_TYPE
 723
 724 dnl Where is <signal.h> located?  Needed as input for signames.awk
 725 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 726 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 727                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 728                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 729                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 730                  /usr/include/sys/signal.h      dnl Almost everybody else
 731                  /dev/null;                     dnl Just in case we fall through
 732 do
 733   test -f $SIGNAL_H && \
 734   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 735   break
 736 done
 737 nmh_cv_path_signal_h=$SIGNAL_H
 738 ])
 739 SIGNAL_H=$nmh_cv_path_signal_h
 740 AC_SUBST(SIGNAL_H)dnl
 741
 742 dnl
 743 dnl Sigh, this is required because under the new world order autoconf has
 744 dnl nothing to create in a few of the build directories when doing an object
 745 dnl tree build.  So make sure we created certain directories if they don't
 746 dnl exist.
 747 dnl
 748
 749 AC_CONFIG_COMMANDS([build-directories],
 750 [test -d etc || ${MKDIR_P} etc
 751 test -d man || ${MKDIR_P} man])
 752
 753 AC_CONFIG_COMMANDS_POST([
 754
 755 dnl These odd looking assignments are done to expand out unexpanded
 756 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 757 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 758 dnl again to get the final answer.
 759 dnl We only use the expanded versions to print the install paths in
 760 dnl the final summary and should use them nowhere else (see the autoconf
 761 dnl docs for the rationale for bindir etc being unexpanded).
 762 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 763 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 764 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 765 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 766 eval "nmhrpm=${nmhrpm}";
 767
 768 AC_MSG_NOTICE([
 769 nmh configuration
 770 -----------------
 771 nmh version                : AC_PACKAGE_VERSION
 772 host os                    : ${host}
 773 compiler                   : ${CC}
 774 compiler flags             : ${CFLAGS}
 775 linker flags               : ${LDFLAGS}
 776 preprocessor flags         : ${CPPFLAGS}
 777 source code location       : ${srcdir}
 778 binary install path        : ${nmhbin}
 779 library install path       : ${nmhlib}
 780 config files install path  : ${nmhsysconf}
 781 man page install path      : ${nmhman}
 782 RPM build root             : ${nmhrpm}
 783 backup prefix              : ${backup_prefix}
 784 transport system           : ${MTS}
 785 file locking type          : ${LOCKTYPE}
 786 default smtp servers       : ${smtpservers}
 787 default editor             : ${editorpath}
 788 default pager              : ${pagerpath}
 789 SASL support               : ${sasl_support}
 790 TLS support                : ${tls_support}
 791 ])])dnl
 792
 793 dnl ---------------
 794 dnl OUTPUT MAKEFILE
 795 dnl ---------------
 796 AC_CONFIG_FILES([Makefile test/common.sh])
 797 AC_OUTPUT