git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ([2.61])
   7
   8 AC_INIT([nmh], m4_normalize(m4_include([VERSION])), [nmh-workers@nongnu.org])
   9 AC_CONFIG_SRCDIR([h/nmh.h])
  10 AC_CONFIG_HEADER([config.h])
  11 AM_INIT_AUTOMAKE([-Wall -Werror foreign subdir-objects])
  12
  13 AC_CANONICAL_HOST
  14
  15 AC_MSG_NOTICE([configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION])
  16 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  17
  18 dnl What date of nmh are we building?
  19 DATE=`cat ${srcdir}/DATE`
  20 AC_MSG_NOTICE([configuring for nmh dated $DATE])
  21 AC_SUBST([DATE])dnl
  22
  23 dnl --------------------------
  24 dnl CHECK COMMAND LINE OPTIONS
  25 dnl --------------------------
  26
  27 dnl Do you want to debug nmh?
  28 AC_ARG_ENABLE([debug],
  29   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  30 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  31 AS_IF([test x"$enable_nmh_debug" = x"yes"], [enable_debug=yes])
  32
  33 dnl Allow users to send email from addresses other than their default?
  34 AC_ARG_ENABLE(masquerade,
  35   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  36     [enable up to 3 types of address masquerading]),
  37   [AS_IF([test x"$enable_masquerade" = x"yes"],
  38          [masquerade="draft_from mmailid username_extension"],
  39          [masquerade="$enable_masquerade"])],
  40   [masquerade="draft_from mmailid username_extension"])
  41 AC_SUBST(masquerade)dnl
  42
  43 dnl Do you want to disable use of locale functions
  44 AH_TEMPLATE([LOCALE],
  45 [Undefine if you don't want locale features.  By default this is defined.])
  46 AC_ARG_ENABLE([locale],
  47   [AC_HELP_STRING([--disable-locale], [turn off locale features])],
  48   [AS_IF([test x$enableval = xyes], [AC_DEFINE(LOCALE)])],
  49   [AC_DEFINE(LOCALE)])
  50
  51 dnl Do you want client-side support for using SASL for authentication?
  52 dnl Note that this code will be enabled for both POP and SMTP
  53 AC_ARG_WITH([cyrus-sasl], AS_HELP_STRING([--with-cyrus-sasl],
  54   [Enable SASL support via the Cyrus SASL library]))
  55 AS_IF([test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"],[
  56       AC_DEFINE([CYRUS_SASL], [1],
  57                 [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  58       AS_IF([test x"$with_cyrus_sasl" != xyes],[
  59             AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  60             AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])])
  61       sasl_support=yes], [sasl_support=no])
  62
  63 dnl Do you want client-side support for encryption with TLS?
  64 AC_ARG_WITH([tls], AS_HELP_STRING([--with-tls], [Enable TLS support]))
  65 AS_IF([test x"$with_tls" != x -a x"$with_tls" != x"no"],[
  66       AC_DEFINE([TLS_SUPPORT], [1], [Support TLS for session encryption.])dnl
  67       tls_support=yes],[tls_support=no])
  68
  69 dnl What should be the default editor?
  70 AC_ARG_WITH([editor],
  71   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  72
  73 AS_IF([test -n "$with_editor"], [editorpath="$with_editor"])
  74
  75 dnl Set the backup prefix
  76 AC_ARG_WITH([hash-backup],
  77   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
  78 AS_IF([test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"],
  79       [backup_prefix="#"], [backup_prefix=","])
  80 AC_DEFINE_UNQUOTED([BACKUP_PREFIX], "$backup_prefix",
  81     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
  82
  83 dnl What method of locking to use?
  84 AC_ARG_WITH(locking,
  85   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
  86   [specify the file locking method]))
  87
  88 if test x"$with_locking" = x"dot"; then
  89   LOCKTYPE="dot"
  90   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
  91 elif test x"$with_locking" = x"flock"; then
  92   LOCKTYPE="flock"
  93   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
  94 elif test x"$with_locking" = x"lockf"; then
  95   LOCKTYPE="lockf"
  96   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
  97 elif test x"$with_locking" = x"fcntl"; then
  98   LOCKTYPE="fcntl"
  99   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 100 else
 101   LOCKTYPE="dot"
 102   AC_DEFINE(DOT_LOCKING)dnl
 103 fi
 104
 105 dnl Should we use a locking directory?
 106 AC_ARG_ENABLE([lockdir], [
 107   AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 108   AS_IF([test "x$enableval" = xyes],[
 109     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 110   AS_IF([test "x$LOCKTYPE" != xdot],[
 111     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 112   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 113                      [Directory to store dot-locking lock files])
 114 ])
 115
 116 dnl What method of posting should post use?
 117 AC_ARG_WITH([mts],
 118   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 119   [specify the default mail transport agent/service]))
 120
 121 AS_IF([test x"$with_mts" = x"smtp"], [MTS="smtp"],
 122       [test x"$with_mts" = x"sendmail"], [MTS="sendmail"],
 123       [MTS="smtp"])
 124 AC_SUBST([MTS])dnl
 125
 126 dnl Both the smtp and sendmail mail transport services use the smtp code
 127 AC_DEFINE([SMTPMTS], [1],
 128   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 129
 130 dnl What should be the default pager?
 131 AC_ARG_WITH([pager],
 132   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 133
 134 AS_IF([test -n "$with_pager"], [pagerpath="$with_pager"])
 135
 136 dnl What should be the default mail server(s)?
 137 AC_ARG_WITH(smtpservers,
 138   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 139   [specify the default SMTP server(s) @<:@localhost@:>@]))
 140 AS_IF([test -n "$with_smtpservers"], [smtpservers="$with_smtpservers"],
 141       [smtpservers="localhost"])
 142 AC_SUBST([smtpservers])dnl
 143
 144 dnl ----------------------------------------------------
 145 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 146 dnl ----------------------------------------------------
 147 AC_PREFIX_DEFAULT([/usr/local/nmh])
 148
 149 dnl ------------------
 150 dnl CHECK THE COMPILER
 151 dnl ------------------
 152 dnl We want these before the checks,
 153 dnl so the checks can modify their values.
 154 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 155 if test x"$enable_debug" = x"yes"; then
 156   test -z "$LDFLAGS" && LDFLAGS=-g
 157 fi
 158
 159 AC_PROG_CC
 160 AM_PROG_CC_C_O
 161
 162 AC_CACHE_CHECK([whether preprocessor supports -Wunused-macros],
 163   [nmh_cv_has_unusedmacros],
 164   [nmh_saved_cppflags="$CPPFLAGS"
 165    CPPFLAGS="$CPPFLAGS -Wunused-macros -Wno-unused-macros"
 166    AC_TRY_COMPILE([],[],nmh_cv_has_unusedmacros=yes,nmh_cv_has_unusedmacros=no)
 167    CPPFLAGS="$nmh_saved_cppflags"])
 168
 169 if test "$nmh_cv_has_unusedmacros" = 'yes'; then
 170   test -z "$CPPLAGS"  &&  CPPFLAGS=-Wunused-macros \
 171                       ||  CPPFLAGS="$CPPFLAGS -Wunused-macros"
 172   DISABLE_UNUSED_MACROS_WARNING=-Wno-unused-macros
 173 fi
 174 AC_SUBST(DISABLE_UNUSED_MACROS_WARNING)dnl
 175
 176 AC_CACHE_CHECK([whether compiler supports -Wextra], [nmh_cv_has_wextra],
 177 [nmh_saved_cflags="$CFLAGS"
 178  CFLAGS="$CFLAGS -Wextra -Wno-clobbered"
 179  AC_TRY_COMPILE([],[],nmh_cv_has_wextra=yes,nmh_cv_has_wextra=no)
 180  CFLAGS="$nmh_saved_cflags"])
 181
 182 AC_CACHE_CHECK([whether compiler supports -Wno-pointer-sign], [nmh_cv_has_noptrsign],
 183 [nmh_saved_cflags="$CFLAGS"
 184  CFLAGS="$CFLAGS -Wno-pointer-sign"
 185  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 186  CFLAGS="$nmh_saved_cflags"])
 187
 188 dnl if the user hasn't specified CFLAGS, then
 189 dnl   if compiler is gcc, then
 190 dnl    use -O2 and some warning flags
 191 dnl   else use -O
 192 dnl We use -Wall and -Wextra if supported.  If the compiler supports it we
 193 dnl also use -Wno-pointer-sign, because gcc 4 now produces a lot of new
 194 dnl warnings which are probably mostly spurious and which in any case we
 195 dnl don't want to deal with now.
 196 if test "$nmh_cv_has_noptrsign" = "yes"; then
 197     if test "$nmh_cv_has_wextra" = "yes"; then
 198         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered -Wno-pointer-sign"
 199     else
 200         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 201     fi
 202 else
 203     if test "$nmh_cv_has_wextra" = "yes"; then
 204         nmh_gcc_warnflags="-Wall -Wextra -Wno-clobbered"
 205     else
 206         nmh_gcc_warnflags="-Wall"
 207     fi
 208 fi
 209
 210 if test -n "$auto_cflags"; then
 211   if test x"$enable_debug" = x"yes"; then
 212     if test -n "$GCC"; then
 213       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 214     else
 215       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 216     fi
 217   else
 218     if test -z "$LDFLAGS"; then
 219       case "$build_os" in
 220         darwin*)
 221           LDFLAGS=
 222           ;;
 223         *)
 224           LDFLAGS=-s
 225           ;;
 226       esac
 227     fi
 228     if test -n "$GCC"; then
 229       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 230     else
 231       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 232     fi
 233   fi
 234 fi
 235
 236 AC_C_CONST              dnl Does compiler support `const'.
 237
 238 dnl ------------------
 239 dnl CHECK FOR PROGRAMS
 240 dnl ------------------
 241 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 242 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 243 AC_PROG_RANLIB          dnl Check for `ranlib'
 244 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 245 AC_PROG_SED             dnl Check for Posix-compliant sed
 246 AC_PROG_LEX             dnl Check for lex/flex
 247
 248 dnl Look for `cut'
 249 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 250 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 251
 252 dnl ----------------------------------------------
 253 dnl check for lclint, and lint if it doesn't exist
 254 dnl ----------------------------------------------
 255 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 256 if test x$ac_cv_prog_linttmp1 != xno ; then
 257   LINT=$ac_cv_prog_linttmp1
 258   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 259 else
 260   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 261   if test x$ac_cv_prog_linttmp2 != xno ; then
 262     LINT=$ac_cv_prog_linttmp2
 263     LINTFLAGS=""
 264   else
 265     LINT="echo 'No lint program found'"
 266     LINTFLAGS=""
 267   fi
 268 fi
 269 AC_SUBST([LINT])dnl
 270 AC_SUBST([LINTFLAGS])dnl
 271
 272 dnl Look for `ls'
 273 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 274 AC_PATH_PROG([lspath], [ls], [no], [$pathtmp])
 275
 276 dnl See how we get ls to display the owner and the group
 277 if test "$lspath" != "no"; then
 278   AC_CACHE_CHECK([how to get ls to show us the group ownership of a file],
 279                  [nmh_cv_ls_grpopt],
 280   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 281     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 282     dnl ls, it would seem -l gave us both the user and group.  On this type of
 283     dnl ls, -g makes _only_ the group be displayed (and not the user).
 284     nmh_cv_ls_grpopt="-l"
 285   else
 286     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 287     nmh_cv_ls_grpopt="-lg"
 288   fi])
 289 fi
 290
 291 dnl Look for `more'
 292 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 293 AC_PATH_PROG([morepath], [more], [no], [$pathtmp])
 294
 295 dnl If pager is not specified yet,
 296 dnl then use `more' as the default.
 297 if test -z "$pagerpath"; then
 298   pagerpath="$morepath"
 299 fi
 300 AC_SUBST(pagerpath)dnl
 301
 302 dnl Look for `sendmail'
 303 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 304 AC_PATH_PROG([sendmailpath], [sendmail], [/usr/sbin/sendmail], [$pathtmp])
 305
 306 dnl Look for `vi'
 307 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 308 AC_PATH_PROG([vipath], [vi], [/bin/vi], [$pathtmp])
 309
 310 dnl If editor is not specified yet,
 311 dnl then use `vi' as the default.
 312 AS_IF([test -z "$editorpath"], [editorpath="$vipath"])
 313 AC_SUBST([editorpath])dnl
 314
 315 dnl ----------------------------------------------------------
 316 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 317 dnl ----------------------------------------------------------
 318 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 319 [for mailspool in /var/mail        dnl
 320                   /var/spool/mail  dnl
 321                   /usr/spool/mail  dnl
 322                   /dev/null;       dnl Just in case we fall through
 323 do
 324   test -d $mailspool && break
 325 done
 326 nmh_cv_mailspool=$mailspool
 327 ])
 328 mailspool=$nmh_cv_mailspool
 329 AC_SUBST([mailspool])dnl
 330
 331 dnl See whether the mail spool directory is world-writable.
 332 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 333   AC_CACHE_CHECK(whether the mail spool is world-writable,
 334                  nmh_cv_mailspool_world_writable,
 335   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 336     nmh_cv_mailspool_world_writable=no
 337   else
 338     nmh_cv_mailspool_world_writable=yes
 339   fi])
 340 fi
 341
 342 dnl Also, check for liblockfile (as found on Debian systems)
 343 AC_CHECK_HEADER([lockfile.h], [AC_CHECK_LIB(lockfile, lockfile_create)])
 344
 345 dnl and whether its companion program dotlockfile is setgid
 346 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 347 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 348   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 349     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 350     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 351         nmh_cv_dotlockfile_setgid=yes
 352       else
 353         nmh_cv_dotlockfile_setgid=no
 354       fi])
 355   fi
 356 fi
 357
 358 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 359 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 360 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 361   dnl do we really need both of these?
 362   AC_DEFINE(MAILGROUP,1,
 363     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 364   SETGID_MAIL=1
 365 fi
 366 AC_SUBST(SETGID_MAIL)dnl
 367
 368 dnl Use ls to see which group owns the mail spool directory.
 369 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 370 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 371 ])
 372 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 373 AC_SUBST(MAIL_SPOOL_GRP)dnl
 374
 375 dnl ------------------
 376 dnl CHECK HEADER FILES
 377 dnl ------------------
 378
 379 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 380 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 381 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 382 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 383 dnl declared; if so they should have an entry added to this case statement.
 384 dnl NB that we must define this on the compiler command line, not in config.h,
 385 dnl because it must be set before any system header is included and there's no
 386 dnl portable way to make sure that files generated by lex include config.h
 387 dnl before system header files.
 388
 389 AS_CASE(["$host_os"],
 390         [linux*],
 391         [# Like DEFS, but doesn't get stomped on by configure when using config.h:
 392     test -z "$OURDEFS"  &&  OURDEFS="-D_GNU_SOURCE"  \
 393                         ||  OURDEFS="$OURDEFS -D_GNU_SOURCE"])
 394 AC_SUBST(OURDEFS)
 395
 396 AC_HEADER_STDC
 397 AC_HEADER_TIOCGWINSZ
 398 AC_CHECK_HEADERS([errno.h fcntl.h crypt.h ncurses/termcap.h termcap.h \
 399                   langinfo.h wchar.h wctype.h iconv.h netdb.h \
 400                   sys/param.h sys/time.h sys/stream.h])
 401
 402 dnl
 403 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 404 dnl really use a whole set of them, but this check should be
 405 dnl sufficient.
 406 dnl
 407 AC_CHECK_HEADER(libio.h, [
 408   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 409     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 410
 411 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 412   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 413 [[#if HAVE_SYS_STREAM_H
 414 #  include <sys/stream.h>
 415 #endif
 416 ]])
 417
 418 dnl ---------------
 419 dnl CHECK FUNCTIONS
 420 dnl ---------------
 421 AC_CHECK_FUNCS([writev lstat nl_langinfo])
 422
 423 dnl Check for multibyte character set support
 424 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 425     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 426   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 427     [Define to enable support for multibyte character sets.])
 428 fi
 429
 430 dnl -------------------
 431 dnl CHECK FOR LIBRARIES
 432 dnl -------------------
 433 dnl Check location of modf
 434 AC_CHECK_FUNC([modf], , AC_CHECK_LIB([m], [modf]))
 435
 436 dnl Checks for network libraries (nsl, socket)
 437 NMH_CHECK_NETLIBS
 438
 439 termcap_curses_order="termcap curses ncurses"
 440 for lib in $termcap_curses_order; do
 441   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 442 done
 443 AC_SUBST([TERMLIB])dnl
 444 AS_IF([test "x$TERMLIB" = "x"],
 445       [AC_MSG_FAILURE([Could not find tgetent in any library.  Is there a curses
 446 or ncurses library or package that you can install?])])
 447
 448
 449 dnl ---------------
 450 dnl CHECK FOR ICONV
 451 dnl ---------------
 452
 453 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 454 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 455   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 456   if test "x$ac_found_iconv" = "xno"; then
 457     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 458     if test "x$ac_found_iconv" = "xno"; then
 459       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 460     fi
 461     if test "x$ac_found_iconv" != "xno"; then
 462       ICONVLIB="-liconv"
 463     fi
 464   else
 465     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 466     AC_CHECK_DECL(_libiconv_version,
 467       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 468       [ #include <iconv.h> ])
 469   fi
 470 fi
 471 if test "x$ac_found_iconv" = xyes; then
 472   AC_DEFINE([HAVE_ICONV], [1], [Define if you have the iconv() function.])
 473 fi
 474 AC_SUBST([ICONVLIB])
 475
 476 dnl Check if iconv uses const in prototype declaration
 477 if test "x$ac_found_iconv" = "xyes"; then
 478   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 479     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 480         #include <iconv.h>]],
 481         [[#ifdef __cplusplus
 482           "C"
 483           #endif
 484           #if defined(__STDC__) || defined(__cplusplus)
 485           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 486           #else
 487           size_t iconv();
 488           #endif]])],
 489       [ac_cv_iconv_const=],
 490       [ac_cv_iconv_const=const])])
 491   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 492     [Define as const if the declaration of iconv() needs const.])
 493 fi
 494
 495 dnl --------------
 496 dnl CHECK FOR NDBM
 497 dnl --------------
 498
 499 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 500             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 501 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 502             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 503
 504 if test "$nmh_ndbm" = "autodetect"; then
 505   if test "$nmh_ndbmheader" != "autodetect"; then
 506     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 507   else
 508
 509     dnl There are at least four implementations of ndbm, and
 510     dnl several of those can be in different places at the whim
 511     dnl of the system integrator. A good summary of this mess
 512     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 513
 514     dnl Classic ndbm with no library required (eg NetBSD): try this
 515     dnl first so we don't accidentally link in a pointless but harmless
 516     dnl library in one of the later ndbm.h+libfoo tests:
 517     NMH_CHECK_NDBM(ndbm.h,,,
 518     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 519       NMH_CHECK_NDBM(db.h,db,,
 520     dnl Berkeley DBv1 emulating ndbm:
 521         NMH_CHECK_NDBM(ndbm.h,db,,
 522           NMH_CHECK_NDBM(ndbm.h,db1,,
 523     dnl Classic ndbm:
 524             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 525     dnl glibc2.1 systems put db1 in a subdir:
 526               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 527     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 528     dnl and possibly needing gbdm_compat library:
 529                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 530                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 531                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 532                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 533
 534   fi
 535 else
 536   dnl We don't really need to check that the user-specified values work,
 537   dnl but it is a convenience to the user to bomb out early rather than
 538   dnl after configure and half the compile process.
 539   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 540 fi
 541
 542 if test "$nmh_ndbm_found" = "no"; then
 543   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 544 else
 545   dnl Now export the lib/header to our makefile/config.h:
 546   if test x"$nmh_ndbmheader" != x; then
 547     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 548       [Define to the header containing the ndbm API prototypes.])
 549   fi
 550   if test x"$nmh_ndbm" != x; then
 551     NDBM_LIBS="-l$nmh_ndbm"
 552   else
 553     NDBM_LIBS=
 554   fi
 555   AC_SUBST([NDBM_LIBS])
 556 fi
 557
 558 dnl ------------------
 559 dnl Set RPM build root
 560 dnl ------------------
 561 dnl nmhrpm is used in the final summary, see below.  The default value is
 562 dnl reported there as ./RPM, consistent with the reporting of the default
 563 dnl source code location as ., but its absolute path is used in the Makefile.
 564 AC_ARG_WITH(rpmdir,
 565   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 566   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 567           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 568 AC_SUBST([rpmdir])
 569
 570
 571 dnl --------------------
 572 dnl CHECK FOR CYRUS-SASL
 573 dnl --------------------
 574
 575 AS_IF([test x"$sasl_support" = x"yes"],[
 576   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 577   AC_CHECK_LIB([sasl2], [sasl_client_new], [SASLLIB="-lsasl2"],
 578     [AC_MSG_ERROR([Cyrus SASL library not found])])],[SASLLIB=""])
 579 AC_SUBST([SASLLIB])
 580
 581 dnl -----------------
 582 dnl CHECK FOR OPENSSL
 583 dnl -----------------
 584
 585 AS_IF([test x"$tls_support" = x"yes"],[
 586   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 587   AC_CHECK_LIB([crypto], [BIO_write], ,
 588     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 589   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 590     [AC_MSG_ERROR([OpenSSL library not found])])])
 591
 592 dnl ---------------------
 593 dnl CHECK TERMCAP LIBRARY
 594 dnl ---------------------
 595
 596 dnl Add the termcap library, so that the following configure
 597 dnl tests will find it when it tries to link test programs.
 598 nmh_save_LIBS="$LIBS"
 599 LIBS="$TERMLIB $LIBS"
 600
 601 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 602 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 603 dnl in tgetstr().
 604 dnl Under Cygwin test program crashes but exit code is still 0. So,
 605 dnl we test for a file that porgram should create
 606 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 607 [Define to 1 if tgetent() accepts NULL as a buffer.])
 608 AC_CACHE_CHECK(if tgetent accepts NULL,
 609 nmh_cv_func_tgetent_accepts_null,
 610 [AC_TRY_RUN([
 611 main()
 612 {
 613     char buf[4096];
 614     int r1 = tgetent(buf, "vt100");
 615     int r2 = tgetent((char*)0,"vt100");
 616     if (r1 >= 0 && r1 == r2) {
 617         char tbuf[1024], *u;
 618         u = tbuf;
 619         tgetstr("cl", &u);
 620         creat("conftest.tgetent", 0640);
 621     }
 622     exit((r1 != r2) || r2 == -1);
 623 }
 624 ],
 625   if test -f conftest.tgetent; then
 626     nmh_cv_func_tgetent_accepts_null=yes
 627   else
 628     nmh_cv_func_tgetent_accepts_null=no
 629   fi,
 630   nmh_cv_func_tgetent_accepts_null=no,
 631   nmh_cv_func_tgetent_accepts_null=no)])
 632 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 633   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 634 fi
 635 AC_CACHE_CHECK(if tgetent returns 0 on success,
 636 nmh_cv_func_tgetent_zero_success,
 637 [AC_TRY_RUN([
 638 main()
 639 {
 640     char buf[4096];
 641     int r1 = tgetent(buf, "!@#$%^&*");
 642     int r2 = tgetent(buf, "vt100");
 643     if (r1 < 0 && r2 == 0) {
 644         char tbuf[1024], *u;
 645         u = tbuf;
 646         tgetstr("cl", &u);
 647         creat("conftest.tgetent0", 0640);
 648     }
 649     exit(r1 == r2);
 650 }
 651 ],
 652   if test -f conftest.tgetent0; then
 653     nmh_cv_func_tgetent_zero_success=yes
 654   else
 655     nmh_cv_func_tgetent_zero_success=no
 656   fi,
 657   nmh_cv_func_tgetent_zero_success=no,
 658   nmh_cv_func_tgetent_zero_success=no)])
 659 AH_TEMPLATE([TGETENT_SUCCESS],
 660 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 661 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 662   AC_DEFINE(TGETENT_SUCCESS, 0)
 663 else
 664   AC_DEFINE(TGETENT_SUCCESS, 1)
 665 fi
 666
 667 dnl Now put the libraries back to what it was before we
 668 dnl starting checking the termcap library.
 669 LIBS="$nmh_save_LIBS"
 670
 671 dnl --------------
 672 dnl CHECK TYPEDEFS
 673 dnl --------------
 674 AC_TYPE_PID_T
 675 AC_TYPE_OFF_T
 676 AC_TYPE_UID_T
 677 AC_TYPE_MODE_T
 678 AC_TYPE_SIZE_T
 679
 680 dnl ----------------
 681 dnl CHECK STRUCTURES
 682 dnl ----------------
 683
 684 dnl For platforms such as FreeBSD that have tm_gmtoff in struct tm.
 685 dnl (FreeBSD has a timezone() function but not a timezone global
 686 dnl variable that is visible).
 687 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[#include <time.h>])
 688
 689 AC_STRUCT_DIRENT_D_TYPE
 690
 691 dnl Where is <signal.h> located?  Needed as input for signames.awk
 692 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 693 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 694                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 695                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 696                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 697                  /usr/include/sys/signal.h      dnl Almost everybody else
 698                  /dev/null;                     dnl Just in case we fall through
 699 do
 700   test -f $SIGNAL_H && \
 701   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 702   break
 703 done
 704 nmh_cv_path_signal_h=$SIGNAL_H
 705 ])
 706 SIGNAL_H=$nmh_cv_path_signal_h
 707 AC_SUBST(SIGNAL_H)dnl
 708
 709 dnl
 710 dnl Sigh, this is required because under the new world order autoconf has
 711 dnl nothing to create in a few of the build directories when doing an object
 712 dnl tree build.  So make sure we created certain directories if they don't
 713 dnl exist.
 714 dnl
 715
 716 AC_CONFIG_COMMANDS([build-directories],
 717 [test -d etc || ${MKDIR_P} etc
 718 test -d man || ${MKDIR_P} man])
 719
 720 AC_CONFIG_COMMANDS_POST([
 721
 722 dnl These odd looking assignments are done to expand out unexpanded
 723 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man'),
 724 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 725 dnl again to get the final answer.
 726 dnl We only use the expanded versions to print the install paths in
 727 dnl the final summary and should use them nowhere else (see the autoconf
 728 dnl docs for the rationale for bindir etc being unexpanded).
 729 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 730 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 731 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 732 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 733 eval "nmhrpm=${nmhrpm}";
 734
 735 AC_MSG_NOTICE([
 736 nmh configuration
 737 -----------------
 738 nmh version                : AC_PACKAGE_VERSION
 739 host os                    : ${host}
 740 compiler                   : ${CC}
 741 compiler flags             : ${CFLAGS}
 742 linker flags               : ${LDFLAGS}
 743 definitions                : ${OURDEFS}
 744 source code location       : ${srcdir}
 745 binary install path        : ${nmhbin}
 746 library install path       : ${nmhlib}
 747 config files install path  : ${nmhsysconf}
 748 man page install path      : ${nmhman}
 749 RPM build root             : ${nmhrpm}
 750 backup prefix              : ${backup_prefix}
 751 transport system           : ${MTS}
 752 file locking type          : ${LOCKTYPE}
 753 default smtp servers       : ${smtpservers}
 754 default editor             : ${editorpath}
 755 default pager              : ${pagerpath}
 756 email address masquerading : ${masquerade}
 757 SASL support               : ${sasl_support}
 758 TLS support                : ${tls_support}
 759 ])])dnl
 760
 761 dnl ---------------
 762 dnl OUTPUT MAKEFILE
 763 dnl ---------------
 764 AC_CONFIG_FILES([Makefile])
 765 AC_OUTPUT