git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(mmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want to debug nmh?
  41 AC_ARG_ENABLE(debug,
  42   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  43 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  44 if test x"$enable_nmh_debug" = x"yes"; then
  45   enable_debug=yes
  46 fi
  47
  48 dnl Allow users to send email from addresses other than their default?
  49 AC_ARG_ENABLE(masquerade,
  50   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  51     [enable up to 3 types of address masquerading]),
  52   [if test x"$enable_masquerade" = x"yes"; then
  53     masquerade="draft_from mmailid username_extension"
  54   else
  55     masquerade="$enable_masquerade"
  56   fi], [masquerade="draft_from mmailid username_extension"])
  57 AC_SUBST(masquerade)dnl
  58
  59 dnl Do you want mhe support?
  60 AC_ARG_ENABLE(mhe,
  61   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  62
  63 dnl mhe support is on by default, so define it unless --disable-mhe or the
  64 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  65 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  66   AC_DEFINE(MHE, 1,
  67     [Define to compile in support for the Emacs front-end mh-e.])dnl
  68 fi
  69
  70 dnl Do you want to disable use of locale functions
  71 AH_TEMPLATE([LOCALE],
  72 [Undefine if you don't want locale features.  By default this is defined.])
  73 AC_ARG_ENABLE([locale],
  74 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  75 [if test x$enableval = xyes; then
  76   AC_DEFINE(LOCALE)
  77 fi],
  78 AC_DEFINE(LOCALE)
  79 )
  80
  81 dnl Do you want client-side support for using SASL for authentication?
  82 dnl Note that this code will be enabled for SMTP
  83 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
  84   [Enable SASL support via the Cyrus SASL library]))
  85 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
  86   AC_DEFINE(CYRUS_SASL, 1,
  87     [Define to use the Cyrus SASL library for authentication of SMTP.])dnl
  88   if test x"$with_cyrus_sasl" != xyes; then
  89     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
  90     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
  91   fi
  92   sasl_support=yes
  93 else
  94   sasl_support=no
  95 fi
  96
  97 dnl Do you want client-side support for encryption with TLS?
  98 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
  99 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
 100   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
 101   tls_support=yes
 102 else
 103   tls_support=no
 104 fi
 105
 106 dnl What should be the default editor?
 107 AC_ARG_WITH(editor,
 108   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 109
 110 if test -n "$with_editor"; then
 111   editorpath="$with_editor"
 112 fi
 113
 114 dnl Set the backup prefix
 115 AC_ARG_WITH([hash-backup],
 116   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 117 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 118   backup_prefix="#"
 119 else
 120   backup_prefix=","
 121 fi
 122 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 123     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 124
 125 dnl What method of locking to use?
 126 AC_ARG_WITH(locking,
 127   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 128   [specify the file locking method]))
 129
 130 if test x"$with_locking" = x"dot"; then
 131   LOCKTYPE="dot"
 132   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 133 elif test x"$with_locking" = x"flock"; then
 134   LOCKTYPE="flock"
 135   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 136 elif test x"$with_locking" = x"lockf"; then
 137   LOCKTYPE="lockf"
 138   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 139 elif test x"$with_locking" = x"fcntl"; then
 140   LOCKTYPE="fcntl"
 141   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 142 else
 143   LOCKTYPE="dot"
 144   AC_DEFINE(DOT_LOCKING)dnl
 145 fi
 146
 147 dnl What method of posting should post use?
 148 dnl We'll always use sendmail now. (mmh)
 149 MTS="sendmail"
 150 dnl #AC_SUBST(MTS)dnl
 151
 152 dnl Both the smtp and sendmail mail transport services use the smtp code
 153 AC_DEFINE(SMTPMTS, 1,
 154   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 155
 156 dnl What should be the default pager?
 157 AC_ARG_WITH(pager,
 158   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 159
 160 if test -n "$with_pager"; then
 161   pagerpath="$with_pager"
 162 fi
 163
 164 dnl ----------------------------------------------------
 165 dnl Default location is /usr/local/mmh/{bin,etc,lib,share/man}
 166 dnl ----------------------------------------------------
 167 AC_PREFIX_DEFAULT(/usr/local/mmh)
 168
 169
 170 dnl ------------------
 171 dnl CHECK THE COMPILER
 172 dnl ------------------
 173 dnl We want these before the checks,
 174 dnl so the checks can modify their values.
 175 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 176 if test x"$enable_debug" = x"yes"; then
 177   test -z "$LDFLAGS" && LDFLAGS=-g
 178 fi
 179
 180 AC_PROG_CC
 181
 182 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 183 [nmh_saved_cflags="$CFLAGS"
 184  CFLAGS="$CFLAGS -Wno-pointer-sign"
 185  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 186  CFLAGS="$nmh_saved_cflags"])
 187
 188 dnl if the user hasn't specified CFLAGS, then
 189 dnl   if compiler is gcc, then
 190 dnl     use -O2 and some warning flags
 191 dnl   else use -O
 192 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 193 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 194 dnl spurious and which in any case we don't want to deal with now.
 195 if test "$nmh_cv_has_noptrsign" = "yes"; then
 196         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 197 else
 198         nmh_gcc_warnflags="-Wall"
 199 fi
 200
 201 if test -n "$auto_cflags"; then
 202   if test x"$enable_debug" = x"yes"; then
 203     if test -n "$GCC"; then
 204       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 205     else
 206       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 207     fi
 208   else
 209     if test -z "$LDFLAGS"; then
 210       case "$build_os" in
 211         darwin*)
 212           LDFLAGS=
 213           ;;
 214         *)
 215           LDFLAGS=-s
 216           ;;
 217       esac
 218     fi
 219     if test -n "$GCC"; then
 220       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 221     else
 222       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 223     fi
 224   fi
 225 fi
 226
 227 AC_C_CONST              dnl Does compiler support `const'.
 228
 229 dnl ------------------
 230 dnl CHECK FOR PROGRAMS
 231 dnl ------------------
 232 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 233 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 234 AC_PROG_RANLIB          dnl Check for `ranlib'
 235 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 236 AC_PROG_LEX             dnl Check for lex/flex
 237
 238 dnl Look for `cut'
 239 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 240 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 241
 242 dnl ----------------------------------------------
 243 dnl check for lclint, and lint if it doesn't exist
 244 dnl ----------------------------------------------
 245 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 246 if test x$ac_cv_prog_linttmp1 != xno ; then
 247   LINT=$ac_cv_prog_linttmp1
 248   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 249 else
 250   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 251   if test x$ac_cv_prog_linttmp2 != xno ; then
 252     LINT=$ac_cv_prog_linttmp2
 253     LINTFLAGS=""
 254   else
 255     LINT="echo 'No lint program found'"
 256     LINTFLAGS=""
 257   fi
 258 fi
 259 AC_SUBST(LINT)dnl
 260 AC_SUBST(LINTFLAGS)dnl
 261
 262 dnl try to figure out which one we've got
 263 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 264 NMH_PROG_GNU_LIBTOOL
 265
 266 dnl Check for lorder and tsort commands
 267 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 268 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 269
 270 dnl If either doesn't exist, replace them with echo and cat
 271 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 272   LORDER=echo
 273   TSORT=cat
 274   AC_SUBST(LORDER)dnl
 275   AC_SUBST(TSORT)dnl
 276 dnl Mac OS X has lorder, but sh is too broken for it to work
 277 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 278 dnl   LORDER=echo
 279 dnl   TSORT=cat
 280 dnl   AC_SUBST(LORDER)dnl
 281 dnl   AC_SUBST(TSORT)dnl
 282 fi
 283
 284 dnl Check whether tsort can deal with loops
 285 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 286   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 287     nmh_cv_tsort_loop=no
 288   else
 289     nmh_cv_tsort_loop=yes
 290   fi])
 291 if test x$nmh_cv_tsort_loop = xno ; then
 292   LORDER=echo
 293   TSORT=cat
 294   AC_SUBST(LORDER)dnl
 295   AC_SUBST(TSORT)dnl
 296 fi
 297
 298 dnl Look for `ls'
 299 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 300 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 301
 302 dnl See how we get ls to display the owner and the group
 303 if test "$lspath" != "no"; then
 304   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 305                  nmh_cv_ls_grpopt,
 306   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 307     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 308     dnl ls, it would seem -l gave us both the user and group.  On this type of
 309     dnl ls, -g makes _only_ the group be displayed (and not the user).
 310     nmh_cv_ls_grpopt="-l"
 311   else
 312     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 313     nmh_cv_ls_grpopt="-lg"
 314   fi])
 315 fi
 316
 317 dnl Look for `more'
 318 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 319 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 320
 321 dnl If pager is not specified yet,
 322 dnl then use `more' as the default.
 323 if test -z "$pagerpath"; then
 324   pagerpath="$morepath"
 325 fi
 326 AC_SUBST(pagerpath)dnl
 327
 328 dnl Look for `sendmail'
 329 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 330 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 331
 332 dnl Look for `vi'
 333 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 334 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 335
 336 dnl If editor is not specified yet,
 337 dnl then use `vi' as the default.
 338 if test -z "$editorpath"; then
 339   editorpath="$vipath"
 340 fi
 341 AC_SUBST(editorpath)dnl
 342
 343 dnl ----------------------------------------------------------
 344 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 345 dnl ----------------------------------------------------------
 346 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 347 [for mailspool in /var/mail        dnl
 348                   /var/spool/mail  dnl
 349                   /usr/spool/mail  dnl
 350                   /dev/null;       dnl Just in case we fall through
 351 do
 352   test -d $mailspool && break
 353 done
 354 nmh_cv_mailspool=$mailspool
 355 ])
 356 mailspool=$nmh_cv_mailspool
 357 AC_SUBST(mailspool)dnl
 358
 359 dnl See whether the mail spool directory is world-writable.
 360 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 361   AC_CACHE_CHECK(whether the mail spool is world-writable,
 362                  nmh_cv_mailspool_world_writable,
 363   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 364     nmh_cv_mailspool_world_writable=no
 365   else
 366     nmh_cv_mailspool_world_writable=yes
 367   fi])
 368 fi
 369
 370 dnl Also, check for liblockfile (as found on Debian systems)
 371 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 372
 373 dnl and whether its companion program dotlockfile is setgid
 374 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 375 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 376   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 377     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 378     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 379         nmh_cv_dotlockfile_setgid=yes
 380       else
 381         nmh_cv_dotlockfile_setgid=no
 382       fi])
 383   fi
 384 fi
 385
 386 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 387 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 388 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 389   dnl do we really need both of these?
 390   AC_DEFINE(MAILGROUP,1,
 391     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 392   SETGID_MAIL=1
 393 fi
 394 AC_SUBST(SETGID_MAIL)dnl
 395
 396 dnl Use ls to see which group owns the mail spool directory.
 397 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 398 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 399 ])
 400 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 401 AC_SUBST(MAIL_SPOOL_GRP)dnl
 402
 403 dnl ------------------
 404 dnl CHECK HEADER FILES
 405 dnl ------------------
 406
 407 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 408 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 409 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 410 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 411 dnl declared; if so they should have an entry added to this case statement.
 412 dnl NB that we must define this on the compiler command line, not in config.h,
 413 dnl because it must be set before any system header is included and there's no
 414 dnl portable way to make sure that files generated by lex include config.h
 415 dnl before system header files.
 416
 417 case "$target_os" in
 418   linux*)
 419     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 420     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 421     ;;
 422 esac
 423 AC_SUBST(OURDEFS)
 424
 425 AC_HEADER_DIRENT
 426 AC_HEADER_STDC
 427 AC_HEADER_TIME
 428 AC_HEADER_SYS_WAIT
 429 AC_HEADER_STAT
 430 AC_HEADER_TIOCGWINSZ
 431 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 432                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 433                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 434                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 435                  arpa/inet.h arpa/ftp.h)
 436
 437 dnl
 438 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 439 dnl really use a whole set of them, but this check should be
 440 dnl sufficient.
 441 dnl
 442 AC_CHECK_HEADER(libio.h, [
 443   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 444     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 445
 446 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 447   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 448 [[#if HAVE_SYS_STREAM_H
 449 #  include <sys/stream.h>
 450 #endif
 451 ]])
 452
 453 dnl ---------------
 454 dnl CHECK FUNCTIONS
 455 dnl ---------------
 456 AC_FUNC_VFORK
 457 AC_CHECK_LIB(mkstemp,mkstemp)
 458 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 459                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 460                getutent nl_langinfo mbtowc wcwidth)
 461
 462 dnl sigsetjmp may be a macro
 463 AC_MSG_CHECKING(for sigsetjmp)
 464 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 465   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 466     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 467   [AC_MSG_RESULT(no)])
 468
 469 AC_REPLACE_FUNCS(memmove snprintf strerror strdup)
 470
 471 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 472 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 473 dnl any system header.
 474 dnl
 475 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 476 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 477 dnl need to check?
 478 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 479 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 480                 AC_EGREP_HEADER(initgroups, unistd.h,
 481                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 482
 483 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 484 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 485 dnl seems to work perfectly and IBM apparently uses it in internal code).
 486 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 487 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 488 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 489 dnl prototype.
 490 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 491   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 492
 493 dnl Check for multibyte character set support
 494 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 495     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 496   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 497     [Define to enable support for multibyte character sets.])
 498 fi
 499
 500 dnl -------------------
 501 dnl CHECK FOR LIBRARIES
 502 dnl -------------------
 503 dnl Check location of modf
 504 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 505
 506 dnl Checks for network libraries (nsl, socket)
 507 AC_CHECK_NETLIBS
 508
 509 termcap_curses_order="termcap curses ncurses"
 510 for lib in $termcap_curses_order; do
 511   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 512 done
 513 AC_SUBST(TERMLIB)dnl
 514
 515 dnl ---------------
 516 dnl CHECK FOR ICONV
 517 dnl ---------------
 518
 519 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 520 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 521   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 522   if test "x$ac_found_iconv" = "xno"; then
 523     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 524     if test "x$ac_found_iconv" = "xno"; then
 525       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 526     fi
 527     if test "x$ac_found_iconv" != "xno"; then
 528       LIBS="-liconv $LIBS"
 529     fi
 530   else
 531     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 532     AC_CHECK_DECL(_libiconv_version,
 533       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 534       [ #include <iconv.h> ])
 535   fi
 536 fi
 537 if test "x$ac_found_iconv" = xyes; then
 538   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 539 fi
 540
 541 dnl Check if iconv uses const in prototype declaration
 542 if test "x$ac_found_iconv" = "xyes"; then
 543   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 544     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 545         #include <iconv.h>]],
 546         [[#ifdef __cplusplus
 547           "C"
 548           #endif
 549           #if defined(__STDC__) || defined(__cplusplus)
 550           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 551           #else
 552           size_t iconv();
 553           #endif]])],
 554       [ac_cv_iconv_const=],
 555       [ac_cv_iconv_const=const])])
 556   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 557     [Define as const if the declaration of iconv() needs const.])
 558 fi
 559
 560 dnl --------------
 561 dnl CHECK FOR NDBM
 562 dnl --------------
 563
 564 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 565             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 566 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 567             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 568
 569 if test "$nmh_ndbm" = "autodetect"; then
 570   if test "$nmh_ndbmheader" != "autodetect"; then
 571     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 572   else
 573
 574     dnl There are at least four implementations of ndbm, and
 575     dnl several of those can be in different places at the whim
 576     dnl of the system integrator. A good summary of this mess
 577     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 578
 579     dnl Classic ndbm with no library required (eg NetBSD): try this
 580     dnl first so we don't accidentally link in a pointless but harmless
 581     dnl library in one of the later ndbm.h+libfoo tests:
 582     NMH_CHECK_NDBM(ndbm.h,,,
 583     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 584       NMH_CHECK_NDBM(db.h,db,,
 585     dnl Berkeley DBv1 emulating ndbm:
 586         NMH_CHECK_NDBM(ndbm.h,db,,
 587           NMH_CHECK_NDBM(ndbm.h,db1,,
 588     dnl Classic ndbm:
 589             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 590     dnl glibc2.1 systems put db1 in a subdir:
 591               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 592     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 593     dnl and possibly needing gbdm_compat library:
 594                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 595                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 596                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 597                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 598
 599   fi
 600 else
 601   dnl We don't really need to check that the user-specified values work,
 602   dnl but it is a convenience to the user to bomb out early rather than
 603   dnl after configure and half the compile process.
 604   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 605 fi
 606
 607 if test "$nmh_ndbm_found" = "no"; then
 608   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 609 else
 610   dnl Now export the lib/header to our makefile/config.h:
 611   if test x"$nmh_ndbmheader" != x; then
 612     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 613       [Define to the header containing the ndbm API prototypes.])
 614   fi
 615   if test x"$nmh_ndbm" != x; then
 616     NDBM_LIBS="-l$nmh_ndbm"
 617   else
 618     NDBM_LIBS=
 619   fi
 620   AC_SUBST(NDBM_LIBS)
 621 fi
 622
 623
 624 dnl --------------------
 625 dnl CHECK FOR CYRUS-SASL
 626 dnl --------------------
 627
 628 AS_IF([test x"$sasl_support" = x"yes"],[
 629   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 630   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 631     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 632
 633 dnl -----------------
 634 dnl CHECK FOR OPENSSL
 635 dnl -----------------
 636
 637 AS_IF([test x"$tls_support" = x"yes"],[
 638   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 639   AC_CHECK_LIB([crypto], [BIO_write], ,
 640     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 641   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 642     [AC_MSG_ERROR([OpenSSL library not found])])])
 643
 644 dnl ---------------------
 645 dnl CHECK TERMCAP LIBRARY
 646 dnl ---------------------
 647
 648 dnl Add the termcap library, so that the following configure
 649 dnl tests will find it when it tries to link test programs.
 650 nmh_save_LIBS="$LIBS"
 651 LIBS="$TERMLIB $LIBS"
 652
 653 dnl Checks for external variable ospeed in the termcap library.
 654 AC_CACHE_CHECK(if an include file defines ospeed,
 655 nmh_cv_decl_ospeed_include_defines,
 656 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 657 #if HAVE_TERMIOS_H
 658 #include <termios.h>
 659 #endif
 660 #if HAVE_TERMCAP_H
 661 #include <termcap.h>
 662 #endif]], [[ospeed = 0;]])],
 663 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 664
 665 if test $nmh_cv_decl_ospeed_include_defines = no; then
 666   AC_CACHE_CHECK(if you must define ospeed,
 667   nmh_cv_decl_ospeed_must_define,
 668   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 669   [[extern short ospeed; ospeed = 0;]])],
 670   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 671 fi
 672
 673 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 674 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 675   AC_DEFINE(HAVE_OSPEED)dnl
 676 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 677   AC_DEFINE(HAVE_OSPEED)
 678   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 679     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 680 fi
 681
 682 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 683 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 684 dnl in tgetstr().
 685 dnl Under Cygwin test program crashes but exit code is still 0. So,
 686 dnl we test for a file that porgram should create
 687 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 688 [Define to 1 if tgetent() accepts NULL as a buffer.])
 689 AC_CACHE_CHECK(if tgetent accepts NULL,
 690 nmh_cv_func_tgetent_accepts_null,
 691 [AC_TRY_RUN([
 692 main()
 693 {
 694     char buf[4096];
 695     int r1 = tgetent(buf, "vt100");
 696     int r2 = tgetent((char*)0,"vt100");
 697     if (r1 >= 0 && r1 == r2) {
 698         char tbuf[1024], *u;
 699         u = tbuf;
 700         tgetstr("cl", &u);
 701         creat("conftest.tgetent", 0640);
 702     }
 703     exit((r1 != r2) || r2 == -1);
 704 }
 705 ],
 706   if test -f conftest.tgetent; then
 707     nmh_cv_func_tgetent_accepts_null=yes
 708   else
 709     nmh_cv_func_tgetent_accepts_null=no
 710   fi,
 711   nmh_cv_func_tgetent_accepts_null=no,
 712   nmh_cv_func_tgetent_accepts_null=no)])
 713 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 714   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 715 fi
 716 AC_CACHE_CHECK(if tgetent returns 0 on success,
 717 nmh_cv_func_tgetent_zero_success,
 718 [AC_TRY_RUN([
 719 main()
 720 {
 721     char buf[4096];
 722     int r1 = tgetent(buf, "!@#$%^&*");
 723     int r2 = tgetent(buf, "vt100");
 724     if (r1 < 0 && r2 == 0) {
 725         char tbuf[1024], *u;
 726         u = tbuf;
 727         tgetstr("cl", &u);
 728         creat("conftest.tgetent0", 0640);
 729     }
 730     exit(r1 == r2);
 731 }
 732 ],
 733   if test -f conftest.tgetent0; then
 734     nmh_cv_func_tgetent_zero_success=yes
 735   else
 736     nmh_cv_func_tgetent_zero_success=no
 737   fi,
 738   nmh_cv_func_tgetent_zero_success=no,
 739   nmh_cv_func_tgetent_zero_success=no)])
 740 AH_TEMPLATE([TGETENT_SUCCESS],
 741 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 742 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 743   AC_DEFINE(TGETENT_SUCCESS, 0)
 744 else
 745   AC_DEFINE(TGETENT_SUCCESS, 1)
 746 fi
 747
 748 dnl Now put the libraries back to what it was before we
 749 dnl starting checking the termcap library.
 750 LIBS="$nmh_save_LIBS"
 751
 752 dnl --------------
 753 dnl CHECK TYPEDEFS
 754 dnl --------------
 755 AC_TYPE_SIGNAL
 756 AC_TYPE_PID_T
 757 AC_TYPE_OFF_T
 758 AC_TYPE_UID_T
 759 AC_TYPE_MODE_T
 760 AC_TYPE_SIZE_T
 761
 762 dnl Check for sigset_t.  Currently I'm looking in
 763 dnl <sys/types.h> and <signal.h>.  Others might need
 764 dnl to be added.
 765 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 766 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 767 #include <signal.h>]], [[sigset_t tempsigset;]])],
 768 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 769 if test $nmh_cv_type_sigset_t = no; then
 770   AC_DEFINE(sigset_t, unsigned int,
 771     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 772 fi
 773
 774 dnl ----------------
 775 dnl CHECK STRUCTURES
 776 dnl ----------------
 777 AC_CHECK_MEMBERS(struct stat.st_blksize)
 778
 779 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 780   [#ifdef TIME_WITH_SYS_TIME
 781 # include <sys/time.h>
 782 # include <time.h>
 783 #else
 784 # ifdef TM_IN_SYS_TIME
 785 #  include <sys/time.h>
 786 # else
 787 #  include <time.h>
 788 # endif
 789 #endif])
 790
 791 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 792
 793 AC_MSG_CHECKING(for union wait)
 794 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 795   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 796 #include <sys/wait.h>]],
 797     [[union wait status; int pid; pid = wait (&status);
 798 #ifdef WEXITSTATUS
 799 /* Some POSIXoid systems have both the new-style macros and the old
 800    union wait type, and they do not work together.  If union wait
 801    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 802         if (WEXITSTATUS (status) != 0) pid = -1;
 803 #ifdef WTERMSIG
 804         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 805         -- blow chunks here --
 806 #endif
 807 #endif
 808 #ifdef HAVE_WAITPID
 809         /* Make sure union wait works with waitpid.  */
 810         pid = waitpid (-1, &status, 0);
 811 #endif
 812       ]])],
 813     [nmh_cv_union_wait=yes],
 814     [nmh_cv_union_wait=no])])
 815 if test "$nmh_cv_union_wait" = yes; then
 816   AC_DEFINE(HAVE_UNION_WAIT, 1,
 817     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 818 fi
 819 AC_MSG_RESULT($nmh_cv_union_wait)
 820
 821 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 822
 823 dnl -------------
 824 dnl CHECK SIGNALS
 825 dnl -------------
 826 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 827 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 828 AC_MSG_CHECKING(what style of signals to use)
 829 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 830   signals_style=POSIX_SIGNALS
 831   AC_DEFINE(POSIX_SIGNALS, 1,
 832     [Define to 1 if you use POSIX style signal handling.])
 833   AC_DEFINE(RELIABLE_SIGNALS)
 834 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 835   signals_style=BSD_SIGNALS
 836   AC_DEFINE(BSD_SIGNALS,1,
 837     [Define to 1 if you use BSD style signal handling (and can block signals).])
 838   AC_DEFINE(RELIABLE_SIGNALS)
 839 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 840   signals_style=SYSV_SIGNALS
 841   AC_DEFINE(SYSV_SIGNALS,1,
 842     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 843 else
 844   signals_style=NO_SIGNAL_BLOCKING
 845   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 846     [Define to 1 if you have no signal blocking at all (bummer).])
 847 fi
 848
 849 AC_MSG_RESULT($signals_style)
 850
 851 dnl Where is <signal.h> located?  Needed as input for signames.awk
 852 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 853 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 854                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 855                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 856                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 857                  /usr/include/sys/signal.h      dnl Almost everybody else
 858                  /dev/null;                     dnl Just in case we fall through
 859 do
 860   test -f $SIGNAL_H && \
 861   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 862   break
 863 done
 864 nmh_cv_path_signal_h=$SIGNAL_H
 865 ])
 866 SIGNAL_H=$nmh_cv_path_signal_h
 867 AC_SUBST(SIGNAL_H)dnl
 868
 869 dnl ----------------
 870 dnl OS SPECIFIC DEFINES
 871 dnl ----------------
 872 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 873 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 874 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 875 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 876 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 877
 878 case "$target_os" in
 879
 880   solaris2*)
 881     AC_DEFINE(SYS5)
 882     AC_DEFINE(SVR4)
 883     ;;
 884   irix*)
 885     AC_DEFINE(SYS5)
 886     AC_DEFINE(SVR4)
 887     ;;
 888   osf*)
 889     AC_DEFINE(SYS5)
 890     AC_DEFINE(SVR4)
 891     ;;
 892   aix*)
 893     AC_DEFINE(SYS5)
 894     AC_DEFINE(SVR4)
 895     ;;
 896   sunos4*)
 897     AC_DEFINE(BSD42)
 898     ;;
 899   freebsd*)
 900     AC_DEFINE(BSD42)
 901     AC_DEFINE(BSD44)
 902     ;;
 903   netbsd*)
 904     AC_DEFINE(BSD42)
 905     AC_DEFINE(BSD44)
 906     ;;
 907   openbsd*)
 908     AC_DEFINE(BSD42)
 909     AC_DEFINE(BSD44)
 910     ;;
 911   bsd/os*)
 912     AC_DEFINE(BSD42)
 913     AC_DEFINE(BSD44)
 914     ;;
 915   sco5*)
 916     AC_DEFINE(SYS5)
 917     AC_DEFINE(SCO_5_STDIO)
 918     ;;
 919 esac
 920
 921
 922 dnl ----------------
 923 dnl OUTPUT MAKEFILES
 924 dnl ----------------
 925 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 926                 mts/Makefile mts/smtp/Makefile \
 927                 etc/Makefile docs/Makefile man/Makefile)
 928 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
 929 AC_OUTPUT
 930
 931 dnl These odd looking assignments are done to expand out unexpanded
 932 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
 933 dnl but expanding that gives '${prefix}/share/man', so we need to expand
 934 dnl again to get the final answer.
 935 dnl We only use the expanded versions to print the install paths in
 936 dnl the final summary and should use them nowhere else (see the autoconf
 937 dnl docs for the rationale for bindir etc being unexpanded).
 938 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
 939 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
 940 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
 941 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
 942
 943 echo "
 944 nmh configuration
 945 -----------------
 946 nmh version                : AC_PACKAGE_VERSION
 947 target os                  : ${target}
 948 compiler                   : ${CC}
 949 compiler flags             : ${CFLAGS}
 950 linker flags               : ${LDFLAGS}
 951 definitions                : ${OURDEFS}
 952 source code location       : ${srcdir}
 953 binary install path        : ${nmhbin}
 954 library install path       : ${nmhlib}
 955 config files install path  : ${nmhsysconf}
 956 man page install path      : ${nmhman}
 957 backup prefix              : ${backup_prefix}
 958 transport system           : ${MTS}
 959 file locking type          : ${LOCKTYPE}
 960 default editor             : ${editorpath}
 961 default pager              : ${pagerpath}
 962 email address masquerading : ${masquerade}
 963 SASL support               : ${sasl_support}
 964 TLS support                : ${tls_support}"
 965 echo ""