git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want mhe support?
  60 AC_ARG_ENABLE(mhe,
  61   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  62
  63 dnl mhe support is on by default, so define it unless --disable-mhe or the
  64 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  65 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  66   AC_DEFINE(MHE, 1,
  67     [Define to compile in support for the Emacs front-end mh-e.])dnl
  68 fi
  69
  70 dnl Do you want client-side support for pop?
  71 AC_ARG_ENABLE(pop,
  72   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  73 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  74 if test x"$enable_nmh_pop" = x"yes"; then
  75   enable_pop=yes
  76 fi
  77
  78 dnl Do you want to disable use of locale functions
  79 AH_TEMPLATE([LOCALE],
  80 [Undefine if you don't want locale features.  By default this is defined.])
  81 AC_ARG_ENABLE([locale],
  82 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  83 [if test x$enableval = xyes; then
  84   AC_DEFINE(LOCALE)
  85 fi],
  86 AC_DEFINE(LOCALE)
  87 )
  88
  89 dnl Do you want client-side support for using SASL for authentication?
  90 dnl Note that this code will be enabled for both POP and SMTP
  91 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
  92   [Enable SASL support via the Cyrus SASL library]))
  93 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  94   AC_DEFINE(CYRUS_SASL, 1,
  95     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
  96   if test x"$with_cyrus_sasl" != xyes; then
  97     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  98     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  99   fi
 100   sasl_support=yes
 101 else
 102   sasl_support=no
 103 fi
 104
 105 dnl Do you want client-side support for encryption with TLS?
 106 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
 107 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
 108   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
 109   tls_support=yes
 110 else
 111   tls_support=no
 112 fi
 113
 114 dnl What should be the default editor?
 115 AC_ARG_WITH(editor,
 116   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 117
 118 if test -n "$with_editor"; then
 119   editorpath="$with_editor"
 120 fi
 121
 122 dnl Set the backup prefix
 123 AC_ARG_WITH([hash-backup],
 124   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 125 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 126   backup_prefix="#"
 127 else
 128   backup_prefix=","
 129 fi
 130 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 131     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 132
 133 dnl After we know if we're including apop and kpop support, do pop stuff
 134 if test x"$enable_pop" = x"yes"; then
 135   AC_DEFINE(POP, 1,
 136     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 137   POPLIB=popsbr.o
 138   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 139 else
 140   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 141 fi
 142 AC_SUBST(POPLIB)dnl
 143 AC_SUBST(POPSED)dnl
 144
 145 dnl What method of locking to use?
 146 AC_ARG_WITH(locking,
 147   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 148   [specify the file locking method]))
 149
 150 if test x"$with_locking" = x"dot"; then
 151   LOCKTYPE="dot"
 152   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 153 elif test x"$with_locking" = x"flock"; then
 154   LOCKTYPE="flock"
 155   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 156 elif test x"$with_locking" = x"lockf"; then
 157   LOCKTYPE="lockf"
 158   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 159 elif test x"$with_locking" = x"fcntl"; then
 160   LOCKTYPE="fcntl"
 161   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 162 else
 163   LOCKTYPE="dot"
 164   AC_DEFINE(DOT_LOCKING)dnl
 165 fi
 166
 167 dnl What method of posting should post use?
 168 dnl We'll always use sendmail now. (mmh)
 169 MTS="sendmail"
 170 dnl #AC_SUBST(MTS)dnl
 171
 172 dnl Both the smtp and sendmail mail transport services use the smtp code
 173 AC_DEFINE(SMTPMTS, 1,
 174   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 175
 176 dnl What should be the default pager?
 177 AC_ARG_WITH(pager,
 178   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 179
 180 if test -n "$with_pager"; then
 181   pagerpath="$with_pager"
 182 fi
 183
 184 dnl What should be the default mail server(s)?
 185 AC_ARG_WITH(smtpservers,
 186   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 187   [specify the default SMTP server(s) @<:@localhost@:>@]))
 188 if test -n "$with_smtpservers"; then
 189   smtpservers="$with_smtpservers"
 190 else
 191   smtpservers="localhost"
 192 fi
 193 AC_SUBST(smtpservers)dnl
 194
 195 dnl ----------------------------------------------------
 196 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
 197 dnl ----------------------------------------------------
 198 AC_PREFIX_DEFAULT(/usr/local/mmh)
 199
 200
 201 dnl ------------------
 202 dnl CHECK THE COMPILER
 203 dnl ------------------
 204 dnl We want these before the checks,
 205 dnl so the checks can modify their values.
 206 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 207 if test x"$enable_debug" = x"yes"; then
 208   test -z "$LDFLAGS" && LDFLAGS=-g
 209 fi
 210
 211 AC_PROG_CC
 212
 213 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 214 [nmh_saved_cflags="$CFLAGS"
 215  CFLAGS="$CFLAGS -Wno-pointer-sign"
 216  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 217  CFLAGS="$nmh_saved_cflags"])
 218
 219 dnl if the user hasn't specified CFLAGS, then
 220 dnl   if compiler is gcc, then
 221 dnl     use -O2 and some warning flags
 222 dnl   else use -O
 223 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 224 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 225 dnl spurious and which in any case we don't want to deal with now.
 226 if test "$nmh_cv_has_noptrsign" = "yes"; then
 227         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 228 else
 229         nmh_gcc_warnflags="-Wall"
 230 fi
 231
 232 if test -n "$auto_cflags"; then
 233   if test x"$enable_debug" = x"yes"; then
 234     if test -n "$GCC"; then
 235       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 236     else
 237       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 238     fi
 239   else
 240     if test -z "$LDFLAGS"; then
 241       case "$build_os" in
 242         darwin*)
 243           LDFLAGS=
 244           ;;
 245         *)
 246           LDFLAGS=-s
 247           ;;
 248       esac
 249     fi
 250     if test -n "$GCC"; then
 251       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 252     else
 253       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 254     fi
 255   fi
 256 fi
 257
 258 AC_C_CONST              dnl Does compiler support `const'.
 259
 260 dnl ------------------
 261 dnl CHECK FOR PROGRAMS
 262 dnl ------------------
 263 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 264 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 265 AC_PROG_RANLIB          dnl Check for `ranlib'
 266 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 267 AC_PROG_LEX             dnl Check for lex/flex
 268
 269 dnl Look for `cut'
 270 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 271 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 272
 273 dnl ----------------------------------------------
 274 dnl check for lclint, and lint if it doesn't exist
 275 dnl ----------------------------------------------
 276 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 277 if test x$ac_cv_prog_linttmp1 != xno ; then
 278   LINT=$ac_cv_prog_linttmp1
 279   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 280 else
 281   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 282   if test x$ac_cv_prog_linttmp2 != xno ; then
 283     LINT=$ac_cv_prog_linttmp2
 284     LINTFLAGS=""
 285   else
 286     LINT="echo 'No lint program found'"
 287     LINTFLAGS=""
 288   fi
 289 fi
 290 AC_SUBST(LINT)dnl
 291 AC_SUBST(LINTFLAGS)dnl
 292
 293 dnl try to figure out which one we've got
 294 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 295 NMH_PROG_GNU_LIBTOOL
 296
 297 dnl Check for lorder and tsort commands
 298 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 299 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 300
 301 dnl If either doesn't exist, replace them with echo and cat
 302 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 303   LORDER=echo
 304   TSORT=cat
 305   AC_SUBST(LORDER)dnl
 306   AC_SUBST(TSORT)dnl
 307 dnl Mac OS X has lorder, but sh is too broken for it to work
 308 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 309 dnl   LORDER=echo
 310 dnl   TSORT=cat
 311 dnl   AC_SUBST(LORDER)dnl
 312 dnl   AC_SUBST(TSORT)dnl
 313 fi
 314
 315 dnl Check whether tsort can deal with loops
 316 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 317   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 318     nmh_cv_tsort_loop=no
 319   else
 320     nmh_cv_tsort_loop=yes
 321   fi])
 322 if test x$nmh_cv_tsort_loop = xno ; then
 323   LORDER=echo
 324   TSORT=cat
 325   AC_SUBST(LORDER)dnl
 326   AC_SUBST(TSORT)dnl
 327 fi
 328
 329 dnl Look for `ls'
 330 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 331 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 332
 333 dnl See how we get ls to display the owner and the group
 334 if test "$lspath" != "no"; then
 335   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 336                  nmh_cv_ls_grpopt,
 337   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 338     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 339     dnl ls, it would seem -l gave us both the user and group.  On this type of
 340     dnl ls, -g makes _only_ the group be displayed (and not the user).
 341     nmh_cv_ls_grpopt="-l"
 342   else
 343     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 344     nmh_cv_ls_grpopt="-lg"
 345   fi])
 346 fi
 347
 348 dnl Look for `more'
 349 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 350 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 351
 352 dnl If pager is not specified yet,
 353 dnl then use `more' as the default.
 354 if test -z "$pagerpath"; then
 355   pagerpath="$morepath"
 356 fi
 357 AC_SUBST(pagerpath)dnl
 358
 359 dnl Look for `sendmail'
 360 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 361 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 362
 363 dnl Look for `vi'
 364 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 365 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 366
 367 dnl If editor is not specified yet,
 368 dnl then use `vi' as the default.
 369 if test -z "$editorpath"; then
 370   editorpath="$vipath"
 371 fi
 372 AC_SUBST(editorpath)dnl
 373
 374 dnl ----------------------------------------------------------
 375 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 376 dnl ----------------------------------------------------------
 377 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 378 [for mailspool in /var/mail        dnl
 379                   /var/spool/mail  dnl
 380                   /usr/spool/mail  dnl
 381                   /dev/null;       dnl Just in case we fall through
 382 do
 383   test -d $mailspool && break
 384 done
 385 nmh_cv_mailspool=$mailspool
 386 ])
 387 mailspool=$nmh_cv_mailspool
 388 AC_SUBST(mailspool)dnl
 389
 390 dnl See whether the mail spool directory is world-writable.
 391 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 392   AC_CACHE_CHECK(whether the mail spool is world-writable,
 393                  nmh_cv_mailspool_world_writable,
 394   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 395     nmh_cv_mailspool_world_writable=no
 396   else
 397     nmh_cv_mailspool_world_writable=yes
 398   fi])
 399 fi
 400
 401 dnl Also, check for liblockfile (as found on Debian systems)
 402 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 403
 404 dnl and whether its companion program dotlockfile is setgid
 405 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 406 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 407   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 408     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 409     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 410         nmh_cv_dotlockfile_setgid=yes
 411       else
 412         nmh_cv_dotlockfile_setgid=no
 413       fi])
 414   fi
 415 fi
 416
 417 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 418 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 419 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 420   dnl do we really need both of these?
 421   AC_DEFINE(MAILGROUP,1,
 422     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 423   SETGID_MAIL=1
 424 fi
 425 AC_SUBST(SETGID_MAIL)dnl
 426
 427 dnl Use ls to see which group owns the mail spool directory.
 428 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 429 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 430 ])
 431 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 432 AC_SUBST(MAIL_SPOOL_GRP)dnl
 433
 434 dnl ------------------
 435 dnl CHECK HEADER FILES
 436 dnl ------------------
 437
 438 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 439 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 440 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 441 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 442 dnl declared; if so they should have an entry added to this case statement.
 443 dnl NB that we must define this on the compiler command line, not in config.h,
 444 dnl because it must be set before any system header is included and there's no
 445 dnl portable way to make sure that files generated by lex include config.h
 446 dnl before system header files.
 447
 448 case "$target_os" in
 449   linux*)
 450     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 451     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 452     ;;
 453 esac
 454 AC_SUBST(OURDEFS)
 455
 456 AC_HEADER_DIRENT
 457 AC_HEADER_STDC
 458 AC_HEADER_TIME
 459 AC_HEADER_SYS_WAIT
 460 AC_HEADER_STAT
 461 AC_HEADER_TIOCGWINSZ
 462 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 463                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 464                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 465                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 466                  arpa/inet.h arpa/ftp.h)
 467
 468 dnl
 469 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 470 dnl really use a whole set of them, but this check should be
 471 dnl sufficient.
 472 dnl
 473 AC_CHECK_HEADER(libio.h, [
 474   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 475     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 476
 477 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 478   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 479 [[#if HAVE_SYS_STREAM_H
 480 #  include <sys/stream.h>
 481 #endif
 482 ]])
 483
 484 dnl ---------------
 485 dnl CHECK FUNCTIONS
 486 dnl ---------------
 487 AC_FUNC_VFORK
 488 AC_CHECK_LIB(mkstemp,mkstemp)
 489 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 490                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 491                getutent nl_langinfo mbtowc wcwidth)
 492
 493 dnl sigsetjmp may be a macro
 494 AC_MSG_CHECKING(for sigsetjmp)
 495 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 496   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 497     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 498   [AC_MSG_RESULT(no)])
 499
 500 AC_REPLACE_FUNCS(memmove snprintf strerror strdup)
 501
 502 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 503 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 504 dnl any system header.
 505 dnl
 506 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 507 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 508 dnl need to check?
 509 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 510 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 511                 AC_EGREP_HEADER(initgroups, unistd.h,
 512                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 513
 514 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 515 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 516 dnl seems to work perfectly and IBM apparently uses it in internal code).
 517 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 518 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 519 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 520 dnl prototype.
 521 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 522   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 523
 524 dnl Check for multibyte character set support
 525 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 526     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 527   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 528     [Define to enable support for multibyte character sets.])
 529 fi
 530
 531 dnl -------------------
 532 dnl CHECK FOR LIBRARIES
 533 dnl -------------------
 534 dnl Check location of modf
 535 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 536
 537 dnl Checks for network libraries (nsl, socket)
 538 AC_CHECK_NETLIBS
 539
 540 termcap_curses_order="termcap curses ncurses"
 541 for lib in $termcap_curses_order; do
 542   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 543 done
 544 AC_SUBST(TERMLIB)dnl
 545
 546 dnl ---------------
 547 dnl CHECK FOR ICONV
 548 dnl ---------------
 549
 550 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 551 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 552   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 553   if test "x$ac_found_iconv" = "xno"; then
 554     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 555     if test "x$ac_found_iconv" = "xno"; then
 556       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 557     fi
 558     if test "x$ac_found_iconv" != "xno"; then
 559       LIBS="-liconv $LIBS"
 560     fi
 561   else
 562     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 563     AC_CHECK_DECL(_libiconv_version,
 564       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 565       [ #include <iconv.h> ])
 566   fi
 567 fi
 568 if test "x$ac_found_iconv" = xyes; then
 569   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 570 fi
 571
 572 dnl Check if iconv uses const in prototype declaration
 573 if test "x$ac_found_iconv" = "xyes"; then
 574   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 575     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 576         #include <iconv.h>]],
 577         [[#ifdef __cplusplus
 578           "C"
 579           #endif
 580           #if defined(__STDC__) || defined(__cplusplus)
 581           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 582           #else
 583           size_t iconv();
 584           #endif]])],
 585       [ac_cv_iconv_const=],
 586       [ac_cv_iconv_const=const])])
 587   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 588     [Define as const if the declaration of iconv() needs const.])
 589 fi
 590
 591 dnl --------------
 592 dnl CHECK FOR NDBM
 593 dnl --------------
 594
 595 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 596             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 597 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 598             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 599
 600 if test "$nmh_ndbm" = "autodetect"; then
 601   if test "$nmh_ndbmheader" != "autodetect"; then
 602     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 603   else
 604
 605     dnl There are at least four implementations of ndbm, and
 606     dnl several of those can be in different places at the whim
 607     dnl of the system integrator. A good summary of this mess
 608     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 609
 610     dnl Classic ndbm with no library required (eg NetBSD): try this
 611     dnl first so we don't accidentally link in a pointless but harmless
 612     dnl library in one of the later ndbm.h+libfoo tests:
 613     NMH_CHECK_NDBM(ndbm.h,,,
 614     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 615       NMH_CHECK_NDBM(db.h,db,,
 616     dnl Berkeley DBv1 emulating ndbm:
 617         NMH_CHECK_NDBM(ndbm.h,db,,
 618           NMH_CHECK_NDBM(ndbm.h,db1,,
 619     dnl Classic ndbm:
 620             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 621     dnl glibc2.1 systems put db1 in a subdir:
 622               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 623     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 624     dnl and possibly needing gbdm_compat library:
 625                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 626                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 627                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 628                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 629
 630   fi
 631 else
 632   dnl We don't really need to check that the user-specified values work,
 633   dnl but it is a convenience to the user to bomb out early rather than
 634   dnl after configure and half the compile process.
 635   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 636 fi
 637
 638 if test "$nmh_ndbm_found" = "no"; then
 639   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 640 else
 641   dnl Now export the lib/header to our makefile/config.h:
 642   if test x"$nmh_ndbmheader" != x; then
 643     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 644       [Define to the header containing the ndbm API prototypes.])
 645   fi
 646   if test x"$nmh_ndbm" != x; then
 647     NDBM_LIBS="-l$nmh_ndbm"
 648   else
 649     NDBM_LIBS=
 650   fi
 651   AC_SUBST(NDBM_LIBS)
 652 fi
 653
 654
 655 dnl --------------------
 656 dnl CHECK FOR CYRUS-SASL
 657 dnl --------------------
 658
 659 AS_IF([test x"$sasl_support" = x"yes"],[
 660   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 661   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 662     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 663
 664 dnl -----------------
 665 dnl CHECK FOR OPENSSL
 666 dnl -----------------
 667
 668 AS_IF([test x"$tls_support" = x"yes"],[
 669   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 670   AC_CHECK_LIB([crypto], [BIO_write], ,
 671     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 672   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 673     [AC_MSG_ERROR([OpenSSL library not found])])])
 674
 675 dnl ---------------------
 676 dnl CHECK TERMCAP LIBRARY
 677 dnl ---------------------
 678
 679 dnl Add the termcap library, so that the following configure
 680 dnl tests will find it when it tries to link test programs.
 681 nmh_save_LIBS="$LIBS"
 682 LIBS="$TERMLIB $LIBS"
 683
 684 dnl Checks for external variable ospeed in the termcap library.
 685 AC_CACHE_CHECK(if an include file defines ospeed,
 686 nmh_cv_decl_ospeed_include_defines,
 687 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 688 #if HAVE_TERMIOS_H
 689 #include <termios.h>
 690 #endif
 691 #if HAVE_TERMCAP_H
 692 #include <termcap.h>
 693 #endif]], [[ospeed = 0;]])],
 694 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 695
 696 if test $nmh_cv_decl_ospeed_include_defines = no; then
 697   AC_CACHE_CHECK(if you must define ospeed,
 698   nmh_cv_decl_ospeed_must_define,
 699   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 700   [[extern short ospeed; ospeed = 0;]])],
 701   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 702 fi
 703
 704 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 705 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 706   AC_DEFINE(HAVE_OSPEED)dnl
 707 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 708   AC_DEFINE(HAVE_OSPEED)
 709   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 710     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 711 fi
 712
 713 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 714 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 715 dnl in tgetstr().
 716 dnl Under Cygwin test program crashes but exit code is still 0. So,
 717 dnl we test for a file that porgram should create
 718 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 719 [Define to 1 if tgetent() accepts NULL as a buffer.])
 720 AC_CACHE_CHECK(if tgetent accepts NULL,
 721 nmh_cv_func_tgetent_accepts_null,
 722 [AC_TRY_RUN([
 723 main()
 724 {
 725     char buf[4096];
 726     int r1 = tgetent(buf, "vt100");
 727     int r2 = tgetent((char*)0,"vt100");
 728     if (r1 >= 0 && r1 == r2) {
 729         char tbuf[1024], *u;
 730         u = tbuf;
 731         tgetstr("cl", &u);
 732         creat("conftest.tgetent", 0640);
 733     }
 734     exit((r1 != r2) || r2 == -1);
 735 }
 736 ],
 737   if test -f conftest.tgetent; then
 738     nmh_cv_func_tgetent_accepts_null=yes
 739   else
 740     nmh_cv_func_tgetent_accepts_null=no
 741   fi,
 742   nmh_cv_func_tgetent_accepts_null=no,
 743   nmh_cv_func_tgetent_accepts_null=no)])
 744 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 745   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 746 fi
 747 AC_CACHE_CHECK(if tgetent returns 0 on success,
 748 nmh_cv_func_tgetent_zero_success,
 749 [AC_TRY_RUN([
 750 main()
 751 {
 752     char buf[4096];
 753     int r1 = tgetent(buf, "!@#$%^&*");
 754     int r2 = tgetent(buf, "vt100");
 755     if (r1 < 0 && r2 == 0) {
 756         char tbuf[1024], *u;
 757         u = tbuf;
 758         tgetstr("cl", &u);
 759         creat("conftest.tgetent0", 0640);
 760     }
 761     exit(r1 == r2);
 762 }
 763 ],
 764   if test -f conftest.tgetent0; then
 765     nmh_cv_func_tgetent_zero_success=yes
 766   else
 767     nmh_cv_func_tgetent_zero_success=no
 768   fi,
 769   nmh_cv_func_tgetent_zero_success=no,
 770   nmh_cv_func_tgetent_zero_success=no)])
 771 AH_TEMPLATE([TGETENT_SUCCESS],
 772 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 773 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 774   AC_DEFINE(TGETENT_SUCCESS, 0)
 775 else
 776   AC_DEFINE(TGETENT_SUCCESS, 1)
 777 fi
 778
 779 dnl Now put the libraries back to what it was before we
 780 dnl starting checking the termcap library.
 781 LIBS="$nmh_save_LIBS"
 782
 783 dnl --------------
 784 dnl CHECK TYPEDEFS
 785 dnl --------------
 786 AC_TYPE_SIGNAL
 787 AC_TYPE_PID_T
 788 AC_TYPE_OFF_T
 789 AC_TYPE_UID_T
 790 AC_TYPE_MODE_T
 791 AC_TYPE_SIZE_T
 792
 793 dnl Check for sigset_t.  Currently I'm looking in
 794 dnl <sys/types.h> and <signal.h>.  Others might need
 795 dnl to be added.
 796 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 797 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 798 #include <signal.h>]], [[sigset_t tempsigset;]])],
 799 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 800 if test $nmh_cv_type_sigset_t = no; then
 801   AC_DEFINE(sigset_t, unsigned int,
 802     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 803 fi
 804
 805 dnl ----------------
 806 dnl CHECK STRUCTURES
 807 dnl ----------------
 808 AC_CHECK_MEMBERS(struct stat.st_blksize)
 809
 810 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 811   [#ifdef TIME_WITH_SYS_TIME
 812 # include <sys/time.h>
 813 # include <time.h>
 814 #else
 815 # ifdef TM_IN_SYS_TIME
 816 #  include <sys/time.h>
 817 # else
 818 #  include <time.h>
 819 # endif
 820 #endif])
 821
 822 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 823
 824 AC_MSG_CHECKING(for union wait)
 825 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 826   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 827 #include <sys/wait.h>]],
 828     [[union wait status; int pid; pid = wait (&status);
 829 #ifdef WEXITSTATUS
 830 /* Some POSIXoid systems have both the new-style macros and the old
 831    union wait type, and they do not work together.  If union wait
 832    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 833         if (WEXITSTATUS (status) != 0) pid = -1;
 834 #ifdef WTERMSIG
 835         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 836         -- blow chunks here --
 837 #endif
 838 #endif
 839 #ifdef HAVE_WAITPID
 840         /* Make sure union wait works with waitpid.  */
 841         pid = waitpid (-1, &status, 0);
 842 #endif
 843       ]])],
 844     [nmh_cv_union_wait=yes],
 845     [nmh_cv_union_wait=no])])
 846 if test "$nmh_cv_union_wait" = yes; then
 847   AC_DEFINE(HAVE_UNION_WAIT, 1,
 848     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 849 fi
 850 AC_MSG_RESULT($nmh_cv_union_wait)
 851
 852 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 853
 854 dnl -------------
 855 dnl CHECK SIGNALS
 856 dnl -------------
 857 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 858 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 859 AC_MSG_CHECKING(what style of signals to use)
 860 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 861   signals_style=POSIX_SIGNALS
 862   AC_DEFINE(POSIX_SIGNALS, 1,
 863     [Define to 1 if you use POSIX style signal handling.])
 864   AC_DEFINE(RELIABLE_SIGNALS)
 865 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 866   signals_style=BSD_SIGNALS
 867   AC_DEFINE(BSD_SIGNALS,1,
 868     [Define to 1 if you use BSD style signal handling (and can block signals).])
 869   AC_DEFINE(RELIABLE_SIGNALS)
 870 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 871   signals_style=SYSV_SIGNALS
 872   AC_DEFINE(SYSV_SIGNALS,1,
 873     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 874 else
 875   signals_style=NO_SIGNAL_BLOCKING
 876   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 877     [Define to 1 if you have no signal blocking at all (bummer).])
 878 fi
 879
 880 AC_MSG_RESULT($signals_style)
 881
 882 dnl Where is <signal.h> located?  Needed as input for signames.awk
 883 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 884 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 885                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 886                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 887                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 888                  /usr/include/sys/signal.h      dnl Almost everybody else
 889                  /dev/null;                     dnl Just in case we fall through
 890 do
 891   test -f $SIGNAL_H && \
 892   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 893   break
 894 done
 895 nmh_cv_path_signal_h=$SIGNAL_H
 896 ])
 897 SIGNAL_H=$nmh_cv_path_signal_h
 898 AC_SUBST(SIGNAL_H)dnl
 899
 900 dnl ----------------
 901 dnl OS SPECIFIC DEFINES
 902 dnl ----------------
 903 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 904 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 905 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 906 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 907 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 908
 909 case "$target_os" in
 910
 911   solaris2*)
 912     AC_DEFINE(SYS5)
 913     AC_DEFINE(SVR4)
 914     ;;
 915   irix*)
 916     AC_DEFINE(SYS5)
 917     AC_DEFINE(SVR4)
 918     ;;
 919   osf*)
 920     AC_DEFINE(SYS5)
 921     AC_DEFINE(SVR4)
 922     ;;
 923   aix*)
 924     AC_DEFINE(SYS5)
 925     AC_DEFINE(SVR4)
 926     ;;
 927   sunos4*)
 928     AC_DEFINE(BSD42)
 929     ;;
 930   freebsd*)
 931     AC_DEFINE(BSD42)
 932     AC_DEFINE(BSD44)
 933     ;;
 934   netbsd*)
 935     AC_DEFINE(BSD42)
 936     AC_DEFINE(BSD44)
 937     ;;
 938   openbsd*)
 939     AC_DEFINE(BSD42)
 940     AC_DEFINE(BSD44)
 941     ;;
 942   bsd/os*)
 943     AC_DEFINE(BSD42)
 944     AC_DEFINE(BSD44)
 945     ;;
 946   sco5*)
 947     AC_DEFINE(SYS5)
 948     AC_DEFINE(SCO_5_STDIO)
 949     ;;
 950 esac
 951
 952
 953 dnl ----------------
 954 dnl OUTPUT MAKEFILES
 955 dnl ----------------
 956 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 957                 mts/Makefile mts/smtp/Makefile \
 958                 etc/Makefile docs/Makefile man/Makefile)
 959 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 960 AC_OUTPUT
 961
 962 dnl These odd looking assignments are done to expand out unexpanded
 963 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 964 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 965 dnl again to get the final answer.
 966 dnl We only use the expanded versions to print the install paths in
 967 dnl the final summary and should use them nowhere else (see the autoconf
 968 dnl docs for the rationale for bindir etc being unexpanded).
 969 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 970 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 971 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 972 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 973
 974 pop_kinds=no
 975 if test x"$enable_pop" = x"yes"; then
 976   pop_kinds="yes ("
 977
 978   if test x"$enable_apop" = x"yes"; then
 979     pop_kinds="${pop_kinds}APOP "
 980   fi
 981
 982   pop_kinds="${pop_kinds}POP3)"
 983 fi
 984
 985 echo "
 986 nmh configuration
 987 -----------------
 988 nmh version                : AC_PACKAGE_VERSION
 989 target os                  : ${target}
 990 compiler                   : ${CC}
 991 compiler flags             : ${CFLAGS}
 992 linker flags               : ${LDFLAGS}
 993 definitions                : ${OURDEFS}
 994 source code location       : ${srcdir}
 995 binary install path        : ${nmhbin}
 996 library install path       : ${nmhlib}
 997 config files install path  : ${nmhsysconf}
 998 man page install path      : ${nmhman}
 999 backup prefix              : ${backup_prefix}
1000 transport system           : ${MTS}
1001 file locking type          : ${LOCKTYPE}
1002 default smtp servers       : ${smtpservers}
1003 default editor             : ${editorpath}
1004 default pager              : ${pagerpath}
1005 email address masquerading : ${masquerade}
1006 pop is enabled             : ${pop_kinds}
1007 SASL support               : ${sasl_support}
1008 TLS support                : ${tls_support}"
1009 echo ""