git.marmaro.de Git - mmh/blob - configure.ac

   1 dnl
   2 dnl configure.ac -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want client-side support for pop?
  60 AC_ARG_ENABLE(pop,
  61   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  62 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  63 if test x"$enable_nmh_pop" = x"yes"; then
  64   enable_pop=yes
  65 fi
  66
  67 dnl Do you want to disable use of locale functions
  68 AH_TEMPLATE([LOCALE],
  69 [Undefine if you don't want locale features.  By default this is defined.])
  70 AC_ARG_ENABLE([locale],
  71 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  72 [if test x$enableval = xyes; then
  73   AC_DEFINE(LOCALE)
  74 fi],
  75 AC_DEFINE(LOCALE)
  76 )
  77
  78 dnl Do you want client-side support for using SASL for authentication?
  79 dnl Note that this code will be enabled for both POP and SMTP
  80 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
  81   [Enable SASL support via the Cyrus SASL library]))
  82 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  83   AC_DEFINE(CYRUS_SASL, 1,
  84     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  85   if test x"$with_cyrus_sasl" != xyes; then
  86     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  87     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  88   fi
  89   sasl_support=yes
  90 else
  91   sasl_support=no
  92 fi
  93
  94 dnl Do you want client-side support for encryption with TLS?
  95 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
  96 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
  97   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
  98   tls_support=yes
  99 else
 100   tls_support=no
 101 fi
 102
 103 dnl What should be the default editor?
 104 AC_ARG_WITH(editor,
 105   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 106
 107 if test -n "$with_editor"; then
 108   editorpath="$with_editor"
 109 fi
 110
 111 dnl Set the backup prefix
 112 AC_ARG_WITH([hash-backup],
 113   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 114 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 115   backup_prefix="#"
 116 else
 117   backup_prefix=","
 118 fi
 119 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 120     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 121
 122 dnl After we know if we're including apop and kpop support, do pop stuff
 123 if test x"$enable_pop" = x"yes"; then
 124   AC_DEFINE(POP, 1,
 125     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 126   POPLIB=popsbr.o
 127   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 128 else
 129   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 130 fi
 131 AC_SUBST(POPLIB)dnl
 132 AC_SUBST(POPSED)dnl
 133
 134 dnl What method of locking to use?
 135 AC_ARG_WITH(locking,
 136   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 137   [specify the file locking method]))
 138
 139 if test x"$with_locking" = x"dot"; then
 140   LOCKTYPE="dot"
 141   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 142 elif test x"$with_locking" = x"flock"; then
 143   LOCKTYPE="flock"
 144   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 145 elif test x"$with_locking" = x"lockf"; then
 146   LOCKTYPE="lockf"
 147   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 148 elif test x"$with_locking" = x"fcntl"; then
 149   LOCKTYPE="fcntl"
 150   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 151 else
 152   LOCKTYPE="dot"
 153   AC_DEFINE(DOT_LOCKING)dnl
 154 fi
 155
 156 dnl Should we use a locking directory?
 157 AC_ARG_ENABLE([lockdir], [
 158   AS_HELP_STRING([--enable-lockdir=dir], [Store dot-lock files in "dir"])], [
 159   AS_IF([test "x$enableval" = xyes],[
 160     AC_MSG_ERROR([--enable-lockdir requires an argument])])
 161   AS_IF([test "x$LOCKTYPE" != xdot],[
 162     AC_MSG_ERROR([Can only use --enable-lockdir with dot locking])])
 163   AC_DEFINE_UNQUOTED([LOCKDIR], ["$enableval"],
 164                      [Directory to store dot-locking lock files])
 165 ])
 166
 167 dnl What method of posting should post use?
 168 AC_ARG_WITH(mts,
 169   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 170   [specify the default mail transport agent/service]))
 171
 172 if test x"$with_mts" = x"smtp"; then
 173   MTS="smtp"
 174 elif test x"$with_mts" = x"sendmail"; then
 175   MTS="sendmail"
 176 else
 177   MTS="smtp"
 178 fi
 179 AC_SUBST(MTS)dnl
 180
 181 dnl Both the smtp and sendmail mail transport services use the smtp code
 182 AC_DEFINE(SMTPMTS, 1,
 183   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 184
 185 dnl What should be the default pager?
 186 AC_ARG_WITH(pager,
 187   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 188
 189 if test -n "$with_pager"; then
 190   pagerpath="$with_pager"
 191 fi
 192
 193 dnl What should be the default mail server(s)?
 194 AC_ARG_WITH(smtpservers,
 195   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 196   [specify the default SMTP server(s) @<:@localhost@:>@]))
 197 if test -n "$with_smtpservers"; then
 198   smtpservers="$with_smtpservers"
 199 else
 200   smtpservers="localhost"
 201 fi
 202 AC_SUBST(smtpservers)dnl
 203
 204 dnl ----------------------------------------------------
 205 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 206 dnl ----------------------------------------------------
 207 AC_PREFIX_DEFAULT(/usr/local/nmh)
 208
 209 dnl ------------------
 210 dnl CHECK THE COMPILER
 211 dnl ------------------
 212 dnl We want these before the checks,
 213 dnl so the checks can modify their values.
 214 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 215 if test x"$enable_debug" = x"yes"; then
 216   test -z "$LDFLAGS" && LDFLAGS=-g
 217 fi
 218
 219 AC_PROG_CC
 220
 221 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 222 [nmh_saved_cflags="$CFLAGS"
 223  CFLAGS="$CFLAGS -Wno-pointer-sign"
 224  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 225  CFLAGS="$nmh_saved_cflags"])
 226
 227 dnl if the user hasn't specified CFLAGS, then
 228 dnl   if compiler is gcc, then
 229 dnl     use -O2 and some warning flags
 230 dnl   else use -O
 231 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 232 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 233 dnl spurious and which in any case we don't want to deal with now.
 234 if test "$nmh_cv_has_noptrsign" = "yes"; then
 235         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 236 else
 237         nmh_gcc_warnflags="-Wall"
 238 fi
 239
 240 if test -n "$auto_cflags"; then
 241   if test x"$enable_debug" = x"yes"; then
 242     if test -n "$GCC"; then
 243       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 244     else
 245       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 246     fi
 247   else
 248     if test -z "$LDFLAGS"; then
 249       case "$build_os" in
 250         darwin*)
 251           LDFLAGS=
 252           ;;
 253         *)
 254           LDFLAGS=-s
 255           ;;
 256       esac
 257     fi
 258     if test -n "$GCC"; then
 259       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 260     else
 261       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 262     fi
 263   fi
 264 fi
 265
 266 AC_C_CONST              dnl Does compiler support `const'.
 267
 268 dnl ------------------
 269 dnl CHECK FOR PROGRAMS
 270 dnl ------------------
 271 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 272 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 273 AC_PROG_RANLIB          dnl Check for `ranlib'
 274 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 275 AC_PROG_LEX             dnl Check for lex/flex
 276
 277 dnl Look for `cut'
 278 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 279 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 280
 281 dnl ----------------------------------------------
 282 dnl check for lclint, and lint if it doesn't exist
 283 dnl ----------------------------------------------
 284 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 285 if test x$ac_cv_prog_linttmp1 != xno ; then
 286   LINT=$ac_cv_prog_linttmp1
 287   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 288 else
 289   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 290   if test x$ac_cv_prog_linttmp2 != xno ; then
 291     LINT=$ac_cv_prog_linttmp2
 292     LINTFLAGS=""
 293   else
 294     LINT="echo 'No lint program found'"
 295     LINTFLAGS=""
 296   fi
 297 fi
 298 AC_SUBST(LINT)dnl
 299 AC_SUBST(LINTFLAGS)dnl
 300
 301 dnl try to figure out which one we've got
 302 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 303 NMH_PROG_GNU_LIBTOOL
 304
 305 dnl Check for lorder and tsort commands
 306 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 307 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 308
 309 dnl If either doesn't exist, replace them with echo and cat
 310 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 311   LORDER=echo
 312   TSORT=cat
 313   AC_SUBST(LORDER)dnl
 314   AC_SUBST(TSORT)dnl
 315 dnl Mac OS X has lorder, but sh is too broken for it to work
 316 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 317 dnl   LORDER=echo
 318 dnl   TSORT=cat
 319 dnl   AC_SUBST(LORDER)dnl
 320 dnl   AC_SUBST(TSORT)dnl
 321 fi
 322
 323 dnl Check whether tsort can deal with loops
 324 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 325   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 326     nmh_cv_tsort_loop=no
 327   else
 328     nmh_cv_tsort_loop=yes
 329   fi])
 330 if test x$nmh_cv_tsort_loop = xno ; then
 331   LORDER=echo
 332   TSORT=cat
 333   AC_SUBST(LORDER)dnl
 334   AC_SUBST(TSORT)dnl
 335 fi
 336
 337 dnl Look for `ls'
 338 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 339 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 340
 341 dnl See how we get ls to display the owner and the group
 342 if test "$lspath" != "no"; then
 343   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 344                  nmh_cv_ls_grpopt,
 345   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 346     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 347     dnl ls, it would seem -l gave us both the user and group.  On this type of
 348     dnl ls, -g makes _only_ the group be displayed (and not the user).
 349     nmh_cv_ls_grpopt="-l"
 350   else
 351     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 352     nmh_cv_ls_grpopt="-lg"
 353   fi])
 354 fi
 355
 356 dnl Look for `more'
 357 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 358 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 359
 360 dnl If pager is not specified yet,
 361 dnl then use `more' as the default.
 362 if test -z "$pagerpath"; then
 363   pagerpath="$morepath"
 364 fi
 365 AC_SUBST(pagerpath)dnl
 366
 367 dnl Look for `sendmail'
 368 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 369 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 370
 371 dnl Look for `vi'
 372 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 373 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 374
 375 dnl If editor is not specified yet,
 376 dnl then use `vi' as the default.
 377 if test -z "$editorpath"; then
 378   editorpath="$vipath"
 379 fi
 380 AC_SUBST(editorpath)dnl
 381
 382 dnl ----------------------------------------------------------
 383 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 384 dnl ----------------------------------------------------------
 385 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 386 [for mailspool in /var/mail        dnl
 387                   /var/spool/mail  dnl
 388                   /usr/spool/mail  dnl
 389                   /dev/null;       dnl Just in case we fall through
 390 do
 391   test -d $mailspool && break
 392 done
 393 nmh_cv_mailspool=$mailspool
 394 ])
 395 mailspool=$nmh_cv_mailspool
 396 AC_SUBST(mailspool)dnl
 397
 398 dnl See whether the mail spool directory is world-writable.
 399 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 400   AC_CACHE_CHECK(whether the mail spool is world-writable,
 401                  nmh_cv_mailspool_world_writable,
 402   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 403     nmh_cv_mailspool_world_writable=no
 404   else
 405     nmh_cv_mailspool_world_writable=yes
 406   fi])
 407 fi
 408
 409 dnl Also, check for liblockfile (as found on Debian systems)
 410 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 411
 412 dnl and whether its companion program dotlockfile is setgid
 413 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 414 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 415   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 416     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 417     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 418         nmh_cv_dotlockfile_setgid=yes
 419       else
 420         nmh_cv_dotlockfile_setgid=no
 421       fi])
 422   fi
 423 fi
 424
 425 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 426 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 427 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 428   dnl do we really need both of these?
 429   AC_DEFINE(MAILGROUP,1,
 430     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 431   SETGID_MAIL=1
 432 fi
 433 AC_SUBST(SETGID_MAIL)dnl
 434
 435 dnl Use ls to see which group owns the mail spool directory.
 436 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 437 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 438 ])
 439 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 440 AC_SUBST(MAIL_SPOOL_GRP)dnl
 441
 442 dnl ------------------
 443 dnl CHECK HEADER FILES
 444 dnl ------------------
 445
 446 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 447 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 448 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 449 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 450 dnl declared; if so they should have an entry added to this case statement.
 451 dnl NB that we must define this on the compiler command line, not in config.h,
 452 dnl because it must be set before any system header is included and there's no
 453 dnl portable way to make sure that files generated by lex include config.h
 454 dnl before system header files.
 455
 456 case "$target_os" in
 457   linux*)
 458     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 459     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 460     ;;
 461 esac
 462 AC_SUBST(OURDEFS)
 463
 464 AC_HEADER_STDC
 465 AC_HEADER_TIME
 466 AC_HEADER_TIOCGWINSZ
 467 AC_CHECK_HEADERS(errno.h fcntl.h crypt.h termcap.h \
 468                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 469                  sys/param.h sys/time.h sys/stream.h)
 470
 471 dnl
 472 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 473 dnl really use a whole set of them, but this check should be
 474 dnl sufficient.
 475 dnl
 476 AC_CHECK_HEADER(libio.h, [
 477   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 478     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 479
 480 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 481   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 482 [[#if HAVE_SYS_STREAM_H
 483 #  include <sys/stream.h>
 484 #endif
 485 ]])
 486
 487 dnl ---------------
 488 dnl CHECK FUNCTIONS
 489 dnl ---------------
 490 AC_CHECK_FUNCS(writev lstat tzset getutent nl_langinfo)
 491
 492 dnl Check for multibyte character set support
 493 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 494     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 495   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 496     [Define to enable support for multibyte character sets.])
 497 fi
 498
 499 dnl -------------------
 500 dnl CHECK FOR LIBRARIES
 501 dnl -------------------
 502 dnl Check location of modf
 503 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 504
 505 dnl Checks for network libraries (nsl, socket)
 506 AC_CHECK_NETLIBS
 507
 508 termcap_curses_order="termcap curses ncurses"
 509 for lib in $termcap_curses_order; do
 510   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 511 done
 512 AC_SUBST(TERMLIB)dnl
 513
 514 dnl ---------------
 515 dnl CHECK FOR ICONV
 516 dnl ---------------
 517
 518 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 519 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 520   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 521   if test "x$ac_found_iconv" = "xno"; then
 522     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 523     if test "x$ac_found_iconv" = "xno"; then
 524       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 525     fi
 526     if test "x$ac_found_iconv" != "xno"; then
 527       LIBS="-liconv $LIBS"
 528     fi
 529   else
 530     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 531     AC_CHECK_DECL(_libiconv_version,
 532       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 533       [ #include <iconv.h> ])
 534   fi
 535 fi
 536 if test "x$ac_found_iconv" = xyes; then
 537   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 538 fi
 539
 540 dnl Check if iconv uses const in prototype declaration
 541 if test "x$ac_found_iconv" = "xyes"; then
 542   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 543     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 544         #include <iconv.h>]],
 545         [[#ifdef __cplusplus
 546           "C"
 547           #endif
 548           #if defined(__STDC__) || defined(__cplusplus)
 549           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 550           #else
 551           size_t iconv();
 552           #endif]])],
 553       [ac_cv_iconv_const=],
 554       [ac_cv_iconv_const=const])])
 555   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 556     [Define as const if the declaration of iconv() needs const.])
 557 fi
 558
 559 dnl --------------
 560 dnl CHECK FOR NDBM
 561 dnl --------------
 562
 563 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 564             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 565 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 566             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 567
 568 if test "$nmh_ndbm" = "autodetect"; then
 569   if test "$nmh_ndbmheader" != "autodetect"; then
 570     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 571   else
 572
 573     dnl There are at least four implementations of ndbm, and
 574     dnl several of those can be in different places at the whim
 575     dnl of the system integrator. A good summary of this mess
 576     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 577
 578     dnl Classic ndbm with no library required (eg NetBSD): try this
 579     dnl first so we don't accidentally link in a pointless but harmless
 580     dnl library in one of the later ndbm.h+libfoo tests:
 581     NMH_CHECK_NDBM(ndbm.h,,,
 582     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 583       NMH_CHECK_NDBM(db.h,db,,
 584     dnl Berkeley DBv1 emulating ndbm:
 585         NMH_CHECK_NDBM(ndbm.h,db,,
 586           NMH_CHECK_NDBM(ndbm.h,db1,,
 587     dnl Classic ndbm:
 588             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 589     dnl glibc2.1 systems put db1 in a subdir:
 590               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 591     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 592     dnl and possibly needing gbdm_compat library:
 593                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 594                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 595                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 596                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 597
 598   fi
 599 else
 600   dnl We don't really need to check that the user-specified values work,
 601   dnl but it is a convenience to the user to bomb out early rather than
 602   dnl after configure and half the compile process.
 603   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 604 fi
 605
 606 if test "$nmh_ndbm_found" = "no"; then
 607   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 608 else
 609   dnl Now export the lib/header to our makefile/config.h:
 610   if test x"$nmh_ndbmheader" != x; then
 611     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 612       [Define to the header containing the ndbm API prototypes.])
 613   fi
 614   if test x"$nmh_ndbm" != x; then
 615     NDBM_LIBS="-l$nmh_ndbm"
 616   else
 617     NDBM_LIBS=
 618   fi
 619   AC_SUBST(NDBM_LIBS)
 620 fi
 621
 622 dnl ------------------
 623 dnl Set RPM build root
 624 dnl ------------------
 625 dnl nmhrpm is used in the final summary, see below.  The default value is
 626 dnl reported there as ./RPM, consistent with the reporting of the default
 627 dnl source code location as ., but its absolute path is used in the Makefile.
 628 AC_ARG_WITH(rpmdir,
 629   AS_HELP_STRING([--with-rpmdir=RPMDIR], [RPM build directory @<:@RPM@:>@]))
 630   AS_IF([test x"$with_rpmdir" = x], [rpmdir='$(abs_srcdir)/RPM'; nmhrpm=./RPM],
 631           [rpmdir="$with_rpmdir"; eval "nmhrpm=${rpmdir}"])
 632 AC_SUBST(rpmdir)
 633
 634
 635 dnl --------------------
 636 dnl CHECK FOR CYRUS-SASL
 637 dnl --------------------
 638
 639 AS_IF([test x"$sasl_support" = x"yes"],[
 640   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 641   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 642     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 643
 644 dnl -----------------
 645 dnl CHECK FOR OPENSSL
 646 dnl -----------------
 647
 648 AS_IF([test x"$tls_support" = x"yes"],[
 649   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 650   AC_CHECK_LIB([crypto], [BIO_write], ,
 651     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 652   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 653     [AC_MSG_ERROR([OpenSSL library not found])])])
 654
 655 dnl ---------------------
 656 dnl CHECK TERMCAP LIBRARY
 657 dnl ---------------------
 658
 659 dnl Add the termcap library, so that the following configure
 660 dnl tests will find it when it tries to link test programs.
 661 nmh_save_LIBS="$LIBS"
 662 LIBS="$TERMLIB $LIBS"
 663
 664 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 665 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 666 dnl in tgetstr().
 667 dnl Under Cygwin test program crashes but exit code is still 0. So,
 668 dnl we test for a file that porgram should create
 669 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 670 [Define to 1 if tgetent() accepts NULL as a buffer.])
 671 AC_CACHE_CHECK(if tgetent accepts NULL,
 672 nmh_cv_func_tgetent_accepts_null,
 673 [AC_TRY_RUN([
 674 main()
 675 {
 676     char buf[4096];
 677     int r1 = tgetent(buf, "vt100");
 678     int r2 = tgetent((char*)0,"vt100");
 679     if (r1 >= 0 && r1 == r2) {
 680         char tbuf[1024], *u;
 681         u = tbuf;
 682         tgetstr("cl", &u);
 683         creat("conftest.tgetent", 0640);
 684     }
 685     exit((r1 != r2) || r2 == -1);
 686 }
 687 ],
 688   if test -f conftest.tgetent; then
 689     nmh_cv_func_tgetent_accepts_null=yes
 690   else
 691     nmh_cv_func_tgetent_accepts_null=no
 692   fi,
 693   nmh_cv_func_tgetent_accepts_null=no,
 694   nmh_cv_func_tgetent_accepts_null=no)])
 695 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 696   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 697 fi
 698 AC_CACHE_CHECK(if tgetent returns 0 on success,
 699 nmh_cv_func_tgetent_zero_success,
 700 [AC_TRY_RUN([
 701 main()
 702 {
 703     char buf[4096];
 704     int r1 = tgetent(buf, "!@#$%^&*");
 705     int r2 = tgetent(buf, "vt100");
 706     if (r1 < 0 && r2 == 0) {
 707         char tbuf[1024], *u;
 708         u = tbuf;
 709         tgetstr("cl", &u);
 710         creat("conftest.tgetent0", 0640);
 711     }
 712     exit(r1 == r2);
 713 }
 714 ],
 715   if test -f conftest.tgetent0; then
 716     nmh_cv_func_tgetent_zero_success=yes
 717   else
 718     nmh_cv_func_tgetent_zero_success=no
 719   fi,
 720   nmh_cv_func_tgetent_zero_success=no,
 721   nmh_cv_func_tgetent_zero_success=no)])
 722 AH_TEMPLATE([TGETENT_SUCCESS],
 723 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 724 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 725   AC_DEFINE(TGETENT_SUCCESS, 0)
 726 else
 727   AC_DEFINE(TGETENT_SUCCESS, 1)
 728 fi
 729
 730 dnl Now put the libraries back to what it was before we
 731 dnl starting checking the termcap library.
 732 LIBS="$nmh_save_LIBS"
 733
 734 dnl --------------
 735 dnl CHECK TYPEDEFS
 736 dnl --------------
 737 AC_TYPE_PID_T
 738 AC_TYPE_OFF_T
 739 AC_TYPE_UID_T
 740 AC_TYPE_MODE_T
 741 AC_TYPE_SIZE_T
 742
 743 dnl ----------------
 744 dnl CHECK STRUCTURES
 745 dnl ----------------
 746
 747 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 748   [#ifdef TIME_WITH_SYS_TIME
 749 # include <sys/time.h>
 750 # include <time.h>
 751 #else
 752 # ifdef TM_IN_SYS_TIME
 753 #  include <sys/time.h>
 754 # else
 755 #  include <time.h>
 756 # endif
 757 #endif])
 758
 759 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 760
 761 AC_STRUCT_DIRENT_D_TYPE
 762
 763 dnl Where is <signal.h> located?  Needed as input for signames.awk
 764 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 765 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 766                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 767                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 768                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 769                  /usr/include/sys/signal.h      dnl Almost everybody else
 770                  /dev/null;                     dnl Just in case we fall through
 771 do
 772   test -f $SIGNAL_H && \
 773   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 774   break
 775 done
 776 nmh_cv_path_signal_h=$SIGNAL_H
 777 ])
 778 SIGNAL_H=$nmh_cv_path_signal_h
 779 AC_SUBST(SIGNAL_H)dnl
 780
 781 dnl ----------------
 782 dnl OS SPECIFIC DEFINES
 783 dnl ----------------
 784 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 785 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 786 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 787 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 788 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 789
 790 case "$target_os" in
 791
 792   solaris2*)
 793     AC_DEFINE(SYS5)
 794     AC_DEFINE(SVR4)
 795     ;;
 796   irix*)
 797     AC_DEFINE(SYS5)
 798     AC_DEFINE(SVR4)
 799     ;;
 800   osf*)
 801     AC_DEFINE(SYS5)
 802     AC_DEFINE(SVR4)
 803     ;;
 804   aix*)
 805     AC_DEFINE(SYS5)
 806     AC_DEFINE(SVR4)
 807     ;;
 808   sunos4*)
 809     AC_DEFINE(BSD42)
 810     ;;
 811   freebsd*)
 812     AC_DEFINE(BSD42)
 813     AC_DEFINE(BSD44)
 814     ;;
 815   netbsd*)
 816     AC_DEFINE(BSD42)
 817     AC_DEFINE(BSD44)
 818     ;;
 819   openbsd*)
 820     AC_DEFINE(BSD42)
 821     AC_DEFINE(BSD44)
 822     ;;
 823   bsd/os*)
 824     AC_DEFINE(BSD42)
 825     AC_DEFINE(BSD44)
 826     ;;
 827   sco5*)
 828     AC_DEFINE(SYS5)
 829     AC_DEFINE(SCO_5_STDIO)
 830     ;;
 831 esac
 832
 833
 834 dnl ----------------
 835 dnl OUTPUT MAKEFILES
 836 dnl ----------------
 837 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 838                 mts/Makefile mts/smtp/Makefile \
 839                 etc/Makefile docs/Makefile man/Makefile)
 840 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 841 AC_OUTPUT
 842
 843 dnl These odd looking assignments are done to expand out unexpanded
 844 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 845 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 846 dnl again to get the final answer.
 847 dnl We only use the expanded versions to print the install paths in
 848 dnl the final summary and should use them nowhere else (see the autoconf
 849 dnl docs for the rationale for bindir etc being unexpanded).
 850 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 851 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 852 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 853 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 854 eval "nmhrpm=${nmhrpm}";
 855
 856 pop_kinds=no
 857 if test x"$enable_pop" = x"yes"; then
 858   pop_kinds="yes ("
 859
 860   if test x"$enable_apop" = x"yes"; then
 861     pop_kinds="${pop_kinds}APOP "
 862   fi
 863
 864   pop_kinds="${pop_kinds}POP3)"
 865 fi
 866
 867 echo "
 868 nmh configuration
 869 -----------------
 870 nmh version                : AC_PACKAGE_VERSION
 871 target os                  : ${target}
 872 compiler                   : ${CC}
 873 compiler flags             : ${CFLAGS}
 874 linker flags               : ${LDFLAGS}
 875 definitions                : ${OURDEFS}
 876 source code location       : ${srcdir}
 877 binary install path        : ${nmhbin}
 878 library install path       : ${nmhlib}
 879 config files install path  : ${nmhsysconf}
 880 man page install path      : ${nmhman}
 881 RPM build root             : ${nmhrpm}
 882 backup prefix              : ${backup_prefix}
 883 transport system           : ${MTS}
 884 file locking type          : ${LOCKTYPE}
 885 default smtp servers       : ${smtpservers}
 886 default editor             : ${editorpath}
 887 default pager              : ${pagerpath}
 888 email address masquerading : ${masquerade}
 889 pop is enabled             : ${pop_kinds}
 890 SASL support               : ${sasl_support}
 891 TLS support                : ${tls_support}"
 892 echo ""