git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Allow users to send email from addresses other than their default?
  34 AC_ARG_ENABLE(masquerade,
  35   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  36     [enable up to 3 types of address masquerading]),
  37   [AS_IF([test x"$enable_masquerade" = x"yes"],
  38          [masquerade="draft_from mmailid username_extension"],
  39          [masquerade="$enable_masquerade"])],
  40   [masquerade="draft_from mmailid username_extension"])
  41 AC_SUBST(masquerade)dnl
  42
  43 dnl Do you want to disable use of locale functions
  44 AH_TEMPLATE([LOCALE],
  45 [Undefine if you don't want locale features.  By default this is defined.])
  46 AC_ARG_ENABLE([locale],
  47   [AC_HELP_STRING([--disable-locale], [turn off locale features])],
  48   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  49   [AC_DEFINE(LOCALE)])
  50
  51 dnl Do you want client-side support for using SASL for authentication?
  52 dnl Note that this code will be enabled for both POP and SMTP
  53 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  54   [Enable SASL support via the Cyrus SASL library]))
  55 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  56       AC_DEFINE([CYRUS_SASL], [1],
  57                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  58       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  59             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  60             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  61       sasl_support=yes], [sasl_support=no])
  62
  63 dnl Do you want client-side support for encryption with TLS?
  64 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  65 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  66       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  67       tls_support=yes],[tls_support=no])
  68
  69 dnl What should be the default editor?
  70 AC_ARG_WITH([editor],
  71   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  72
  73 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  74
  75 dnl Set the backup prefix
  76 AC_ARG_WITH([hash-backup],
  77   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  78 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  79       [backup_prefix="#"], [backup_prefix=","])
  80 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  81     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  82
  83 dnl What method of locking to use?
  84 AC_ARG_WITH(locking,
  85   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  86   [specify the file locking method]))
  87
  88 if test x"$with_locking" = x"dot"; then
  89   LOCKTYPE="dot"
  90   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  91 elif test x"$with_locking" = x"flock"; then
  92   LOCKTYPE="flock"
  93   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  94 elif test x"$with_locking" = x"lockf"; then
  95   LOCKTYPE="lockf"
  96   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  97 elif test x"$with_locking" = x"fcntl"; then
  98   LOCKTYPE="fcntl"
  99   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 100 else
 101   LOCKTYPE="dot"
 102   AC_DEFINE(DOT_LOCKING)dnl
 103 fi
 104
 105 dnl Should we use a locking directory?
 106 AC_ARG_ENABLE([lockdir], [
 107   AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 108   AS_IF([test "x$enableval" = xyes],[
 109     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 110   AS_IF([test "x$LOCKTYPE" != xdot],[
 111     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 112   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 113                      [Directory to store dot-locking lock files])
 114 ])
 115
 116 dnl What method of posting should post use?
 117 AC_ARG_WITH([mts],
 118   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 119   [specify the default mail transport agent/service]))
 120
 121 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 122       [test x"$with_mts" = x"sendmail"], [MTS="sendmail"],
 123       [MTS="smtp"])
 124 AC_SUBST([MTS])dnl
 125
 126 dnl Both the smtp and sendmail mail transport services use the smtp code
 127 AC_DEFINE([SMTPMTS], [1],
 128   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 129
 130 dnl What should be the default pager?
 131 AC_ARG_WITH([pager],
 132   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 133
 134 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 135
 136 dnl What should be the default mail server(s)?
 137 AC_ARG_WITH(smtpservers,
 138   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 139   [specify the default SMTP server(s) @<:@localhost@:>@]))
 140 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 141       [smtpservers="localhost"])
 142 AC_SUBST([smtpservers])dnl
 143
 144 dnl ----------------------------------------------------
 145 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 146 dnl ----------------------------------------------------
 147 AC_PREFIX_DEFAULT([/usr/local/nmh])
 148
 149 dnl ------------------
 150 dnl CHECK THE COMPILER
 151 dnl ------------------
 152 dnl We want these before the checks,
 153 dnl so the checks can modify their values.
 154 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 155 if test x"$enable_debug" = x"yes"; then
 156   test -z "$LDFLAGS" && LDFLAGS=-g
 157 fi
 158
 159 AC_PROG_CC
 160 AM_PROG_CC_C_O
 161
 162 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 163   [nmh_cv_has_unusedmacros],
 164   [nmh_saved_cppflags="$CPPFLAGS"
 165    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 166    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 167    CPPFLAGS="$nmh_saved_cppflags"])
 168
 169 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 170   test -z "$CPPFLAGS"  &&  CPPFLAGS=-Wunused-macros \
 171                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 172   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 173 fi
 174 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 175
 176 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 177 [nmh_saved_cflags="$CFLAGS"
 178  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 179  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 180  CFLAGS="$nmh_saved_cflags"])
 181
 182 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 183 [nmh_saved_cflags="$CFLAGS"
 184  CFLAGS="$CFLAGS -Wno-pointer-sign"
 185  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 186  CFLAGS="$nmh_saved_cflags"])
 187
 188 dnl if the user hasn't specified CFLAGS, then
 189 dnl   if compiler is gcc, then
 190 dnl    use -O2 and some warning flags
 191 dnl   else use -O
 192 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 193 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 194 dnl warnings which are probably mostly spurious and which in any case we
 195 dnl don't want to deal with now.
 196 if test "$nmh_cv_has_noptrsign" = "yes"; then
 197     if test "$nmh_cv_has_wextra" = "yes"; then
 198         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered -Wno-pointer-sign"
 199     else
 200         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 201     fi
 202 else
 203     if test "$nmh_cv_has_wextra" = "yes"; then
 204         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered"
 205     else
 206         nmh_gcc_warnflags="-Wall"
 207     fi
 208 fi
 209
 210 if test -n "$auto_cflags"; then
 211   if test x"$enable_debug" = x"yes"; then
 212     if test -n "$GCC"; then
 213       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 214     else
 215       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 216     fi
 217   else
 218     if test -z "$LDFLAGS"; then
 219       case "$build_os" in
 220         darwin*)
 221           LDFLAGS=
 222           ;;
 223         *)
 224           LDFLAGS=-s
 225           ;;
 226       esac
 227     fi
 228     if test -n "$GCC"; then
 229       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 230     else
 231       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 232     fi
 233   fi
 234 fi
 235
 236 AC_C_CONST              dnl Does compiler support `const'.
 237
 238 dnl ------------------
 239 dnl CHECK FOR PROGRAMS
 240 dnl ------------------
 241 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 242 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 243 AC_PROG_RANLIB          dnl Check for `ranlib'
 244 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 245 AC_PROG_SED             dnl Check for Posix-compliant sed
 246 AC_PROG_LEX             dnl Check for lex/flex
 247
 248 dnl Look for `cut'
 249 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 250 AC_PATH_PROG([cutpath], [cut], [no], [$pathtmp])
 251
 252 dnl
 253 dnl Check for MD5 program and formatting command
 254 dnl
 255 AC_CHECK_PROGS([MD5SUM], [md5sum md5], [missing])
 256 AS_CASE(["${MD5SUM}"],
 257         [md5sum], [MD5FMT="cat"],
 258         [md5], [[MD5FMT="${SED} -e 's/MD5 *(\(.*\)) *= \([0-9a-f]*\)/\2  \1/'"]],
 259         [MD5FMT="missing"])
 260 AC_SUBST([MD5FMT])
 261
 262 dnl ----------------------------------------------
 263 dnl check for lclint, and lint if it doesn't exist
 264 dnl ----------------------------------------------
 265 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 266 if test x$ac_cv_prog_linttmp1 != xno ; then
 267   LINT=$ac_cv_prog_linttmp1
 268   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 269 else
 270   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 271   if test x$ac_cv_prog_linttmp2 != xno ; then
 272     LINT=$ac_cv_prog_linttmp2
 273     LINTFLAGS=""
 274   else
 275     LINT="echo 'No lint program found'"
 276     LINTFLAGS=""
 277   fi
 278 fi
 279 AC_SUBST([LINT])dnl
 280 AC_SUBST([LINTFLAGS])dnl
 281
 282 dnl Look for `ls'
 283 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 284 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 285
 286 dnl See how we get ls to display the owner and the group
 287 if test "$lspath" != "no"; then
 288   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 289                  [nmh_cv_ls_grpopt],
 290   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 291     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 292     dnl ls, it would seem -l gave us both the user and group.  On this type of
 293     dnl ls, -g makes _only_ the group be displayed (and not the user).
 294     nmh_cv_ls_grpopt="-l"
 295   else
 296     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 297     nmh_cv_ls_grpopt="-lg"
 298   fi])
 299 fi
 300
 301 dnl Look for `more'
 302 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 303 AC_PATH_PROG([morepath], [more], [no], [$pathtmp])
 304
 305 dnl If pager is not specified yet,
 306 dnl then use `more' as the default.
 307 if test -z "$pagerpath"; then
 308   pagerpath="$morepath"
 309 fi
 310 AC_SUBST(pagerpath)dnl
 311
 312 dnl Look for `sendmail'
 313 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 314 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 315
 316 dnl Look for `vi'
 317 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 318 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 319
 320 dnl If editor is not specified yet,
 321 dnl then use `vi' as the default.
 322 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 323 AC_SUBST([editorpath])dnl
 324
 325 dnl ----------------------------------------------------------
 326 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 327 dnl ----------------------------------------------------------
 328 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 329 [for mailspool in /var/mail        dnl
 330                   /var/spool/mail  dnl
 331                   /usr/spool/mail  dnl
 332                   /dev/null;       dnl Just in case we fall through
 333 do
 334   test -d $mailspool && break
 335 done
 336 nmh_cv_mailspool=$mailspool
 337 ])
 338 mailspool=$nmh_cv_mailspool
 339 AC_SUBST([mailspool])dnl
 340
 341 dnl See whether the mail spool directory is world-writable.
 342 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 343   AC_CACHE_CHECK(whether the mail spool is world-writable,
 344                  nmh_cv_mailspool_world_writable,
 345   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 346     nmh_cv_mailspool_world_writable=no
 347   else
 348     nmh_cv_mailspool_world_writable=yes
 349   fi])
 350 fi
 351
 352 dnl Also, check for liblockfile (as found on Debian systems)
 353 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 354
 355 dnl and whether its companion program dotlockfile is setgid
 356 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 357 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 358   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 359     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 360     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 361         nmh_cv_dotlockfile_setgid=yes
 362       else
 363         nmh_cv_dotlockfile_setgid=no
 364       fi])
 365   fi
 366 fi
 367
 368 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 369 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 370 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 371   dnl do we really need both of these?
 372   AC_DEFINE(MAILGROUP,1,
 373     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 374   SETGID_MAIL=1
 375 fi
 376 AC_SUBST(SETGID_MAIL)dnl
 377
 378 dnl Use ls to see which group owns the mail spool directory.
 379 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 380 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 381 ])
 382 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 383 AC_SUBST(MAIL_SPOOL_GRP)dnl
 384
 385 dnl ------------------
 386 dnl CHECK HEADER FILES
 387 dnl ------------------
 388
 389 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 390 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 391 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 392 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 393 dnl declared; if so they should have an entry added to this case statement.
 394 dnl NB that we must define this on the compiler command line, not in config.h,
 395 dnl because it must be set before any system header is included and there's no
 396 dnl portable way to make sure that files generated by lex include config.h
 397 dnl before system header files.
 398
 399 AS_CASE(["$host_os"],
 400         [linux*],
 401         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 402           AS_IF([test -z "$CPPFLAGS"],[CPPFLAGS="-D_GNU_SOURCE"],
 403                 [CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"])])
 404
 405 AC_HEADER_STDC
 406 AC_HEADER_TIOCGWINSZ
 407 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 408                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 409                   sys/param.h sys/time.h sys/stream.h])
 410
 411 dnl
 412 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 413 dnl really use a whole set of them, but this check should be
 414 dnl sufficient.
 415 dnl
 416 AC_CHECK_HEADER(libio.h, [
 417   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 418     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 419
 420 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 421   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 422 [[#if HAVE_SYS_STREAM_H
 423 #  include <sys/stream.h>
 424 #endif
 425 ]])
 426
 427 dnl ---------------
 428 dnl CHECK FUNCTIONS
 429 dnl ---------------
 430 AC_CHECK_FUNCS([writev lstat nl_langinfo])
 431
 432 dnl Check for multibyte character set support
 433 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 434     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 435   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 436     [Define to enable support for multibyte character sets.])
 437 fi
 438
 439 dnl -------------------
 440 dnl CHECK FOR LIBRARIES
 441 dnl -------------------
 442 dnl Check location of modf
 443 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 444
 445 dnl Checks for network libraries (nsl, socket)
 446 NMH_CHECK_NETLIBS
 447
 448 termcap_curses_order="termcap curses ncurses"
 449 for lib in $termcap_curses_order; do
 450   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 451 done
 452 AC_SUBST([TERMLIB])dnl
 453 AS_IF([test "x$TERMLIB" = "x"],
 454       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 455 or ncurses library or package that you can install?])])
 456
 457
 458 dnl ---------------
 459 dnl CHECK FOR ICONV
 460 dnl ---------------
 461
 462 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 463 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 464   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 465   if test "x$ac_found_iconv" = "xno"; then
 466     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 467     if test "x$ac_found_iconv" = "xno"; then
 468       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 469     fi
 470     if test "x$ac_found_iconv" != "xno"; then
 471       ICONVLIB="-liconv"
 472     fi
 473   else
 474     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 475     AC_CHECK_DECL(_libiconv_version,
 476       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 477       [ #include <iconv.h> ])
 478   fi
 479 fi
 480 if test "x$ac_found_iconv" = xyes; then
 481   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 482 fi
 483 AC_SUBST([ICONVLIB])
 484
 485 dnl Check if iconv uses const in prototype declaration
 486 if test "x$ac_found_iconv" = "xyes"; then
 487   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 488     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 489         #include <iconv.h>]],
 490         [[#ifdef __cplusplus
 491           "C"
 492           #endif
 493           #if defined(__STDC__) || defined(__cplusplus)
 494           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 495           #else
 496           size_t iconv();
 497           #endif]])],
 498       [ac_cv_iconv_const=],
 499       [ac_cv_iconv_const=const])])
 500   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 501     [Define as const if the declaration of iconv() needs const.])
 502 fi
 503
 504 dnl --------------
 505 dnl CHECK FOR NDBM
 506 dnl --------------
 507
 508 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 509             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 510 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 511             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 512
 513 if test "$nmh_ndbm" = "autodetect"; then
 514   if test "$nmh_ndbmheader" != "autodetect"; then
 515     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 516   else
 517
 518     dnl There are at least four implementations of ndbm, and
 519     dnl several of those can be in different places at the whim
 520     dnl of the system integrator. A good summary of this mess
 521     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 522
 523     dnl Classic ndbm with no library required (eg NetBSD): try this
 524     dnl first so we don't accidentally link in a pointless but harmless
 525     dnl library in one of the later ndbm.h+libfoo tests:
 526     NMH_CHECK_NDBM(ndbm.h,,,
 527     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 528       NMH_CHECK_NDBM(db.h,db,,
 529     dnl Berkeley DBv1 emulating ndbm:
 530         NMH_CHECK_NDBM(ndbm.h,db,,
 531           NMH_CHECK_NDBM(ndbm.h,db1,,
 532     dnl Classic ndbm:
 533             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 534     dnl glibc2.1 systems put db1 in a subdir:
 535               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 536     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 537     dnl and possibly needing gbdm_compat library:
 538                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 539                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 540                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 541                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 542
 543   fi
 544 else
 545   dnl We don't really need to check that the user-specified values work,
 546   dnl but it is a convenience to the user to bomb out early rather than
 547   dnl after configure and half the compile process.
 548   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 549 fi
 550
 551 if test "$nmh_ndbm_found" = "no"; then
 552   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 553 else
 554   dnl Now export the lib/header to our makefile/config.h:
 555   if test x"$nmh_ndbmheader" != x; then
 556     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 557       [Define to the header containing the ndbm API prototypes.])
 558   fi
 559   if test x"$nmh_ndbm" != x; then
 560     NDBM_LIBS="-l$nmh_ndbm"
 561   else
 562     NDBM_LIBS=
 563   fi
 564   AC_SUBST([NDBM_LIBS])
 565 fi
 566
 567 dnl ------------------
 568 dnl Set RPM build root
 569 dnl ------------------
 570 dnl nmhrpm is used in the final summary, see below.  The default value is
 571 dnl reported there as ./RPM, consistent with the reporting of the default
 572 dnl source code location as ., but its absolute path is used in the Makefile.
 573 AC_ARG_WITH(rpmdir,
 574   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 575   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 576           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 577 AC_SUBST([rpmdir])
 578
 579
 580 dnl --------------------
 581 dnl CHECK FOR CYRUS-SASL
 582 dnl --------------------
 583
 584 AS_IF([test x"$sasl_support" = x"yes"],[
 585   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 586   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 587     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 588 AC_SUBST([SASLLIB])
 589
 590 dnl -----------------
 591 dnl CHECK FOR OPENSSL
 592 dnl -----------------
 593
 594 AS_IF([test x"$tls_support" = x"yes"],[
 595   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 596   AC_CHECK_LIB([crypto], [BIO_write], ,
 597     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 598   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 599     [AC_MSG_ERROR([OpenSSL library not found])])])
 600
 601 dnl ---------------------
 602 dnl CHECK TERMCAP LIBRARY
 603 dnl ---------------------
 604
 605 dnl Add the termcap library, so that the following configure
 606 dnl tests will find it when it tries to link test programs.
 607 nmh_save_LIBS="$LIBS"
 608 LIBS="$TERMLIB $LIBS"
 609
 610 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 611 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 612 dnl in tgetstr().
 613 dnl Under Cygwin test program crashes but exit code is still 0. So,
 614 dnl we test for a file that porgram should create
 615 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 616 [Define to 1 if tgetent() accepts NULL as a buffer.])
 617 AC_CACHE_CHECK(if tgetent accepts NULL,
 618 nmh_cv_func_tgetent_accepts_null,
 619 [AC_TRY_RUN([
 620 main()
 621 {
 622     char buf[4096];
 623     int r1 = tgetent(buf, "vt100");
 624     int r2 = tgetent((char*)0,"vt100");
 625     if (r1 >= 0 && r1 == r2) {
 626         char tbuf[1024], *u;
 627         u = tbuf;
 628         tgetstr("cl", &u);
 629         creat("conftest.tgetent", 0640);
 630     }
 631     exit((r1 != r2) || r2 == -1);
 632 }
 633 ],
 634   if test -f conftest.tgetent; then
 635     nmh_cv_func_tgetent_accepts_null=yes
 636   else
 637     nmh_cv_func_tgetent_accepts_null=no
 638   fi,
 639   nmh_cv_func_tgetent_accepts_null=no,
 640   nmh_cv_func_tgetent_accepts_null=no)])
 641 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 642   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 643 fi
 644 AC_CACHE_CHECK(if tgetent returns 0 on success,
 645 nmh_cv_func_tgetent_zero_success,
 646 [AC_TRY_RUN([
 647 main()
 648 {
 649     char buf[4096];
 650     int r1 = tgetent(buf, "!@#$%^&*");
 651     int r2 = tgetent(buf, "vt100");
 652     if (r1 < 0 && r2 == 0) {
 653         char tbuf[1024], *u;
 654         u = tbuf;
 655         tgetstr("cl", &u);
 656         creat("conftest.tgetent0", 0640);
 657     }
 658     exit(r1 == r2);
 659 }
 660 ],
 661   if test -f conftest.tgetent0; then
 662     nmh_cv_func_tgetent_zero_success=yes
 663   else
 664     nmh_cv_func_tgetent_zero_success=no
 665   fi,
 666   nmh_cv_func_tgetent_zero_success=no,
 667   nmh_cv_func_tgetent_zero_success=no)])
 668 AH_TEMPLATE([TGETENT_SUCCESS],
 669 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 670 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 671   AC_DEFINE(TGETENT_SUCCESS, 0)
 672 else
 673   AC_DEFINE(TGETENT_SUCCESS, 1)
 674 fi
 675
 676 dnl Now put the libraries back to what it was before we
 677 dnl starting checking the termcap library.
 678 LIBS="$nmh_save_LIBS"
 679
 680 dnl --------------
 681 dnl CHECK TYPEDEFS
 682 dnl --------------
 683 AC_TYPE_PID_T
 684 AC_TYPE_OFF_T
 685 AC_TYPE_UID_T
 686 AC_TYPE_MODE_T
 687 AC_TYPE_SIZE_T
 688
 689 dnl ----------------
 690 dnl CHECK STRUCTURES
 691 dnl ----------------
 692
 693 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 694 dnl (FreeBSD has a timezone() function but not a timezone global
 695 dnl variable that is visible).
 696 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 697
 698 AC_STRUCT_DIRENT_D_TYPE
 699
 700 dnl Where is <signal.h> located?  Needed as input for signames.awk
 701 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 702 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 703                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 704                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 705                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 706                  /usr/include/sys/signal.h      dnl Almost everybody else
 707                  /dev/null;                     dnl Just in case we fall through
 708 do
 709   test -f $SIGNAL_H && \
 710   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 711   break
 712 done
 713 nmh_cv_path_signal_h=$SIGNAL_H
 714 ])
 715 SIGNAL_H=$nmh_cv_path_signal_h
 716 AC_SUBST(SIGNAL_H)dnl
 717
 718 dnl
 719 dnl Sigh, this is required because under the new world order autoconf has
 720 dnl nothing to create in a few of the build directories when doing an object
 721 dnl tree build.  So make sure we created certain directories if they don't
 722 dnl exist.
 723 dnl
 724
 725 AC_CONFIG_COMMANDS([build-directories],
 726 [test -d etc || ${MKDIR_P} etc
 727 test -d man || ${MKDIR_P} man])
 728
 729 AC_CONFIG_COMMANDS_POST([
 730
 731 dnl These odd looking assignments are done to expand out unexpanded
 732 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 733 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 734 dnl again to get the final answer.
 735 dnl We only use the expanded versions to print the install paths in
 736 dnl the final summary and should use them nowhere else (see the autoconf
 737 dnl docs for the rationale for bindir etc being unexpanded).
 738 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 739 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 740 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 741 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 742 eval "nmhrpm=${nmhrpm}";
 743
 744 AC_MSG_NOTICE([
 745 nmh configuration
 746 -----------------
 747 nmh version                : AC_PACKAGE_VERSION
 748 host os                    : ${host}
 749 compiler                   : ${CC}
 750 compiler flags             : ${CFLAGS}
 751 linker flags               : ${LDFLAGS}
 752 preprocessor flags         : ${CPPFLAGS}
 753 source code location       : ${srcdir}
 754 binary install path        : ${nmhbin}
 755 library install path       : ${nmhlib}
 756 config files install path  : ${nmhsysconf}
 757 man page install path      : ${nmhman}
 758 RPM build root             : ${nmhrpm}
 759 backup prefix              : ${backup_prefix}
 760 transport system           : ${MTS}
 761 file locking type          : ${LOCKTYPE}
 762 default smtp servers       : ${smtpservers}
 763 default editor             : ${editorpath}
 764 default pager              : ${pagerpath}
 765 email address masquerading : ${masquerade}
 766 SASL support               : ${sasl_support}
 767 TLS support                : ${tls_support}
 768 ])])dnl
 769
 770 dnl ---------------
 771 dnl OUTPUT MAKEFILE
 772 dnl ---------------
 773 AC_CONFIG_FILES([Makefile test/common.sh])
 774 AC_OUTPUT