git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want mhe support?
  60 AC_ARG_ENABLE(mhe,
  61   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  62
  63 dnl mhe support is on by default, so define it unless --disable-mhe or the
  64 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  65 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  66   AC_DEFINE(MHE, 1,
  67     [Define to compile in support for the Emacs front-end mh-e.])dnl
  68 fi
  69
  70 dnl Do you want to disable use of locale functions
  71 AH_TEMPLATE([LOCALE],
  72 [Undefine if you don't want locale features.  By default this is defined.])
  73 AC_ARG_ENABLE([locale],
  74 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  75 [if test x$enableval = xyes; then
  76   AC_DEFINE(LOCALE)
  77 fi],
  78 AC_DEFINE(LOCALE)
  79 )
  80
  81 dnl Do you want client-side support for encryption with TLS?
  82 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
  83 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
  84   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
  85   tls_support=yes
  86 else
  87   tls_support=no
  88 fi
  89
  90 dnl What should be the default editor?
  91 AC_ARG_WITH(editor,
  92   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
  93
  94 if test -n "$with_editor"; then
  95   editorpath="$with_editor"
  96 fi
  97
  98 dnl Set the backup prefix
  99 AC_ARG_WITH([hash-backup],
 100   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 101 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 102   backup_prefix="#"
 103 else
 104   backup_prefix=","
 105 fi
 106 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 107     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 108
 109 dnl What method of locking to use?
 110 AC_ARG_WITH(locking,
 111   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 112   [specify the file locking method]))
 113
 114 if test x"$with_locking" = x"dot"; then
 115   LOCKTYPE="dot"
 116   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 117 elif test x"$with_locking" = x"flock"; then
 118   LOCKTYPE="flock"
 119   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 120 elif test x"$with_locking" = x"lockf"; then
 121   LOCKTYPE="lockf"
 122   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 123 elif test x"$with_locking" = x"fcntl"; then
 124   LOCKTYPE="fcntl"
 125   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 126 else
 127   LOCKTYPE="dot"
 128   AC_DEFINE(DOT_LOCKING)dnl
 129 fi
 130
 131 dnl What should be the default pager?
 132 AC_ARG_WITH(pager,
 133   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 134
 135 if test -n "$with_pager"; then
 136   pagerpath="$with_pager"
 137 fi
 138
 139 dnl ----------------------------------------------------
 140 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
 141 dnl ----------------------------------------------------
 142 AC_PREFIX_DEFAULT(/usr/local/mmh)
 143
 144
 145 dnl ------------------
 146 dnl CHECK THE COMPILER
 147 dnl ------------------
 148 dnl We want these before the checks,
 149 dnl so the checks can modify their values.
 150 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 151 if test x"$enable_debug" = x"yes"; then
 152   test -z "$LDFLAGS" && LDFLAGS=-g
 153 fi
 154
 155 AC_PROG_CC
 156
 157 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 158 [nmh_saved_cflags="$CFLAGS"
 159  CFLAGS="$CFLAGS -Wno-pointer-sign"
 160  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 161  CFLAGS="$nmh_saved_cflags"])
 162
 163 dnl if the user hasn't specified CFLAGS, then
 164 dnl   if compiler is gcc, then
 165 dnl     use -O2 and some warning flags
 166 dnl   else use -O
 167 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 168 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 169 dnl spurious and which in any case we don't want to deal with now.
 170 if test "$nmh_cv_has_noptrsign" = "yes"; then
 171         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 172 else
 173         nmh_gcc_warnflags="-Wall"
 174 fi
 175
 176 if test -n "$auto_cflags"; then
 177   if test x"$enable_debug" = x"yes"; then
 178     if test -n "$GCC"; then
 179       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 180     else
 181       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 182     fi
 183   else
 184     if test -z "$LDFLAGS"; then
 185       case "$build_os" in
 186         darwin*)
 187           LDFLAGS=
 188           ;;
 189         *)
 190           LDFLAGS=-s
 191           ;;
 192       esac
 193     fi
 194     if test -n "$GCC"; then
 195       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 196     else
 197       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 198     fi
 199   fi
 200 fi
 201
 202 AC_C_CONST              dnl Does compiler support `const'.
 203
 204 dnl ------------------
 205 dnl CHECK FOR PROGRAMS
 206 dnl ------------------
 207 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 208 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 209 AC_PROG_RANLIB          dnl Check for `ranlib'
 210 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 211 AC_PROG_LEX             dnl Check for lex/flex
 212
 213 dnl Look for `cut'
 214 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 215 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 216
 217 dnl ----------------------------------------------
 218 dnl check for lclint, and lint if it doesn't exist
 219 dnl ----------------------------------------------
 220 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 221 if test x$ac_cv_prog_linttmp1 != xno ; then
 222   LINT=$ac_cv_prog_linttmp1
 223   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 224 else
 225   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 226   if test x$ac_cv_prog_linttmp2 != xno ; then
 227     LINT=$ac_cv_prog_linttmp2
 228     LINTFLAGS=""
 229   else
 230     LINT="echo 'No lint program found'"
 231     LINTFLAGS=""
 232   fi
 233 fi
 234 AC_SUBST(LINT)dnl
 235 AC_SUBST(LINTFLAGS)dnl
 236
 237 dnl try to figure out which one we've got
 238 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 239 NMH_PROG_GNU_LIBTOOL
 240
 241 dnl Check for lorder and tsort commands
 242 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 243 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 244
 245 dnl If either doesn't exist, replace them with echo and cat
 246 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 247   LORDER=echo
 248   TSORT=cat
 249   AC_SUBST(LORDER)dnl
 250   AC_SUBST(TSORT)dnl
 251 dnl Mac OS X has lorder, but sh is too broken for it to work
 252 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 253 dnl   LORDER=echo
 254 dnl   TSORT=cat
 255 dnl   AC_SUBST(LORDER)dnl
 256 dnl   AC_SUBST(TSORT)dnl
 257 fi
 258
 259 dnl Check whether tsort can deal with loops
 260 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 261   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 262     nmh_cv_tsort_loop=no
 263   else
 264     nmh_cv_tsort_loop=yes
 265   fi])
 266 if test x$nmh_cv_tsort_loop = xno ; then
 267   LORDER=echo
 268   TSORT=cat
 269   AC_SUBST(LORDER)dnl
 270   AC_SUBST(TSORT)dnl
 271 fi
 272
 273 dnl Look for `ls'
 274 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 275 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 276
 277 dnl See how we get ls to display the owner and the group
 278 if test "$lspath" != "no"; then
 279   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 280                  nmh_cv_ls_grpopt,
 281   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 282     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 283     dnl ls, it would seem -l gave us both the user and group.  On this type of
 284     dnl ls, -g makes _only_ the group be displayed (and not the user).
 285     nmh_cv_ls_grpopt="-l"
 286   else
 287     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 288     nmh_cv_ls_grpopt="-lg"
 289   fi])
 290 fi
 291
 292 dnl Look for `more'
 293 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 294 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 295
 296 dnl If pager is not specified yet,
 297 dnl then use `more' as the default.
 298 if test -z "$pagerpath"; then
 299   pagerpath="$morepath"
 300 fi
 301 AC_SUBST(pagerpath)dnl
 302
 303 dnl Look for `sendmail'
 304 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 305 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 306
 307 dnl Look for `vi'
 308 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 309 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 310
 311 dnl If editor is not specified yet,
 312 dnl then use `vi' as the default.
 313 if test -z "$editorpath"; then
 314   editorpath="$vipath"
 315 fi
 316 AC_SUBST(editorpath)dnl
 317
 318 dnl ----------------------------------------------------------
 319 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 320 dnl ----------------------------------------------------------
 321 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 322 [for mailspool in /var/mail        dnl
 323                   /var/spool/mail  dnl
 324                   /usr/spool/mail  dnl
 325                   /dev/null;       dnl Just in case we fall through
 326 do
 327   test -d $mailspool && break
 328 done
 329 nmh_cv_mailspool=$mailspool
 330 ])
 331 mailspool=$nmh_cv_mailspool
 332 AC_SUBST(mailspool)dnl
 333
 334 dnl See whether the mail spool directory is world-writable.
 335 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 336   AC_CACHE_CHECK(whether the mail spool is world-writable,
 337                  nmh_cv_mailspool_world_writable,
 338   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 339     nmh_cv_mailspool_world_writable=no
 340   else
 341     nmh_cv_mailspool_world_writable=yes
 342   fi])
 343 fi
 344
 345 dnl Also, check for liblockfile (as found on Debian systems)
 346 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 347
 348 dnl and whether its companion program dotlockfile is setgid
 349 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 350 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 351   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 352     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 353     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 354         nmh_cv_dotlockfile_setgid=yes
 355       else
 356         nmh_cv_dotlockfile_setgid=no
 357       fi])
 358   fi
 359 fi
 360
 361 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 362 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 363 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 364   dnl do we really need both of these?
 365   AC_DEFINE(MAILGROUP,1,
 366     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 367   SETGID_MAIL=1
 368 fi
 369 AC_SUBST(SETGID_MAIL)dnl
 370
 371 dnl Use ls to see which group owns the mail spool directory.
 372 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 373 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 374 ])
 375 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 376 AC_SUBST(MAIL_SPOOL_GRP)dnl
 377
 378 dnl ------------------
 379 dnl CHECK HEADER FILES
 380 dnl ------------------
 381
 382 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 383 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 384 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 385 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 386 dnl declared; if so they should have an entry added to this case statement.
 387 dnl NB that we must define this on the compiler command line, not in config.h,
 388 dnl because it must be set before any system header is included and there's no
 389 dnl portable way to make sure that files generated by lex include config.h
 390 dnl before system header files.
 391
 392 case "$target_os" in
 393   linux*)
 394     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 395     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 396     ;;
 397 esac
 398 AC_SUBST(OURDEFS)
 399
 400 AC_HEADER_DIRENT
 401 AC_HEADER_STDC
 402 AC_HEADER_TIME
 403 AC_HEADER_SYS_WAIT
 404 AC_HEADER_STAT
 405 AC_HEADER_TIOCGWINSZ
 406 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 407                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 408                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 409                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 410                  arpa/inet.h arpa/ftp.h)
 411
 412 dnl
 413 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 414 dnl really use a whole set of them, but this check should be
 415 dnl sufficient.
 416 dnl
 417 AC_CHECK_HEADER(libio.h, [
 418   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 419     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 420
 421 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 422   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 423 [[#if HAVE_SYS_STREAM_H
 424 #  include <sys/stream.h>
 425 #endif
 426 ]])
 427
 428 dnl ---------------
 429 dnl CHECK FUNCTIONS
 430 dnl ---------------
 431 AC_FUNC_VFORK
 432 AC_CHECK_LIB(mkstemp,mkstemp)
 433 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 434                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 435                getutent nl_langinfo mbtowc wcwidth)
 436
 437 dnl sigsetjmp may be a macro
 438 AC_MSG_CHECKING(for sigsetjmp)
 439 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 440   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 441     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 442   [AC_MSG_RESULT(no)])
 443
 444 AC_REPLACE_FUNCS(memmove snprintf strerror strdup)
 445
 446 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 447 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 448 dnl any system header.
 449 dnl
 450 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 451 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 452 dnl need to check?
 453 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 454 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 455                 AC_EGREP_HEADER(initgroups, unistd.h,
 456                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 457
 458 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 459 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 460 dnl seems to work perfectly and IBM apparently uses it in internal code).
 461 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 462 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 463 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 464 dnl prototype.
 465 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 466   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 467
 468 dnl Check for multibyte character set support
 469 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 470     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 471   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 472     [Define to enable support for multibyte character sets.])
 473 fi
 474
 475 dnl -------------------
 476 dnl CHECK FOR LIBRARIES
 477 dnl -------------------
 478 dnl Check location of modf
 479 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 480
 481 dnl Checks for network libraries (nsl, socket)
 482 AC_CHECK_NETLIBS
 483
 484 termcap_curses_order="termcap curses ncurses"
 485 for lib in $termcap_curses_order; do
 486   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 487 done
 488 AC_SUBST(TERMLIB)dnl
 489
 490 dnl ---------------
 491 dnl CHECK FOR ICONV
 492 dnl ---------------
 493
 494 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 495 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 496   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 497   if test "x$ac_found_iconv" = "xno"; then
 498     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 499     if test "x$ac_found_iconv" = "xno"; then
 500       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 501     fi
 502     if test "x$ac_found_iconv" != "xno"; then
 503       LIBS="-liconv $LIBS"
 504     fi
 505   else
 506     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 507     AC_CHECK_DECL(_libiconv_version,
 508       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 509       [ #include <iconv.h> ])
 510   fi
 511 fi
 512 if test "x$ac_found_iconv" = xyes; then
 513   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 514 fi
 515
 516 dnl Check if iconv uses const in prototype declaration
 517 if test "x$ac_found_iconv" = "xyes"; then
 518   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 519     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 520         #include <iconv.h>]],
 521         [[#ifdef __cplusplus
 522           "C"
 523           #endif
 524           #if defined(__STDC__) || defined(__cplusplus)
 525           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 526           #else
 527           size_t iconv();
 528           #endif]])],
 529       [ac_cv_iconv_const=],
 530       [ac_cv_iconv_const=const])])
 531   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 532     [Define as const if the declaration of iconv() needs const.])
 533 fi
 534
 535 dnl --------------
 536 dnl CHECK FOR NDBM
 537 dnl --------------
 538
 539 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 540             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 541 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 542             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 543
 544 if test "$nmh_ndbm" = "autodetect"; then
 545   if test "$nmh_ndbmheader" != "autodetect"; then
 546     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 547   else
 548
 549     dnl There are at least four implementations of ndbm, and
 550     dnl several of those can be in different places at the whim
 551     dnl of the system integrator. A good summary of this mess
 552     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 553
 554     dnl Classic ndbm with no library required (eg NetBSD): try this
 555     dnl first so we don't accidentally link in a pointless but harmless
 556     dnl library in one of the later ndbm.h+libfoo tests:
 557     NMH_CHECK_NDBM(ndbm.h,,,
 558     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 559       NMH_CHECK_NDBM(db.h,db,,
 560     dnl Berkeley DBv1 emulating ndbm:
 561         NMH_CHECK_NDBM(ndbm.h,db,,
 562           NMH_CHECK_NDBM(ndbm.h,db1,,
 563     dnl Classic ndbm:
 564             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 565     dnl glibc2.1 systems put db1 in a subdir:
 566               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 567     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 568     dnl and possibly needing gbdm_compat library:
 569                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 570                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 571                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 572                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 573
 574   fi
 575 else
 576   dnl We don't really need to check that the user-specified values work,
 577   dnl but it is a convenience to the user to bomb out early rather than
 578   dnl after configure and half the compile process.
 579   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 580 fi
 581
 582 if test "$nmh_ndbm_found" = "no"; then
 583   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 584 else
 585   dnl Now export the lib/header to our makefile/config.h:
 586   if test x"$nmh_ndbmheader" != x; then
 587     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 588       [Define to the header containing the ndbm API prototypes.])
 589   fi
 590   if test x"$nmh_ndbm" != x; then
 591     NDBM_LIBS="-l$nmh_ndbm"
 592   else
 593     NDBM_LIBS=
 594   fi
 595   AC_SUBST(NDBM_LIBS)
 596 fi
 597
 598
 599 dnl -----------------
 600 dnl CHECK FOR OPENSSL
 601 dnl -----------------
 602
 603 AS_IF([test x"$tls_support" = x"yes"],[
 604   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 605   AC_CHECK_LIB([crypto], [BIO_write], ,
 606     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 607   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 608     [AC_MSG_ERROR([OpenSSL library not found])])])
 609
 610 dnl ---------------------
 611 dnl CHECK TERMCAP LIBRARY
 612 dnl ---------------------
 613
 614 dnl Add the termcap library, so that the following configure
 615 dnl tests will find it when it tries to link test programs.
 616 nmh_save_LIBS="$LIBS"
 617 LIBS="$TERMLIB $LIBS"
 618
 619 dnl Checks for external variable ospeed in the termcap library.
 620 AC_CACHE_CHECK(if an include file defines ospeed,
 621 nmh_cv_decl_ospeed_include_defines,
 622 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 623 #if HAVE_TERMIOS_H
 624 #include <termios.h>
 625 #endif
 626 #if HAVE_TERMCAP_H
 627 #include <termcap.h>
 628 #endif]], [[ospeed = 0;]])],
 629 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 630
 631 if test $nmh_cv_decl_ospeed_include_defines = no; then
 632   AC_CACHE_CHECK(if you must define ospeed,
 633   nmh_cv_decl_ospeed_must_define,
 634   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 635   [[extern short ospeed; ospeed = 0;]])],
 636   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 637 fi
 638
 639 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 640 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 641   AC_DEFINE(HAVE_OSPEED)dnl
 642 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 643   AC_DEFINE(HAVE_OSPEED)
 644   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 645     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 646 fi
 647
 648 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 649 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 650 dnl in tgetstr().
 651 dnl Under Cygwin test program crashes but exit code is still 0. So,
 652 dnl we test for a file that porgram should create
 653 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 654 [Define to 1 if tgetent() accepts NULL as a buffer.])
 655 AC_CACHE_CHECK(if tgetent accepts NULL,
 656 nmh_cv_func_tgetent_accepts_null,
 657 [AC_TRY_RUN([
 658 main()
 659 {
 660     char buf[4096];
 661     int r1 = tgetent(buf, "vt100");
 662     int r2 = tgetent((char*)0,"vt100");
 663     if (r1 >= 0 && r1 == r2) {
 664         char tbuf[1024], *u;
 665         u = tbuf;
 666         tgetstr("cl", &u);
 667         creat("conftest.tgetent", 0640);
 668     }
 669     exit((r1 != r2) || r2 == -1);
 670 }
 671 ],
 672   if test -f conftest.tgetent; then
 673     nmh_cv_func_tgetent_accepts_null=yes
 674   else
 675     nmh_cv_func_tgetent_accepts_null=no
 676   fi,
 677   nmh_cv_func_tgetent_accepts_null=no,
 678   nmh_cv_func_tgetent_accepts_null=no)])
 679 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 680   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 681 fi
 682 AC_CACHE_CHECK(if tgetent returns 0 on success,
 683 nmh_cv_func_tgetent_zero_success,
 684 [AC_TRY_RUN([
 685 main()
 686 {
 687     char buf[4096];
 688     int r1 = tgetent(buf, "!@#$%^&*");
 689     int r2 = tgetent(buf, "vt100");
 690     if (r1 < 0 && r2 == 0) {
 691         char tbuf[1024], *u;
 692         u = tbuf;
 693         tgetstr("cl", &u);
 694         creat("conftest.tgetent0", 0640);
 695     }
 696     exit(r1 == r2);
 697 }
 698 ],
 699   if test -f conftest.tgetent0; then
 700     nmh_cv_func_tgetent_zero_success=yes
 701   else
 702     nmh_cv_func_tgetent_zero_success=no
 703   fi,
 704   nmh_cv_func_tgetent_zero_success=no,
 705   nmh_cv_func_tgetent_zero_success=no)])
 706 AH_TEMPLATE([TGETENT_SUCCESS],
 707 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 708 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 709   AC_DEFINE(TGETENT_SUCCESS, 0)
 710 else
 711   AC_DEFINE(TGETENT_SUCCESS, 1)
 712 fi
 713
 714 dnl Now put the libraries back to what it was before we
 715 dnl starting checking the termcap library.
 716 LIBS="$nmh_save_LIBS"
 717
 718 dnl --------------
 719 dnl CHECK TYPEDEFS
 720 dnl --------------
 721 AC_TYPE_SIGNAL
 722 AC_TYPE_PID_T
 723 AC_TYPE_OFF_T
 724 AC_TYPE_UID_T
 725 AC_TYPE_MODE_T
 726 AC_TYPE_SIZE_T
 727
 728 dnl Check for sigset_t.  Currently I'm looking in
 729 dnl <sys/types.h> and <signal.h>.  Others might need
 730 dnl to be added.
 731 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 732 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 733 #include <signal.h>]], [[sigset_t tempsigset;]])],
 734 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 735 if test $nmh_cv_type_sigset_t = no; then
 736   AC_DEFINE(sigset_t, unsigned int,
 737     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 738 fi
 739
 740 dnl ----------------
 741 dnl CHECK STRUCTURES
 742 dnl ----------------
 743 AC_CHECK_MEMBERS(struct stat.st_blksize)
 744
 745 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 746   [#ifdef TIME_WITH_SYS_TIME
 747 # include <sys/time.h>
 748 # include <time.h>
 749 #else
 750 # ifdef TM_IN_SYS_TIME
 751 #  include <sys/time.h>
 752 # else
 753 #  include <time.h>
 754 # endif
 755 #endif])
 756
 757 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 758
 759 AC_MSG_CHECKING(for union wait)
 760 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 761   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 762 #include <sys/wait.h>]],
 763     [[union wait status; int pid; pid = wait (&status);
 764 #ifdef WEXITSTATUS
 765 /* Some POSIXoid systems have both the new-style macros and the old
 766    union wait type, and they do not work together.  If union wait
 767    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 768         if (WEXITSTATUS (status) != 0) pid = -1;
 769 #ifdef WTERMSIG
 770         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 771         -- blow chunks here --
 772 #endif
 773 #endif
 774 #ifdef HAVE_WAITPID
 775         /* Make sure union wait works with waitpid.  */
 776         pid = waitpid (-1, &status, 0);
 777 #endif
 778       ]])],
 779     [nmh_cv_union_wait=yes],
 780     [nmh_cv_union_wait=no])])
 781 if test "$nmh_cv_union_wait" = yes; then
 782   AC_DEFINE(HAVE_UNION_WAIT, 1,
 783     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 784 fi
 785 AC_MSG_RESULT($nmh_cv_union_wait)
 786
 787 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 788
 789 dnl -------------
 790 dnl CHECK SIGNALS
 791 dnl -------------
 792 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 793 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 794 AC_MSG_CHECKING(what style of signals to use)
 795 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 796   signals_style=POSIX_SIGNALS
 797   AC_DEFINE(POSIX_SIGNALS, 1,
 798     [Define to 1 if you use POSIX style signal handling.])
 799   AC_DEFINE(RELIABLE_SIGNALS)
 800 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 801   signals_style=BSD_SIGNALS
 802   AC_DEFINE(BSD_SIGNALS,1,
 803     [Define to 1 if you use BSD style signal handling (and can block signals).])
 804   AC_DEFINE(RELIABLE_SIGNALS)
 805 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 806   signals_style=SYSV_SIGNALS
 807   AC_DEFINE(SYSV_SIGNALS,1,
 808     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 809 else
 810   signals_style=NO_SIGNAL_BLOCKING
 811   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 812     [Define to 1 if you have no signal blocking at all (bummer).])
 813 fi
 814
 815 AC_MSG_RESULT($signals_style)
 816
 817 dnl Where is <signal.h> located?  Needed as input for signames.awk
 818 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 819 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 820                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 821                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 822                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 823                  /usr/include/sys/signal.h      dnl Almost everybody else
 824                  /dev/null;                     dnl Just in case we fall through
 825 do
 826   test -f $SIGNAL_H && \
 827   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 828   break
 829 done
 830 nmh_cv_path_signal_h=$SIGNAL_H
 831 ])
 832 SIGNAL_H=$nmh_cv_path_signal_h
 833 AC_SUBST(SIGNAL_H)dnl
 834
 835 dnl ----------------
 836 dnl OS SPECIFIC DEFINES
 837 dnl ----------------
 838 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 839 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 840 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 841 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 842 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 843
 844 case "$target_os" in
 845
 846   solaris2*)
 847     AC_DEFINE(SYS5)
 848     AC_DEFINE(SVR4)
 849     ;;
 850   irix*)
 851     AC_DEFINE(SYS5)
 852     AC_DEFINE(SVR4)
 853     ;;
 854   osf*)
 855     AC_DEFINE(SYS5)
 856     AC_DEFINE(SVR4)
 857     ;;
 858   aix*)
 859     AC_DEFINE(SYS5)
 860     AC_DEFINE(SVR4)
 861     ;;
 862   sunos4*)
 863     AC_DEFINE(BSD42)
 864     ;;
 865   freebsd*)
 866     AC_DEFINE(BSD42)
 867     AC_DEFINE(BSD44)
 868     ;;
 869   netbsd*)
 870     AC_DEFINE(BSD42)
 871     AC_DEFINE(BSD44)
 872     ;;
 873   openbsd*)
 874     AC_DEFINE(BSD42)
 875     AC_DEFINE(BSD44)
 876     ;;
 877   bsd/os*)
 878     AC_DEFINE(BSD42)
 879     AC_DEFINE(BSD44)
 880     ;;
 881   sco5*)
 882     AC_DEFINE(SYS5)
 883     AC_DEFINE(SCO_5_STDIO)
 884     ;;
 885 esac
 886
 887
 888 dnl ----------------
 889 dnl OUTPUT MAKEFILES
 890 dnl ----------------
 891 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 892                 etc/Makefile docs/Makefile man/Makefile)
 893 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 894 AC_OUTPUT
 895
 896 dnl These odd looking assignments are done to expand out unexpanded
 897 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 898 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 899 dnl again to get the final answer.
 900 dnl We only use the expanded versions to print the install paths in
 901 dnl the final summary and should use them nowhere else (see the autoconf
 902 dnl docs for the rationale for bindir etc being unexpanded).
 903 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 904 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 905 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 906 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 907
 908 echo "
 909 nmh configuration
 910 -----------------
 911 nmh version                : AC_PACKAGE_VERSION
 912 target os                  : ${target}
 913 compiler                   : ${CC}
 914 compiler flags             : ${CFLAGS}
 915 linker flags               : ${LDFLAGS}
 916 definitions                : ${OURDEFS}
 917 source code location       : ${srcdir}
 918 binary install path        : ${nmhbin}
 919 library install path       : ${nmhlib}
 920 config files install path  : ${nmhsysconf}
 921 man page install path      : ${nmhman}
 922 backup prefix              : ${backup_prefix}
 923 file locking type          : ${LOCKTYPE}
 924 default editor             : ${editorpath}
 925 default pager              : ${pagerpath}
 926 email address masquerading : ${masquerade}
 927 TLS support                : ${tls_support}"
 928 echo ""