git.marmaro.de Git - mmh/blob - configure.in

   1 dnl
   2 dnl configure.in -- autoconf template for nmh
   3 dnl
   4
   5 dnl Move this up a bit
   6 AC_PREREQ(2.61)
   7
   8 AC_INIT(nmh, m4_normalize(m4_include([VERSION])))
   9 AC_CONFIG_SRCDIR(h/nmh.h)
  10 AC_CONFIG_HEADER(config.h)
  11
  12 AC_CANONICAL_TARGET
  13
  14 dnl ---------------------
  15 dnl define a macro or two
  16 dnl ---------------------
  17
  18 AC_DEFUN(NMH_PROG_GNU_LIBTOOL, [
  19 if test -n "$LIBTOOL" ; then
  20   tmptest=`$LIBTOOL --version 2>&1 | grep GNU`
  21   if test x"$tmptest" != x  ; then
  22     GNU_LIBTOOL=1
  23     AC_SUBST(GNU_LIBTOOL)dnl
  24   fi
  25 fi
  26 ] )
  27
  28 echo "configuring for AC_PACKAGE_NAME-AC_PACKAGE_VERSION"
  29 AC_SUBST(VERSION,AC_PACKAGE_VERSION)dnl
  30
  31 dnl What date of nmh are we building?
  32 DATE=`cat ${srcdir}/DATE`
  33 echo "configuring for nmh dated $DATE"
  34 AC_SUBST(DATE)dnl
  35
  36 dnl --------------------------
  37 dnl CHECK COMMAND LINE OPTIONS
  38 dnl --------------------------
  39
  40 dnl Do you want client-side support for apop?
  41 AC_ARG_ENABLE(apop, AS_HELP_STRING([--enable-apop],
  42   [enable client-side support for POP3 and APOP]))
  43 if test x"$enable_apop" = x"yes"; then
  44   AC_DEFINE(APOP, 1,
  45     [Define to compile client-side support for apop into inc and msgchk.])dnl
  46   APOPLIB=md5.o
  47   enable_pop=yes
  48 fi
  49 AC_SUBST(APOPLIB)dnl
  50
  51 dnl Do you want to debug nmh?
  52 AC_ARG_ENABLE(debug,
  53   AS_HELP_STRING([--enable-debug],[enable nmh code debugging]))
  54 dnl The old redundant --enable-nmh-debug is deprecated and undocumented.
  55 if test x"$enable_nmh_debug" = x"yes"; then
  56   enable_debug=yes
  57 fi
  58
  59 dnl Allow users to send email from addresses other than their default?
  60 AC_ARG_ENABLE(masquerade,
  61   AS_HELP_STRING([--enable-masquerade='draft_from mmailid username_extension'],
  62     [enable up to 3 types of address masquerading]),
  63   [if test x"$enable_masquerade" = x"yes"; then
  64     masquerade="draft_from mmailid username_extension"
  65   else
  66     masquerade="$enable_masquerade"
  67   fi],
  68   masquerade="draft_from mmailid username_extension")
  69 AC_SUBST(masquerade)dnl
  70
  71 dnl Do you want mhe support?
  72 AC_ARG_ENABLE(mhe,
  73   AS_HELP_STRING([--disable-mhe],[disable mhe support]))
  74
  75 dnl mhe support is on by default, so define it unless --disable-mhe or the
  76 dnl deprecated, undocumented --disable-nmh-mhe are specified.
  77 if test x"$enable_mhe" != x"no" -a x"$enable_nmh_mhe" != x"no"; then
  78   AC_DEFINE(MHE, 1,
  79     [Define to compile in support for the Emacs front-end mh-e.])dnl
  80 fi
  81
  82 dnl Do you want client-side support for pop?
  83 AC_ARG_ENABLE(pop,
  84   AS_HELP_STRING([--enable-pop], [enable client-side support for plain POP3]))
  85 dnl The old redundant --enable-nmh-pop is deprecated and undocumented.
  86 if test x"$enable_nmh_pop" = x"yes"; then
  87   enable_pop=yes
  88 fi
  89
  90 dnl Do you want to disable use of locale functions
  91 AH_TEMPLATE([LOCALE],
  92 [Undefine if you don't want locale features.  By default this is defined.])
  93 AC_ARG_ENABLE([locale],
  94 AC_HELP_STRING([--disable-locale], [turn off locale features]),
  95 [if test x$enableval = xyes; then
  96   AC_DEFINE(LOCALE)
  97 fi],
  98 AC_DEFINE(LOCALE)
  99 )
 100
 101 dnl Do you want client-side support for using SASL for authentication?
 102 dnl Note that this code will be enabled for both POP and SMTP
 103 AC_ARG_WITH(cyrus-sasl, AS_HELP_STRING([--with-cyrus-sasl],
 104   [Enable SASL support via the Cyrus SASL library]))
 105 if test x"$with_cyrus_sasl" != x -a x"$with_cyrus_sasl" != x"no"; then
 106   AC_DEFINE(CYRUS_SASL, 1,
 107     [Define to use the Cyrus SASL library for authentication of POP and SMTP.])dnl
 108   if test x"$with_cyrus_sasl" != xyes; then
 109     AC_MSG_WARN([Arguments to --with-cyrus-sasl now ignored])
 110     AC_MSG_WARN([Please pass the appropriate arguments to CPPFLAGS/LDFLAGS])
 111   fi
 112   sasl_support=yes
 113 else
 114   sasl_support=no
 115 fi
 116
 117 dnl Do you want client-side support for encryption with TLS?
 118 AC_ARG_WITH(tls, AS_HELP_STRING([--with-tls], [Enable TLS support]))
 119 if test x"$with_tls" != x -a x"$with_tls" != x"no"; then
 120   AC_DEFINE(TLS_SUPPORT, 1, [Support TLS for session encryption.])dnl
 121   tls_support=yes
 122 else
 123   tls_support=no
 124 fi
 125
 126 dnl What should be the default editor?
 127 AC_ARG_WITH(editor,
 128   AS_HELP_STRING([--with-editor=EDITOR],[specify the default editor]))
 129
 130 if test -n "$with_editor"; then
 131   editorpath="$with_editor"
 132 fi
 133
 134 dnl Set the backup prefix
 135 AC_ARG_WITH([hash-backup],
 136   AS_HELP_STRING([--with-hash-backup],[use # as the backup prefix (default: ,)]))
 137 if test x"$with_hash_backup" != x -a x"$with_hash_backup" != x"no"; then
 138   backup_prefix="#"
 139 else
 140   backup_prefix=","
 141 fi
 142 AC_DEFINE_UNQUOTED(BACKUP_PREFIX, "$backup_prefix",
 143     [The prefix that is prepended to the name of message files when they are "removed" by rmm. This should typically be `,' or `#'.])dnl
 144
 145 dnl Do you want support for hesiod
 146 AC_ARG_WITH(hesiod,
 147   AS_HELP_STRING([--with-hesiod=DIR],[specify location of Hesiod]))
 148 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 149   AC_DEFINE(HESIOD,1,[Define this to compile support for using Hesiod.])dnl
 150 fi
 151
 152 dnl After we know if we're including apop and kpop support, do pop stuff
 153 if test x"$enable_pop" = x"yes"; then
 154   AC_DEFINE(POP, 1,
 155     [Define this to compile client-side support for pop into inc and msgchk.])dnl
 156   POPLIB=popsbr.o
 157   POPSED='/^%nmhbeginpop%/d;/^%nmhendpop%/d'
 158 else
 159   POPSED='/^%nmhbeginpop%/,/^%nmhendpop%/d'
 160 fi
 161 AC_SUBST(POPLIB)dnl
 162 AC_SUBST(POPSED)dnl
 163
 164 dnl What method of locking to use?
 165 AC_ARG_WITH(locking,
 166   AS_HELP_STRING([--with-locking=@<:@dot|fcntl|flock|lockf@:>@],
 167   [specify the file locking method]))
 168
 169 if test x"$with_locking" = x"dot"; then
 170   LOCKTYPE="dot"
 171   AC_DEFINE(DOT_LOCKING, 1, [Define to use dot based file locking.])dnl
 172 elif test x"$with_locking" = x"flock"; then
 173   LOCKTYPE="flock"
 174   AC_DEFINE(FLOCK_LOCKING, 1, [Define to use flock() based locking.])dnl
 175 elif test x"$with_locking" = x"lockf"; then
 176   LOCKTYPE="lockf"
 177   AC_DEFINE(LOCKF_LOCKING, 1, [Define to use lockf() based locking.])dnl
 178 elif test x"$with_locking" = x"fcntl"; then
 179   LOCKTYPE="fcntl"
 180   AC_DEFINE(FCNTL_LOCKING, 1, [Define to use fnctl() based locking.])dnl
 181 else
 182   LOCKTYPE="dot"
 183   AC_DEFINE(DOT_LOCKING)dnl
 184 fi
 185
 186 dnl What method of posting should post use?
 187 AC_ARG_WITH(mts,
 188   AS_HELP_STRING([--with-mts=@<:@smtp|sendmail@:>@],
 189   [specify the default mail transport agent/service]))
 190
 191 if test x"$with_mts" = x"smtp"; then
 192   MTS="smtp"
 193 elif test x"$with_mts" = x"sendmail"; then
 194   MTS="sendmail"
 195 else
 196   MTS="smtp"
 197 fi
 198 AC_SUBST(MTS)dnl
 199
 200 dnl Both the smtp and sendmail mail transport services use the smtp code
 201 AC_DEFINE(SMTPMTS, 1,
 202   [Define if you want SMTP (simple mail transport protocol) support.])dnl
 203
 204 dnl What should be the default pager?
 205 AC_ARG_WITH(pager,
 206   AS_HELP_STRING([--with-pager=PAGER],[specify the default pager]))
 207
 208 if test -n "$with_pager"; then
 209   pagerpath="$with_pager"
 210 fi
 211
 212 dnl What should be the default mail server(s)?
 213 AC_ARG_WITH(smtpservers,
 214   AS_HELP_STRING([--with-smtpservers='SMTPSERVER1@<:@ SMTPSERVER2...@:>@'],
 215   [specify the default SMTP server(s) @<:@localhost@:>@]))
 216 if test -n "$with_smtpservers"; then
 217   smtpservers="$with_smtpservers"
 218 else
 219   smtpservers="localhost"
 220 fi
 221 AC_SUBST(smtpservers)dnl
 222
 223 dnl ----------------------------------------------------
 224 dnl Default location is /usr/local/nmh/{bin,etc,lib,man}
 225 dnl ----------------------------------------------------
 226 AC_PREFIX_DEFAULT(/usr/local/nmh)
 227
 228 dnl ------------------
 229 dnl CHECK THE COMPILER
 230 dnl ------------------
 231 dnl We want these before the checks,
 232 dnl so the checks can modify their values.
 233 test -z "$CFLAGS" && CFLAGS= auto_cflags=1
 234 if test x"$enable_debug" = x"yes"; then
 235   test -z "$LDFLAGS" && LDFLAGS=-g
 236 fi
 237
 238 AC_PROG_CC
 239
 240 AC_CACHE_CHECK(whether compiler supports -Wno-pointer-sign, nmh_cv_has_noptrsign,
 241 [nmh_saved_cflags="$CFLAGS"
 242  CFLAGS="$CFLAGS -Wno-pointer-sign"
 243  AC_TRY_COMPILE([],[],nmh_cv_has_noptrsign=yes,nmh_cv_has_noptrsign=no)
 244  CFLAGS="$nmh_saved_cflags"])
 245
 246 dnl if the user hasn't specified CFLAGS, then
 247 dnl   if compiler is gcc, then
 248 dnl     use -O2 and some warning flags
 249 dnl   else use -O
 250 dnl We use -Wall; if the compiler supports it we also use -Wno-pointer-sign,
 251 dnl because gcc 4 now produces a lot of new warnings which are probably mostly
 252 dnl spurious and which in any case we don't want to deal with now.
 253 if test "$nmh_cv_has_noptrsign" = "yes"; then
 254         nmh_gcc_warnflags="-Wall -Wno-pointer-sign"
 255 else
 256         nmh_gcc_warnflags="-Wall"
 257 fi
 258
 259 if test -n "$auto_cflags"; then
 260   if test x"$enable_debug" = x"yes"; then
 261     if test -n "$GCC"; then
 262       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -g" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -g"
 263     else
 264       test -z "$CFLAGS" && CFLAGS=-g || CFLAGS="$CFLAGS -g"
 265     fi
 266   else
 267     if test -z "$LDFLAGS"; then
 268       case "$build_os" in
 269         darwin*)
 270           LDFLAGS=
 271           ;;
 272         *)
 273           LDFLAGS=-s
 274           ;;
 275       esac
 276     fi
 277     if test -n "$GCC"; then
 278       test -z "$CFLAGS" && CFLAGS="$nmh_gcc_warnflags -O2" || CFLAGS="$CFLAGS $nmh_gcc_warnflags -O2"
 279     else
 280       test -z "$CFLAGS" && CFLAGS=-O  || CFLAGS="$CFLAGS -O"
 281     fi
 282   fi
 283 fi
 284
 285 AC_C_CONST              dnl Does compiler support `const'.
 286
 287 dnl ------------------
 288 dnl CHECK FOR PROGRAMS
 289 dnl ------------------
 290 AC_PROG_MAKE_SET        dnl Does make define $MAKE
 291 AC_PROG_INSTALL         dnl Check for BSD compatible `install'
 292 AC_PROG_RANLIB          dnl Check for `ranlib'
 293 AC_PROG_AWK             dnl Check for mawk,gawk,nawk, then awk
 294 AC_PROG_LEX             dnl Check for lex/flex
 295
 296 dnl Look for `cut'
 297 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 298 AC_PATH_PROG(cutpath, cut, no, [$pathtmp])
 299
 300 dnl ----------------------------------------------
 301 dnl check for lclint, and lint if it doesn't exist
 302 dnl ----------------------------------------------
 303 AC_CHECK_PROG(linttmp1, lclint, lclint, no)dnl
 304 if test x$ac_cv_prog_linttmp1 != xno ; then
 305   LINT=$ac_cv_prog_linttmp1
 306   LINTFLAGS="-weak +posixlib -macrovarprefixexclude"
 307 else
 308   AC_CHECK_PROG(linttmp2, lint, lint, no)dnl
 309   if test x$ac_cv_prog_linttmp2 != xno ; then
 310     LINT=$ac_cv_prog_linttmp2
 311     LINTFLAGS=""
 312   else
 313     LINT="echo 'No lint program found'"
 314     LINTFLAGS=""
 315   fi
 316 fi
 317 AC_SUBST(LINT)dnl
 318 AC_SUBST(LINTFLAGS)dnl
 319
 320 dnl try to figure out which one we've got
 321 AC_CHECK_PROG(LIBTOOL, libtool, libtool, , [$pathtmp])
 322 NMH_PROG_GNU_LIBTOOL
 323
 324 dnl Check for lorder and tsort commands
 325 AC_CHECK_PROG(LORDER, lorder, lorder, no)dnl
 326 AC_CHECK_PROG(TSORT, tsort, tsort, no)dnl
 327
 328 dnl If either doesn't exist, replace them with echo and cat
 329 if test x$ac_cv_prog_LORDER != xlorder -o x$ac_cv_prog_TSORT != xtsort; then
 330   LORDER=echo
 331   TSORT=cat
 332   AC_SUBST(LORDER)dnl
 333   AC_SUBST(TSORT)dnl
 334 dnl Mac OS X has lorder, but sh is too broken for it to work
 335 dnl elif test -z "`lorder config/config.c 2>&1 | grep config/config.c`" ; then
 336 dnl   LORDER=echo
 337 dnl   TSORT=cat
 338 dnl   AC_SUBST(LORDER)dnl
 339 dnl   AC_SUBST(TSORT)dnl
 340 fi
 341
 342 dnl Check whether tsort can deal with loops
 343 AC_CACHE_CHECK(whether tsort can deal with loops, nmh_cv_tsort_loop,
 344   [if test -z "`echo a b b a | tsort 2>/dev/null | grep a`" ; then
 345     nmh_cv_tsort_loop=no
 346   else
 347     nmh_cv_tsort_loop=yes
 348   fi])
 349 if test x$nmh_cv_tsort_loop = xno ; then
 350   LORDER=echo
 351   TSORT=cat
 352   AC_SUBST(LORDER)dnl
 353   AC_SUBST(TSORT)dnl
 354 fi
 355
 356 dnl Look for `ls'
 357 pathtmp=/usr/bin:/bin:/usr/local/bin:/usr/xpg4/bin:/usr/ucb
 358 AC_PATH_PROG(lspath, ls, no, [$pathtmp])
 359
 360 dnl See how we get ls to display the owner and the group
 361 if test "$lspath" != "no"; then
 362   AC_CACHE_CHECK(how to get ls to show us the group ownership of a file,
 363                  nmh_cv_ls_grpopt,
 364   [if test x"`$lspath -dl / | $AWK '{print $9}'`" = x"/"; then
 365     dnl There were 9 parameters, so unless this is a really bizarre, nonstandard
 366     dnl ls, it would seem -l gave us both the user and group.  On this type of
 367     dnl ls, -g makes _only_ the group be displayed (and not the user).
 368     nmh_cv_ls_grpopt="-l"
 369   else
 370     dnl Looks like -l only gave us the user, so we need -g to get the group too.
 371     nmh_cv_ls_grpopt="-lg"
 372   fi])
 373 fi
 374
 375 dnl Look for `more'
 376 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 377 AC_PATH_PROG(morepath, more, no, [$pathtmp])
 378
 379 dnl If pager is not specified yet,
 380 dnl then use `more' as the default.
 381 if test -z "$pagerpath"; then
 382   pagerpath="$morepath"
 383 fi
 384 AC_SUBST(pagerpath)dnl
 385
 386 dnl Look for `sendmail'
 387 pathtmp=/usr/lib:/usr/sbin:/usr/etc:/usr/ucblib:/usr/bin:/bin
 388 AC_PATH_PROG(sendmailpath, sendmail, /usr/sbin/sendmail, [$pathtmp])
 389
 390 dnl Look for `vi'
 391 pathtmp=/usr/bin:/bin:/usr/ucb:/usr/local/bin
 392 AC_PATH_PROG(vipath, vi, /bin/vi, [$pathtmp])
 393
 394 dnl If editor is not specified yet,
 395 dnl then use `vi' as the default.
 396 if test -z "$editorpath"; then
 397   editorpath="$vipath"
 398 fi
 399 AC_SUBST(editorpath)dnl
 400
 401 dnl ----------------------------------------------------------
 402 dnl FIND MAIL SPOOL AND SEE IF WE NEED TO MAKE inc SETGID MAIL
 403 dnl ----------------------------------------------------------
 404 AC_CACHE_CHECK(where mail spool is located, nmh_cv_mailspool,
 405 [for mailspool in /var/mail        dnl
 406                   /var/spool/mail  dnl
 407                   /usr/spool/mail  dnl
 408                   /dev/null;       dnl Just in case we fall through
 409 do
 410   test -d $mailspool && break
 411 done
 412 nmh_cv_mailspool=$mailspool
 413 ])
 414 mailspool=$nmh_cv_mailspool
 415 AC_SUBST(mailspool)dnl
 416
 417 dnl See whether the mail spool directory is world-writable.
 418 if test "$lspath" != "no" -a "$cutpath" != "no"; then
 419   AC_CACHE_CHECK(whether the mail spool is world-writable,
 420                  nmh_cv_mailspool_world_writable,
 421   [if test "`$lspath -dlL $mailspool | $cutpath -c9`" = "-"; then
 422     nmh_cv_mailspool_world_writable=no
 423   else
 424     nmh_cv_mailspool_world_writable=yes
 425   fi])
 426 fi
 427
 428 dnl Also, check for liblockfile (as found on Debian systems)
 429 AC_CHECK_HEADER(lockfile.h, AC_CHECK_LIB(lockfile, lockfile_create) )
 430
 431 dnl and whether its companion program dotlockfile is setgid
 432 AC_PATH_PROG(dotlockfilepath, dotlockfile, no)
 433 if test "$ac_cv_lib_lockfile_lockfile_create" != "no" ; then
 434   if test "$ac_cv_path_dotlockfilepath" != "no" ; then
 435     AC_CACHE_CHECK(whether dotlockfile is setgid, nmh_cv_dotlockfile_setgid,
 436     [ if test -g "$ac_cv_path_dotlockfilepath" ; then
 437         nmh_cv_dotlockfile_setgid=yes
 438       else
 439         nmh_cv_dotlockfile_setgid=no
 440       fi])
 441   fi
 442 fi
 443
 444 dnl If mailspool is not world-writable and dotlockfile is not setgid,
 445 dnl we need to #define MAILGROUP to 1 and make inc setgid.
 446 if test x"$LOCKTYPE" = x"dot" -a x"$nmh_cv_mailspool_world_writable" = x"no" -a x"$nmh_cv_dotlockfile_setgid" != x"yes" ; then
 447   dnl do we really need both of these?
 448   AC_DEFINE(MAILGROUP,1,
 449     [Define to 1 if you need to make `inc' set-group-id because your mail spool is not world writable. There are no guarantees as to the safety of doing this, but this #define will add some extra security checks.])dnl
 450   SETGID_MAIL=1
 451 fi
 452 AC_SUBST(SETGID_MAIL)dnl
 453
 454 dnl Use ls to see which group owns the mail spool directory.
 455 AC_CACHE_CHECK(what group owns the mail spool, nmh_cv_ls_mail_grp,
 456 [nmh_cv_ls_mail_grp=`$lspath -dL $nmh_cv_ls_grpopt $mailspool|$AWK '{print $4}'`
 457 ])
 458 MAIL_SPOOL_GRP=$nmh_cv_ls_mail_grp
 459 AC_SUBST(MAIL_SPOOL_GRP)dnl
 460
 461 dnl ------------------
 462 dnl CHECK HEADER FILES
 463 dnl ------------------
 464
 465 dnl On glibc we need to define at least the '_XOPEN_SOURCE' level of features,
 466 dnl or wchar.h doesn't declare a prototype for wcwidth(). But if we only define
 467 dnl that level then db.h won't compile. So we define _GNU_SOURCE which turns
 468 dnl on everything. Perhaps other OSes need some feature switch set to get wcwidth()
 469 dnl declared; if so they should have an entry added to this case statement.
 470 dnl NB that we must define this on the compiler command line, not in config.h,
 471 dnl because it must be set before any system header is included and there's no
 472 dnl portable way to make sure that files generated by lex include config.h
 473 dnl before system header files.
 474
 475 case "$target_os" in
 476   linux*)
 477     # Like DEFS, but doesn't get stomped on by configure when using config.h:
 478     OURDEFS="$OURDEFS -D_GNU_SOURCE"
 479     ;;
 480 esac
 481 AC_SUBST(OURDEFS)
 482
 483 AC_HEADER_DIRENT
 484 AC_HEADER_STDC
 485 AC_HEADER_TIME
 486 AC_HEADER_SYS_WAIT
 487 AC_HEADER_STAT
 488 AC_HEADER_TIOCGWINSZ
 489 AC_CHECK_HEADERS(string.h memory.h stdlib.h unistd.h errno.h fcntl.h \
 490                  limits.h crypt.h termcap.h termio.h termios.h locale.h \
 491                  langinfo.h wchar.h wctype.h iconv.h netdb.h \
 492                  sys/param.h sys/time.h sys/utsname.h sys/stream.h \
 493                  arpa/inet.h arpa/ftp.h)
 494
 495 dnl
 496 dnl Checks for _IO_write_ptr. A Linuxism used by nmh on linux. We
 497 dnl really use a whole set of them, but this check should be
 498 dnl sufficient.
 499 dnl
 500 AC_CHECK_HEADER(libio.h, [
 501   AC_EGREP_HEADER(_IO_write_ptr, libio.h, [
 502     AC_DEFINE(LINUX_STDIO,1,[Use the Linux _IO_*_ptr defines from <libio.h>.]) ]) ])
 503
 504 AC_CHECK_HEADER([sys/ptem.h], AC_DEFINE(WINSIZE_IN_PTEM,1,
 505   [Define to 1 if `struct winsize' requires <sys/ptem.h>.]),,
 506 [[#if HAVE_SYS_STREAM_H
 507 #  include <sys/stream.h>
 508 #endif
 509 ]])
 510
 511 dnl ---------------
 512 dnl CHECK FUNCTIONS
 513 dnl ---------------
 514 AC_FUNC_VFORK
 515 AC_CHECK_LIB(mkstemp,mkstemp)
 516 AC_CHECK_FUNCS(waitpid wait3 sigaction sigprocmask sigblock sigsetmask \
 517                sighold sigrelse writev lstat uname tzset killpg mkstemp \
 518                getutent nl_langinfo mbtowc wcwidth)
 519
 520 dnl sigsetjmp may be a macro
 521 AC_MSG_CHECKING(for sigsetjmp)
 522 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]],
 523   [[sigsetjmp((void *)0, 0);]])],[AC_DEFINE(HAVE_SIGSETJMP, 1,
 524     [Define to 1 if you have the `sigsetjmp'.]) AC_MSG_RESULT(yes)],
 525   [AC_MSG_RESULT(no)])
 526
 527 AC_REPLACE_FUNCS(memmove snprintf strerror strdup)
 528
 529 dnl Look for the initgroups() declaration.  On AIX 4.[13], Solaris 4.1.3, and
 530 dnl ULTRIX 4.2A the function is defined in libc but there's no declaration in
 531 dnl any system header.
 532 dnl
 533 dnl On Solaris 2.[456], the declaration is in <grp.h>.  On HP-UX 9-11 and
 534 dnl (reportedly) FreeBSD 3.[23], it's in <unistd.h>.  Any other locations we
 535 dnl need to check?
 536 AH_TEMPLATE(INITGROUPS_HEADER, [Define to the header containing the declaration of `initgroups'.])
 537 AC_EGREP_HEADER(initgroups, grp.h, AC_DEFINE(INITGROUPS_HEADER, <grp.h>),
 538                 AC_EGREP_HEADER(initgroups, unistd.h,
 539                                 AC_DEFINE(INITGROUPS_HEADER, <unistd.h>)))
 540
 541 dnl On AIX 4.1, snprintf() is defined in libc.a but there's no prototype in
 542 dnl <stdio.h> or elsewhere.  Apparently it's not officially supported (though it
 543 dnl seems to work perfectly and IBM apparently uses it in internal code).
 544 dnl Anyhow, if we omit our own snprintf() and vsnprintf() prototypes when we
 545 dnl HAVE_SNPRINTF, we get a billion warnings at compile time.  Use the C
 546 dnl preprocessor to preprocess stdio.h and make sure that there's actually a
 547 dnl prototype.
 548 AC_EGREP_HEADER(snprintf, stdio.h, AC_DEFINE(HAVE_SNPRINTF_PROTOTYPE,1,
 549   [Define to 1 if <stdio.h> has a prototype for snprintf().]))
 550
 551 dnl Check for multibyte character set support
 552 if test "x$ac_cv_header_wchar_h" = "xyes" -a "x$ac_cv_header_wctype_h" = "xyes" \
 553     -a "x$ac_cv_func_wcwidth" = "xyes" -a "x$ac_cv_func_mbtowc" = "xyes"; then
 554   AC_DEFINE(MULTIBYTE_SUPPORT, 1,
 555     [Define to enable support for multibyte character sets.])
 556 fi
 557
 558 dnl -------------------
 559 dnl CHECK FOR LIBRARIES
 560 dnl -------------------
 561 dnl Check location of modf
 562 AC_CHECK_FUNC(modf, , AC_CHECK_LIB(m, modf))
 563
 564 dnl Checks for network libraries (nsl, socket)
 565 AC_CHECK_NETLIBS
 566
 567 termcap_curses_order="termcap curses ncurses"
 568 for lib in $termcap_curses_order; do
 569   AC_CHECK_LIB(${lib}, tgetent, [TERMLIB="-l$lib"; break])
 570 done
 571 AC_SUBST(TERMLIB)dnl
 572
 573 dnl ---------------
 574 dnl CHECK FOR ICONV
 575 dnl ---------------
 576
 577 dnl Find iconv. It may be in libiconv and may be iconv() or libiconv()
 578 if test "x$ac_cv_header_iconv_h" = "xyes"; then
 579   AC_CHECK_FUNC(iconv, ac_found_iconv=yes, ac_found_iconv=no)
 580   if test "x$ac_found_iconv" = "xno"; then
 581     AC_CHECK_LIB(iconv, iconv, ac_found_iconv=yes)
 582     if test "x$ac_found_iconv" = "xno"; then
 583       AC_CHECK_LIB(iconv, libiconv, ac_found_iconv=yes)
 584     fi
 585     if test "x$ac_found_iconv" != "xno"; then
 586       LIBS="-liconv $LIBS"
 587     fi
 588   else
 589     dnl Handle case where there is a native iconv but iconv.h is from libiconv
 590     AC_CHECK_DECL(_libiconv_version,
 591       [ AC_CHECK_LIB(iconv, libiconv, LIBS="-liconv $LIBS") ],,
 592       [ #include <iconv.h> ])
 593   fi
 594 fi
 595 if test "x$ac_found_iconv" = xyes; then
 596   AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 597 fi
 598
 599 dnl Check if iconv uses const in prototype declaration
 600 if test "x$ac_found_iconv" = "xyes"; then
 601   AC_CACHE_CHECK(for iconv declaration, ac_cv_iconv_const,
 602     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
 603         #include <iconv.h>]],
 604         [[#ifdef __cplusplus
 605           "C"
 606           #endif
 607           #if defined(__STDC__) || defined(__cplusplus)
 608           size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 609           #else
 610           size_t iconv();
 611           #endif]])],
 612       [ac_cv_iconv_const=],
 613       [ac_cv_iconv_const=const])])
 614   AC_DEFINE_UNQUOTED([ICONV_CONST], $ac_cv_iconv_const,
 615     [Define as const if the declaration of iconv() needs const.])
 616 fi
 617
 618 dnl --------------
 619 dnl CHECK FOR NDBM
 620 dnl --------------
 621
 622 AC_ARG_WITH([ndbm],AS_HELP_STRING([--with-ndbm=ARG],[use -lARG to link with ndbm]),
 623             [nmh_ndbm=$withval],[nmh_ndbm=autodetect])
 624 AC_ARG_WITH([ndbmheader],AS_HELP_STRING([--with-ndbmheader=ARG],[#include <ARG> to use ndbm]),
 625             [nmh_ndbmheader=$withval],[nmh_ndbmheader=autodetect])
 626
 627 if test "$nmh_ndbm" = "autodetect"; then
 628   if test "$nmh_ndbmheader" != "autodetect"; then
 629     AC_MSG_ERROR([must specify both --with-ndbm and --with-ndbmheader or neither])
 630   else
 631
 632     dnl There are at least four implementations of ndbm, and
 633     dnl several of those can be in different places at the whim
 634     dnl of the system integrator. A good summary of this mess
 635     dnl can be found at http://www.unixpapa.com/incnote/dbm.html
 636
 637     dnl Classic ndbm with no library required (eg NetBSD): try this
 638     dnl first so we don't accidentally link in a pointless but harmless
 639     dnl library in one of the later ndbm.h+libfoo tests:
 640     NMH_CHECK_NDBM(ndbm.h,,,
 641     dnl Berkeley DBv2 emulating ndbm: header in db.h:
 642       NMH_CHECK_NDBM(db.h,db,,
 643     dnl Berkeley DBv1 emulating ndbm:
 644         NMH_CHECK_NDBM(ndbm.h,db,,
 645           NMH_CHECK_NDBM(ndbm.h,db1,,
 646     dnl Classic ndbm:
 647             NMH_CHECK_NDBM(ndbm.h,ndbm,,
 648     dnl glibc2.1 systems put db1 in a subdir:
 649               NMH_CHECK_NDBM(db1/ndbm.h,db1,,
 650     dnl GNU gdbm emulating ndbm, with header possibly in gdbm/
 651     dnl and possibly needing gbdm_compat library:
 652                 NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm,,
 653                   NMH_CHECK_NDBM(gdbm/ndbm.h,gdbm_compat -lgdbm,,
 654                     NMH_CHECK_NDBM(ndbm.h,gdbm,,
 655                       NMH_CHECK_NDBM(ndbm.h,gdbm_compat -lgdbm))))))))))
 656
 657   fi
 658 else
 659   dnl We don't really need to check that the user-specified values work,
 660   dnl but it is a convenience to the user to bomb out early rather than
 661   dnl after configure and half the compile process.
 662   NMH_CHECK_NDBM([$nmh_ndbmheader],[$nmh_ndbm])
 663 fi
 664
 665 if test "$nmh_ndbm_found" = "no"; then
 666   AC_MSG_ERROR([could not find a working ndbm library/header combination])
 667 else
 668   dnl Now export the lib/header to our makefile/config.h:
 669   if test x"$nmh_ndbmheader" != x; then
 670     AC_DEFINE_UNQUOTED(NDBM_HEADER, <$nmh_ndbmheader>,
 671       [Define to the header containing the ndbm API prototypes.])
 672   fi
 673   if test x"$nmh_ndbm" != x; then
 674     NDBM_LIBS="-l$nmh_ndbm"
 675   else
 676     NDBM_LIBS=
 677   fi
 678   AC_SUBST(NDBM_LIBS)
 679 fi
 680
 681
 682 dnl ----------------
 683 dnl CHECK FOR HESIOD
 684 dnl ----------------
 685 if test x"$with_hesiod" != x -a x"$with_hesiod" != x"no"; then
 686   if test x"$with_hesiod" != x"yes"; then
 687     HESIOD_INCLUDES="-I$with_hesiod/include"
 688     HESIOD_LIBS="-L$with_hesiod/lib"
 689   fi
 690   AC_CHECK_FUNC(res_send,
 691         [AC_CHECK_LIB(hesiod, hes_resolve,
 692                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod"],
 693                 [AC_MSG_ERROR(Hesiod library not found)],
 694                 $HESIOD_LIBS)],
 695         [AC_CHECK_LIB(hesiod, hes_resolve,
 696                 [HESIOD_LIBS="$HESIOD_LIBS -lhesiod -lresolv"],
 697                 [AC_MSG_ERROR(Hesiod library not found)],
 698                 $HESIOD_LIBS -lresolv)])
 699
 700 fi
 701 AC_SUBST(HESIOD_INCLUDES)dnl
 702 AC_SUBST(HESIOD_LIBS)dnl
 703
 704 dnl --------------------
 705 dnl CHECK FOR CYRUS-SASL
 706 dnl --------------------
 707
 708 AS_IF([test x"$sasl_support" = x"yes"],[
 709   AC_CHECK_HEADER([sasl/sasl.h], , [AC_MSG_ERROR([sasl.h not found])])
 710   AC_CHECK_LIB([sasl2], [sasl_client_new], ,
 711     [AC_MSG_ERROR([Cyrus SASL library not found])])])
 712
 713 dnl -----------------
 714 dnl CHECK FOR OPENSSL
 715 dnl -----------------
 716
 717 AS_IF([test x"$tls_support" = x"yes"],[
 718   AC_CHECK_HEADER([openssl/ssl.h], , [AC_MSG_ERROR([openssl/ssl.h not found])])
 719   AC_CHECK_LIB([crypto], [BIO_write], ,
 720     [AC_MSG_ERROR([OpenSSL crypto library not found])])
 721   AC_CHECK_LIB([ssl], [SSL_library_init], ,
 722     [AC_MSG_ERROR([OpenSSL library not found])])])
 723
 724 dnl ---------------------
 725 dnl CHECK TERMCAP LIBRARY
 726 dnl ---------------------
 727
 728 dnl Add the termcap library, so that the following configure
 729 dnl tests will find it when it tries to link test programs.
 730 nmh_save_LIBS="$LIBS"
 731 LIBS="$TERMLIB $LIBS"
 732
 733 dnl Checks for external variable ospeed in the termcap library.
 734 AC_CACHE_CHECK(if an include file defines ospeed,
 735 nmh_cv_decl_ospeed_include_defines,
 736 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 737 #if HAVE_TERMIOS_H
 738 #include <termios.h>
 739 #endif
 740 #if HAVE_TERMCAP_H
 741 #include <termcap.h>
 742 #endif]], [[ospeed = 0;]])],
 743 nmh_cv_decl_ospeed_include_defines=yes,nmh_cv_decl_ospeed_include_defines=no)])
 744
 745 if test $nmh_cv_decl_ospeed_include_defines = no; then
 746   AC_CACHE_CHECK(if you must define ospeed,
 747   nmh_cv_decl_ospeed_must_define,
 748   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 749   [[extern short ospeed; ospeed = 0;]])],
 750   nmh_cv_decl_ospeed_must_define=yes,nmh_cv_decl_ospeed_must_define=no)])
 751 fi
 752
 753 AH_TEMPLATE(HAVE_OSPEED, [Define to 1 if your termcap library has the ospeed variable.])
 754 if test $nmh_cv_decl_ospeed_include_defines = yes; then
 755   AC_DEFINE(HAVE_OSPEED)dnl
 756 elif test $nmh_cv_decl_ospeed_must_define = yes; then
 757   AC_DEFINE(HAVE_OSPEED)
 758   AC_DEFINE(MUST_DEFINE_OSPEED, 1,
 759     [Define to 1 if you have ospeed, but it is not defined in termcap.h.])
 760 fi
 761
 762 dnl Check if tgetent accepts NULL (and will allocate its own termcap buffer)
 763 dnl Some termcaps reportedly accept a zero buffer, but then dump core
 764 dnl in tgetstr().
 765 dnl Under Cygwin test program crashes but exit code is still 0. So,
 766 dnl we test for a file that porgram should create
 767 AH_TEMPLATE([TGETENT_ACCEPTS_NULL],
 768 [Define to 1 if tgetent() accepts NULL as a buffer.])
 769 AC_CACHE_CHECK(if tgetent accepts NULL,
 770 nmh_cv_func_tgetent_accepts_null,
 771 [AC_TRY_RUN([
 772 main()
 773 {
 774     char buf[4096];
 775     int r1 = tgetent(buf, "vt100");
 776     int r2 = tgetent((char*)0,"vt100");
 777     if (r1 >= 0 && r1 == r2) {
 778         char tbuf[1024], *u;
 779         u = tbuf;
 780         tgetstr("cl", &u);
 781         creat("conftest.tgetent", 0640);
 782     }
 783     exit((r1 != r2) || r2 == -1);
 784 }
 785 ],
 786   if test -f conftest.tgetent; then
 787     nmh_cv_func_tgetent_accepts_null=yes
 788   else
 789     nmh_cv_func_tgetent_accepts_null=no
 790   fi,
 791   nmh_cv_func_tgetent_accepts_null=no,
 792   nmh_cv_func_tgetent_accepts_null=no)])
 793 if test x$nmh_cv_func_tgetent_accepts_null = xyes; then
 794   AC_DEFINE(TGETENT_ACCEPTS_NULL)
 795 fi
 796 AC_CACHE_CHECK(if tgetent returns 0 on success,
 797 nmh_cv_func_tgetent_zero_success,
 798 [AC_TRY_RUN([
 799 main()
 800 {
 801     char buf[4096];
 802     int r1 = tgetent(buf, "!@#$%^&*");
 803     int r2 = tgetent(buf, "vt100");
 804     if (r1 < 0 && r2 == 0) {
 805         char tbuf[1024], *u;
 806         u = tbuf;
 807         tgetstr("cl", &u);
 808         creat("conftest.tgetent0", 0640);
 809     }
 810     exit(r1 == r2);
 811 }
 812 ],
 813   if test -f conftest.tgetent0; then
 814     nmh_cv_func_tgetent_zero_success=yes
 815   else
 816     nmh_cv_func_tgetent_zero_success=no
 817   fi,
 818   nmh_cv_func_tgetent_zero_success=no,
 819   nmh_cv_func_tgetent_zero_success=no)])
 820 AH_TEMPLATE([TGETENT_SUCCESS],
 821 [Define to what tgetent() returns on success (0 on HP-UX X/Open curses).])
 822 if test x$nmh_cv_func_tgetent_zero_success = xyes; then
 823   AC_DEFINE(TGETENT_SUCCESS, 0)
 824 else
 825   AC_DEFINE(TGETENT_SUCCESS, 1)
 826 fi
 827
 828 dnl Now put the libraries back to what it was before we
 829 dnl starting checking the termcap library.
 830 LIBS="$nmh_save_LIBS"
 831
 832 dnl --------------
 833 dnl CHECK TYPEDEFS
 834 dnl --------------
 835 AC_TYPE_SIGNAL
 836 AC_TYPE_PID_T
 837 AC_TYPE_OFF_T
 838 AC_TYPE_UID_T
 839 AC_TYPE_MODE_T
 840 AC_TYPE_SIZE_T
 841
 842 dnl Check for sigset_t.  Currently I'm looking in
 843 dnl <sys/types.h> and <signal.h>.  Others might need
 844 dnl to be added.
 845 AC_CACHE_CHECK(for sigset_t, nmh_cv_type_sigset_t,
 846 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 847 #include <signal.h>]], [[sigset_t tempsigset;]])],
 848 nmh_cv_type_sigset_t=yes,nmh_cv_type_sigset_t=no)])
 849 if test $nmh_cv_type_sigset_t = no; then
 850   AC_DEFINE(sigset_t, unsigned int,
 851     [Define to `unsigned int' if <sys/types.h> or <signal.h> doesn't define.])
 852 fi
 853
 854 dnl ----------------
 855 dnl CHECK STRUCTURES
 856 dnl ----------------
 857 AC_CHECK_MEMBERS(struct stat.st_blksize)
 858
 859 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,,
 860   [#ifdef TIME_WITH_SYS_TIME
 861 # include <sys/time.h>
 862 # include <time.h>
 863 #else
 864 # ifdef TM_IN_SYS_TIME
 865 #  include <sys/time.h>
 866 # else
 867 #  include <time.h>
 868 # endif
 869 #endif])
 870
 871 AC_CHECK_MEMBERS(struct utmp.ut_type,,,[#include <utmp.h>])
 872
 873 AC_MSG_CHECKING(for union wait)
 874 AC_CACHE_VAL(nmh_cv_union_wait, [dnl
 875   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 876 #include <sys/wait.h>]],
 877     [[union wait status; int pid; pid = wait (&status);
 878 #ifdef WEXITSTATUS
 879 /* Some POSIXoid systems have both the new-style macros and the old
 880    union wait type, and they do not work together.  If union wait
 881    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
 882         if (WEXITSTATUS (status) != 0) pid = -1;
 883 #ifdef WTERMSIG
 884         /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
 885         -- blow chunks here --
 886 #endif
 887 #endif
 888 #ifdef HAVE_WAITPID
 889         /* Make sure union wait works with waitpid.  */
 890         pid = waitpid (-1, &status, 0);
 891 #endif
 892       ]])],
 893     [nmh_cv_union_wait=yes],
 894     [nmh_cv_union_wait=no])])
 895 if test "$nmh_cv_union_wait" = yes; then
 896   AC_DEFINE(HAVE_UNION_WAIT, 1,
 897     [Define to 1 if you have the \`union wait' type in <sys/wait.h>.])
 898 fi
 899 AC_MSG_RESULT($nmh_cv_union_wait)
 900
 901 CHECK_TYPE_STRUCT_DIRENT_D_TYPE()
 902
 903 dnl -------------
 904 dnl CHECK SIGNALS
 905 dnl -------------
 906 dnl What style of signal do you have (POSIX, BSD, or SYSV)?
 907 AH_TEMPLATE(RELIABLE_SIGNALS, [Define to 1 if you have reliable signals.])
 908 AC_MSG_CHECKING(what style of signals to use)
 909 if test $ac_cv_func_sigaction = yes -a $ac_cv_func_sigprocmask = yes; then
 910   signals_style=POSIX_SIGNALS
 911   AC_DEFINE(POSIX_SIGNALS, 1,
 912     [Define to 1 if you use POSIX style signal handling.])
 913   AC_DEFINE(RELIABLE_SIGNALS)
 914 elif test $ac_cv_func_sigblock = yes -a $ac_cv_func_sigsetmask = yes; then
 915   signals_style=BSD_SIGNALS
 916   AC_DEFINE(BSD_SIGNALS,1,
 917     [Define to 1 if you use BSD style signal handling (and can block signals).])
 918   AC_DEFINE(RELIABLE_SIGNALS)
 919 elif test $ac_cv_func_sighold = yes -a $ac_cv_func_sigrelse = yes; then
 920   signals_style=SYSV_SIGNALS
 921   AC_DEFINE(SYSV_SIGNALS,1,
 922     [Define to 1 if you use SYSV style signal handling (and can block signals).])
 923 else
 924   signals_style=NO_SIGNAL_BLOCKING
 925   AC_DEFINE(NO_SIGNAL_BLOCKING,1,
 926     [Define to 1 if you have no signal blocking at all (bummer).])
 927 fi
 928
 929 AC_MSG_RESULT($signals_style)
 930
 931 dnl Where is <signal.h> located?  Needed as input for signames.awk
 932 AC_CACHE_CHECK(where signal.h is located, nmh_cv_path_signal_h,
 933 [for SIGNAL_H in /usr/include/bsd/sys/signal.h  dnl Next
 934                  /usr/include/asm/signal.h      dnl Linux 1.3.0 and above
 935                  /usr/include/asm/signum.h      dnl some versions of Linux/Alpha
 936                  /usr/include/linux/signal.h    dnl Linux up to 1.2.11
 937                  /usr/include/sys/signal.h      dnl Almost everybody else
 938                  /dev/null;                     dnl Just in case we fall through
 939 do
 940   test -f $SIGNAL_H && \
 941   grep '#[      ]*define[       ][      ]*SIG[0-9A-Z]*[         ]*[0-9][0-9]*' $SIGNAL_H > /dev/null && \
 942   break
 943 done
 944 nmh_cv_path_signal_h=$SIGNAL_H
 945 ])
 946 SIGNAL_H=$nmh_cv_path_signal_h
 947 AC_SUBST(SIGNAL_H)dnl
 948
 949 dnl ----------------
 950 dnl OS SPECIFIC DEFINES
 951 dnl ----------------
 952 AH_TEMPLATE(SYS5, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX, SCO5; only used in vmh.c which is not built.])
 953 AH_TEMPLATE(SVR4, [Defined for Solaris 2.x, Irix, OSF/1, HP-UX, AIX; only used in vmh.c which is not built.])
 954 AH_TEMPLATE(BSD44, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody; only used in vmh.c which is not built.])
 955 AH_TEMPLATE(BSD42, [Defined for SunOS 4, FreeBSD, NetBSD, OpenBSD, BSD/OS, Mac OS X/Rhapsody -- does PicoBSD have uname?])
 956 AH_TEMPLATE(SCO_5_STDIO, [Defined for SCO5.])
 957
 958 case "$target_os" in
 959
 960   solaris2*)
 961     AC_DEFINE(SYS5)
 962     AC_DEFINE(SVR4)
 963     ;;
 964   irix*)
 965     AC_DEFINE(SYS5)
 966     AC_DEFINE(SVR4)
 967     ;;
 968   osf*)
 969     AC_DEFINE(SYS5)
 970     AC_DEFINE(SVR4)
 971     ;;
 972   aix*)
 973     AC_DEFINE(SYS5)
 974     AC_DEFINE(SVR4)
 975     ;;
 976   sunos4*)
 977     AC_DEFINE(BSD42)
 978     ;;
 979   freebsd*)
 980     AC_DEFINE(BSD42)
 981     AC_DEFINE(BSD44)
 982     ;;
 983   netbsd*)
 984     AC_DEFINE(BSD42)
 985     AC_DEFINE(BSD44)
 986     ;;
 987   openbsd*)
 988     AC_DEFINE(BSD42)
 989     AC_DEFINE(BSD44)
 990     ;;
 991   bsd/os*)
 992     AC_DEFINE(BSD42)
 993     AC_DEFINE(BSD44)
 994     ;;
 995   sco5*)
 996     AC_DEFINE(SYS5)
 997     AC_DEFINE(SCO_5_STDIO)
 998     ;;
 999 esac
1000
1001
1002 dnl ----------------
1003 dnl OUTPUT MAKEFILES
1004 dnl ----------------
1005 AC_CONFIG_FILES(Makefile config/Makefile h/Makefile sbr/Makefile uip/Makefile \
1006                 mts/Makefile mts/smtp/Makefile \
1007                 etc/Makefile docs/Makefile man/Makefile)
1008 AC_CONFIG_COMMANDS([stamp],[test -z "$CONFIG_HEADERS" || echo > stamp-h])
1009 AC_OUTPUT
1010
1011 dnl These odd looking assignments are done to expand out unexpanded
1012 dnl variables in bindir et al (for instance mandir is '${datarootdir}/man',
1013 dnl but expanding that gives '${prefix}/share/man', so we need to expand
1014 dnl again to get the final answer.
1015 dnl We only use the expanded versions to print the install paths in
1016 dnl the final summary and should use them nowhere else (see the autoconf
1017 dnl docs for the rationale for bindir etc being unexpanded).
1018 eval "nmhbin=${bindir}";         eval "nmhbin=${nmhbin}"
1019 eval "nmhsysconf=${sysconfdir}"; eval "nmhsysconf=${nmhsysconf}"
1020 eval "nmhlib=${libdir}";         eval "nmhlib=${nmhlib}"
1021 eval "nmhman=${mandir}";         eval "nmhman=${nmhman}"
1022
1023 pop_kinds=no
1024 if test x"$enable_pop" = x"yes"; then
1025   pop_kinds="yes ("
1026
1027   if test x"$enable_apop" = x"yes"; then
1028     pop_kinds="${pop_kinds}APOP "
1029   fi
1030
1031   pop_kinds="${pop_kinds}POP3)"
1032 fi
1033
1034 echo "
1035 nmh configuration
1036 -----------------
1037 nmh version                : AC_PACKAGE_VERSION
1038 target os                  : ${target}
1039 compiler                   : ${CC}
1040 compiler flags             : ${CFLAGS}
1041 linker flags               : ${LDFLAGS}
1042 definitions                : ${OURDEFS}
1043 source code location       : ${srcdir}
1044 binary install path        : ${nmhbin}
1045 library install path       : ${nmhlib}
1046 config files install path  : ${nmhsysconf}
1047 man page install path      : ${nmhman}
1048 backup prefix              : ${backup_prefix}
1049 transport system           : ${MTS}
1050 file locking type          : ${LOCKTYPE}
1051 default smtp servers       : ${smtpservers}
1052 default editor             : ${editorpath}
1053 default pager              : ${pagerpath}
1054 email address masquerading : ${masquerade}
1055 pop is enabled             : ${pop_kinds}
1056 SASL support               : ${sasl_support}
1057 TLS support                : ${tls_support}"
1058 echo ""