git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4 dnl $Id$
   5 dnl
   6
   7 AC_INIT(h/nmh.h)
   8 AC_CONFIG_HEADER(config.h)
   9
  10 AC_CANONICAL_SYSTEM
  11
  12 dnl What version of nmh are we building?
  13 VERSION=`sed -e 's/nmh-//' ${srcdir}/VERSION`
  14 echo "configuring for nmh-$VERSION"
  15 AC_SUBST(VERSION)dnl
  16
  17 dnl -------------------------
  18 dnl CHECK COMMAND LINE OPTION
  19 dnl -------------------------
  20 dnl What method of posting should post use?
  21 undefine([mts])dnl
  22 AC_ARG_WITH(mts,
  23 [  --with-mts=MTS          specify the mail transport agent])
  24
  25 if test x$with_mts = xsmtp; then
  26   MTS="smtp"
  27   MTSLIB="mts/smtp/libsmtp.a"
  28   AC_DEFINE(SMTPMTS)dnl
  29 elif test x$with_mts = xsendmail; then
  30   MTS="sendmail"
  31   MTSLIB="mts/sendmail/libsend.a"
  32   AC_DEFINE(SENDMTS)dnl
  33 else
  34   MTS="smtp"
  35   MTSLIB="mts/smtp/libsmtp.a"
  36   AC_DEFINE(SMTPMTS)dnl
  37 fi
  38
  39 AC_SUBST(MTS)
  40 AC_SUBST(MTSLIB)
  41
  42 dnl What should be the default editor?
  43 undefine([editor])dnl
  44 AC_ARG_WITH(editor,
  45 [  --with-editor=EDITOR    specify the default editor])
  46
  47 if test -n "$with_editor"; then
  48   editorpath="$with_editor"
  49 fi
  50
  51 dnl What should be the default pager?
  52 undefine([pager])dnl
  53 AC_ARG_WITH(pager,
  54 [  --with-pager=PAGER      specify the default pager])
  55
  56 if test -n "$with_pager"; then
  57   pagerpath="$with_pager"
  58 fi
  59
  60 dnl Do you want mhe support?
  61 undefine([nmh-mhe])dnl
  62 AC_ARG_ENABLE(nmh-mhe,
  63 [  --enable-nmh-mhe        enable mhe support (DEFAULT)])
  64
  65 dnl mhe support is on by default, so define it unless
  66 dnl explicitly disabled.
  67 if test x$enable_nmh_mhe != xno; then
  68   AC_DEFINE(MHE)dnl
  69 fi
  70
  71 dnl Do you want client-side support for pop
  72 undefine([nmh-pop])dnl
  73 AC_ARG_ENABLE(nmh-pop,
  74 [  --enable-nmh-pop        enable client-side support for pop])
  75 if test x$enable_nmh_pop = xyes; then
  76   AC_DEFINE(POP)dnl
  77   POPLIB=popsbr.o
  78   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
  79 else
  80   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
  81 fi
  82 AC_SUBST(POPLIB)dnl
  83 AC_SUBST(POPSED)dnl
  84
  85 dnl Do you want client-side support for kpop
  86 AC_ARG_WITH(krb4,
  87 [  --with-krb4=PREFIX      specify location of Kerberos V4 for kpop support])
  88 if test x$with_krb4 != x -a x$with_krb4 != xno; then
  89   AC_DEFINE(KPOP)dnl
  90   AC_DEFINE(KPOP_PRINCIPAL, "pop")dnl
  91 fi
  92
  93 dnl Do you want support for hesiod
  94 AC_ARG_WITH(hesiod,
  95 [  --with-hesiod=PREFIX    specify location of Hesiod])
  96 if test x$with_hesiod != x -a x$with_hesiod != xno; then
  97   AC_DEFINE(HESIOD)dnl
  98 fi
  99
 100 dnl Do you want to debug nmh?
 101 undefine([nmh-debug])dnl
 102 AC_ARG_ENABLE(nmh-debug,
 103 [  --enable-nmh-debug      enable nmh code debugging])
 104
 105 dnl ----------------------------------------------------
 106 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 107 dnl ----------------------------------------------------
 108 AC_PREFIX_DEFAULT(/usr/local/nmh)
 109
 110 dnl ------------------
 111 dnl CHECK THE COMPILER
 112 dnl ------------------
 113 dnl We want these before the checks,
 114 dnl so the checks can modify their values.
 115 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 116 if test x$enable_nmh_debug = xyes; then
 117   test -z "$LDFLAGS" && LDFLAGS=-g
 118 fi
 119
 120 AC_PROG_CC
 121
 122 dnl if the user hasn't specified CFLAGS, then
 123 dnl   if compiler is gcc, then
 124 dnl     use -O2 and some warning flags
 125 dnl   else use -O
 126 if test -n "$auto_cflags"; then
 127   if test x$enable_nmh_debug = xyes; then
 128     if test -n "$GCC"; then
 129       test -z "$CFLAGS" && CFLAGS="-Wall -g" || CFLAGS="$CFLAGS -Wall -g"
 130     else
 131       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 132     fi
 133   else
 134     test -z "$LDFLAGS" && LDFLAGS=-s
 135     if test -n "$GCC"; then
 136       test -z "$CFLAGS" && CFLAGS=-O2 || CFLAGS="$CFLAGS -O2"
 137     else
 138       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 139     fi
 140   fi
 141 fi
 142
 143 AC_C_CONST              dnl Does compiler support `const'.
 144
 145 dnl ------------------
 146 dnl CHECK FOR PROGRAMS
 147 dnl ------------------
 148 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 149 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 150 AC_PROG_RANLIB          dnl Check for `ranlib'
 151 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 152 AC_PROG_LEX             dnl Check for lex/flex
 153
 154 dnl Look for `cut'
 155 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 156 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 157
 158 dnl Check for lorder and tsort commands
 159 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 160 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 161
 162 dnl If either doesn't exist, replace them with echo and cat
 163 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 164   LORDER=echo
 165   TSORT=cat
 166   AC_SUBST(LORDER)dnl
 167   AC_SUBST(TSORT)dnl
 168 fi
 169
 170 dnl Look for `ls'
 171 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 172 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 173
 174 dnl See how we get ls to display the owner and the group
 175 if test "$lspath" != "no"; then
 176   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 177                  nmh_cv_ls_grpopt,
 178   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 179     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 180     dnl ls, it would seem -l gave us both the user and group.  On this type of
 181     dnl ls, -g makes _only_ the group be displayed (and not the user).
 182     nmh_cv_ls_grpopt="-l"
 183   else
 184     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 185     nmh_cv_ls_grpopt="-lg"
 186   fi])
 187 fi
 188
 189 dnl Look for `more'
 190 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 191 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 192
 193 dnl If pager is not specified yet,
 194 dnl then use `more' as the default.
 195 if test -z "$pagerpath"; then
 196   pagerpath="$morepath"
 197 fi
 198 AC_SUBST(pagerpath)dnl
 199
 200 dnl Look for `sendmail'
 201 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 202 AC_PATH_PROG(sendmailpath, sendmail, no, [$pathtmp])
 203
 204 dnl Look for `vi'
 205 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 206 AC_PATH_PROG(vipath, vi, no, [$pathtmp])
 207
 208 dnl If editor is not specified yet,
 209 dnl then use `vi' as the default.
 210 if test -z "$editorpath"; then
 211   editorpath="$vipath"
 212 fi
 213 AC_SUBST(editorpath)dnl
 214
 215 dnl Check for broken vi
 216 AC_CACHE_CHECK(for broken vi, nmh_cv_attvibug,
 217 [if echo 'r /nonexist-file
 218 q' | ex > /dev/null 2>&1
 219 then
 220         nmh_cv_attvibug=no
 221 else
 222         nmh_cv_attvibug=yes
 223 fi])
 224
 225 if test "$nmh_cv_attvibug" = yes; then
 226   AC_DEFINE(ATTVIBUG)
 227 fi
 228
 229 dnl ----------------------------------------------------------
 230 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 231 dnl ----------------------------------------------------------
 232 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 233 [for mailspool in /var/mail        dnl
 234                   /var/spool/mail  dnl
 235                   /usr/spool/mail  dnl
 236                   /dev/null;       dnl Just in case we fall through
 237 do
 238   test -d $mailspool && break
 239 done
 240 nmh_cv_mailspool=$mailspool
 241 ])
 242 mailspool=$nmh_cv_mailspool
 243 AC_SUBST(mailspool)dnl
 244
 245 dnl See whether the mail spool directory is world-writable.
 246 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 247   AC_CACHE_CHECK(whether the mail spool is world-writable,
 248                  nmh_cv_mailspool_world_writable,
 249   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 250     nmh_cv_mailspool_world_writable=no
 251   else
 252     nmh_cv_mailspool_world_writable=yes
 253   fi])
 254 fi
 255
 256 dnl ...If it's not, we need to #define MAILGROUP to 1 and make inc setgid.
 257 if test x"$nmh_cv_mailspool_world_writable" = x"no"; then
 258   dnl do we really need both of these?
 259   AC_DEFINE(MAILGROUP)
 260   SETGID_MAIL=1
 261 fi
 262 AC_SUBST(SETGID_MAIL)dnl
 263
 264 dnl see if we can determine which group owns the mail spool dir
 265 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 266 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 267  dnl Should we just set it to whatever ls reports, rather than only allowing
 268  dnl certain values...?
 269  if test x$nmh_cv_ls_mail_grp = xmail; then
 270    MAIL_SPOOL_GRP="mail"
 271  elif test x$nmh_cv_ls_mail_grp = xwheel; then
 272    MAIL_SPOOL_GRP="wheel"
 273  else
 274    MAIL_SPOOL_GRP="'0'"
 275  fi])
 276 AC_SUBST(MAIL_SPOOL_GRP)dnl
 277
 278 dnl ------------------
 279 dnl CHECK HEADER FILES
 280 dnl ------------------
 281 AC_HEADER_DIRENT
 282 AC_HEADER_STDC
 283 AC_HEADER_TIME
 284 AC_HEADER_SYS_WAIT
 285 AC_HEADER_STAT
 286 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 287                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 288                  sys/param.h sys/time.h sys/utsname.h arpa/inet.h \
 289                  arpa/ftp.h)
 290
 291 AC_CACHE_CHECK(POSIX termios, nmh_cv_sys_posix_termios,
 292 [AC_TRY_LINK([#include <sys/types.h>
 293 #include <unistd.h>
 294 #include <termios.h>],
 295 [/* SunOS 4.0.3 has termios.h but not the library calls.  */
 296 tcgetattr(0, 0);],
 297   nmh_cv_sys_posix_termios=yes, nmh_cv_sys_posix_termios=no)])
 298
 299 if test $nmh_cv_sys_posix_termios = yes; then
 300   AC_CACHE_CHECK(TIOCGWINSZ in termios.h,
 301   nmh_cv_header_termios_h_tiocgwinsz,
 302   [AC_TRY_LINK([#include <sys/types.h>
 303 #include <termios.h>],
 304   [int x = TIOCGWINSZ;],
 305   nmh_cv_header_termios_h_tiocgwinsz=yes,
 306   nmh_cv_header_termios_h_tiocgwinsz=no)])
 307 else
 308   nmh_cv_header_termios_h_tiocgwinsz=no
 309 fi
 310
 311 if test $nmh_cv_header_termios_h_tiocgwinsz = no; then
 312   AC_CACHE_CHECK(TIOCGWINSZ in sys/ioctl.h,
 313   nmh_cv_header_sys_ioctl_h_tiocgwinsz,
 314   [AC_TRY_LINK([#include <sys/types.h>
 315 #include <sys/ioctl.h>],
 316   [int x = TIOCGWINSZ;],
 317   nmh_cv_header_sys_ioctl_h_tiocgwinsz=yes,
 318   nmh_cv_header_sys_ioctl_h_tiocgwinsz=no)])
 319   if test $nmh_cv_header_sys_ioctl_h_tiocgwinsz = yes; then
 320     AC_DEFINE(GWINSZ_IN_SYS_IOCTL)
 321   fi
 322 fi
 323
 324 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM))
 325
 326 dnl ---------------
 327 dnl CHECK FUNCTIONS
 328 dnl ---------------
 329 AC_FUNC_VFORK
 330 AC_CHECK_LIB(mkstemp,mkstemp)
 331 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 332                sighold sigrelse writev lstat uname tzset killpg mkstemp)
 333
 334 dnl sigsetjmp may be a macro
 335 AC_MSG_CHECKING(for sigsetjmp)
 336 AC_TRY_LINK([#include <setjmp.h>], [sigsetjmp((void *)0, 0);],
 337         [AC_DEFINE(HAVE_SIGSETJMP) AC_MSG_RESULT(yes)], AC_MSG_RESULT(no))
 338
 339 AC_REPLACE_FUNCS(snprintf strerror strdup)
 340
 341 dnl -------------------
 342 dnl CHECK FOR LIBRARIES
 343 dnl -------------------
 344 dnl Check location of modf
 345 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 346
 347 dnl Checks for network libraries (nsl, socket)
 348 AC_CHECK_NETLIBS
 349
 350 dnl Check for bug in libraries such that ruserpass
 351 dnl needs to be linked as _ruserpass.
 352 AC_CHECK_RUSERPASS
 353
 354 termcap_curses_order="termcap curses ncurses"
 355 for lib in $termcap_curses_order; do
 356   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 357 done
 358 AC_SUBST(TERMLIB)dnl
 359
 360
 361 dnl --------------
 362 dnl CHECK FOR NDBM
 363 dnl --------------
 364 dnl Checks for ndbm
 365 AC_CHECK_FUNC(dbm_open, ,
 366   AC_CHECK_LIB(ndbm, dbm_open, ,
 367     AC_CHECK_LIB(dbm, dbm_open)))
 368
 369 dnl ----------------
 370 dnl CHECK FOR NDBM.H
 371 dnl ----------------
 372 AC_CHECK_HEADERS(db1/ndbm.h)
 373
 374 dnl ----------------
 375 dnl CHECK FOR HESIOD
 376 dnl ----------------
 377 if test x$with_hesiod != x -a x$with_hesiod != xno; then
 378   if test x$with_hesiod != xyes; then
 379     HESIOD_INCLUDES="-I$with_hesiod/include"
 380     HESIOD_LIBS="-L$with_hesiod/lib"
 381   fi
 382   AC_CHECK_FUNC(res_send, ,
 383     AC_CHECK_LIB(resolv, res_send))
 384   AC_CHECK_LIB(hesiod, hes_resolve, [HESIOD_LIBS="$HESIOD_LIBS -lhesiod"],
 385     [AC_MSG_ERROR(Hesiod library not found)], $HESIOD_LIBS)
 386 fi
 387 AC_SUBST(HESIOD_INCLUDES)dnl
 388 AC_SUBST(HESIOD_LIBS)dnl
 389
 390 dnl ----------------------------------
 391 dnl CHECK FOR KRB4 (Kerberos4 support)
 392 dnl ----------------------------------
 393 if test x$with_krb4 != x -a x$with_krb4 != xno; then
 394   if test x$with_krb4 != xyes; then
 395     KRB4_INCLUDES="-I$with_krb4/include"
 396     if test -d "$with_krb4/include/kerberosIV"; then
 397       KRB4_INCLUDES="$KRB4_INCLUDES -I$with_krb4/include/kerberosIV"
 398     fi
 399     KRB4_LIBS="-L$with_krb4/lib"
 400   elif test -d /usr/include/kerberosIV; then
 401     KRB4_INCLUDES="-I/usr/include/kerberosIV"
 402   fi
 403   AC_CHECK_LIB(krb4, krb_rd_req,
 404     [KRB4_LIBS="$KRB4_LIBS -lkrb4 -ldes425 -lkrb5 -lcrypto -lcom_err"],
 405     [AC_CHECK_LIB(krb, krb_rd_req,
 406       [KRB4_LIBS="$KRB4_LIBS -lkrb -ldes"],
 407       [AC_MSG_ERROR(Kerberos 4 libraries not found)],
 408       $KRB4_LIBS -ldes)],
 409     $KRB4_LIBS -ldes425 -lkrb5 -lcrypto -lcom_err)
 410 fi
 411 AC_SUBST(KRB4_INCLUDES)dnl
 412 AC_SUBST(KRB4_LIBS)dnl
 413
 414 dnl ---------------------
 415 dnl CHECK TERMCAP LIBRARY
 416 dnl ---------------------
 417
 418 dnl Add the termcap library, so that the following configure
 419 dnl tests will find it when it tries to link test programs.
 420 nmh_save_LIBS="$LIBS"
 421 LIBS="$TERMLIB $LIBS"
 422
 423 dnl Checks for external variable ospeed in the termcap library.
 424 AC_CACHE_CHECK(if an include file defines ospeed,
 425 nmh_cv_decl_ospeed_include_defines,
 426 [AC_TRY_LINK(
 427 [#include <sys/types.h>
 428 #if HAVE_TERMIOS_H
 429 #include <termios.h>
 430 #endif
 431 #if HAVE_TERMCAP_H
 432 #include <termcap.h>
 433 #endif], [ospeed = 0;],
 434 nmh_cv_decl_ospeed_include_defines=yes,
 435 nmh_cv_decl_ospeed_include_defines=no)])
 436
 437 if test $nmh_cv_decl_ospeed_include_defines = no; then
 438   AC_CACHE_CHECK(if you must define ospeed,
 439   nmh_cv_decl_ospeed_must_define,
 440   [AC_TRY_LINK( ,[extern short ospeed; ospeed = 0;],
 441   nmh_cv_decl_ospeed_must_define=yes,
 442   nmh_cv_decl_ospeed_must_define=no)])
 443 fi
 444
 445 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 446   AC_DEFINE(HAVE_OSPEED)
 447 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 448   AC_DEFINE(HAVE_OSPEED)
 449   AC_DEFINE(MUST_DEFINE_OSPEED)
 450 fi
 451
 452 dnl dnl Checks if tgetent accepts NULL and will
 453 dnl dnl allocate its own termcap buffer.
 454 dnl AC_CACHE_CHECK(if tgetent accepts NULL,
 455 dnl nmh_cv_func_tgetent_accepts_null,
 456 dnl [AC_TRY_RUN([main(){int i = tgetent((char*)0,"vt100");exit(!i || i == -1);}],
 457 dnl   nmh_cv_func_tgetent_accepts_null=yes,
 458 dnl   nmh_cv_func_tgetent_accepts_null=no,
 459 dnl   nmh_cv_func_tgetent_accepts_null=no)])
 460 dnl if test $nmh_cv_func_tgetent_accepts_null = yes; then
 461 dnl   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 462 dnl fi
 463
 464 dnl Now put the libraries back to what it was before we
 465 dnl starting checking the termcap library.
 466 LIBS="$nmh_save_LIBS"
 467
 468 dnl --------------
 469 dnl CHECK TYPEDEFS
 470 dnl --------------
 471 AC_TYPE_SIGNAL
 472 AC_TYPE_PID_T
 473 AC_TYPE_OFF_T
 474 AC_TYPE_UID_T
 475 AC_TYPE_MODE_T
 476 AC_TYPE_SIZE_T
 477
 478 dnl Check for sigset_t.  Currently I'm looking in
 479 dnl <sys/types.h> and <signal.h>.  Others might need
 480 dnl to be added.
 481 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 482 [AC_TRY_COMPILE(
 483 [#include <sys/types.h>
 484 #include <signal.h>], [sigset_t tempsigset;],
 485   nmh_cv_type_sigset_t=yes, nmh_cv_type_sigset_t=no)])
 486 if test $nmh_cv_type_sigset_t = no; then
 487   AC_DEFINE(sigset_t, unsigned int)
 488 fi
 489
 490 dnl ----------------
 491 dnl CHECK STRUCTURES
 492 dnl ----------------
 493 AC_STRUCT_ST_BLKSIZE
 494
 495 AC_CACHE_CHECK(for tm_gmtoff in struct tm, nmh_cv_struct_tm_gmtoff,
 496 [AC_TRY_COMPILE(
 497 [#ifdef TIME_WITH_SYS_TIME
 498 # include <sys/time.h>
 499 # include <time.h>
 500 #else
 501 # ifdef TM_IN_SYS_TIME
 502 #  include <sys/time.h>
 503 # else
 504 #  include <time.h>
 505 # endif
 506 #endif],
 507 [struct tm temptm; temptm.tm_gmtoff = 0;],
 508   nmh_cv_struct_tm_gmtoff=yes, nmh_cv_struct_tm_gmtoff=no)])
 509 if test $nmh_cv_struct_tm_gmtoff = yes; then
 510   AC_DEFINE(HAVE_TM_GMTOFF)
 511 fi
 512
 513 dnl -------------
 514 dnl CHECK SIGNALS
 515 dnl -------------
 516 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 517 AC_MSG_CHECKING(what style of signals to use)
 518 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 519   signals_style=POSIX_SIGNALS
 520   AC_DEFINE(POSIX_SIGNALS)
 521   AC_DEFINE(RELIABLE_SIGNALS)
 522 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 523   signals_style=BSD_SIGNALS
 524   AC_DEFINE(BSD_SIGNALS)
 525   AC_DEFINE(RELIABLE_SIGNALS)
 526 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 527   signals_style=SYSV_SIGNALS
 528   AC_DEFINE(SYSV_SIGNALS)
 529 else
 530   signals_style=NO_SIGNAL_BLOCKING
 531   AC_DEFINE(NO_SIGNAL_BLOCKING)
 532 fi
 533
 534 AC_MSG_RESULT($signals_style)
 535
 536 dnl Where is <signal.h> located?  Needed as input for signames.awk
 537 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 538 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 539                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 540                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 541                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 542                  /usr/include/sys/signal.h      dnl Almost everybody else
 543                  /dev/null;                     dnl Just in case we fall through
 544 do
 545   test -f $SIGNAL_H && \
 546   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 547   break
 548 done
 549 nmh_cv_path_signal_h=$SIGNAL_H
 550 ])
 551 SIGNAL_H=$nmh_cv_path_signal_h
 552 AC_SUBST(SIGNAL_H)dnl
 553
 554 dnl ----------------
 555 dnl OS SPECIFIC DEFINES
 556 dnl ----------------
 557 case "$target_os" in
 558
 559   solaris2*)
 560     AC_DEFINE(SYS5)
 561     AC_DEFINE(SVR4)
 562     ;;
 563   irix*)
 564     AC_DEFINE(SYS5)
 565     AC_DEFINE(SVR4)
 566     ;;
 567   osf*)
 568     AC_DEFINE(SYS5)
 569     AC_DEFINE(SVR4)
 570     ;;
 571   aix*)
 572     AC_DEFINE(SYS5)
 573     AC_DEFINE(SVR4)
 574     ;;
 575   sunos4*)
 576     AC_DEFINE(BIND)
 577     AC_DEFINE(BSD42)
 578     ;;
 579   linux*)
 580     AC_DEFINE(LINUX_STDIO)
 581     ;;
 582   freebsd*)
 583     AC_DEFINE(BIND)
 584     AC_DEFINE(BSD42)
 585     AC_DEFINE(BSD44)
 586     ;;
 587   netbsd*)
 588     AC_DEFINE(BIND)
 589     AC_DEFINE(BSD42)
 590     AC_DEFINE(BSD44)
 591     ;;
 592   openbsd*)
 593     AC_DEFINE(BIND)
 594     AC_DEFINE(BSD42)
 595     AC_DEFINE(BSD44)
 596     ;;
 597   bsd/os*)
 598     AC_DEFINE(BIND)
 599     AC_DEFINE(BSD42)
 600     AC_DEFINE(BSD44)
 601     ;;
 602   sco5*)
 603     AC_DEFINE(SYS5)
 604     AC_DEFINE(SCO_5_STDIO)
 605     ;;
 606 esac
 607
 608
 609 dnl ----------------
 610 dnl OUTPUT MAKEFILES
 611 dnl ----------------
 612 AC_OUTPUT(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
 613           zotnet/Makefile zotnet/mts/Makefile zotnet/tws/Makefile \
 614           zotnet/mf/Makefile zotnet/bboards/Makefile mts/Makefile \
 615           mts/smtp/Makefile mts/sendmail/Makefile mts/mmdf/Makefile \
 616           etc/Makefile man/Makefile, \
 617           [test -z "$CONFIG_HEADERS" || echo > stamp-h])
 618
 619 eval "nmhbin=${bindir}";         eval "nmhbin2=${nmhbin}"
 620 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf2=${nmhsysconf}"
 621 eval "nmhlib=${libdir}";         eval "nmhlib2=${nmhlib}"
 622 eval "nmhman=${mandir}"
 623
 624 echo "
 625 nmh configuration
 626 -----------------
 627 nmh version               : ${VERSION}
 628 target os                 : ${target}
 629 compiler                  : ${CC}
 630 compiler flags            : ${CFLAGS}
 631 linker flags              : ${LDFLAGS}
 632 source code location      : ${srcdir}
 633 binary install path       : ${nmhbin2}
 634 libary install path       : ${nmhlib2}
 635 config files install path : ${nmhsysconf2}
 636 man page install path     : ${nmhman}
 637 transport system          : ${MTS}
 638 default editor            : ${editorpath}
 639 default pager             : ${pagerpath}"
 640 echo ""